New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in branches/UKMO/dev_r5518_GO6_package_OMP/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_GO6_package_OMP/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 9176

Last change on this file since 9176 was 9176, checked in by andmirek, 6 years ago

#2001: OMP directives
File size: 10.0 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6   !! History :  OPA  ! 1990-09  (G. Madec)  Original code
7   !!            4.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            6.0  ! 1996-01  (G. Madec)  statement function for e3
9   !!            8.0  ! 1997-07  (G. Madec)  lbc calls
10   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2004-08  (C. Talandier) New trends organization
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
16   !!                   using an iso-level bilaplacian operator
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE ldfdyn_oce      ! ocean dynamics: lateral physics
21   !
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE wrk_nemo        ! Memory Allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dyn_ldf_bilap   ! called by step.F90
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "ldfdyn_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE dyn_ldf_bilap( kt )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE dyn_ldf_bilap  ***
46      !!
47      !! ** Purpose :   Compute the before trend of the lateral momentum
48      !!      diffusion and add it to the general trend of momentum equation.
49      !!
50      !! ** Method  :   The before horizontal momentum diffusion trend is a
51      !!      bi-harmonic operator (bilaplacian type) which separates the
52      !!      divergent and rotational parts of the flow.
53      !!      Its horizontal components are computed as follow:
54      !!      laplacian:
55      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
56      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
57      !!      third derivative:
58      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
59      !!          zlu = ahmu * zlu
60      !!          zlv = ahmv * zlv
61      !!       * curl and divergence of the laplacian
62      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
63      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
64      !!      bilaplacian:
65      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
66      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
67      !!      If ln_sco=F and ln_zps=F, the vertical scale factors in the
68      !!      rotational part of the diffusion are simplified
69      !!      Add this before trend to the general trend (ua,va):
70      !!            (ua,va) = (ua,va) + (diffu,diffv)
71      !!
72      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
73      !!               mixing trend.
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      !
77      INTEGER  ::   ji, jj, jk                  ! dummy loop indices
78      REAL(wp) ::   zua, zva, zbt, ze2u, ze2v   ! temporary scalar
79      REAL(wp),      DIMENSION(jpi,jpj  ) :: zcu, zcv
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zuf, zut, zlu, zlv
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_bilap')
84      !
85!     CALL wrk_alloc( jpi, jpj,      zcu, zcv           )
86      CALL wrk_alloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
87      !
88      IF( kt == nit000 .AND. lwp ) THEN
89         WRITE(numout,*)
90         WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
91         WRITE(numout,*) '~~~~~~~~~~~~~'
92      ENDIF
93
94!!bug gm this should be enough
95!!$      zuf(:,:,jpk) = 0.e0
96!!$      zut(:,:,jpk) = 0.e0
97!!$      zlu(:,:,jpk) = 0.e0
98!!$      zlv(:,:,jpk) = 0.e0
99      zuf(:,:,:) = 0._wp
100      zut(:,:,:) = 0._wp
101      zlu(:,:,:) = 0._wp
102      zlv(:,:,:) = 0._wp
103
104         !
105         ! Laplacian
106         ! ---------
107
108         IF( ln_sco .OR. ln_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
109!$OMP PARALLEL DO
110            !                                                ! ===============
111            DO jk = 1, jpkm1                                 ! Horizontal slab
112               !                                             ! ===============
113               ! Laplacian
114               ! ---------
115                  zuf(:,:,jk) = rotb(:,:,jk) * fse3f(:,:,jk)
116                  DO jj = 2, jpjm1
117                     DO ji = fs_2, fs_jpim1   ! vector opt.
118                        zlu(ji,jj,jk) = - ( zuf(ji,jj,jk) - zuf(ji,jj-1,jk) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
119                           &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
120   
121                        zlv(ji,jj,jk) = + ( zuf(ji,jj,jk) - zuf(ji-1,jj,jk) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
122                           &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
123                     END DO
124                  END DO
125            END DO
126         ELSE                            ! z-coordinate - full step
127!$OMP PARALLEL DO
128           !                                                ! ===============
129            DO jk = 1, jpkm1                                 ! Horizontal slab
130               !                                             ! ===============
131               DO jj = 2, jpjm1
132                  DO ji = fs_2, fs_jpim1   ! vector opt.
133                     zlu(ji,jj,jk) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
134                        &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
135   
136                     zlv(ji,jj,jk) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
137                        &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
138                  END DO 
139               END DO 
140            END DO
141         ENDIF
142      CALL lbc_lnk( zlu, 'U', -1. )   ;   CALL lbc_lnk( zlv, 'V', -1. )   ! Boundary conditions
143!$OMP PARALLE DO PRIVATE(zcu, zcv, zbt)
144      DO jk = 1, jpkm1
145   
146         ! Third derivative
147         ! ----------------
148         
149         ! Multiply by the eddy viscosity coef. (at u- and v-points)
150         zlu(:,:,jk) = zlu(:,:,jk) * ( fsahmu(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
151
152         zlv(:,:,jk) = zlv(:,:,jk) * ( fsahmv(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
153         
154         ! Contravariant "laplacian"
155         DO jj = 1, jpj
156            DO ji = 1, jpi
157               zcu(ji,jj) = e1u(ji,jj) * zlu(ji,jj,jk)
158               zcv(ji,jj) = e2v(ji,jj) * zlv(ji,jj,jk)
159            END DO
160         END DO
161         
162         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
163         DO jj = 1, jpjm1
164            DO ji = 1, fs_jpim1   ! vector opt.
165               zuf(ji,jj,jk) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
166                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
167                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
168            END DO 
169         END DO 
170
171         ! Laplacian Horizontal fluxes
172         DO jj = 1, jpjm1
173            DO ji = 1, fs_jpim1   ! vector opt.
174               zlu(ji,jj,jk) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj,jk)
175               zlv(ji,jj,jk) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj,jk)
176            END DO
177         END DO
178
179         ! Laplacian divergence
180         DO jj = 2, jpj
181            DO ji = fs_2, jpi   ! vector opt.
182               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
183               zut(ji,jj,jk) = (  zlu(ji,jj,jk) - zlu(ji-1,jj  ,jk)   &
184                  &             + zlv(ji,jj,jk) - zlv(ji  ,jj-1,jk) ) / zbt
185            END DO
186         END DO
187      END DO
188
189
190      ! boundary conditions on the laplacian curl and div (zuf,zut)
191!!bug gm no need to do this 2 following lbc...
192      CALL lbc_lnk( zuf, 'F', 1. )
193      CALL lbc_lnk( zut, 'T', 1. )
194!OMP PARALLEL DO PRIVATE(ze2u, ze2v, zua, zva)
195      DO jk = 1, jpkm1     
196   
197         ! Bilaplacian
198         ! -----------
199
200         DO jj = 2, jpjm1
201            DO ji = fs_2, fs_jpim1   ! vector opt.
202               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
203               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
204               ! horizontal biharmonic diffusive trends
205               zua = - ( zuf(ji  ,jj,jk) - zuf(ji,jj-1,jk) ) / ze2u   &
206                  &  + ( zut(ji+1,jj,jk) - zut(ji,jj  ,jk) ) / e1u(ji,jj)
207
208               zva = + ( zuf(ji,jj  ,jk) - zuf(ji-1,jj,jk) ) / ze2v   &
209                  &  + ( zut(ji,jj+1,jk) - zut(ji  ,jj,jk) ) / e2v(ji,jj)
210               ! add it to the general momentum trends
211               ua(ji,jj,jk) = ua(ji,jj,jk) + zua * ( fsahmu(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
212               va(ji,jj,jk) = va(ji,jj,jk) + zva * ( fsahmv(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
213            END DO
214         END DO
215
216         !                                             ! ===============
217      END DO                                           !   End of slab
218      !                                                ! ===============
219!     CALL wrk_dealloc( jpi, jpj,      zcu, zcv           )
220      CALL wrk_dealloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
221      !
222      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_bilap')
223      !
224   END SUBROUTINE dyn_ldf_bilap
225
226   !!======================================================================
227END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.