New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
asmphyto2dbal_hadocc.F90 in branches/UKMO/dev_r5518_GO6_package_asm_3d_bgc/NEMOGCM/NEMO/OPA_SRC/ASM – NEMO

source: branches/UKMO/dev_r5518_GO6_package_asm_3d_bgc/NEMOGCM/NEMO/OPA_SRC/ASM/asmphyto2dbal_hadocc.F90 @ 9432

Last change on this file since 9432 was 9432, checked in by dford, 6 years ago

Rename logchlbal to phyto2dbal.
File size: 15.0 KB
Line 
1MODULE asmphyto2dbal_hadocc
2   !!======================================================================
3   !!                       ***  MODULE asmphyto2dbal_hadocc  ***
4   !! Calculate increments to HadOCC based on surface phyto2d increments
5   !!
6   !! IMPORTANT NOTE: This calls the bioanalysis routine of Hemmings et al.
7   !! For licensing reasons this is kept in its own internal Met Office
8   !! branch (dev/frdf/vn3.6_nitrogen_balancing) rather than in the Paris
9   !! repository, and must be merged in when building.
10   !!
11   !!======================================================================
12   !! History :  3.6  ! 2017-08  (D. Ford)     Adapted from bioanal.F90
13   !!----------------------------------------------------------------------
14#if defined key_asminc && defined key_hadocc
15   !!----------------------------------------------------------------------
16   !! 'key_asminc'          : assimilation increment interface
17   !! 'key_hadocc'          : HadOCC model
18   !!----------------------------------------------------------------------
19   !! asm_phyto2d_bal_hadocc : routine to calculate increments to HadOCC
20   !!----------------------------------------------------------------------
21   USE par_kind,      ONLY: wp             ! kind parameters
22   USE par_oce,       ONLY: jpi, jpj, jpk  ! domain array sizes
23   USE dom_oce,       ONLY: gdepw_n        ! domain information
24   USE iom                                 ! i/o
25   USE par_hadocc                          ! HadOCC parameters
26   USE had_bgc_stnd,  ONLY: kmt            ! HadOCC parameters
27   USE had_bgc_const                       ! HadOCC parameters
28   USE par_trc,       ONLY: jptra          ! Tracer parameters
29   USE bioanalysis                         ! Nitrogen balancing
30
31   IMPLICIT NONE
32   PRIVATE                   
33
34   PUBLIC asm_phyto2d_bal_hadocc
35
36   ! Default values for biological assimilation parameters
37   ! Should match Hemmings et al. (2008)
38   REAL(wp), PARAMETER :: balnutext  =  0.6    !: Default nutrient balancing factor
39   REAL(wp), PARAMETER :: balnutmin  =  0.1    !: Fraction of phytoplankton loss to nutrient
40   REAL(wp), PARAMETER :: r          =  1      !: Reliability of model specific growth rate
41   REAL(wp), PARAMETER :: beta_g     =  0.05   !: Low rate bias correction for growth rate estimator
42   REAL(wp), PARAMETER :: beta_l     =  0.05   !: Low rate bias correction for primary loss rate estimator
43   REAL(wp), PARAMETER :: beta_m     =  0.05   !: Low rate bias correction for secondary loss rate estimator
44   REAL(wp), PARAMETER :: a_g        =  0.2    !: Error s.d. for log10 of growth rate estimator
45   REAL(wp), PARAMETER :: a_l        =  0.4    !: Error s.d. for log10 of primary loss rate estimator
46   REAL(wp), PARAMETER :: a_m        =  0.7    !: Error s.d. for log10 of secondary loss rate estimator
47   REAL(wp), PARAMETER :: zfracb0    =  0.7    !: Base zooplankton fraction of loss to Z & D
48   REAL(wp), PARAMETER :: zfracb1    =  0      !: Phytoplankton sensitivity of zooplankton fraction
49   REAL(wp), PARAMETER :: qrfmax     =  1.1    !: Maximum nutrient limitation reduction factor
50   REAL(wp), PARAMETER :: qafmax     =  1.1    !: Maximum nutrient limitation amplification factor
51   REAL(wp), PARAMETER :: zrfmax     =  2      !: Maximum zooplankton reduction factor
52   REAL(wp), PARAMETER :: zafmax     =  2      !: Maximum zooplankton amplification factor
53   REAL(wp), PARAMETER :: prfmax     =  10     !: Maximum phytoplankton reduction factor (secondary)
54   REAL(wp), PARAMETER :: incphymin  =  0.0001 !: Minimum size of non-zero phytoplankton increment
55   REAL(wp), PARAMETER :: integnstep =  20     !: Number of steps for p.d.f. integral evaluation
56   REAL(wp), PARAMETER :: pthreshold =  0.01   !: Fractional threshold level for setting p.d.f.
57   !
58   LOGICAL,  PARAMETER :: diag_active           = .TRUE.  !: Depth-independent diagnostics
59   LOGICAL,  PARAMETER :: diag_fulldepth_active = .TRUE.  !: Full-depth diagnostics
60   LOGICAL,  PARAMETER :: gl_active             = .TRUE.  !: Growth/loss-based balancing
61   LOGICAL,  PARAMETER :: nbal_active           = .TRUE.  !: Nitrogen balancing
62   LOGICAL,  PARAMETER :: subsurf_active        = .TRUE.  !: Increments below MLD
63   LOGICAL,  PARAMETER :: deepneg_active        = .FALSE. !: Negative primary increments below MLD
64   LOGICAL,  PARAMETER :: deeppos_active        = .FALSE. !: Positive primary increments below MLD
65   LOGICAL,  PARAMETER :: nutprof_active        = .TRUE.  !: Secondary increments
66
67CONTAINS
68
69   SUBROUTINE asm_phyto2d_bal_hadocc( ld_chltot,                      &
70      &                               pinc_chltot,                    &
71      &                               ld_phytot,                      &
72      &                               pinc_phytot,                    &
73      &                               pincper,                        &
74      &                               p_maxchlinc, ld_phytobal, pmld, &
75      &                               pgrow_avg_bkg, ploss_avg_bkg,   &
76      &                               phyt_avg_bkg, mld_max_bkg,      &
77      &                               cchl_p_bkg,                     &
78      &                               tracer_bkg, phyto2d_balinc )
79      !!---------------------------------------------------------------------------
80      !!                    ***  ROUTINE asm_phyto2d_bal_hadocc  ***
81      !!
82      !! ** Purpose :   calculate increments to HadOCC from 2d phytoplankton increments
83      !!
84      !! ** Method  :   call nitrogen balancing scheme
85      !!
86      !! ** Action  :   populate phyto2d_balinc
87      !!
88      !! References :   Hemmings et al., 2008, J. Mar. Res.
89      !!                Ford et al., 2012, Ocean Sci.
90      !!---------------------------------------------------------------------------
91      !!
92      LOGICAL,  INTENT(in   )                               :: ld_chltot      ! Assim chltot y/n
93      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj)           :: pinc_chltot    ! chltot increments
94      LOGICAL,  INTENT(in   )                               :: ld_phytot      ! Assim phytot y/n
95      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj)           :: pinc_phytot    ! phytot increments
96      REAL(wp), INTENT(in   )                               :: pincper        ! Assimilation period
97      REAL(wp), INTENT(in   )                               :: p_maxchlinc    ! Max chl increment
98      LOGICAL,  INTENT(in   )                               :: ld_phytobal    ! Balancing y/n
99      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj)           :: pmld           ! Mixed layer depth
100      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)           :: pgrow_avg_bkg  ! Avg phyto growth
101      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)           :: ploss_avg_bkg  ! Avg phyto loss
102      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)           :: phyt_avg_bkg   ! Avg phyto
103      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)           :: mld_max_bkg    ! Max MLD
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)           :: cchl_p_bkg     ! Surface C:Chl
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk,jptra) :: tracer_bkg     ! State variables
106      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj,jpk,jptra) :: phyto2d_balinc ! Balancing increments
107      !!
108      INTEGER                                               :: ji, jj, jk, jn ! Loop counters
109      INTEGER                                               :: jkmax          ! Loop index
110      INTEGER,                 DIMENSION(6)                 :: i_tracer       ! Tracer indices
111      REAL(wp),                DIMENSION(16)                :: modparm        ! Model parameters
112      REAL(wp),                DIMENSION(20)                :: assimparm      ! Assimilation parameters
113      REAL(wp),                DIMENSION(jpi,jpj,jpk,6)     :: bstate         ! Background state
114      REAL(wp),                DIMENSION(jpi,jpj,jpk,6)     :: outincs        ! Balancing increments
115      REAL(wp),                DIMENSION(jpi,jpj,22)        :: diag           ! Depth-indep diagnostics
116      REAL(wp),                DIMENSION(jpi,jpj,jpk,22)    :: diag_fulldepth ! Full-depth diagnostics
117      !!---------------------------------------------------------------------------
118
119      IF ( ld_chltot ) THEN
120         ! If p_maxchlinc > 0 then cap total absolute chlorophyll increment at that value
121         DO jj = 1, jpj
122            DO ji = 1, jpi
123               IF ( p_maxchlinc > 0.0 ) THEN
124                  pinc_chltot(ji,jj) = MAX( -1.0 * p_maxchlinc, MIN( pinc_chltot(ji,jj), p_maxchlinc ) )
125               ENDIF
126            END DO
127         END DO
128      ELSE
129         CALL ctl_stop( ' No PFT assimilation quite yet' )
130      ENDIF
131     
132      IF ( ld_phytobal ) THEN   ! Nitrogen balancing
133
134         ! Set up model parameters to be passed into Hemmings balancing routine
135         modparm(1)  = grow_sat
136         modparm(2)  = psmax
137         modparm(3)  = par
138         modparm(4)  = alpha
139         modparm(5)  = resp_rate
140         modparm(6)  = pmort_rate
141         modparm(7)  = phyto_min
142         modparm(8)  = z_mort_1
143         modparm(9)  = z_mort_2
144         modparm(10) = c2n_p
145         modparm(11) = c2n_z
146         modparm(12) = c2n_d
147         modparm(13) = graze_threshold
148         modparm(14) = holling_coef
149         modparm(15) = graze_sat
150         modparm(16) = graze_max
151
152         ! Set up assimilation parameters to be passed into balancing routine
153         ! Not sure what assimparm(1) is meant to be, but it doesn't get used
154         assimparm(2)  = balnutext
155         assimparm(3)  = balnutmin
156         assimparm(4)  = r
157         assimparm(5)  = beta_g
158         assimparm(6)  = beta_l
159         assimparm(7)  = beta_m
160         assimparm(8)  = a_g
161         assimparm(9)  = a_l
162         assimparm(10) = a_m
163         assimparm(11) = zfracb0
164         assimparm(12) = zfracb1
165         assimparm(13) = qrfmax
166         assimparm(14) = qafmax
167         assimparm(15) = zrfmax
168         assimparm(16) = zafmax
169         assimparm(17) = prfmax
170         assimparm(18) = incphymin
171         assimparm(19) = integnstep
172         assimparm(20) = pthreshold
173
174         ! Set up external tracer indices array bstate
175         i_tracer(1) = 1   ! nutrient
176         i_tracer(2) = 2   ! phytoplankton
177         i_tracer(3) = 3   ! zooplankton
178         i_tracer(4) = 4   ! detritus
179         i_tracer(5) = 5   ! DIC
180         i_tracer(6) = 6   ! Alkalinity
181
182         ! Set background state
183         bstate(:,:,:,i_tracer(1)) = tracer_bkg(:,:,:,jp_had_nut)
184         bstate(:,:,:,i_tracer(2)) = tracer_bkg(:,:,:,jp_had_phy)
185         bstate(:,:,:,i_tracer(3)) = tracer_bkg(:,:,:,jp_had_zoo)
186         bstate(:,:,:,i_tracer(4)) = tracer_bkg(:,:,:,jp_had_pdn)
187         bstate(:,:,:,i_tracer(5)) = tracer_bkg(:,:,:,jp_had_dic)
188         bstate(:,:,:,i_tracer(6)) = tracer_bkg(:,:,:,jp_had_alk)
189
190         ! Call nitrogen balancing routine
191         CALL bio_analysis( jpi, jpj, jpk, ZDZ(:,:,:), i_tracer, modparm,               &
192            &               n2be_p, n2be_z, n2be_d, assimparm,                          &
193            &               INT(pincper), 1, kmt(:,:), tmask(:,:,:),                    &
194            &               pmld(:,:), mld_max_bkg(:,:), pinc_chltot(:,:), cchl_p_bkg(:,:), &
195            &               nbal_active, phyt_avg_bkg(:,:),                             &
196            &               gl_active, pgrow_avg_bkg(:,:), ploss_avg_bkg(:,:),          &
197            &               subsurf_active, deepneg_active,                             &
198            &               deeppos_active, nutprof_active,                             &
199            &               bstate, outincs,                                            &
200            &               diag_active, diag,                                          &
201            &               diag_fulldepth_active, diag_fulldepth )
202
203         ! Save balancing increments
204         phyto2d_balinc(:,:,:,jp_had_nut) = outincs(:,:,:,i_tracer(1))
205         phyto2d_balinc(:,:,:,jp_had_phy) = outincs(:,:,:,i_tracer(2))
206         phyto2d_balinc(:,:,:,jp_had_zoo) = outincs(:,:,:,i_tracer(3))
207         phyto2d_balinc(:,:,:,jp_had_pdn) = outincs(:,:,:,i_tracer(4))
208         phyto2d_balinc(:,:,:,jp_had_dic) = outincs(:,:,:,i_tracer(5))
209         phyto2d_balinc(:,:,:,jp_had_alk) = outincs(:,:,:,i_tracer(6))
210     
211      ELSE   ! No nitrogen balancing
212     
213         ! Initialise phytoplankton increment to zero
214         phyto2d_balinc(:,:,:,jp_had_phy) = 0.0
215         
216         ! Convert surface chlorophyll increment to phytoplankton nitrogen
217         phyto2d_balinc(:,:,1,jp_had_phy) = ( cchl_p_bkg(:,:) / (mw_carbon * c2n_p) ) * pinc_chltot(:,:)
218         
219         ! Propagate through mixed layer
220         DO jj = 1, jpj
221            DO ji = 1, jpi
222               !
223               jkmax = jpk-1
224               DO jk = jpk-1, 1, -1
225                  IF ( ( pmld(ji,jj) >  gdepw_n(ji,jj,jk)   ) .AND. &
226                     & ( pmld(ji,jj) <= gdepw_n(ji,jj,jk+1) ) ) THEN
227                     pmld(ji,jj) = gdepw_n(ji,jj,jk+1)
228                     jkmax = jk
229                  ENDIF
230               END DO
231               !
232               DO jk = 2, jkmax
233                  phyto2d_balinc(ji,jj,jk,jp_had_phy) = phyto2d_balinc(ji,jj,1,jp_had_phy)
234               END DO
235               !
236            END DO
237         END DO
238
239         ! Set other balancing increments to zero
240         phyto2d_balinc(:,:,:,jp_had_nut) = 0.0
241         phyto2d_balinc(:,:,:,jp_had_zoo) = 0.0
242         phyto2d_balinc(:,:,:,jp_had_pdn) = 0.0
243         phyto2d_balinc(:,:,:,jp_had_dic) = 0.0
244         phyto2d_balinc(:,:,:,jp_had_alk) = 0.0
245     
246      ENDIF
247
248   END SUBROUTINE asm_phyto2d_bal_hadocc
249
250#else
251   !!----------------------------------------------------------------------
252   !!   Default option : Empty routine
253   !!----------------------------------------------------------------------
254CONTAINS
255   SUBROUTINE asm_phyto2d_bal_hadocc( ld_chltot,                      &
256      &                               pinc_chltot,                    &
257      &                               ld_phytot,                      &
258      &                               pinc_phytot,                    &
259      &                               pincper,                        &
260      &                               p_maxchlinc, ld_phytobal, pmld, &
261      &                               pgrow_avg_bkg, ploss_avg_bkg,   &
262      &                               phyt_avg_bkg, mld_max_bkg,      &
263      &                               cchl_p_bkg,                     &
264      &                               tracer_bkg, phyto2d_balinc )
265      LOGICAL :: ld_chltot
266      REAL    :: pinc_chltot(:,:)
267      LOGICAL :: ld_phytot
268      REAL    :: pinc_phytot(:,:)
269      REAL    :: pincper
270      REAL    :: p_maxchlinc
271      LOGICAL :: ld_phytobal
272      REAL    :: pmld(:,:)
273      REAL    :: pgrow_avg_bkg(:,:)
274      REAL    :: ploss_avg_bkg(:,:)
275      REAL    :: phyt_avg_bkg(:,:)
276      REAL    :: mld_max_bkg(:,:)
277      REAL    :: cchl_p_bkg(:,:)
278      REAL    :: tracer_bkg(:,:,:,:)
279      REAL    :: phyto2d_balinc(:,:,:,:)
280      WRITE(*,*) 'asm_phyto2d_bal_hadocc: You should not have seen this print! error?'
281   END SUBROUTINE asm_phyto2d_bal_hadocc
282#endif
283
284   !!======================================================================
285END MODULE asmphyto2dbal_hadocc
Note: See TracBrowser for help on using the repository browser.