New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tranxt.F90 in branches/UKMO/dev_r5518_GO6_package_OMP/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_GO6_package_OMP/NEMOGCM/NEMO/OPA_SRC/TRA/tranxt.F90 @ 9176

Last change on this file since 9176 was 9176, checked in by andmirek, 6 years ago

#2001: OMP directives
File size: 19.4 KB
Line 
1MODULE tranxt
2   !!======================================================================
3   !!                       ***  MODULE  tranxt  ***
4   !! Ocean active tracers:  time stepping on temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   tra_nxt       : time stepping on tracers
23   !!   tra_nxt_fix   : time stepping on tracers : fixed    volume case
24   !!   tra_nxt_vvl   : time stepping on tracers : variable volume case
25   !!----------------------------------------------------------------------
26   USE oce             ! ocean dynamics and tracers variables
27   USE dom_oce         ! ocean space and time domain variables
28   USE sbc_oce         ! surface boundary condition: ocean
29   USE sbcrnf          ! river runoffs
30   USE sbcisf          ! ice shelf melting/freezing
31   USE zdf_oce         ! ocean vertical mixing
32   USE domvvl          ! variable volume
33   USE dynspg_oce      ! surface     pressure gradient variables
34   USE dynhpg          ! hydrostatic pressure gradient
35   USE trd_oce         ! trends: ocean variables
36   USE trdtra          ! trends manager: tracers
37   USE traqsr          ! penetrative solar radiation (needed for nksr)
38   USE phycst          ! physical constant
39   USE ldftra_oce      ! lateral physics on tracers
40   USE bdy_oce         ! BDY open boundary condition variables
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE wrk_nemo        ! Memory allocation
47   USE timing          ! Timing
48#if defined key_agrif
49   USE agrif_opa_interp
50#endif
51
52   IMPLICIT NONE
53   PRIVATE
54
55   PUBLIC   tra_nxt       ! routine called by step.F90
56   PUBLIC   tra_nxt_fix   ! to be used in trcnxt
57   PUBLIC   tra_nxt_vvl   ! to be used in trcnxt
58
59   REAL(wp) ::   rbcp   ! Brown & Campana parameters for semi-implicit hpg
60
61   !! * Substitutions
62#  include "domzgr_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO-Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_nxt( kt )
71      !!----------------------------------------------------------------------
72      !!                   ***  ROUTINE tranxt  ***
73      !!
74      !! ** Purpose :   Apply the boundary condition on the after temperature 
75      !!             and salinity fields, achieved the time stepping by adding
76      !!             the Asselin filter on now fields and swapping the fields.
77      !!
78      !! ** Method  :   At this stage of the computation, ta and sa are the
79      !!             after temperature and salinity as the time stepping has
80      !!             been performed in trazdf_imp or trazdf_exp module.
81      !!
82      !!              - Apply lateral boundary conditions on (ta,sa)
83      !!             at the local domain   boundaries through lbc_lnk call,
84      !!             at the one-way open boundaries (lk_bdy=T),
85      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
86      !!
87      !!              - Update lateral boundary conditions on AGRIF children
88      !!             domains (lk_agrif=T)
89      !!
90      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
91      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
94      !!
95      INTEGER  ::   jk, jn    ! dummy loop indices
96      REAL(wp) ::   zfact     ! local scalars
97      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start( 'tra_nxt')
101      !
102      IF( kt == nit000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'tra_nxt : achieve the time stepping by Asselin filter and array swap'
105         IF(lwp) WRITE(numout,*) '~~~~~~~'
106         !
107         rbcp = 0.25_wp * (1._wp + atfp) * (1._wp + atfp) * ( 1._wp - atfp)      ! Brown & Campana parameter for semi-implicit hpg
108      ENDIF
109
110      ! Update after tracer on domain lateral boundaries
111      !
112#if defined key_agrif
113      CALL Agrif_tra                     ! AGRIF zoom boundaries
114#endif
115      !
116      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1._wp )      ! local domain boundaries  (T-point, unchanged sign)
117      CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1._wp )
118      !
119#if defined key_bdy 
120      IF( lk_bdy )   CALL bdy_tra( kt )  ! BDY open boundaries
121#endif
122 
123      ! set time step size (Euler/Leapfrog)
124      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dtra(:) =     rdttra(:)      ! at nit000             (Euler)
125      ELSEIF( kt <= nit000 + 1 )           THEN   ;   r2dtra(:) = 2._wp* rdttra(:)      ! at nit000 or nit000+1 (Leapfrog)
126      ENDIF
127
128      ! trends computation initialisation
129      IF( l_trdtra )   THEN                    ! store now fields before applying the Asselin filter
130         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
131         ztrdt(:,:,:) = tsn(:,:,:,jp_tem) 
132         ztrds(:,:,:) = tsn(:,:,:,jp_sal)
133         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
134            CALL trd_tra( kt, 'TRA', jp_tem, jptra_zdfp, ztrdt )
135            CALL trd_tra( kt, 'TRA', jp_sal, jptra_zdfp, ztrds )
136         ENDIF
137      ENDIF
138
139      IF( neuler == 0 .AND. kt == nit000 ) THEN       ! Euler time-stepping at first time-step (only swap)
140         DO jn = 1, jpts
141            DO jk = 1, jpkm1
142               tsn(:,:,jk,jn) = tsa(:,:,jk,jn)   
143            END DO
144         END DO
145      ELSE                                            ! Leap-Frog + Asselin filter time stepping
146         !
147         IF( lk_vvl )  THEN   ;   CALL tra_nxt_vvl( kt, nit000, rdttra, 'TRA', tsb, tsn, tsa,   &
148           &                                                              sbc_tsc, sbc_tsc_b, jpts )  ! variable volume level (vvl)
149         ELSE                 ;   CALL tra_nxt_fix( kt, nit000,         'TRA', tsb, tsn, tsa, jpts )  ! fixed    volume level
150         ENDIF
151      ENDIF     
152      !
153     ! trends computation
154      IF( l_trdtra ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt     
155!$OMP PARALLEL DO PRIVATE(zfact)
156         DO jk = 1, jpkm1
157            zfact = 1._wp / r2dtra(jk)             
158            ztrdt(:,:,jk) = ( tsb(:,:,jk,jp_tem) - ztrdt(:,:,jk) ) * zfact
159            ztrds(:,:,jk) = ( tsb(:,:,jk,jp_sal) - ztrds(:,:,jk) ) * zfact
160         END DO
161         CALL trd_tra( kt, 'TRA', jp_tem, jptra_atf, ztrdt )
162         CALL trd_tra( kt, 'TRA', jp_sal, jptra_atf, ztrds )
163         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
164      END IF
165      !
166      !                        ! control print
167      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
168         &                       tab3d_2=tsn(:,:,:,jp_sal), clinfo2=       ' Sn: ', mask2=tmask )
169      !
170      IF( nn_timing == 1 )   CALL timing_stop('tra_nxt')
171      !
172   END SUBROUTINE tra_nxt
173
174
175   SUBROUTINE tra_nxt_fix( kt, kit000, cdtype, ptb, ptn, pta, kjpt )
176      !!----------------------------------------------------------------------
177      !!                   ***  ROUTINE tra_nxt_fix  ***
178      !!
179      !! ** Purpose :   fixed volume: apply the Asselin time filter and
180      !!                swap the tracer fields.
181      !!
182      !! ** Method  : - Apply a Asselin time filter on now fields.
183      !!              - save in (ta,sa) an average over the three time levels
184      !!             which will be used to compute rdn and thus the semi-implicit
185      !!             hydrostatic pressure gradient (ln_dynhpg_imp = T)
186      !!              - swap tracer fields to prepare the next time_step.
187      !!                This can be summurized for tempearture as:
188      !!             ztm = tn + rbcp * [ta -2 tn + tb ]       ln_dynhpg_imp = T
189      !!             ztm = 0                                   otherwise
190      !!                   with rbcp=1/4 * (1-atfp^4) / (1-atfp)
191      !!             tb  = tn + atfp*[ tb - 2 tn + ta ]
192      !!             tn  = ta 
193      !!             ta  = ztm       (NB: reset to 0 after eos_bn2 call)
194      !!
195      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
196      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
197      !!----------------------------------------------------------------------
198      INTEGER         , INTENT(in   )                               ::   kt       ! ocean time-step index
199      INTEGER         , INTENT(in   )                               ::   kit000   ! first time step index
200      CHARACTER(len=3), INTENT(in   )                               ::   cdtype   ! =TRA or TRC (tracer indicator)
201      INTEGER         , INTENT(in   )                               ::   kjpt     ! number of tracers
202      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptb      ! before tracer fields
203      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptn      ! now tracer fields
204      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   pta      ! tracer trend
205      !
206      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
207      LOGICAL  ::   ll_tra_hpg       ! local logical
208      REAL(wp) ::   ztn, ztd         ! local scalars
209      !!----------------------------------------------------------------------
210
211      IF( kt == kit000 )  THEN
212         IF(lwp) WRITE(numout,*)
213         IF(lwp) WRITE(numout,*) 'tra_nxt_fix : time stepping', cdtype
214         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
215      ENDIF
216      !
217      IF( cdtype == 'TRA' )  THEN   ;   ll_tra_hpg = ln_dynhpg_imp    ! active  tracers case  and  semi-implicit hpg   
218      ELSE                          ;   ll_tra_hpg = .FALSE.          ! passive tracers case or NO semi-implicit hpg
219      ENDIF
220      !
221      DO jn = 1, kjpt
222         !
223         DO jk = 1, jpkm1
224            DO jj = 1, jpj
225               DO ji = 1, jpi
226                  ztn = ptn(ji,jj,jk,jn)                                   
227                  ztd = pta(ji,jj,jk,jn) - 2. * ztn + ptb(ji,jj,jk,jn)      !  time laplacian on tracers
228                  !
229                  ptb(ji,jj,jk,jn) = ztn + atfp * ztd                       ! ptb <-- filtered ptn
230                  ptn(ji,jj,jk,jn) = pta(ji,jj,jk,jn)                       ! ptn <-- pta
231                  !
232                  IF( ll_tra_hpg )   pta(ji,jj,jk,jn) = ztn + rbcp * ztd    ! pta <-- Brown & Campana average
233               END DO
234           END DO
235         END DO
236         !
237      END DO
238      !
239   END SUBROUTINE tra_nxt_fix
240
241
242   SUBROUTINE tra_nxt_vvl( kt, kit000, p2dt, cdtype, ptb, ptn, pta, psbc_tc, psbc_tc_b, kjpt )
243      !!----------------------------------------------------------------------
244      !!                   ***  ROUTINE tra_nxt_vvl  ***
245      !!
246      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
247      !!                and swap the tracer fields.
248      !!
249      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
250      !!              - save in (ta,sa) a thickness weighted average over the three
251      !!             time levels which will be used to compute rdn and thus the semi-
252      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
253      !!              - swap tracer fields to prepare the next time_step.
254      !!                This can be summurized for tempearture as:
255      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
256      !!                  /( e3t_n    + rbcp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )   
257      !!             ztm = 0                                                       otherwise
258      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
259      !!                  /( e3t_n    + atfp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )
260      !!             tn  = ta
261      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
262      !!
263      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
264      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
265      !!----------------------------------------------------------------------
266      INTEGER         , INTENT(in   )                               ::  kt       ! ocean time-step index
267      INTEGER         , INTENT(in   )                               ::  kit000   ! first time step index
268      REAL(wp)        , INTENT(in   ), DIMENSION(jpk)               ::  p2dt     ! time-step
269      CHARACTER(len=3), INTENT(in   )                               ::  cdtype   ! =TRA or TRC (tracer indicator)
270      INTEGER         , INTENT(in   )                               ::  kjpt     ! number of tracers
271      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::  ptb      ! before tracer fields
272      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::  ptn      ! now tracer fields
273      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::  pta      ! tracer trend
274      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt)      ::  psbc_tc   ! surface tracer content
275      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt)      ::  psbc_tc_b ! before surface tracer content
276
277      !!     
278      LOGICAL  ::   ll_tra_hpg, ll_traqsr, ll_rnf, ll_isf   ! local logical
279      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
280      REAL(wp) ::   zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
281      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
282      !!----------------------------------------------------------------------
283      !
284      IF( kt == kit000 )  THEN
285         IF(lwp) WRITE(numout,*)
286         IF(lwp) WRITE(numout,*) 'tra_nxt_vvl : time stepping', cdtype
287         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
288      ENDIF
289      !
290      IF( cdtype == 'TRA' )  THEN   
291         ll_tra_hpg = ln_dynhpg_imp    ! active  tracers case  and  semi-implicit hpg
292         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
293         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
294         IF (nn_isf .GE. 1) THEN
295            ll_isf = .TRUE.            ! active  tracers case  and  ice shelf melting/freezing
296         ELSE
297            ll_isf = .FALSE.
298         END IF
299      ELSE                         
300         ll_tra_hpg = .FALSE.          ! passive tracers case or NO semi-implicit hpg
301         ll_traqsr  = .FALSE.          ! active  tracers case and NO solar penetration
302         ll_rnf     = .FALSE.          ! passive tracers or NO river runoffs
303         ll_isf     = .FALSE.          ! passive tracers or NO ice shelf melting/freezing
304      ENDIF
305      !
306      DO jn = 1, kjpt     
307!$OMP PARALLEL DO PRIVATE(zfact1, zfact2, ze3t_b, ze3t_n, ze3t_a, ztc_b, ztc_n, ztc_a, ze3t_d, ztc_d, &
308!$OMP&                    ze3t_f, ztc_f, ze3t_d)
309         DO jk = 1, jpkm1
310            zfact1 = atfp * p2dt(jk)
311            zfact2 = zfact1 / rau0
312            DO jj = 1, jpj
313               DO ji = 1, jpi
314                  ze3t_b = fse3t_b(ji,jj,jk)
315                  ze3t_n = fse3t_n(ji,jj,jk)
316                  ze3t_a = fse3t_a(ji,jj,jk)
317                  !                                         ! tracer content at Before, now and after
318                  ztc_b  = ptb(ji,jj,jk,jn) * ze3t_b
319                  ztc_n  = ptn(ji,jj,jk,jn) * ze3t_n
320                  ztc_a  = pta(ji,jj,jk,jn) * ze3t_a
321                  !
322                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
323                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
324                  !
325                  ze3t_f = ze3t_n + atfp * ze3t_d
326                  ztc_f  = ztc_n  + atfp * ztc_d
327                  !
328                  IF( jk == mikt(ji,jj) ) THEN           ! first level
329                     ze3t_f = ze3t_f - zfact2 * ( (emp_b(ji,jj)    - emp(ji,jj)   )  &
330                            &                   - (rnf_b(ji,jj)    - rnf(ji,jj)   )  &
331                            &                   + (fwfisf_b(ji,jj) - fwfisf(ji,jj))  )
332                     ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
333                  ENDIF
334
335                  ! solar penetration (temperature only)
336                  IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            & 
337                     &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) ) 
338
339                  ! river runoff
340                  IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
341                     &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) & 
342                     &                              * fse3t_n(ji,jj,jk) / h_rnf(ji,jj)
343
344                  ! ice shelf
345                  IF( ll_isf ) THEN
346                     ! level fully include in the Losch_2008 ice shelf boundary layer
347                     IF ( jk >= misfkt(ji,jj) .AND. jk < misfkb(ji,jj) )                          &
348                        ztc_f  = ztc_f  - zfact1 * ( risf_tsc(ji,jj,jn) - risf_tsc_b(ji,jj,jn) )  &
349                               &                 * fse3t_n(ji,jj,jk) * r1_hisf_tbl (ji,jj)
350                     ! level partially include in Losch_2008 ice shelf boundary layer
351                     IF ( jk == misfkb(ji,jj) )                                                   &
352                        ztc_f  = ztc_f  - zfact1 * ( risf_tsc(ji,jj,jn) - risf_tsc_b(ji,jj,jn) )  &
353                               &                 * fse3t_n(ji,jj,jk) * r1_hisf_tbl (ji,jj) * ralpha(ji,jj)
354                  END IF
355
356                  ze3t_f = 1.e0 / ze3t_f
357                  ptb(ji,jj,jk,jn) = ztc_f * ze3t_f       ! ptb <-- ptn filtered
358                  ptn(ji,jj,jk,jn) = pta(ji,jj,jk,jn)     ! ptn <-- pta
359                  !
360                  IF( ll_tra_hpg ) THEN        ! semi-implicit hpg (T & S only)
361                     ze3t_d           = 1.e0   / ( ze3t_n + rbcp * ze3t_d )
362                     pta(ji,jj,jk,jn) = ze3t_d * ( ztc_n  + rbcp * ztc_d  )   ! ta <-- Brown & Campana average
363                  ENDIF
364               END DO
365            END DO
366         END DO
367         !
368      END DO
369      !
370   END SUBROUTINE tra_nxt_vvl
371
372   !!======================================================================
373END MODULE tranxt
Note: See TracBrowser for help on using the repository browser.