New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in branches/UKMO/dev_r5518_GO6_package_MEDUSA_extra_CMIP6_diags/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_GO6_package_MEDUSA_extra_CMIP6_diags/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 7083

Last change on this file since 7083 was 7083, checked in by malcolmroberts, 8 years ago

Merged in dev_r5518_GO6_package up to revision 7076
File size: 16.7 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27# endif 
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30   USE diaptr         ! Heat/Salt transport diagnostics
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_adv_eiv   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "ldfeiv_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_adv_eiv  ***
52      !!
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   The eddy induced advection is computed from the slope
57      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
58      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
59      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
60      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
61      !!                               + dj[ aeiv e1v mj(wslpj) ] }
62      !!      add the eiv component to the model velocity:
63      !!         p.n = p.n + z._eiv
64      !!
65      !! ** Action  : - add to p.n the eiv component
66      !!----------------------------------------------------------------------
67      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
68      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
69      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
70      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
73      !!
74      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
75      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
76      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
77# if defined key_diaeiv 
78      REAL(wp) ::   zztmp                      ! local scalar
79# endif 
80      REAL(wp), POINTER, DIMENSION(:,:) :: zu_eiv, zv_eiv, zw_eiv, z2d
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: z3d, z3d_T
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start( 'tra_adv_eiv')
85      !
86# if defined key_diaeiv 
87      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
88      CALL wrk_alloc( jpi, jpj, jpk, z3d, z3d_T )
89# else
90      CALL wrk_alloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
91# endif
92
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
97# if defined key_diaeiv 
98         IF( cdtype == 'TRA') THEN
99            u_eiv(:,:,:) = 0.e0
100            v_eiv(:,:,:) = 0.e0
101            w_eiv(:,:,:) = 0.e0
102         END IF
103# endif
104      ENDIF
105
106      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
107     
108                                                    ! =================
109      DO jk = 1, jpkm1                              !  Horizontal slab
110         !                                          ! =================
111         DO jj = 1, jpjm1
112            DO ji = 1, fs_jpim1   ! vector opt.
113               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
114               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
115               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
116               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
117
118               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
119               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
120   
121               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
122               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
123            END DO
124         END DO
125# if defined key_diaeiv 
126         IF( cdtype == 'TRA') THEN
127            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
128            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
129         END IF
130# endif
131         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
132            DO jj = 2, jpjm1
133               DO ji = fs_2, fs_jpim1   ! vector opt.
134# if defined key_traldf_c2d || defined key_traldf_c3d
135                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
136                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
137                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
138                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
139 
140                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
141# else
142                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
143                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
144                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
145                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
146
147                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
148# endif
149                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
150               END DO
151            END DO
152# if defined key_diaeiv 
153            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
154# endif
155         ENDIF
156         !                                          ! =================
157      END DO                                        !    End of slab 
158      !                                             ! =================
159
160# if defined key_diaeiv 
161      IF( cdtype == 'TRA') THEN
162         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
163         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
164         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
165         IF( iom_use('weiv_masstr') ) THEN   ! vertical mass transport & its square value
166           z2d(:,:) = rau0 * e12t(:,:)
167           DO jk = 1, jpk
168              z3d(:,:,jk) = w_eiv(:,:,jk) * z2d(:,:)
169           END DO
170           CALL iom_put( "weiv_masstr" , z3d ) 
171         ENDIF
172         IF( iom_use("ueiv_masstr") .OR. iom_use("ueiv_heattr") .OR. iom_use('ueiv_heattr3d')        &
173                                    .OR. iom_use("ueiv_salttr") .OR. iom_use('ueiv_salttr3d') ) THEN
174            z3d(:,:,jpk) = 0.e0
175            DO jk = 1, jpkm1
176               z3d(:,:,jk) = rau0 * u_eiv(:,:,jk) * e2u(:,:) * fse3u(:,:,jk) * umask(:,:,jk)
177            END DO
178            CALL iom_put( "ueiv_masstr", z3d )                  ! mass transport in i-direction
179         ENDIF
180
181         IF( iom_use('ueiv_heattr') .OR. iom_use('ueiv_heattr3d') ) THEN
182            zztmp = 0.5 * rcp 
183            z2d(:,:) = 0.e0 
184            z3d_T(:,:,:) = 0.e0 
185            DO jk = 1, jpkm1
186               DO jj = 2, jpjm1
187                  DO ji = fs_2, fs_jpim1   ! vector opt.
188                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_tem) + tsn(ji+1,jj,jk,jp_tem) )
189                     z2d(ji,jj) = z2d(ji,jj) + z3d_T(ji,jj,jk) 
190                  END DO
191               END DO
192            END DO
193            IF (iom_use('ueiv_heattr') ) THEN
194               CALL lbc_lnk( z2d, 'U', -1. )
195               CALL iom_put( "ueiv_heattr", zztmp * z2d )                  ! 2D heat transport in i-direction
196            ENDIF
197            IF (iom_use('ueiv_heattr3d') ) THEN
198               CALL lbc_lnk( z3d_T, 'U', -1. )
199               CALL iom_put( "ueiv_heattr3d", zztmp * z3d_T )              ! 3D heat transport in i-direction
200            ENDIF
201         ENDIF
202
203         IF( iom_use('ueiv_salttr') .OR. iom_use('ueiv_salttr3d') ) THEN
204            zztmp = 0.5 * 0.001
205            z2d(:,:) = 0.e0 
206            z3d_T(:,:,:) = 0.e0 
207            DO jk = 1, jpkm1
208               DO jj = 2, jpjm1
209                  DO ji = fs_2, fs_jpim1   ! vector opt.
210                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_sal) + tsn(ji+1,jj,jk,jp_sal) )
211                     z2d(ji,jj) = z2d(ji,jj) + z3d_T(ji,jj,jk) 
212                  END DO
213               END DO
214            END DO
215            IF (iom_use('ueiv_salttr') ) THEN
216               CALL lbc_lnk( z2d, 'U', -1. )
217               CALL iom_put( "ueiv_salttr", zztmp * z2d )                  ! 2D salt transport in i-direction
218            ENDIF
219            IF (iom_use('ueiv_salttr3d') ) THEN
220               CALL lbc_lnk( z3d_T, 'U', -1. )
221               CALL iom_put( "ueiv_salttr3d", zztmp * z3d_T )              ! 3D salt transport in i-direction
222            ENDIF
223         ENDIF
224
225         IF( iom_use("veiv_masstr") .OR. iom_use("veiv_heattr") .OR. iom_use('veiv_heattr3d')       &
226                                    .OR. iom_use("veiv_salttr") .OR. iom_use('veiv_salttr3d') ) THEN
227            z3d(:,:,jpk) = 0.e0
228            DO jk = 1, jpkm1
229               z3d(:,:,jk) = rau0 * v_eiv(:,:,jk) * e1v(:,:) * fse3v(:,:,jk) * vmask(:,:,jk)
230            END DO
231            CALL iom_put( "veiv_masstr", z3d )                  ! mass transport in j-direction
232         ENDIF
233         IF( iom_use('veiv_heattr') .OR. iom_use('veiv_heattr3d') ) THEN
234            zztmp = 0.5 * rcp 
235            z2d(:,:) = 0.e0 
236            z3d_T(:,:,:) = 0.e0 
237            DO jk = 1, jpkm1
238               DO jj = 2, jpjm1
239                  DO ji = fs_2, fs_jpim1   ! vector opt.
240                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj+1,jk,jp_tem) )
241                     z2d(ji,jj) = z2d(ji,jj) + z3d_T(ji,jj,jk) 
242                  END DO
243               END DO
244            END DO
245            IF (iom_use('veiv_heattr') ) THEN
246               CALL lbc_lnk( z2d, 'V', -1. )
247               CALL iom_put( "veiv_heattr", zztmp * z2d )                  ! 2D heat transport in j-direction
248            ENDIF
249            IF (iom_use('veiv_heattr3d') ) THEN
250               CALL lbc_lnk( z3d_T, 'V', -1. )
251               CALL iom_put( "veiv_heattr3d", zztmp * z3d_T )              ! 3D heat transport in j-direction
252            ENDIF
253         ENDIF
254
255         IF( iom_use('veiv_salttr') .OR. iom_use('veiv_salttr3d') ) THEN
256            zztmp = 0.5 * 0.001
257            z2d(:,:) = 0.e0 
258            z3d_T(:,:,:) = 0.e0 
259            DO jk = 1, jpkm1
260               DO jj = 2, jpjm1
261                  DO ji = fs_2, fs_jpim1   ! vector opt.
262                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_sal) + tsn(ji,jj+1,jk,jp_sal) )
263                     z2d(ji,jj) = z2d(ji,jj) + z3d_T(ji,jj,jk)
264                  END DO
265               END DO
266            END DO
267            IF (iom_use('veiv_salttr') ) THEN
268               CALL lbc_lnk( z2d, 'V', -1. )
269               CALL iom_put( "veiv_salttr", zztmp * z2d )                  ! 2D salt transport in i-direction
270            ENDIF
271            IF (iom_use('veiv_salttr3d') ) THEN
272               CALL lbc_lnk( z3d_T, 'V', -1. )
273               CALL iom_put( "veiv_salttr3d", zztmp * z3d_T )              ! 3D salt transport in i-direction
274            ENDIF
275         ENDIF
276
277         IF( iom_use('weiv_masstr') .OR. iom_use('weiv_heattr3d') .OR. iom_use('weiv_salttr3d')) THEN   ! vertical mass transport & its square value
278           z2d(:,:) = rau0 * e12t(:,:)
279           DO jk = 1, jpk
280              z3d(:,:,jk) = w_eiv(:,:,jk) * z2d(:,:)
281           END DO
282           CALL iom_put( "weiv_masstr" , z3d )                  ! mass transport in k-direction
283         ENDIF
284
285         IF( iom_use('weiv_heattr3d') ) THEN
286            zztmp = 0.5 * rcp 
287            DO jk = 1, jpkm1
288               DO jj = 2, jpjm1
289                  DO ji = fs_2, fs_jpim1   ! vector opt.
290                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj,jk+1,jp_tem) )
291                  END DO
292               END DO
293            END DO
294            CALL lbc_lnk( z3d_T, 'T', 1. )
295            CALL iom_put( "weiv_heattr3d", zztmp * z3d_T )                 ! 3D heat transport in k-direction
296         ENDIF
297
298         IF( iom_use('weiv_salttr3d') ) THEN
299            zztmp = 0.5 * 0.001 
300            DO jk = 1, jpkm1
301               DO jj = 2, jpjm1
302                  DO ji = fs_2, fs_jpim1   ! vector opt.
303                     z3d_T(ji,jj,jk) = z3d(ji,jj,jk) * ( tsn(ji,jj,jk,jp_sal) + tsn(ji,jj,jk+1,jp_sal) )
304                  END DO
305               END DO
306            END DO
307            CALL lbc_lnk( z3d_T, 'T', 1. )
308            CALL iom_put( "weiv_salttr3d", zztmp * z3d_T )                 ! 3D salt transport in k-direction
309         ENDIF
310
311    END IF
312!
313    IF( ln_diaptr .AND. cdtype == 'TRA' ) THEN
314       z3d(:,:,:) = 0._wp
315       DO jk = 1, jpkm1
316          DO jj = 2, jpjm1
317             DO ji = fs_2, fs_jpim1   ! vector opt.
318                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) &
319                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
320             END DO
321          END DO
322       END DO
323       CALL dia_ptr_ohst_components( jp_tem, 'eiv', z3d )
324       z3d(:,:,:) = 0._wp
325       DO jk = 1, jpkm1
326          DO jj = 2, jpjm1
327             DO ji = fs_2, fs_jpim1   ! vector opt.
328                z3d(ji,jj,jk) = v_eiv(ji,jj,jk) * 0.5 * (tsn(ji,jj,jk,jp_sal)+tsn(ji,jj+1,jk,jp_sal)) &
329                &             * e1v(ji,jj) * fse3v(ji,jj,jk)
330             END DO
331          END DO
332       END DO
333       CALL dia_ptr_ohst_components( jp_sal, 'eiv', z3d )
334    ENDIF
335# endif 
336
337# if defined key_diaeiv 
338      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv, z2d )
339      CALL wrk_dealloc( jpi, jpj, jpk, z3d, z3d_T )
340# else
341      CALL wrk_dealloc( jpi, jpj, zu_eiv, zv_eiv, zw_eiv )
342# endif
343      !
344      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv_eiv')
345      !
346    END SUBROUTINE tra_adv_eiv
347
348#else
349   !!----------------------------------------------------------------------
350   !!   Dummy module :             No rotation of the lateral mixing tensor
351   !!----------------------------------------------------------------------
352CONTAINS
353   SUBROUTINE tra_adv_eiv( kt, kit000, pun, pvn, pwn, cdtype )              ! Empty routine
354      INTEGER  ::   kt   
355      INTEGER  ::   kit000   
356      CHARACTER(len=3) ::   cdtype
357      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
358      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', &
359          &  kt, cdtype, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
360   END SUBROUTINE tra_adv_eiv
361#endif
362
363   !!==============================================================================
364END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.