New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_r5518_GO6_package_XIOS_read/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_XIOS_read/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 7923

Last change on this file since 7923 was 7923, checked in by andmirek, 7 years ago

merge changes up to 7573

File size: 39.7 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE diaptr          ! poleward transports           (dia_ptr_init routine)
64   USE diadct          ! sections transports           (dia_dct_init routine)
65   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
66   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67   USE step            ! NEMO time-stepping                 (stp     routine)
68   USE icbini          ! handle bergs, initialisation
69   USE icbstp          ! handle bergs, calving, themodynamics and transport
70   USE cpl_oasis3      ! OASIS3 coupling
71   USE c1d             ! 1D configuration
72   USE step_c1d        ! Time stepping loop for the 1D configuration
73   USE dyndmp          ! Momentum damping
74#if defined key_top
75   USE trcini          ! passive tracer initialisation
76#endif
77   USE lib_mpp         ! distributed memory computing
78#if defined key_iomput
79   USE xios
80#endif
81   USE sbctide, ONLY: lk_tide
82   USE crsini          ! initialise grid coarsening utility
83   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
84   USE sbc_oce, ONLY: lk_oasis
85   USE stopar
86   USE stopts
87
88   IMPLICIT NONE
89   PRIVATE
90
91   PUBLIC   nemo_gcm    ! called by model.F90
92   PUBLIC   nemo_init   ! needed by AGRIF
93   PUBLIC   nemo_alloc  ! needed by TAM
94
95   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
96
97   !!----------------------------------------------------------------------
98   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
99   !! $Id$
100   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
101   !!----------------------------------------------------------------------
102CONTAINS
103
104   SUBROUTINE nemo_gcm
105      !!----------------------------------------------------------------------
106      !!                     ***  ROUTINE nemo_gcm  ***
107      !!
108      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
109      !!              curvilinear mesh on the sphere.
110      !!
111      !! ** Method  : - model general initialization
112      !!              - launch the time-stepping (stp routine)
113      !!              - finalize the run by closing files and communications
114      !!
115      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
116      !!              Madec, 2008, internal report, IPSL.
117      !!----------------------------------------------------------------------
118      INTEGER ::   istp       ! time step index
119      !!----------------------------------------------------------------------
120      !
121#if defined key_agrif
122      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
123#endif
124
125      !                            !-----------------------!
126      CALL nemo_init               !==  Initialisations  ==!
127      !                            !-----------------------!
128#if defined key_agrif
129      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
130      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
131# if defined key_top
132      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
133# endif
134# if defined key_lim2
135      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
136# endif
137#endif
138      ! check that all process are still there... If some process have an error,
139      ! they will never enter in step and other processes will wait until the end of the cpu time!
140      IF( lk_mpp )   CALL mpp_max( nstop )
141
142      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
143
144      !                            !-----------------------!
145      !                            !==   time stepping   ==!
146      !                            !-----------------------!
147      istp = nit000
148#if defined key_c1d
149         DO WHILE ( istp <= nitend .AND. nstop == 0 )
150            CALL stp_c1d( istp )
151            istp = istp + 1
152         END DO
153#else
154          IF( lk_asminc ) THEN
155             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
156             IF( ln_asmdin ) THEN                        ! Direct initialization
157                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
158                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
159                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
160             ENDIF
161          ENDIF
162
163#if defined key_agrif
164          CALL Agrif_Regrid()
165#endif
166
167         DO WHILE ( istp <= nitend .AND. nstop == 0 )
168#if defined key_agrif
169            CALL stp                         ! AGRIF: time stepping
170#else
171            CALL stp( istp )                 ! standard time stepping
172#endif
173            istp = istp + 1
174            IF( lk_mpp )   CALL mpp_max( nstop )
175         END DO
176#endif
177
178      IF( lk_diaobs   )   CALL dia_obs_wri
179      !
180      IF( ln_icebergs )   CALL icb_end( nitend )
181
182      !                            !------------------------!
183      !                            !==  finalize the run  ==!
184      !                            !------------------------!
185      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
186      !
187      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
188         WRITE(numout,cform_err)
189         WRITE(numout,*) nstop, ' error have been found'
190      ENDIF
191      !
192#if defined key_agrif
193      IF( .NOT. Agrif_Root() ) THEN
194         CALL Agrif_ParentGrid_To_ChildGrid()
195         IF( lk_diaobs ) CALL dia_obs_wri
196         IF( nn_timing == 1 )   CALL timing_finalize
197         CALL Agrif_ChildGrid_To_ParentGrid()
198      ENDIF
199#endif
200      IF( nn_timing == 1 )   CALL timing_finalize
201      !
202      CALL nemo_closefile
203      !
204#if defined key_iomput
205      CALL xios_finalize                ! end mpp communications with xios
206      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
207#else
208      IF( lk_oasis ) THEN
209         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
210      ELSE
211         IF( lk_mpp )   CALL mppstop    ! end mpp communications
212      ENDIF
213#endif
214      !
215   END SUBROUTINE nemo_gcm
216
217
218   SUBROUTINE nemo_init
219      !!----------------------------------------------------------------------
220      !!                     ***  ROUTINE nemo_init  ***
221      !!
222      !! ** Purpose :   initialization of the NEMO GCM
223      !!----------------------------------------------------------------------
224      INTEGER ::   ji            ! dummy loop indices
225      INTEGER ::   ilocal_comm   ! local integer
226      INTEGER ::   ios
227      CHARACTER(len=80), DIMENSION(16) ::   cltxt
228      !
229      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
230         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
231         &             nn_bench, nn_timing
232      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
233         &             jpizoom, jpjzoom, jperio, ln_use_jattr
234      !!----------------------------------------------------------------------
235      !
236      cltxt = ''
237      cxios_context = 'nemo'
238      !
239      !                             ! Open reference namelist and configuration namelist files
240      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
241      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      !
243      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
244      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
245901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
246
247      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
248      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
249902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
250
251      !
252      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
253      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
254903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
255
256      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
257      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
258904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
259
260! Force values for AGRIF zoom (cf. agrif_user.F90)
261#if defined key_agrif
262   IF( .NOT. Agrif_Root() ) THEN
263      jpiglo  = nbcellsx + 2 + 2*nbghostcells
264      jpjglo  = nbcellsy + 2 + 2*nbghostcells
265      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
266      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
267      jpidta  = jpiglo
268      jpjdta  = jpjglo
269      jpizoom = 1
270      jpjzoom = 1
271      nperio  = 0
272      jperio  = 0
273      ln_use_jattr = .false.
274   ENDIF
275#endif
276      !
277      !                             !--------------------------------------------!
278      !                             !  set communicator & select the local node  !
279      !                             !  NB: mynode also opens output.namelist.dyn !
280      !                             !      on unit number numond on first proc   !
281      !                             !--------------------------------------------!
282#if defined key_iomput
283      IF( Agrif_Root() ) THEN
284         IF( lk_oasis ) THEN
285            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
286            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
287         ELSE
288            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
289         ENDIF
290      ENDIF
291      ! Nodes selection (control print return in cltxt)
292      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
293#else
294      IF( lk_oasis ) THEN
295         IF( Agrif_Root() ) THEN
296            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
297         ENDIF
298         ! Nodes selection (control print return in cltxt)
299         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
300      ELSE
301         ilocal_comm = 0
302         ! Nodes selection (control print return in cltxt)
303         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
304      ENDIF
305#endif
306      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
307
308      lwm = (narea == 1)                                    ! control of output namelists
309      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
310
311      IF(lwm) THEN
312         ! write merged namelists from earlier to output namelist now that the
313         ! file has been opened in call to mynode. nammpp has already been
314         ! written in mynode (if lk_mpp_mpi)
315         WRITE( numond, namctl )
316         WRITE( numond, namcfg )
317      ENDIF
318
319      ! If dimensions of processor grid weren't specified in the namelist file
320      ! then we calculate them here now that we have our communicator size
321      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
322#if   defined key_mpp_mpi
323         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
324#else
325         jpni  = 1
326         jpnj  = 1
327         jpnij = jpni*jpnj
328#endif
329      END IF
330
331      ! Calculate domain dimensions given calculated jpni and jpnj
332      ! This used to be done in par_oce.F90 when they were parameters rather
333      ! than variables
334      IF( Agrif_Root() ) THEN
335#if defined key_nemocice_decomp
336         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
337         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
338#else
339         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
340         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
341#endif
342      ENDIF         
343         jpk = jpkdta                                             ! third dim
344#if defined key_agrif
345         ! simple trick to use same vertical grid as parent
346         ! but different number of levels:
347         ! Save maximum number of levels in jpkdta, then define all vertical grids
348         ! with this number.
349         ! Suppress once vertical online interpolation is ok
350         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
351#endif
352         jpim1 = jpi-1                                            ! inner domain indices
353         jpjm1 = jpj-1                                            !   "           "
354         jpkm1 = jpk-1                                            !   "           "
355         jpij  = jpi*jpj                                          !  jpi x j
356
357      IF(lwp) THEN                            ! open listing units
358         !
359         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
360         !
361         WRITE(numout,*)
362         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
363         WRITE(numout,*) '                       NEMO team'
364         WRITE(numout,*) '            Ocean General Circulation Model'
365         WRITE(numout,*) '                  version 3.6  (2015) '
366         WRITE(numout,*)
367         WRITE(numout,*)
368         DO ji = 1, SIZE(cltxt)
369            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
370         END DO
371         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
372         !
373      ENDIF
374
375      ! Now we know the dimensions of the grid and numout has been set we can
376      ! allocate arrays
377      CALL nemo_alloc()
378
379      !                             !-------------------------------!
380      !                             !  NEMO general initialization  !
381      !                             !-------------------------------!
382
383      CALL nemo_ctl                          ! Control prints & Benchmark
384
385      !                                      ! Domain decomposition
386      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
387      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
388      ENDIF
389      !
390      IF( nn_timing == 1 )  CALL timing_init
391      !
392      !                                      ! General initialization
393                            CALL     phy_cst    ! Physical constants
394                            CALL     eos_init   ! Equation of state
395      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
396                            CALL     dom_cfg    ! Domain configuration
397                            CALL     dom_init   ! Domain
398
399      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
400
401      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
402
403                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
404
405      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
406
407                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
408
409      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
410      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
411      IF( lk_bdy .AND. lk_tide )   &
412         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
413
414                            CALL dyn_nept_init  ! simplified form of Neptune effect
415      !     
416      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
417      !
418                                ! Ocean physics
419      !                                         ! Vertical physics
420                            CALL     zdf_init      ! namelist read
421                            CALL zdf_bfr_init      ! bottom friction
422      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
423      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
424      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
425      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
426      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
427      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
428         &                  CALL zdf_ddm_init      ! double diffusive mixing
429      !                                         ! Lateral physics
430                            CALL ldf_tra_init      ! Lateral ocean tracer physics
431                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
432      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
433
434      !                                     ! Active tracers
435                            CALL tra_qsr_init   ! penetrative solar radiation qsr
436                            CALL tra_bbc_init   ! bottom heat flux
437      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
438                            CALL tra_dmp_init   ! internal damping trends- tracers
439                            CALL tra_adv_init   ! horizontal & vertical advection
440                            CALL tra_ldf_init   ! lateral mixing
441                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
442
443      !                                     ! Dynamics
444      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
445                            CALL dyn_adv_init   ! advection (vector or flux form)
446                            CALL dyn_vor_init   ! vorticity term including Coriolis
447                            CALL dyn_ldf_init   ! lateral mixing
448                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
449                            CALL dyn_zdf_init   ! vertical diffusion
450                            CALL dyn_spg_init   ! surface pressure gradient
451
452      !                                     ! Misc. options
453      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
454                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
455                            CALL sto_par_init   ! Stochastic parametrization
456      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
457     
458#if defined key_top
459      !                                     ! Passive tracers
460                            CALL     trc_init
461#endif
462      !                                     ! Diagnostics
463      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
464                            CALL dia_ptr_init   ! Poleward TRansports initialization
465      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
466                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
467                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
468      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
469                            CALL dia_obs_init            ! Initialize observational data
470                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
471      ENDIF
472
473      !                                     ! Assimilation increments
474      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
475      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
476      !
477   END SUBROUTINE nemo_init
478
479
480   SUBROUTINE nemo_ctl
481      !!----------------------------------------------------------------------
482      !!                     ***  ROUTINE nemo_ctl  ***
483      !!
484      !! ** Purpose :   control print setting
485      !!
486      !! ** Method  : - print namctl information and check some consistencies
487      !!----------------------------------------------------------------------
488      !
489      IF(lwp) THEN                  ! control print
490         WRITE(numout,*)
491         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
492         WRITE(numout,*) '~~~~~~~ '
493         WRITE(numout,*) '   Namelist namctl'
494         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
495         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
496         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
497         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
498         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
499         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
500         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
501         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
502         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
503         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
504      ENDIF
505      !
506      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
507      nictls    = nn_ictls
508      nictle    = nn_ictle
509      njctls    = nn_jctls
510      njctle    = nn_jctle
511      isplt     = nn_isplt
512      jsplt     = nn_jsplt
513      nbench    = nn_bench
514
515      IF(lwp) THEN                  ! control print
516         WRITE(numout,*)
517         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
518         WRITE(numout,*) '~~~~~~~ '
519         WRITE(numout,*) '   Namelist namcfg'
520         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
521         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
522         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
523         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
524         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
525         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
526         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
527         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
528         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
529         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
530         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
531         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
532      ENDIF
533      !                             ! Parameter control
534      !
535      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
536         IF( lk_mpp .AND. jpnij > 1 ) THEN
537            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
538         ELSE
539            IF( isplt == 1 .AND. jsplt == 1  ) THEN
540               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
541                  &           ' - the print control will be done over the whole domain' )
542            ENDIF
543            ijsplt = isplt * jsplt            ! total number of processors ijsplt
544         ENDIF
545         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
546         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
547         !
548         !                              ! indices used for the SUM control
549         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
550            lsp_area = .FALSE.
551         ELSE                                             ! print control done over a specific  area
552            lsp_area = .TRUE.
553            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
554               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
555               nictls = 1
556            ENDIF
557            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
558               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
559               nictle = jpiglo
560            ENDIF
561            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
562               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
563               njctls = 1
564            ENDIF
565            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
566               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
567               njctle = jpjglo
568            ENDIF
569         ENDIF
570      ENDIF
571      !
572      IF( nbench == 1 ) THEN              ! Benchmark
573         SELECT CASE ( cp_cfg )
574         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
575         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
576            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
577         END SELECT
578      ENDIF
579      !
580      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
581         &                                               'f2003 standard. '                              ,  &
582         &                                               'Compile with key_nosignedzero enabled' )
583      !
584   END SUBROUTINE nemo_ctl
585
586
587   SUBROUTINE nemo_closefile
588      !!----------------------------------------------------------------------
589      !!                     ***  ROUTINE nemo_closefile  ***
590      !!
591      !! ** Purpose :   Close the files
592      !!----------------------------------------------------------------------
593      !
594      IF( lk_mpp )   CALL mppsync
595      !
596      CALL iom_close                                 ! close all input/output files managed by iom_*
597      !
598      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
599      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
600      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
601      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
602      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
603      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
604      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
605      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
606      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
607      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
608      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
609      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
610      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
611
612      !
613      numout = 6                                     ! redefine numout in case it is used after this point...
614      !
615   END SUBROUTINE nemo_closefile
616
617
618   SUBROUTINE nemo_alloc
619      !!----------------------------------------------------------------------
620      !!                     ***  ROUTINE nemo_alloc  ***
621      !!
622      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
623      !!
624      !! ** Method  :
625      !!----------------------------------------------------------------------
626      USE diawri    , ONLY: dia_wri_alloc
627      USE dom_oce   , ONLY: dom_oce_alloc
628      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
629      USE ldftra_oce, ONLY: ldftra_oce_alloc
630      USE trc_oce   , ONLY: trc_oce_alloc
631#if defined key_diadct 
632      USE diadct    , ONLY: diadct_alloc 
633#endif 
634#if defined key_bdy
635      USE bdy_oce   , ONLY: bdy_oce_alloc
636#endif
637      !
638      INTEGER :: ierr
639      !!----------------------------------------------------------------------
640      !
641      ierr =        oce_alloc       ()          ! ocean
642      ierr = ierr + dia_wri_alloc   ()
643      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
644      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
645      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
646      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
647      !
648      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
649      !
650#if defined key_diadct 
651      ierr = ierr + diadct_alloc    ()          !
652#endif 
653#if defined key_bdy
654      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
655#endif
656      !
657      IF( lk_mpp    )   CALL mpp_sum( ierr )
658      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
659      !
660   END SUBROUTINE nemo_alloc
661
662
663   SUBROUTINE nemo_partition( num_pes )
664      !!----------------------------------------------------------------------
665      !!                 ***  ROUTINE nemo_partition  ***
666      !!
667      !! ** Purpose :
668      !!
669      !! ** Method  :
670      !!----------------------------------------------------------------------
671      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
672      !
673      INTEGER, PARAMETER :: nfactmax = 20
674      INTEGER :: nfact ! The no. of factors returned
675      INTEGER :: ierr  ! Error flag
676      INTEGER :: ji
677      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
678      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
679      !!----------------------------------------------------------------------
680      !
681      ierr = 0
682      !
683      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
684      !
685      IF( nfact <= 1 ) THEN
686         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
687         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
688         jpnj = 1
689         jpni = num_pes
690      ELSE
691         ! Search through factors for the pair that are closest in value
692         mindiff = 1000000
693         imin    = 1
694         DO ji = 1, nfact-1, 2
695            idiff = ABS( ifact(ji) - ifact(ji+1) )
696            IF( idiff < mindiff ) THEN
697               mindiff = idiff
698               imin = ji
699            ENDIF
700         END DO
701         jpnj = ifact(imin)
702         jpni = ifact(imin + 1)
703      ENDIF
704      !
705      jpnij = jpni*jpnj
706      !
707   END SUBROUTINE nemo_partition
708
709
710   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
711      !!----------------------------------------------------------------------
712      !!                     ***  ROUTINE factorise  ***
713      !!
714      !! ** Purpose :   return the prime factors of n.
715      !!                knfax factors are returned in array kfax which is of
716      !!                maximum dimension kmaxfax.
717      !! ** Method  :
718      !!----------------------------------------------------------------------
719      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
720      INTEGER                    , INTENT(  out) ::   kerr, knfax
721      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
722      !
723      INTEGER :: ifac, jl, inu
724      INTEGER, PARAMETER :: ntest = 14
725      INTEGER, DIMENSION(ntest) :: ilfax
726      !
727      ! ilfax contains the set of allowed factors.
728      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
729      !!----------------------------------------------------------------------
730      ! ilfax contains the set of allowed factors.
731      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
732
733      ! Clear the error flag and initialise output vars
734      kerr = 0
735      kfax = 1
736      knfax = 0
737
738      ! Find the factors of n.
739      IF( kn == 1 )   GOTO 20
740
741      ! nu holds the unfactorised part of the number.
742      ! knfax holds the number of factors found.
743      ! l points to the allowed factor list.
744      ! ifac holds the current factor.
745
746      inu   = kn
747      knfax = 0
748
749      DO jl = ntest, 1, -1
750         !
751         ifac = ilfax(jl)
752         IF( ifac > inu )   CYCLE
753
754         ! Test whether the factor will divide.
755
756         IF( MOD(inu,ifac) == 0 ) THEN
757            !
758            knfax = knfax + 1            ! Add the factor to the list
759            IF( knfax > kmaxfax ) THEN
760               kerr = 6
761               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
762               return
763            ENDIF
764            kfax(knfax) = ifac
765            ! Store the other factor that goes with this one
766            knfax = knfax + 1
767            kfax(knfax) = inu / ifac
768            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
769         ENDIF
770         !
771      END DO
772
773   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
774      !
775   END SUBROUTINE factorise
776
777#if defined key_mpp_mpi
778
779   SUBROUTINE nemo_northcomms
780      !!======================================================================
781      !!                     ***  ROUTINE  nemo_northcomms  ***
782      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
783      !!                       point-to-point messaging
784      !!=====================================================================
785      !!----------------------------------------------------------------------
786      !!
787      !! ** Purpose :   Initialization of the northern neighbours lists.
788      !!----------------------------------------------------------------------
789      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
790      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
791      !!----------------------------------------------------------------------
792
793      INTEGER  ::   sxM, dxM, sxT, dxT, jn
794      INTEGER  ::   njmppmax
795
796      njmppmax = MAXVAL( njmppt )
797   
798      !initializes the north-fold communication variables
799      isendto(:) = 0
800      nsndto = 0
801
802      !if I am a process in the north
803      IF ( njmpp == njmppmax ) THEN
804          !sxM is the first point (in the global domain) needed to compute the
805          !north-fold for the current process
806          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
807          !dxM is the last point (in the global domain) needed to compute the
808          !north-fold for the current process
809          dxM = jpiglo - nimppt(narea) + 2
810
811          !loop over the other north-fold processes to find the processes
812          !managing the points belonging to the sxT-dxT range
813 
814          DO jn = 1, jpni
815                !sxT is the first point (in the global domain) of the jn
816                !process
817                sxT = nfiimpp(jn, jpnj)
818                !dxT is the last point (in the global domain) of the jn
819                !process
820                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
821                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
822                   nsndto = nsndto + 1
823                     isendto(nsndto) = jn
824                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
825                   nsndto = nsndto + 1
826                     isendto(nsndto) = jn
827                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
828                   nsndto = nsndto + 1
829                     isendto(nsndto) = jn
830                END IF
831          END DO
832          nfsloop = 1
833          nfeloop = nlci
834          DO jn = 2,jpni-1
835           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
836              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
837                 nfsloop = nldi
838              ENDIF
839              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
840                 nfeloop = nlei
841              ENDIF
842           ENDIF
843        END DO
844
845      ENDIF
846      l_north_nogather = .TRUE.
847   END SUBROUTINE nemo_northcomms
848#else
849   SUBROUTINE nemo_northcomms      ! Dummy routine
850      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
851   END SUBROUTINE nemo_northcomms
852#endif
853
854   !!======================================================================
855END MODULE nemogcm
856
857
Note: See TracBrowser for help on using the repository browser.