New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trdtra.F90 in branches/UKMO/dev_r5518_GO6_package_FOAMv14_STOPACK/NEMOGCM/NEMO/OPA_SRC/TRD – NEMO

source: branches/UKMO/dev_r5518_GO6_package_FOAMv14_STOPACK/NEMOGCM/NEMO/OPA_SRC/TRD/trdtra.F90 @ 11404

Last change on this file since 11404 was 11404, checked in by mattmartin, 5 years ago

Included control of the STOPACK options so that it can be switched on/off with the main ln_stopack logical.
File size: 21.3 KB
Line 
1MODULE trdtra
2   !!======================================================================
3   !!                       ***  MODULE  trdtra  ***
4   !! Ocean diagnostics:  ocean tracers trends pre-processing
5   !!=====================================================================
6   !! History :  3.3  !  2010-06  (C. Ethe) creation for the TRA/TRC merge
7   !!            3.5  !  2012-02  (G. Madec) update the comments
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   trd_tra       : pre-process the tracer trends
12   !!   trd_tra_adv   : transform a div(U.T) trend into a U.grad(T) trend
13   !!   trd_tra_mng   : tracer trend manager: dispatch to the diagnostic modules
14   !!   trd_tra_iom   : output 3D tracer trends using IOM
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers variables
17   USE dom_oce        ! ocean domain
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE zdf_oce        ! ocean vertical physics
20   USE trd_oce        ! trends: ocean variables
21   USE trdtrc         ! ocean passive mixed layer tracers trends
22   USE trdglo         ! trends: global domain averaged
23   USE trdpen         ! trends: Potential ENergy
24   USE trdmxl         ! ocean active mixed layer tracers trends
25   USE ldftra_oce     ! ocean active tracers lateral physics
26   USE zdfddm         ! vertical physics: double diffusion
27   USE phycst         ! physical constants
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O manager library
30   USE lib_mpp        ! MPP library
31   USE stopack
32   USE wrk_nemo       ! Memory allocation
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   trd_tra   ! called by all tra_... modules
38
39   REAL(wp) ::   r2dt   ! time-step, = 2 rdttra except at nit000 (=rdttra) if neuler=0
40
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   trdtx, trdty, trdt  ! use to store the temperature trends
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_evd  ! store avt_evd to calculate EVD trend
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   INTEGER FUNCTION trd_tra_alloc()
56      !!---------------------------------------------------------------------
57      !!                  ***  FUNCTION trd_tra_alloc  ***
58      !!---------------------------------------------------------------------
59      ALLOCATE( trdtx(jpi,jpj,jpk) , trdty(jpi,jpj,jpk) , trdt(jpi,jpj,jpk) , avt_evd(jpi,jpj,jpk), STAT= trd_tra_alloc )
60      !
61      IF( lk_mpp             )   CALL mpp_sum ( trd_tra_alloc )
62      IF( trd_tra_alloc /= 0 )   CALL ctl_warn('trd_tra_alloc: failed to allocate arrays')
63   END FUNCTION trd_tra_alloc
64
65
66   SUBROUTINE trd_tra( kt, ctype, ktra, ktrd, ptrd, pun, ptra )
67      !!---------------------------------------------------------------------
68      !!                  ***  ROUTINE trd_tra  ***
69      !!
70      !! ** Purpose : pre-process tracer trends
71      !!
72      !! ** Method  : - mask the trend
73      !!              - advection (ptra present) converte the incoming flux (U.T)
74      !!              into trend (U.T => -U.grat(T)=div(U.T)-T.div(U)) through a
75      !!              call to trd_tra_adv
76      !!              - 'TRA' case : regroup T & S trends
77      !!              - send the trends to trd_tra_mng (trdtrc) for further processing
78      !!----------------------------------------------------------------------
79      INTEGER                         , INTENT(in)           ::   kt      ! time step
80      CHARACTER(len=3)                , INTENT(in)           ::   ctype   ! tracers trends type 'TRA'/'TRC'
81      INTEGER                         , INTENT(in)           ::   ktra    ! tracer index
82      INTEGER                         , INTENT(in)           ::   ktrd    ! tracer trend index
83      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in)           ::   ptrd    ! tracer trend  or flux
84      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pun     ! now velocity
85      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   ptra    ! now tracer variable
86      !
87      INTEGER  ::   jk   ! loop indices
88      REAL(wp), POINTER, DIMENSION(:,:,:)  ::   zwt, zws, ztrdt, ztrds   ! 3D workspace
89      !!----------------------------------------------------------------------
90      !
91      CALL wrk_alloc( jpi, jpj, jpk, ztrds )
92      !     
93      IF( .NOT. ALLOCATED( trdtx ) ) THEN      ! allocate trdtra arrays
94         IF( trd_tra_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trd_tra : unable to allocate arrays' )
95      ENDIF
96
97      IF( ctype == 'TRA' .AND. ktra == jp_tem ) THEN   !==  Temperature trend  ==!
98         !
99         SELECT CASE( ktrd )
100         !                            ! advection: transform the advective flux into a trend
101         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'X', trdtx ) 
102         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Y', trdty ) 
103         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Z', trdt  ) 
104         CASE( jptra_bbc,    &        ! qsr, bbc: on temperature only, send to trd_tra_mng
105            &  jptra_qsr )   ;   trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
106                                 ztrds(:,:,:) = 0._wp
107                                 CALL trd_tra_mng( trdt, ztrds, ktrd, kt )
108         CASE( jptra_evd )   ;   avt_evd(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
109         CASE DEFAULT                 ! other trends: masked trends
110            trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)              ! mask & store
111         END SELECT
112         !
113      ENDIF
114
115      IF( ctype == 'TRA' .AND. ktra == jp_sal ) THEN      !==  Salinity trends  ==!
116         !
117         SELECT CASE( ktrd )
118         !                            ! advection: transform the advective flux into a trend
119         !                            !            and send T & S trends to trd_tra_mng
120         CASE( jptra_xad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'X'  , ztrds ) 
121                                  CALL trd_tra_mng( trdtx, ztrds, ktrd, kt   )
122         CASE( jptra_yad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Y'  , ztrds ) 
123                                  CALL trd_tra_mng( trdty, ztrds, ktrd, kt   )
124         CASE( jptra_zad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Z'  , ztrds ) 
125                                  CALL trd_tra_mng( trdt , ztrds, ktrd, kt   )
126         CASE( jptra_zdfp )           ! diagnose the "PURE" Kz trend (here: just before the swap)
127            !                         ! iso-neutral diffusion case otherwise jptra_zdf is "PURE"
128            CALL wrk_alloc( jpi, jpj, jpk, zwt, zws, ztrdt )
129            !
130            zwt(:,:, 1 ) = 0._wp   ;   zws(:,:, 1 ) = 0._wp            ! vertical diffusive fluxes
131            zwt(:,:,jpk) = 0._wp   ;   zws(:,:,jpk) = 0._wp
132            DO jk = 2, jpk
133               zwt(:,:,jk) = avt(:,:,jk) * ( tsa(:,:,jk-1,jp_tem) - tsa(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
134               zws(:,:,jk) = fsavs(:,:,jk) * ( tsa(:,:,jk-1,jp_sal) - tsa(:,:,jk,jp_sal) ) / fse3w(:,:,jk) * tmask(:,:,jk)
135            END DO
136            !
137            ztrdt(:,:,jpk) = 0._wp   ;   ztrds(:,:,jpk) = 0._wp
138            DO jk = 1, jpkm1
139               ztrdt(:,:,jk) = ( zwt(:,:,jk) - zwt(:,:,jk+1) ) / fse3t(:,:,jk)
140               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk) 
141            END DO
142            CALL trd_tra_mng( ztrdt, ztrds, jptra_zdfp, kt ) 
143            !
144            !                         ! Also calculate EVD trend at this point.
145            zwt(:,:,:) = 0._wp   ;   zws(:,:,:) = 0._wp            ! vertical diffusive fluxes
146            DO jk = 2, jpk
147               zwt(:,:,jk) = avt_evd(:,:,jk) * ( tsa(:,:,jk-1,jp_tem) - tsa(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
148               zws(:,:,jk) = avt_evd(:,:,jk) * ( tsa(:,:,jk-1,jp_sal) - tsa(:,:,jk,jp_sal) ) / fse3w(:,:,jk) * tmask(:,:,jk)
149            END DO
150            !
151            ztrdt(:,:,jpk) = 0._wp   ;   ztrds(:,:,jpk) = 0._wp
152            DO jk = 1, jpkm1
153               ztrdt(:,:,jk) = ( zwt(:,:,jk) - zwt(:,:,jk+1) ) / fse3t(:,:,jk)
154               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk) 
155            END DO
156            CALL trd_tra_mng( ztrdt, ztrds, jptra_evd, kt ) 
157            !
158            CALL wrk_dealloc( jpi, jpj, jpk, zwt, zws, ztrdt )
159            !
160         CASE DEFAULT                 ! other trends: mask and send T & S trends to trd_tra_mng
161            ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
162            CALL trd_tra_mng( trdt, ztrds, ktrd, kt ) 
163         END SELECT
164      ENDIF
165
166      IF( ctype == 'TRC' ) THEN                           !==  passive tracer trend  ==!
167         !
168         SELECT CASE( ktrd )
169         !                            ! advection: transform the advective flux into a masked trend
170         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'X', ztrds ) 
171         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Y', ztrds ) 
172         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Z', ztrds ) 
173         CASE DEFAULT                 ! other trends: just masked
174                                 ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
175         END SELECT
176         !                            ! send trend to trd_trc
177         CALL trd_trc( ztrds, ktra, ktrd, kt ) 
178         !
179      ENDIF
180      !
181      CALL wrk_dealloc( jpi, jpj, jpk, ztrds )
182      !
183   END SUBROUTINE trd_tra
184
185
186   SUBROUTINE trd_tra_adv( pf, pun, ptn, cdir, ptrd )
187      !!---------------------------------------------------------------------
188      !!                  ***  ROUTINE trd_tra_adv  ***
189      !!
190      !! ** Purpose :   transformed a advective flux into a masked advective trends
191      !!
192      !! ** Method  :   use the following transformation: -div(U.T) = - U grad(T) + T.div(U)
193      !!       i-advective trends = -un. di-1[T] = -( di-1[fi] - tn di-1[un] )
194      !!       j-advective trends = -un. di-1[T] = -( dj-1[fi] - tn dj-1[un] )
195      !!       k-advective trends = -un. di+1[T] = -( dk+1[fi] - tn dk+1[un] )
196      !!                where fi is the incoming advective flux.
197      !!----------------------------------------------------------------------
198      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pf      ! advective flux in one direction
199      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pun     ! now velocity   in one direction
200      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   ptn     ! now or before tracer
201      CHARACTER(len=1)                , INTENT(in   ) ::   cdir    ! X/Y/Z direction
202      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   ptrd    ! advective trend in one direction
203      !
204      INTEGER  ::   ji, jj, jk   ! dummy loop indices
205      INTEGER  ::   ii, ij, ik   ! index shift as function of the direction
206      !!----------------------------------------------------------------------
207      !
208      SELECT CASE( cdir )      ! shift depending on the direction
209      CASE( 'X' )   ;   ii = 1   ;   ij = 0   ;   ik = 0      ! i-trend
210      CASE( 'Y' )   ;   ii = 0   ;   ij = 1   ;   ik = 0      ! j-trend
211      CASE( 'Z' )   ;   ii = 0   ;   ij = 0   ;   ik =-1      ! k-trend
212      END SELECT
213      !
214      !                        ! set to zero uncomputed values
215      ptrd(jpi,:,:) = 0._wp   ;   ptrd(1,:,:) = 0._wp
216      ptrd(:,jpj,:) = 0._wp   ;   ptrd(:,1,:) = 0._wp
217      ptrd(:,:,jpk) = 0._wp
218      !
219      DO jk = 1, jpkm1         ! advective trend
220         DO jj = 2, jpjm1
221            DO ji = fs_2, fs_jpim1   ! vector opt.
222               ptrd(ji,jj,jk) = - (     pf (ji,jj,jk) - pf (ji-ii,jj-ij,jk-ik)                        &
223                 &                  - ( pun(ji,jj,jk) - pun(ji-ii,jj-ij,jk-ik) ) * ptn(ji,jj,jk)  )   &
224                 &              / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )  * tmask(ji,jj,jk)
225            END DO
226         END DO
227      END DO
228      !
229   END SUBROUTINE trd_tra_adv
230
231
232   SUBROUTINE trd_tra_mng( ptrdx, ptrdy, ktrd, kt )
233      !!---------------------------------------------------------------------
234      !!                  ***  ROUTINE trd_tra_mng  ***
235      !!
236      !! ** Purpose :   Dispatch all tracer trends computation, e.g. 3D output,
237      !!                integral constraints, potential energy, and/or
238      !!                mixed layer budget.
239      !!----------------------------------------------------------------------
240      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
241      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
242      INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
243      INTEGER                   , INTENT(in   ) ::   kt      ! time step
244      !!----------------------------------------------------------------------
245
246      IF( neuler == 0 .AND. kt == nit000    ) THEN   ;   r2dt =      rdt      ! = rdtra (restart with Euler time stepping)
247      ELSEIF(               kt <= nit000 + 1) THEN   ;   r2dt = 2. * rdt      ! = 2 rdttra (leapfrog)
248      ENDIF
249
250      !                   ! 3D output of tracers trends using IOM interface
251      IF( ln_tra_trd )   CALL trd_tra_iom ( ptrdx, ptrdy, ktrd, kt )
252      IF( ln_tra_trd .AND. ln_stopack .AND. ln_sppt_tra )  &
253         & CALL tra_sppt_collect( ptrdx, ptrdy, ktrd, kt )
254
255      !  Integral Constraints Properties for tracers trends                                       !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
256      IF( ln_glo_trd )   CALL trd_glo( ptrdx, ptrdy, ktrd, 'TRA', kt )
257
258      !                   ! Potential ENergy trends
259      IF( ln_PE_trd  )   CALL trd_pen( ptrdx, ptrdy, ktrd, kt, r2dt )
260
261      !                   ! Mixed layer trends for active tracers
262      IF( ln_tra_mxl )   THEN   
263         !-----------------------------------------------------------------------------------------------
264         ! W.A.R.N.I.N.G :
265         ! jptra_ldf : called by traldf.F90
266         !                 at this stage we store:
267         !                  - the lateral geopotential diffusion (here, lateral = horizontal)
268         !                  - and the iso-neutral diffusion if activated
269         ! jptra_zdf : called by trazdf.F90
270         !                 * in case of iso-neutral diffusion we store the vertical diffusion component in the
271         !                   lateral trend including the K_z contrib, which will be removed later (see trd_mxl)
272         !-----------------------------------------------------------------------------------------------
273
274         SELECT CASE ( ktrd )
275         CASE ( jptra_xad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_xad, '3D' )   ! zonal    advection
276         CASE ( jptra_yad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_yad, '3D' )   ! merid.   advection
277         CASE ( jptra_zad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zad, '3D' )   ! vertical advection
278         CASE ( jptra_ldf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion
279         CASE ( jptra_bbl )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbl, '3D' )   ! bottom boundary layer
280         CASE ( jptra_zdf )
281            IF( ln_traldf_iso ) THEN ; CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion (K_z)
282            ELSE                   ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zdf, '3D' )   ! vertical diffusion (K_z)
283            ENDIF
284         CASE ( jptra_dmp )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_dmp, '3D' )   ! internal 3D restoring (tradmp)
285         CASE ( jptra_qsr )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '3D' )   ! air-sea : penetrative sol radiat
286         CASE ( jptra_nsr )        ;   ptrdx(:,:,2:jpk) = 0._wp   ;   ptrdy(:,:,2:jpk) = 0._wp
287                                       CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '2D' )   ! air-sea : non penetr sol radiation
288         CASE ( jptra_bbc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbc, '3D' )   ! bottom bound cond (geoth flux)
289         CASE ( jptra_npc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_npc, '3D' )   ! non penetr convect adjustment
290         CASE ( jptra_atf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_atf, '3D' )   ! asselin time filter (last trend)
291                                   !
292                                       CALL trd_mxl( kt, r2dt )                             ! trends: Mixed-layer (output)
293         END SELECT
294         !
295      ENDIF
296      !
297   END SUBROUTINE trd_tra_mng
298
299
300   SUBROUTINE trd_tra_iom( ptrdx, ptrdy, ktrd, kt )
301      !!---------------------------------------------------------------------
302      !!                  ***  ROUTINE trd_tra_iom  ***
303      !!
304      !! ** Purpose :   output 3D tracer trends using IOM
305      !!----------------------------------------------------------------------
306     REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
307     REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
308     INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
309     INTEGER                   , INTENT(in   ) ::   kt      ! time step
310     !!
311     INTEGER ::   ji, jj, jk   ! dummy loop indices
312     INTEGER ::   ikbu, ikbv   ! local integers
313     REAL(wp), POINTER, DIMENSION(:,:)   ::   z2dx, z2dy   ! 2D workspace
314     !!----------------------------------------------------------------------
315     !
316     !!gm Rq: mask the trends already masked in trd_tra, but lbc_lnk should probably be added
317     !
318     ! Trends evaluated every time step that could go to the standard T file and can be output every ts into a 1ts file if 1ts output is selected
319     SELECT CASE( ktrd )
320     ! This total trend is done every time step
321     CASE( jptra_tot  )   ;   CALL iom_put( "ttrd_tot" , ptrdx )           ! model total trend
322        CALL iom_put( "strd_tot" , ptrdy )
323     END SELECT
324
325     ! These trends are done every second time step. When 1ts output is selected must go different (2ts) file from standard T-file
326     IF( MOD( kt, 2 ) == 0 ) THEN
327        SELECT CASE( ktrd )
328        CASE( jptra_xad  )   ;   CALL iom_put( "ttrd_xad" , ptrdx )        ! x- horizontal advection
329           CALL iom_put( "strd_xad" , ptrdy )
330        CASE( jptra_yad  )   ;   CALL iom_put( "ttrd_yad" , ptrdx )        ! y- horizontal advection
331           CALL iom_put( "strd_yad" , ptrdy )
332        CASE( jptra_zad  )   ;   CALL iom_put( "ttrd_zad" , ptrdx )        ! z- vertical   advection
333           CALL iom_put( "strd_zad" , ptrdy )
334           IF( .NOT. lk_vvl ) THEN                   ! cst volume : adv flux through z=0 surface
335              CALL wrk_alloc( jpi, jpj, z2dx, z2dy )
336              z2dx(:,:) = wn(:,:,1) * tsn(:,:,1,jp_tem) / fse3t(:,:,1)
337              z2dy(:,:) = wn(:,:,1) * tsn(:,:,1,jp_sal) / fse3t(:,:,1)
338              CALL iom_put( "ttrd_sad", z2dx )
339              CALL iom_put( "strd_sad", z2dy )
340              CALL wrk_dealloc( jpi, jpj, z2dx, z2dy )
341           ENDIF
342        CASE( jptra_totad  ) ;   CALL iom_put( "ttrd_totad" , ptrdx )      ! total   advection
343           CALL iom_put( "strd_totad" , ptrdy )
344        CASE( jptra_ldf  )   ;   CALL iom_put( "ttrd_ldf" , ptrdx )        ! lateral diffusion
345           CALL iom_put( "strd_ldf" , ptrdy )
346        CASE( jptra_zdf  )   ;   CALL iom_put( "ttrd_zdf" , ptrdx )        ! vertical diffusion (including Kz contribution)
347           CALL iom_put( "strd_zdf" , ptrdy )
348        CASE( jptra_zdfp )   ;   CALL iom_put( "ttrd_zdfp", ptrdx )        ! PURE vertical diffusion (no isoneutral contribution)
349           CALL iom_put( "strd_zdfp", ptrdy )
350        CASE( jptra_evd )    ;   CALL iom_put( "ttrd_evd", ptrdx )         ! EVD trend (convection)
351           CALL iom_put( "strd_evd", ptrdy )
352        CASE( jptra_dmp  )   ;   CALL iom_put( "ttrd_dmp" , ptrdx )        ! internal restoring (damping)
353           CALL iom_put( "strd_dmp" , ptrdy )
354        CASE( jptra_bbl  )   ;   CALL iom_put( "ttrd_bbl" , ptrdx )        ! bottom boundary layer
355           CALL iom_put( "strd_bbl" , ptrdy )
356        CASE( jptra_npc  )   ;   CALL iom_put( "ttrd_npc" , ptrdx )        ! static instability mixing
357           CALL iom_put( "strd_npc" , ptrdy )
358        CASE( jptra_bbc  )   ;   CALL iom_put( "ttrd_bbc" , ptrdx )        ! geothermal heating   (only on temperature)
359        CASE( jptra_nsr  )   ;   CALL iom_put( "ttrd_qns" , ptrdx(:,:,1) ) ! surface forcing + runoff (ln_rnf=T)
360           CALL iom_put( "strd_cdt" , ptrdy(:,:,1) )        ! output as 2D surface fields
361        CASE( jptra_qsr  )   ;   CALL iom_put( "ttrd_qsr" , ptrdx )        ! penetrative solar radiat. (only on temperature)
362        END SELECT
363        ! the Asselin filter trend  is also every other time step but needs to be lagged one time step
364        ! Even when 1ts output is selected can go to the same (2ts) file as the trends plotted every even time step.
365     ELSE IF( MOD( kt, 2 ) == 1 ) THEN
366        SELECT CASE( ktrd )
367        CASE( jptra_atf  )   ;   CALL iom_put( "ttrd_atf" , ptrdx )        ! asselin time Filter
368           CALL iom_put( "strd_atf" , ptrdy )
369        END SELECT
370     END IF
371     !
372   END SUBROUTINE trd_tra_iom
373
374   !!======================================================================
375END MODULE trdtra
Note: See TracBrowser for help on using the repository browser.