| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.4 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !! 3.6 ! 2015-12 (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 18 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and active tracers |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 23 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 24 | USE trd_oce ! trends: ocean variables |
|---|
| 25 | USE trdtra ! trends manager: tracers |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | USE iom ! I/O manager |
|---|
| 30 | USE fldread ! read input fields |
|---|
| 31 | USE restart ! ocean restart |
|---|
| 32 | USE lib_mpp ! MPP library |
|---|
| 33 | USE wrk_nemo ! Memory Allocation |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 40 | PUBLIC tra_qsr_init ! routine called by nemogcm.F90 |
|---|
| 41 | |
|---|
| 42 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 43 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 44 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 45 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 48 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 49 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 50 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 52 | |
|---|
| 53 | ! Module variables |
|---|
| 54 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 55 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 56 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 57 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 58 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "domzgr_substitute.h90" |
|---|
| 62 | # include "vectopt_loop_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE tra_qsr( kt ) |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE tra_qsr *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 75 | !! penetration and add it to the general temperature trend. |
|---|
| 76 | !! |
|---|
| 77 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 78 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 79 | !! Considering the 2 wavebands case: |
|---|
| 80 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 81 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 82 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 83 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 84 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 85 | !! in the last ocean level. |
|---|
| 86 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 87 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 88 | !! used for the computation are calculated one for once as they |
|---|
| 89 | !! depends on k only. |
|---|
| 90 | !! |
|---|
| 91 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 92 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 93 | !! |
|---|
| 94 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 95 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 96 | !! Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562 |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | ! |
|---|
| 99 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 100 | ! |
|---|
| 101 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 102 | INTEGER :: irgb ! local integers |
|---|
| 103 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 104 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 105 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 106 | REAL(wp) :: zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze |
|---|
| 107 | REAL(wp) :: zlogc, zlogc2, zlogc3 |
|---|
| 108 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 109 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d |
|---|
| 110 | !!-------------------------------------------------------------------------- |
|---|
| 111 | ! |
|---|
| 112 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 113 | ! |
|---|
| 114 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 115 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 116 | ! |
|---|
| 117 | IF( kt == nit000 ) THEN |
|---|
| 118 | IF(lwp) WRITE(numout,*) |
|---|
| 119 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 120 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 121 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 122 | ENDIF |
|---|
| 123 | |
|---|
| 124 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 125 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 126 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 127 | ENDIF |
|---|
| 128 | |
|---|
| 129 | ! Set before qsr tracer content field |
|---|
| 130 | ! *********************************** |
|---|
| 131 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 132 | ! ! ----------------------------------- |
|---|
| 133 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 134 | ! |
|---|
| 135 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 136 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 137 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 138 | zfact = 0.5e0 |
|---|
| 139 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 140 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 141 | zfact = 1.e0 |
|---|
| 142 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 143 | ENDIF |
|---|
| 144 | ELSE ! Swap of forcing field |
|---|
| 145 | ! ! --------------------- |
|---|
| 146 | zfact = 0.5e0 |
|---|
| 147 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 148 | ENDIF |
|---|
| 149 | ! Compute now qsr tracer content field |
|---|
| 150 | ! ************************************ |
|---|
| 151 | |
|---|
| 152 | ! ! ============================================== ! |
|---|
| 153 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 154 | ! ! ============================================== ! |
|---|
| 155 | !$OMP PARALLEL DO |
|---|
| 156 | DO jk = 1, jpkm1 |
|---|
| 157 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 158 | END DO |
|---|
| 159 | ! Add to the general trend |
|---|
| 160 | !$OMP PARALLEL DO PRIVATE (z1_e3t) |
|---|
| 161 | DO jk = 1, jpkm1 |
|---|
| 162 | DO jj = 2, jpjm1 |
|---|
| 163 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 164 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 165 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 166 | END DO |
|---|
| 167 | END DO |
|---|
| 168 | END DO |
|---|
| 169 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 170 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 171 | IF ( ln_qsr_ice ) THEN |
|---|
| 172 | DO jj = 1, jpj |
|---|
| 173 | DO ji = 1, jpi |
|---|
| 174 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 175 | fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 176 | ELSE |
|---|
| 177 | fraqsr_1lev(ji,jj) = 1. |
|---|
| 178 | ENDIF |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | ENDIF |
|---|
| 182 | ! ! ============================================== ! |
|---|
| 183 | ELSE ! Ocean alone : |
|---|
| 184 | ! ! ============================================== ! |
|---|
| 185 | ! |
|---|
| 186 | ! ! ------------------------- ! |
|---|
| 187 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 188 | ! ! ------------------------- ! |
|---|
| 189 | ! Set chlorophyl concentration |
|---|
| 190 | IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 191 | ! |
|---|
| 192 | IF( nn_chldta == 1 ) THEN !* 2D Variable Chlorophyll |
|---|
| 193 | ! |
|---|
| 194 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 195 | DO jk = 1, nksr + 1 |
|---|
| 196 | zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1) |
|---|
| 197 | ENDDO |
|---|
| 198 | ! |
|---|
| 199 | ELSE IF( nn_chldta == 2 ) THEN !* -3-D Variable Chlorophyll |
|---|
| 200 | ! |
|---|
| 201 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 202 | !$OMP PARALLEL DO PRIVATE(zchl, zCtot, zze, zlogc, zlogc2, zlogc3, zCb, zCmax, & |
|---|
| 203 | !$OMP& zpsimax, zdelpsi, zCze, zpsi, jk) SHARED (nksr) |
|---|
| 204 | DO jj = 1, jpj |
|---|
| 205 | DO ji = 1, jpi |
|---|
| 206 | zchl = sf_chl(1)%fnow(ji,jj,1) |
|---|
| 207 | zCtot = 40.6 * zchl**0.459 |
|---|
| 208 | zze = 568.2 * zCtot**(-0.746) |
|---|
| 209 | IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293) |
|---|
| 210 | zlogc = LOG( zchl ) |
|---|
| 211 | zlogc2 = zlogc * zlogc |
|---|
| 212 | zlogc3 = zlogc * zlogc * zlogc |
|---|
| 213 | zCb = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3 |
|---|
| 214 | zCmax = 0.299 - 0.289 * zlogc + 0.579 * zlogc2 |
|---|
| 215 | zpsimax = 0.6 - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3 |
|---|
| 216 | zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2 |
|---|
| 217 | zCze = 1.12 * (zchl)**0.803 |
|---|
| 218 | DO jk = 1, nksr + 1 |
|---|
| 219 | zpsi = fsdept(ji,jj,jk) / zze |
|---|
| 220 | zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) ) |
|---|
| 221 | END DO |
|---|
| 222 | ! |
|---|
| 223 | END DO |
|---|
| 224 | END DO |
|---|
| 225 | ! |
|---|
| 226 | ELSE !* Variable ocean volume but constant chrlorophyll |
|---|
| 227 | DO jk = 1, nksr + 1 |
|---|
| 228 | zchl3d(:,:,jk) = 0.05 |
|---|
| 229 | ENDDO |
|---|
| 230 | ENDIF |
|---|
| 231 | ! |
|---|
| 232 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 233 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 234 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 235 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 236 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 237 | zea(:,:,1) = qsr(:,:) |
|---|
| 238 | ! |
|---|
| 239 | DO jk = 2, nksr+1 |
|---|
| 240 | ! |
|---|
| 241 | DO jj = 1, jpj ! Separation in R-G-B depending of vertical profile of Chl |
|---|
| 242 | !CDIR NOVERRCHK |
|---|
| 243 | DO ji = 1, jpi |
|---|
| 244 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) ) |
|---|
| 245 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 246 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 247 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 248 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 249 | END DO |
|---|
| 250 | END DO |
|---|
| 251 | !CDIR NOVERRCHK |
|---|
| 252 | DO jj = 1, jpj |
|---|
| 253 | !CDIR NOVERRCHK |
|---|
| 254 | DO ji = 1, jpi |
|---|
| 255 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 256 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 257 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 258 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 259 | ze0(ji,jj,jk) = zc0 |
|---|
| 260 | ze1(ji,jj,jk) = zc1 |
|---|
| 261 | ze2(ji,jj,jk) = zc2 |
|---|
| 262 | ze3(ji,jj,jk) = zc3 |
|---|
| 263 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 264 | END DO |
|---|
| 265 | END DO |
|---|
| 266 | END DO |
|---|
| 267 | ! |
|---|
| 268 | !$OMP PARALLEL DO |
|---|
| 269 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 270 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 271 | END DO |
|---|
| 272 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 273 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 274 | ! |
|---|
| 275 | IF ( ln_qsr_ice ) THEN ! store attenuation coefficient of the first ocean level |
|---|
| 276 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 277 | DO ji = 1, jpi |
|---|
| 278 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) ) |
|---|
| 279 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 280 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 281 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 282 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 283 | END DO |
|---|
| 284 | END DO |
|---|
| 285 | ! |
|---|
| 286 | !$OMP PARALLEL DO PRIVATE(zc0, zc1, zc2, zc3) |
|---|
| 287 | DO jj = 1, jpj |
|---|
| 288 | DO ji = 1, jpi |
|---|
| 289 | zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 290 | zc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 291 | zc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 292 | zc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 293 | fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,2) |
|---|
| 294 | END DO |
|---|
| 295 | END DO |
|---|
| 296 | ! |
|---|
| 297 | ENDIF |
|---|
| 298 | ! |
|---|
| 299 | ELSE !* Constant Chlorophyll |
|---|
| 300 | DO jk = 1, nksr |
|---|
| 301 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 302 | END DO |
|---|
| 303 | ! store attenuation coefficient of the first ocean level |
|---|
| 304 | IF( ln_qsr_ice ) THEN |
|---|
| 305 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 306 | ENDIF |
|---|
| 307 | ENDIF |
|---|
| 308 | |
|---|
| 309 | ENDIF |
|---|
| 310 | ! ! ------------------------- ! |
|---|
| 311 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 312 | ! ! ------------------------- ! |
|---|
| 313 | ! |
|---|
| 314 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 315 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 316 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 317 | !$OMP PARALLEL DO PRIVATE (zc0, zc1) |
|---|
| 318 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 319 | DO jj = 1, jpj |
|---|
| 320 | DO ji = 1, jpi |
|---|
| 321 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 322 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 323 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 324 | END DO |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 328 | IF ( ln_qsr_ice ) THEN |
|---|
| 329 | !$OMP PARALLEL DO PRIVATE (zc0, zc1) |
|---|
| 330 | DO jj = 1, jpj |
|---|
| 331 | DO ji = 1, jpi |
|---|
| 332 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 333 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 334 | fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 335 | END DO |
|---|
| 336 | END DO |
|---|
| 337 | ENDIF |
|---|
| 338 | ELSE !* constant volume: coef. computed one for all |
|---|
| 339 | !$OMP PARALLEL DO |
|---|
| 340 | DO jk = 1, nksr |
|---|
| 341 | DO jj = 2, jpjm1 |
|---|
| 342 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 343 | ! (ISF) no light penetration below the ice shelves |
|---|
| 344 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1) |
|---|
| 345 | END DO |
|---|
| 346 | END DO |
|---|
| 347 | END DO |
|---|
| 348 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 349 | IF ( ln_qsr_ice ) THEN |
|---|
| 350 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 351 | ENDIF |
|---|
| 352 | ! |
|---|
| 353 | ENDIF |
|---|
| 354 | ! |
|---|
| 355 | ENDIF |
|---|
| 356 | ! |
|---|
| 357 | ! Add to the general trend |
|---|
| 358 | !$OMP PARALLEL DO PRIVATE (z1_e3t) |
|---|
| 359 | DO jk = 1, nksr |
|---|
| 360 | DO jj = 2, jpjm1 |
|---|
| 361 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 362 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 363 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 364 | END DO |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | ! |
|---|
| 368 | ENDIF |
|---|
| 369 | ! |
|---|
| 370 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 371 | ! ******************************* |
|---|
| 372 | IF(lwp) WRITE(numout,*) |
|---|
| 373 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 374 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 375 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 376 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b' , qsr_hc ) |
|---|
| 377 | CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev ) ! default definition in sbcssm |
|---|
| 378 | ! |
|---|
| 379 | ENDIF |
|---|
| 380 | |
|---|
| 381 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 382 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 383 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt ) |
|---|
| 384 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 385 | ENDIF |
|---|
| 386 | ! ! print mean trends (used for debugging) |
|---|
| 387 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 388 | ! |
|---|
| 389 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 390 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 391 | ! |
|---|
| 392 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 393 | ! |
|---|
| 394 | END SUBROUTINE tra_qsr |
|---|
| 395 | |
|---|
| 396 | |
|---|
| 397 | SUBROUTINE tra_qsr_init |
|---|
| 398 | !!---------------------------------------------------------------------- |
|---|
| 399 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 400 | !! |
|---|
| 401 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 402 | !! |
|---|
| 403 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 404 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 405 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 406 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 407 | !! (1968) classification. |
|---|
| 408 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 409 | !! |
|---|
| 410 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 411 | !! |
|---|
| 412 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | ! |
|---|
| 415 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 416 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 417 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 418 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 419 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 420 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 421 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 422 | ! |
|---|
| 423 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 424 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 425 | !! |
|---|
| 426 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 427 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 428 | !!---------------------------------------------------------------------- |
|---|
| 429 | |
|---|
| 430 | ! |
|---|
| 431 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 432 | ! |
|---|
| 433 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 434 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 435 | ! |
|---|
| 436 | |
|---|
| 437 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 438 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 439 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 440 | |
|---|
| 441 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 442 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 443 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 444 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 445 | ! |
|---|
| 446 | IF(lwp) THEN ! control print |
|---|
| 447 | WRITE(numout,*) |
|---|
| 448 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 449 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 450 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 451 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 452 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 453 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 454 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 455 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 456 | WRITE(numout,*) ' RGB : Chl data (=1/2) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 457 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 458 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 459 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 460 | ENDIF |
|---|
| 461 | |
|---|
| 462 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 463 | ! |
|---|
| 464 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 465 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 466 | ln_qsr_bio = .FALSE. |
|---|
| 467 | ENDIF |
|---|
| 468 | ! |
|---|
| 469 | ioptio = 0 ! Parameter control |
|---|
| 470 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 471 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 472 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 473 | ! |
|---|
| 474 | IF( ioptio /= 1 ) & |
|---|
| 475 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 476 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 477 | ! |
|---|
| 478 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 479 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 480 | IF( ln_qsr_rgb .AND. nn_chldta == 2 ) nqsr = 3 |
|---|
| 481 | IF( ln_qsr_2bd ) nqsr = 4 |
|---|
| 482 | IF( ln_qsr_bio ) nqsr = 5 |
|---|
| 483 | ! |
|---|
| 484 | IF(lwp) THEN ! Print the choice |
|---|
| 485 | WRITE(numout,*) |
|---|
| 486 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 487 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - 2D Chl data ' |
|---|
| 488 | IF( nqsr == 3 ) WRITE(numout,*) ' R-G-B light penetration - 3D Chl data ' |
|---|
| 489 | IF( nqsr == 4 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 490 | IF( nqsr == 5 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 491 | ENDIF |
|---|
| 492 | ! |
|---|
| 493 | ENDIF |
|---|
| 494 | ! ! ===================================== ! |
|---|
| 495 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 496 | ! ! ===================================== ! |
|---|
| 497 | ! |
|---|
| 498 | xsi0r = 1.e0 / rn_si0 |
|---|
| 499 | xsi1r = 1.e0 / rn_si1 |
|---|
| 500 | ! ! ---------------------------------- ! |
|---|
| 501 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 502 | ! ! ---------------------------------- ! |
|---|
| 503 | ! |
|---|
| 504 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 505 | ! |
|---|
| 506 | ! !* level of light extinction |
|---|
| 507 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 508 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 509 | ENDIF |
|---|
| 510 | |
|---|
| 511 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 512 | ! |
|---|
| 513 | IF( nn_chldta == 1 .OR. nn_chldta == 2 ) THEN !* Chl data : set sf_chl structure |
|---|
| 514 | IF(lwp) WRITE(numout,*) |
|---|
| 515 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 516 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 517 | IF( ierror > 0 ) THEN |
|---|
| 518 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 519 | ENDIF |
|---|
| 520 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 521 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 522 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 523 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 524 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 525 | ! |
|---|
| 526 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 527 | IF(lwp) WRITE(numout,*) |
|---|
| 528 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 529 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 530 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 531 | ELSE ! constant volume: computes one for all |
|---|
| 532 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 533 | ! |
|---|
| 534 | zchl = 0.05 ! constant chlorophyll |
|---|
| 535 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 536 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 537 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 538 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 539 | ! |
|---|
| 540 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 541 | ze0(:,:,1) = rn_abs |
|---|
| 542 | ze1(:,:,1) = zcoef |
|---|
| 543 | ze2(:,:,1) = zcoef |
|---|
| 544 | ze3(:,:,1) = zcoef |
|---|
| 545 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 546 | !$OMP PARALLEL DO PRIVATE(zc0, zc1, zc2, zc3) |
|---|
| 547 | DO jk = 2, nksr+1 |
|---|
| 548 | DO jj = 1, jpj |
|---|
| 549 | DO ji = 1, jpi |
|---|
| 550 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 551 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 552 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 553 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 554 | ze0(ji,jj,jk) = zc0 |
|---|
| 555 | ze1(ji,jj,jk) = zc1 |
|---|
| 556 | ze2(ji,jj,jk) = zc2 |
|---|
| 557 | ze3(ji,jj,jk) = zc3 |
|---|
| 558 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 559 | END DO |
|---|
| 560 | END DO |
|---|
| 561 | END DO |
|---|
| 562 | ! |
|---|
| 563 | !$OMP PARALLEL DO |
|---|
| 564 | DO jk = 1, nksr |
|---|
| 565 | ! (ISF) no light penetration below the ice shelves |
|---|
| 566 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1) |
|---|
| 567 | END DO |
|---|
| 568 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 569 | ENDIF |
|---|
| 570 | ENDIF |
|---|
| 571 | ! |
|---|
| 572 | ENDIF |
|---|
| 573 | ! ! ---------------------------------- ! |
|---|
| 574 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 575 | ! ! ---------------------------------- ! |
|---|
| 576 | ! |
|---|
| 577 | ! ! level of light extinction |
|---|
| 578 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 579 | IF(lwp) THEN |
|---|
| 580 | WRITE(numout,*) |
|---|
| 581 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 582 | ENDIF |
|---|
| 583 | ! |
|---|
| 584 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 585 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 586 | ELSE ! constant volume: computes one for all |
|---|
| 587 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 588 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 589 | !$OMP PARALLEL DO PRIVATE(zc0, zc1) |
|---|
| 590 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 591 | DO jj = 1, jpj ! top 400 meters |
|---|
| 592 | DO ji = 1, jpi |
|---|
| 593 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 594 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 595 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) * tmask(ji,jj,1) |
|---|
| 596 | END DO |
|---|
| 597 | END DO |
|---|
| 598 | END DO |
|---|
| 599 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 600 | ! |
|---|
| 601 | ENDIF |
|---|
| 602 | ENDIF |
|---|
| 603 | ! ! ===================================== ! |
|---|
| 604 | ELSE ! No light penetration ! |
|---|
| 605 | ! ! ===================================== ! |
|---|
| 606 | IF(lwp) THEN |
|---|
| 607 | WRITE(numout,*) |
|---|
| 608 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 609 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 610 | ENDIF |
|---|
| 611 | ENDIF |
|---|
| 612 | ! |
|---|
| 613 | ! initialisation of fraqsr_1lev used in sbcssm |
|---|
| 614 | IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 615 | CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev ) |
|---|
| 616 | ELSE |
|---|
| 617 | fraqsr_1lev(:,:) = 1._wp ! default definition |
|---|
| 618 | ENDIF |
|---|
| 619 | ! |
|---|
| 620 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 621 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 622 | ! |
|---|
| 623 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 624 | ! |
|---|
| 625 | END SUBROUTINE tra_qsr_init |
|---|
| 626 | |
|---|
| 627 | !!====================================================================== |
|---|
| 628 | END MODULE traqsr |
|---|
