Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

sbcrnf.F90 @ 7924

Last change on this file since 7924 was 7924, checked in by andmirek, 7 years ago
first commit with XIOS restart read functionality
File size: 29.6 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29	USE iom_def, ONLY : lxios_read
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC sbc_rnf ! routine call in sbcmod module
35	PUBLIC sbc_rnf_div ! routine called in divcurl module
36	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
37	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
38	! !!* namsbc_rnf namelist *
39	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
40	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
41	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
42	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
43	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
44	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
50	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
51	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
52	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
53	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
54	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
55	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
56
57	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
58
59	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
63	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
64	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
65
66	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
69
70	!! * Substitutions
71	# include "domzgr_substitute.h90"
72	!!----------------------------------------------------------------------
73	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
74	!! $Id$
75	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
76	!!----------------------------------------------------------------------
77	CONTAINS
78
79	INTEGER FUNCTION sbc_rnf_alloc()
80	!!----------------------------------------------------------------------
81	!! * ROUTINE sbc_rnf_alloc *
82	!!----------------------------------------------------------------------
83	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
84	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
85	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
86	!
87	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
88	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
89	END FUNCTION sbc_rnf_alloc
90
91
92	SUBROUTINE sbc_rnf( kt )
93	!!----------------------------------------------------------------------
94	!! * ROUTINE sbc_rnf *
95	!!
96	!! ** Purpose : Introduce a climatological run off forcing
97	!!
98	!! ** Method : Set each river mouth with a monthly climatology
99	!! provided from different data.
100	!! CAUTION : upward water flux, runoff forced to be < 0
101	!!
102	!! ** Action : runoff updated runoff field at time-step kt
103	!!----------------------------------------------------------------------
104	INTEGER, INTENT(in) :: kt ! ocean time step
105	!
106	INTEGER :: ji, jj ! dummy loop indices
107	INTEGER :: z_err = 0 ! dummy integer for error handling
108	!!----------------------------------------------------------------------
109	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
110	!
111	CALL wrk_alloc( jpi,jpj, ztfrz)
112
113	! ! ---------------------------------------- !
114	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
115	! ! ---------------------------------------- !
116	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
117	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
118	!
119	ENDIF
120
121	! !-------------------!
122	! ! Update runoff !
123	! !-------------------!
124	!
125	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
126	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
127	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
128	!
129	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
130	!
131	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
132	!
133	! ! set temperature & salinity content of runoffs
134	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
135	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
136	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
137	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
138	END WHERE
139	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
140	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
141	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
142	END WHERE
143	ELSE ! use SST as runoffs temperature
144	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
145	ENDIF
146	! ! use runoffs salinity data
147	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
148	! ! else use S=0 for runoffs (done one for all in the init)
149	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
150	ENDIF
151	!
152	! ! ---------------------------------------- !
153	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
154	! ! ---------------------------------------- !
155	IF( ln_rstart .AND. & !* Restart: read in restart file
156	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
157	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
158	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, lrxios = lxios_read ) ! before runoff
159	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), lrxios = lxios_read ) ! before heat content of runoff
160	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), lrxios = lxios_read ) ! before salinity content of runoff
161	ELSE !* no restart: set from nit000 values
162	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
163	rnf_b (:,: ) = rnf (:,: )
164	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
165	ENDIF
166	ENDIF
167	! ! ---------------------------------------- !
168	IF( lrst_oce ) THEN ! Write in the ocean restart file !
169	! ! ---------------------------------------- !
170	IF(lwp) WRITE(numout,*)
171	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
172	& 'at it= ', kt,' date= ', ndastp
173	IF(lwp) WRITE(numout,*) '~~~~'
174	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
175	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
176	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
177	ENDIF
178	!
179	CALL wrk_dealloc( jpi,jpj, ztfrz)
180	!
181	END SUBROUTINE sbc_rnf
182
183
184	SUBROUTINE sbc_rnf_div( phdivn )
185	!!----------------------------------------------------------------------
186	!! * ROUTINE sbc_rnf *
187	!!
188	!! ** Purpose : update the horizontal divergence with the runoff inflow
189	!!
190	!! ** Method :
191	!! CAUTION : rnf is positive (inflow) decreasing the
192	!! divergence and expressed in m/s
193	!!
194	!! ** Action : phdivn decreased by the runoff inflow
195	!!----------------------------------------------------------------------
196	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
197	!!
198	INTEGER :: ji, jj, jk ! dummy loop indices
199	REAL(wp) :: zfact ! local scalar
200	!!----------------------------------------------------------------------
201	!
202	zfact = 0.5_wp
203	!
204	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
205	IF( lk_vvl ) THEN ! variable volume case
206	DO jj = 1, jpj ! update the depth over which runoffs are distributed
207	DO ji = 1, jpi
208	h_rnf(ji,jj) = 0._wp
209	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
210	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
211	END DO
212	! ! apply the runoff input flow
213	DO jk = 1, nk_rnf(ji,jj)
214	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
215	END DO
216	END DO
217	END DO
218	ELSE ! constant volume case : just apply the runoff input flow
219	DO jj = 1, jpj
220	DO ji = 1, jpi
221	DO jk = 1, nk_rnf(ji,jj)
222	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
223	END DO
224	END DO
225	END DO
226	ENDIF
227	ELSE !== runoff put only at the surface ==!
228	IF( lk_vvl ) THEN ! variable volume case
229	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
230	ENDIF
231	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
232	ENDIF
233	!
234	END SUBROUTINE sbc_rnf_div
235
236
237	SUBROUTINE sbc_rnf_init
238	!!----------------------------------------------------------------------
239	!! * ROUTINE sbc_rnf_init *
240	!!
241	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
242	!!
243	!! ** Method : - read the runoff namsbc_rnf namelist
244	!!
245	!! ** Action : - read parameters
246	!!----------------------------------------------------------------------
247	CHARACTER(len=32) :: rn_dep_file ! runoff file name
248	INTEGER :: ji, jj, jk, jm ! dummy loop indices
249	INTEGER :: ierror, inum ! temporary integer
250	INTEGER :: ios ! Local integer output status for namelist read
251	INTEGER :: nbrec ! temporary integer
252	REAL(wp) :: zacoef
253	REAL(wp), DIMENSION(12) :: zrec ! times records
254	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
255	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
256	!
257	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
258	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
259	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
260	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
261	!!----------------------------------------------------------------------
262	!
263	! !== allocate runoff arrays
264	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
265	!
266	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
267	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
268	nkrnf = 0
269	rnf (:,:) = 0.0_wp
270	rnf_b (:,:) = 0.0_wp
271	rnfmsk (:,:) = 0.0_wp
272	rnfmsk_z(:) = 0.0_wp
273	RETURN
274	ENDIF
275	!
276	! ! ============
277	! ! Namelist
278	! ! ============
279	!
280	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
281	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
282	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
283
284	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
285	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
286	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
287	IF(lwm) WRITE ( numond, namsbc_rnf )
288	!
289	! ! Control print
290	IF(lwp) THEN
291	WRITE(numout,*)
292	WRITE(numout,*) 'sbc_rnf : runoff '
293	WRITE(numout,*) '~~~~~~~ '
294	WRITE(numout,*) ' Namelist namsbc_rnf'
295	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
296	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
297	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
298	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
299	ENDIF
300	! ! ==================
301	! ! Type of runoff
302	! ! ==================
303	!
304	IF( .NOT. l_rnfcpl ) THEN
305	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
306	IF(lwp) WRITE(numout,*)
307	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
308	IF( ierror > 0 ) THEN
309	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
310	ENDIF
311	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
312	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
313	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
314	ENDIF
315	!
316	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
317	IF(lwp) WRITE(numout,*)
318	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
319	ALLOCATE( sf_t_rnf(1), STAT=ierror )
320	IF( ierror > 0 ) THEN
321	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
322	ENDIF
323	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
324	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
325	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
326	ENDIF
327	!
328	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
329	IF(lwp) WRITE(numout,*)
330	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
331	ALLOCATE( sf_s_rnf(1), STAT=ierror )
332	IF( ierror > 0 ) THEN
333	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
334	ENDIF
335	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
336	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
337	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
338	ENDIF
339	!
340	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
341	IF(lwp) WRITE(numout,*)
342	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
343	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
344	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
345	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
346	ENDIF
347	CALL iom_open ( rn_dep_file, inum ) ! open file
348	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
349	CALL iom_close( inum ) ! close file
350	!
351	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
352	DO jj = 1, jpj
353	DO ji = 1, jpi
354	IF( h_rnf(ji,jj) > 0._wp ) THEN
355	jk = 2
356	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
357	END DO
358	nk_rnf(ji,jj) = jk
359	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
360	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
361	ELSE
362	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
363	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
364	ENDIF
365	END DO
366	END DO
367	DO jj = 1, jpj ! set the associated depth
368	DO ji = 1, jpi
369	h_rnf(ji,jj) = 0._wp
370	DO jk = 1, nk_rnf(ji,jj)
371	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
372	END DO
373	END DO
374	END DO
375	!
376	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
377	!
378	IF(lwp) WRITE(numout,*)
379	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
380	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
381	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
382	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
383
384	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
385	CALL iom_gettime( inum, zrec, kntime=nbrec)
386	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
387	DO jm = 1, nbrec
388	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
389	END DO
390	CALL iom_close( inum )
391	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
392	DEALLOCATE( zrnfcl )
393	!
394	h_rnf(:,:) = 1.
395	!
396	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
397	!
398	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
399	!
400	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
401	DO ji = 1, jpi
402	IF( zrnf(ji,jj) > 0._wp ) THEN
403	jk = mbkt(ji,jj)
404	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
405	ENDIF
406	END DO
407	END DO
408	!
409	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
410	DO jj = 1, jpj
411	DO ji = 1, jpi
412	IF( zrnf(ji,jj) > 0._wp ) THEN
413	jk = 2
414	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
415	END DO
416	nk_rnf(ji,jj) = jk
417	ELSE
418	nk_rnf(ji,jj) = 1
419	ENDIF
420	END DO
421	END DO
422	!
423	DEALLOCATE( zrnf )
424	!
425	DO jj = 1, jpj ! set the associated depth
426	DO ji = 1, jpi
427	h_rnf(ji,jj) = 0._wp
428	DO jk = 1, nk_rnf(ji,jj)
429	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
430	END DO
431	END DO
432	END DO
433	!
434	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
435	IF(lwp) WRITE(numout,*) ' create runoff depht file'
436	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
437	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
438	CALL iom_close ( inum )
439	ENDIF
440	ELSE ! runoffs applied at the surface
441	nk_rnf(:,:) = 1
442	h_rnf (:,:) = fse3t(:,:,1)
443	ENDIF
444	!
445	rnf(:,:) = 0._wp ! runoff initialisation
446	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
447	!
448	! ! ========================
449	! ! River mouth vicinity
450	! ! ========================
451	!
452	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
453	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
454	! ! - set to zero SSS damping (ln_ssr=T)
455	! ! - mixed upstream-centered (ln_traadv_cen2=T)
456	!
457	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
458	& 'be spread through depth by ln_rnf_depth' )
459	!
460	nkrnf = 0 ! Number of level over which Kz increase
461	IF( rn_hrnf > 0._wp ) THEN
462	nkrnf = 2
463	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
464	END DO
465	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
466	ENDIF
467	IF(lwp) WRITE(numout,*)
468	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
469	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
470	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
471	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
472	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
473	!
474	CALL rnf_mouth ! set river mouth mask
475	!
476	ELSE ! No treatment at river mouths
477	IF(lwp) WRITE(numout,*)
478	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
479	rnfmsk (:,:) = 0._wp
480	rnfmsk_z(:) = 0._wp
481	nkrnf = 0
482	ENDIF
483	!
484	END SUBROUTINE sbc_rnf_init
485
486
487	SUBROUTINE rnf_mouth
488	!!----------------------------------------------------------------------
489	!! * ROUTINE rnf_mouth *
490	!!
491	!! ** Purpose : define the river mouths mask
492	!!
493	!! ** Method : read the river mouth mask (=0/1) in the river runoff
494	!! climatological file. Defined a given vertical structure.
495	!! CAUTION, the vertical structure is hard coded on the
496	!! first 5 levels.
497	!! This fields can be used to:
498	!! - set an upstream advection scheme
499	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
500	!! - increase vertical on the top nn_krnf vertical levels
501	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
502	!! - set to zero SSS restoring flux at river mouth grid points
503	!!
504	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
505	!! rnfmsk_z vertical structure
506	!!----------------------------------------------------------------------
507	INTEGER :: inum ! temporary integers
508	CHARACTER(len=140) :: cl_rnfile ! runoff file name
509	!!----------------------------------------------------------------------
510	!
511	IF(lwp) WRITE(numout,*)
512	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
513	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
514	!
515	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
516	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
517	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
518	ENDIF
519	!
520	! horizontal mask (read in NetCDF file)
521	CALL iom_open ( cl_rnfile, inum ) ! open file
522	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
523	CALL iom_close( inum ) ! close file
524	!
525	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
526	!
527	rnfmsk_z(:) = 0._wp ! vertical structure
528	rnfmsk_z(1) = 1.0
529	rnfmsk_z(2) = 1.0 ! **********
530	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
531	rnfmsk_z(4) = 0.25 ! **********
532	rnfmsk_z(5) = 0.125
533	!
534	END SUBROUTINE rnf_mouth
535
536	!!======================================================================
537	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_GO6_package_XIOS_read/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 7924

Download in other formats: