New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_r5518_GO6_package_asm_3d_bgc/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_asm_3d_bgc/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9292

Last change on this file since 9292 was 9292, checked in by dford, 6 years ago

Merge in changes from dev_r5518_GO6_package_asm_surf_bgc_v2.

File size: 41.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE asmbal          ! writing out biogeochemical assimilation balancing increments
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71   USE sbccpl 
72   USE cpl_oasis3      ! OASIS3 coupling
73   USE c1d             ! 1D configuration
74   USE step_c1d        ! Time stepping loop for the 1D configuration
75   USE dyndmp          ! Momentum damping
76#if defined key_top
77   USE trcini          ! passive tracer initialisation
78   USE trc, ONLY: numstr  ! tracer stats unit number
79#endif
80   USE lib_mpp         ! distributed memory computing
81#if defined key_iomput
82   USE xios
83#endif
84   USE sbctide, ONLY: lk_tide
85   USE crsini          ! initialise grid coarsening utility
86   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87   USE sbc_oce, ONLY: lk_oasis
88   USE stopar
89   USE stopts
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
99
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE nemo_gcm
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE nemo_gcm  ***
110      !!
111      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
112      !!              curvilinear mesh on the sphere.
113      !!
114      !! ** Method  : - model general initialization
115      !!              - launch the time-stepping (stp routine)
116      !!              - finalize the run by closing files and communications
117      !!
118      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
119      !!              Madec, 2008, internal report, IPSL.
120      !!----------------------------------------------------------------------
121      INTEGER ::   istp       ! time step index
122      !!----------------------------------------------------------------------
123      !
124#if defined key_agrif
125      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
126#endif
127
128      !                            !-----------------------!
129      CALL nemo_init               !==  Initialisations  ==!
130      !                            !-----------------------!
131#if defined key_agrif
132      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
133      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
134# if defined key_top
135      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
136# endif
137# if defined key_lim2
138      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
139# endif
140#endif
141      ! check that all process are still there... If some process have an error,
142      ! they will never enter in step and other processes will wait until the end of the cpu time!
143      IF( lk_mpp )   CALL mpp_max( nstop )
144
145      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
146
147      !                            !-----------------------!
148      !                            !==   time stepping   ==!
149      !                            !-----------------------!
150      istp = nit000
151#if defined key_c1d
152         DO WHILE ( istp <= nitend .AND. nstop == 0 )
153            CALL stp_c1d( istp )
154            istp = istp + 1
155         END DO
156#else
157          IF( lk_asminc ) THEN
158             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
159             IF( ln_asmdin ) THEN                        ! Direct initialization
160                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
161                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
162                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
163                IF( ln_logchlinc ) CALL logchl_asm_inc( nit000 - 1 )
164                IF( ln_fco2inc .OR. ln_pco2inc ) CALL pco2_asm_inc( nit000 - 1 )
165             ENDIF
166          ENDIF
167
168#if defined key_agrif
169          CALL Agrif_Regrid()
170#endif
171
172         DO WHILE ( istp <= nitend .AND. nstop == 0 )
173#if defined key_agrif
174            CALL stp                         ! AGRIF: time stepping
175#else
176            IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
177       CALL stp( istp )
178            ! We don't couple on the final timestep because
179            ! our restart file has already been written
180            ! and contains all the necessary data for a
181            ! restart. sbc_cpl_snd could be called here
182            ! but it would require
183            ! a) A test to ensure it was not performed
184            !    on the very last time-step
185            ! b) the presence of another call to
186            !    sbc_cpl_snd call prior to the main DO loop
187            ! This solution produces identical results
188            ! with fewer lines of code.
189#endif
190            istp = istp + 1
191            IF( lk_mpp )   CALL mpp_max( nstop )
192         END DO
193#endif
194
195      IF( lk_diaobs   )   CALL dia_obs_wri
196      !
197      IF( ( lk_asminc ).AND.( ln_balwri ) ) CALL asm_bal_wri( nitend )  ! Output balancing increments
198      !
199      IF( ln_icebergs )   CALL icb_end( nitend )
200
201      !                            !------------------------!
202      !                            !==  finalize the run  ==!
203      !                            !------------------------!
204      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
205      !
206      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
207         WRITE(numout,cform_err)
208         WRITE(numout,*) nstop, ' error have been found'
209      ENDIF
210      !
211#if defined key_agrif
212      IF( .NOT. Agrif_Root() ) THEN
213         CALL Agrif_ParentGrid_To_ChildGrid()
214         IF( lk_diaobs ) CALL dia_obs_wri
215         IF( nn_timing == 1 )   CALL timing_finalize
216         CALL Agrif_ChildGrid_To_ParentGrid()
217      ENDIF
218#endif
219      IF( nn_timing == 1 )   CALL timing_finalize
220      !
221      CALL nemo_closefile
222      !
223#if defined key_iomput
224      CALL xios_finalize                ! end mpp communications with xios
225      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
226#else
227      IF( lk_oasis ) THEN
228         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
229      ELSE
230         IF( lk_mpp )   CALL mppstop    ! end mpp communications
231      ENDIF
232#endif
233      !
234      ! Met Office addition: if failed, return non-zero exit code
235      IF( nstop /= 0 )  CALL exit( 9 ) 
236      !
237   END SUBROUTINE nemo_gcm
238
239
240   SUBROUTINE nemo_init
241      !!----------------------------------------------------------------------
242      !!                     ***  ROUTINE nemo_init  ***
243      !!
244      !! ** Purpose :   initialization of the NEMO GCM
245      !!----------------------------------------------------------------------
246      INTEGER ::   ji            ! dummy loop indices
247      INTEGER ::   ilocal_comm   ! local integer
248      INTEGER ::   ios
249      CHARACTER(len=80), DIMENSION(16) ::   cltxt
250      !
251      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
252         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
253         &             nn_bench, nn_timing
254      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
255         &             jpizoom, jpjzoom, jperio, ln_use_jattr
256      !!----------------------------------------------------------------------
257      !
258      cltxt = ''
259      cxios_context = 'nemo'
260      !
261      !                             ! Open reference namelist and configuration namelist files
262      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
263      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
264      !
265      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
266      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
267901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
268
269      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
270      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
271902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
272
273      !
274      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
275      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
276903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
277
278      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
279      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
280904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
281
282! Force values for AGRIF zoom (cf. agrif_user.F90)
283#if defined key_agrif
284   IF( .NOT. Agrif_Root() ) THEN
285      jpiglo  = nbcellsx + 2 + 2*nbghostcells
286      jpjglo  = nbcellsy + 2 + 2*nbghostcells
287      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
288      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
289      jpidta  = jpiglo
290      jpjdta  = jpjglo
291      jpizoom = 1
292      jpjzoom = 1
293      nperio  = 0
294      jperio  = 0
295      ln_use_jattr = .false.
296   ENDIF
297#endif
298      !
299      !                             !--------------------------------------------!
300      !                             !  set communicator & select the local node  !
301      !                             !  NB: mynode also opens output.namelist.dyn !
302      !                             !      on unit number numond on first proc   !
303      !                             !--------------------------------------------!
304#if defined key_iomput
305      IF( Agrif_Root() ) THEN
306         IF( lk_oasis ) THEN
307            CALL cpl_init( "toyoce", ilocal_comm )                     ! nemo local communicator given by oasis
308            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
309         ELSE
310            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
311         ENDIF
312      ENDIF
313      ! Nodes selection (control print return in cltxt)
314      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
315#else
316      IF( lk_oasis ) THEN
317         IF( Agrif_Root() ) THEN
318            CALL cpl_init( "toyoce", ilocal_comm )                      ! nemo local communicator given by oasis
319         ENDIF
320         ! Nodes selection (control print return in cltxt)
321         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
322      ELSE
323         ilocal_comm = 0
324         ! Nodes selection (control print return in cltxt)
325         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
326      ENDIF
327#endif
328      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
329
330      lwm = (narea == 1)                                    ! control of output namelists
331      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
332
333      IF(lwm) THEN
334         ! write merged namelists from earlier to output namelist now that the
335         ! file has been opened in call to mynode. nammpp has already been
336         ! written in mynode (if lk_mpp_mpi)
337         WRITE( numond, namctl )
338         WRITE( numond, namcfg )
339      ENDIF
340
341      ! If dimensions of processor grid weren't specified in the namelist file
342      ! then we calculate them here now that we have our communicator size
343      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
344#if   defined key_mpp_mpi
345         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
346#else
347         jpni  = 1
348         jpnj  = 1
349         jpnij = jpni*jpnj
350#endif
351      END IF
352
353      ! Calculate domain dimensions given calculated jpni and jpnj
354      ! This used to be done in par_oce.F90 when they were parameters rather
355      ! than variables
356      IF( Agrif_Root() ) THEN
357#if defined key_nemocice_decomp
358         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
359         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
360#else
361         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
362         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
363#endif
364      ENDIF         
365         jpk = jpkdta                                             ! third dim
366#if defined key_agrif
367         ! simple trick to use same vertical grid as parent
368         ! but different number of levels:
369         ! Save maximum number of levels in jpkdta, then define all vertical grids
370         ! with this number.
371         ! Suppress once vertical online interpolation is ok
372         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
373#endif
374         jpim1 = jpi-1                                            ! inner domain indices
375         jpjm1 = jpj-1                                            !   "           "
376         jpkm1 = jpk-1                                            !   "           "
377         jpij  = jpi*jpj                                          !  jpi x j
378
379      IF(lwp) THEN                            ! open listing units
380         !
381         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
382         !
383         WRITE(numout,*)
384         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
385         WRITE(numout,*) '                       NEMO team'
386         WRITE(numout,*) '            Ocean General Circulation Model'
387         WRITE(numout,*) '                  version 3.6  (2015) '
388         WRITE(numout,*)
389         WRITE(numout,*)
390         DO ji = 1, SIZE(cltxt)
391            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
392         END DO
393         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
394         !
395      ENDIF
396
397      ! Now we know the dimensions of the grid and numout has been set we can
398      ! allocate arrays
399      CALL nemo_alloc()
400
401      !                             !-------------------------------!
402      !                             !  NEMO general initialization  !
403      !                             !-------------------------------!
404
405      CALL nemo_ctl                          ! Control prints & Benchmark
406
407      !                                      ! Domain decomposition
408      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
409      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
410      ENDIF
411      !
412      IF( nn_timing == 1 )  CALL timing_init
413      !
414      !                                      ! General initialization
415                            CALL     phy_cst    ! Physical constants
416                            CALL     eos_init   ! Equation of state
417      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
418                            CALL     dom_cfg    ! Domain configuration
419                            CALL     dom_init   ! Domain
420
421      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
422
423      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
424
425                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
426
427      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
428
429                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
430
431      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
432      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
433      IF( lk_bdy .AND. lk_tide )   &
434         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
435
436                            CALL dyn_nept_init  ! simplified form of Neptune effect
437      !     
438      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
439      !
440                                ! Ocean physics
441      !                                         ! Vertical physics
442                            CALL     zdf_init      ! namelist read
443                            CALL zdf_bfr_init      ! bottom friction
444      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
445      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
446      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
447      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
448      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
449      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
450         &                  CALL zdf_ddm_init      ! double diffusive mixing
451      !                                         ! Lateral physics
452                            CALL ldf_tra_init      ! Lateral ocean tracer physics
453                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
454      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
455
456      !                                     ! Active tracers
457                            CALL tra_qsr_init   ! penetrative solar radiation qsr
458                            CALL tra_bbc_init   ! bottom heat flux
459      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
460                            CALL tra_dmp_init   ! internal damping trends- tracers
461                            CALL tra_adv_init   ! horizontal & vertical advection
462                            CALL tra_ldf_init   ! lateral mixing
463                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
464
465      !                                     ! Dynamics
466      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
467                            CALL dyn_adv_init   ! advection (vector or flux form)
468                            CALL dyn_vor_init   ! vorticity term including Coriolis
469                            CALL dyn_ldf_init   ! lateral mixing
470                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
471                            CALL dyn_zdf_init   ! vertical diffusion
472                            CALL dyn_spg_init   ! surface pressure gradient
473
474      !                                     ! Misc. options
475      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
476                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
477                            CALL sto_par_init   ! Stochastic parametrization
478      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
479     
480#if defined key_top
481      !                                     ! Passive tracers
482                            CALL     trc_init
483#endif
484      !                                     ! Diagnostics
485      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
486                            CALL dia_ptr_init   ! Poleward TRansports initialization
487      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
488                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
489                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
490                            CALL     bias_init  ! Pressure correction bias
491      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
492                            CALL dia_obs_init            ! Initialize observational data
493                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
494      ENDIF
495
496      !                                     ! Assimilation increments
497      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
498      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
499     
500      IF (nstop > 0) THEN
501        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
502      END IF
503
504      !
505   END SUBROUTINE nemo_init
506
507
508   SUBROUTINE nemo_ctl
509      !!----------------------------------------------------------------------
510      !!                     ***  ROUTINE nemo_ctl  ***
511      !!
512      !! ** Purpose :   control print setting
513      !!
514      !! ** Method  : - print namctl information and check some consistencies
515      !!----------------------------------------------------------------------
516      !
517      IF(lwp) THEN                  ! control print
518         WRITE(numout,*)
519         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
520         WRITE(numout,*) '~~~~~~~ '
521         WRITE(numout,*) '   Namelist namctl'
522         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
523         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
524         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
525         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
526         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
527         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
528         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
529         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
530         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
531         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
532      ENDIF
533      !
534      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
535      nictls    = nn_ictls
536      nictle    = nn_ictle
537      njctls    = nn_jctls
538      njctle    = nn_jctle
539      isplt     = nn_isplt
540      jsplt     = nn_jsplt
541      nbench    = nn_bench
542
543      IF(lwp) THEN                  ! control print
544         WRITE(numout,*)
545         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
546         WRITE(numout,*) '~~~~~~~ '
547         WRITE(numout,*) '   Namelist namcfg'
548         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
549         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
550         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
551         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
552         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
553         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
554         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
555         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
556         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
557         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
558         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
559         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
560      ENDIF
561      !                             ! Parameter control
562      !
563      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
564         IF( lk_mpp .AND. jpnij > 1 ) THEN
565            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
566         ELSE
567            IF( isplt == 1 .AND. jsplt == 1  ) THEN
568               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
569                  &           ' - the print control will be done over the whole domain' )
570            ENDIF
571            ijsplt = isplt * jsplt            ! total number of processors ijsplt
572         ENDIF
573         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
574         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
575         !
576         !                              ! indices used for the SUM control
577         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
578            lsp_area = .FALSE.
579         ELSE                                             ! print control done over a specific  area
580            lsp_area = .TRUE.
581            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
582               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
583               nictls = 1
584            ENDIF
585            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
586               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
587               nictle = jpiglo
588            ENDIF
589            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
590               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
591               njctls = 1
592            ENDIF
593            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
594               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
595               njctle = jpjglo
596            ENDIF
597         ENDIF
598      ENDIF
599      !
600      IF( nbench == 1 ) THEN              ! Benchmark
601         SELECT CASE ( cp_cfg )
602         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
603         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
604            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
605         END SELECT
606      ENDIF
607      !
608      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
609         &                                               'f2003 standard. '                              ,  &
610         &                                               'Compile with key_nosignedzero enabled' )
611      !
612   END SUBROUTINE nemo_ctl
613
614
615   SUBROUTINE nemo_closefile
616      !!----------------------------------------------------------------------
617      !!                     ***  ROUTINE nemo_closefile  ***
618      !!
619      !! ** Purpose :   Close the files
620      !!----------------------------------------------------------------------
621      !
622      IF( lk_mpp )   CALL mppsync
623      !
624      CALL iom_close                                 ! close all input/output files managed by iom_*
625      !
626      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
627      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
628      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
629      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
630      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
631      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
632      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
633      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
634      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
635      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
636      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
637      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
638      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
639#if defined key_top
640      IF( numstr          /= -1 )   CLOSE( numstr          )   ! tracer statistics
641#endif
642      !
643      numout = 6                                     ! redefine numout in case it is used after this point...
644      !
645   END SUBROUTINE nemo_closefile
646
647
648   SUBROUTINE nemo_alloc
649      !!----------------------------------------------------------------------
650      !!                     ***  ROUTINE nemo_alloc  ***
651      !!
652      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
653      !!
654      !! ** Method  :
655      !!----------------------------------------------------------------------
656      USE diawri    , ONLY: dia_wri_alloc
657      USE insitu_tem, ONLY: insitu_tem_alloc
658      USE dom_oce   , ONLY: dom_oce_alloc
659      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
660      USE ldftra_oce, ONLY: ldftra_oce_alloc
661      USE trc_oce   , ONLY: trc_oce_alloc
662#if defined key_diadct 
663      USE diadct    , ONLY: diadct_alloc 
664#endif 
665#if defined key_bdy
666      USE bdy_oce   , ONLY: bdy_oce_alloc
667#endif
668      !
669      INTEGER :: ierr
670      !!----------------------------------------------------------------------
671      !
672      ierr =        oce_alloc       ()          ! ocean
673      ierr = ierr + dia_wri_alloc   ()
674      ierr = ierr + insitu_tem_alloc()
675      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
676      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
677      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
678      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
679      !
680      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
681      !
682#if defined key_diadct 
683      ierr = ierr + diadct_alloc    ()          !
684#endif 
685#if defined key_bdy
686      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
687#endif
688      !
689      IF( lk_mpp    )   CALL mpp_sum( ierr )
690      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
691      !
692   END SUBROUTINE nemo_alloc
693
694
695   SUBROUTINE nemo_partition( num_pes )
696      !!----------------------------------------------------------------------
697      !!                 ***  ROUTINE nemo_partition  ***
698      !!
699      !! ** Purpose :
700      !!
701      !! ** Method  :
702      !!----------------------------------------------------------------------
703      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
704      !
705      INTEGER, PARAMETER :: nfactmax = 20
706      INTEGER :: nfact ! The no. of factors returned
707      INTEGER :: ierr  ! Error flag
708      INTEGER :: ji
709      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
710      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
711      !!----------------------------------------------------------------------
712      !
713      ierr = 0
714      !
715      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
716      !
717      IF( nfact <= 1 ) THEN
718         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
719         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
720         jpnj = 1
721         jpni = num_pes
722      ELSE
723         ! Search through factors for the pair that are closest in value
724         mindiff = 1000000
725         imin    = 1
726         DO ji = 1, nfact-1, 2
727            idiff = ABS( ifact(ji) - ifact(ji+1) )
728            IF( idiff < mindiff ) THEN
729               mindiff = idiff
730               imin = ji
731            ENDIF
732         END DO
733         jpnj = ifact(imin)
734         jpni = ifact(imin + 1)
735      ENDIF
736      !
737      jpnij = jpni*jpnj
738      !
739   END SUBROUTINE nemo_partition
740
741
742   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
743      !!----------------------------------------------------------------------
744      !!                     ***  ROUTINE factorise  ***
745      !!
746      !! ** Purpose :   return the prime factors of n.
747      !!                knfax factors are returned in array kfax which is of
748      !!                maximum dimension kmaxfax.
749      !! ** Method  :
750      !!----------------------------------------------------------------------
751      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
752      INTEGER                    , INTENT(  out) ::   kerr, knfax
753      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
754      !
755      INTEGER :: ifac, jl, inu
756      INTEGER, PARAMETER :: ntest = 14
757      INTEGER, DIMENSION(ntest) :: ilfax
758      !
759      ! ilfax contains the set of allowed factors.
760      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
761      !!----------------------------------------------------------------------
762      ! ilfax contains the set of allowed factors.
763      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
764
765      ! Clear the error flag and initialise output vars
766      kerr = 0
767      kfax = 1
768      knfax = 0
769
770      ! Find the factors of n.
771      IF( kn == 1 )   GOTO 20
772
773      ! nu holds the unfactorised part of the number.
774      ! knfax holds the number of factors found.
775      ! l points to the allowed factor list.
776      ! ifac holds the current factor.
777
778      inu   = kn
779      knfax = 0
780
781      DO jl = ntest, 1, -1
782         !
783         ifac = ilfax(jl)
784         IF( ifac > inu )   CYCLE
785
786         ! Test whether the factor will divide.
787
788         IF( MOD(inu,ifac) == 0 ) THEN
789            !
790            knfax = knfax + 1            ! Add the factor to the list
791            IF( knfax > kmaxfax ) THEN
792               kerr = 6
793               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
794               return
795            ENDIF
796            kfax(knfax) = ifac
797            ! Store the other factor that goes with this one
798            knfax = knfax + 1
799            kfax(knfax) = inu / ifac
800            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
801         ENDIF
802         !
803      END DO
804
805   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
806      !
807   END SUBROUTINE factorise
808
809#if defined key_mpp_mpi
810
811   SUBROUTINE nemo_northcomms
812      !!======================================================================
813      !!                     ***  ROUTINE  nemo_northcomms  ***
814      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
815      !!                       point-to-point messaging
816      !!=====================================================================
817      !!----------------------------------------------------------------------
818      !!
819      !! ** Purpose :   Initialization of the northern neighbours lists.
820      !!----------------------------------------------------------------------
821      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
822      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
823      !!----------------------------------------------------------------------
824
825      INTEGER  ::   sxM, dxM, sxT, dxT, jn
826      INTEGER  ::   njmppmax
827
828      njmppmax = MAXVAL( njmppt )
829   
830      !initializes the north-fold communication variables
831      isendto(:) = 0
832      nsndto = 0
833
834      !if I am a process in the north
835      IF ( njmpp == njmppmax ) THEN
836          !sxM is the first point (in the global domain) needed to compute the
837          !north-fold for the current process
838          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
839          !dxM is the last point (in the global domain) needed to compute the
840          !north-fold for the current process
841          dxM = jpiglo - nimppt(narea) + 2
842
843          !loop over the other north-fold processes to find the processes
844          !managing the points belonging to the sxT-dxT range
845 
846          DO jn = 1, jpni
847                !sxT is the first point (in the global domain) of the jn
848                !process
849                sxT = nfiimpp(jn, jpnj)
850                !dxT is the last point (in the global domain) of the jn
851                !process
852                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
853                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
854                   nsndto = nsndto + 1
855                     isendto(nsndto) = jn
856                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
857                   nsndto = nsndto + 1
858                     isendto(nsndto) = jn
859                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
860                   nsndto = nsndto + 1
861                     isendto(nsndto) = jn
862                END IF
863          END DO
864          nfsloop = 1
865          nfeloop = nlci
866          DO jn = 2,jpni-1
867           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
868              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
869                 nfsloop = nldi
870              ENDIF
871              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
872                 nfeloop = nlei
873              ENDIF
874           ENDIF
875        END DO
876
877      ENDIF
878      l_north_nogather = .TRUE.
879   END SUBROUTINE nemo_northcomms
880#else
881   SUBROUTINE nemo_northcomms      ! Dummy routine
882      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
883   END SUBROUTINE nemo_northcomms
884#endif
885
886   !!======================================================================
887END MODULE nemogcm
888
889
Note: See TracBrowser for help on using the repository browser.