source: branches/UKMO/dev_r5518_GO6_package_asm_surf_bgc_v2/NEMOGCM/NEMO/OPA_SRC/ZDF/zdftmx.F90 @ 8495

Last change on this file since 8495 was 8495, checked in by dford, 3 years ago

Merge in changes from dev_r5518_GO6_package_asm_surf_bgc, and adapt to the updated MEDUSA structure.

File size: 52.7 KB
Line 
1MODULE zdftmx
2   !!========================================================================
3   !!                       ***  MODULE  zdftmx  ***
4   !! Ocean physics: vertical tidal mixing coefficient
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy) Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
9   !!----------------------------------------------------------------------
10#if defined key_zdftmx   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdftmx'                                  Tidal vertical mixing
13   !!----------------------------------------------------------------------
14   !!   zdf_tmx       : global     momentum & tracer Kz with tidal induced Kz
15   !!   tmx_itf       : Indonesian momentum & tracer Kz with tidal induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE eosbn2         ! ocean equation of state
22   USE phycst         ! physical constants
23   USE prtctl         ! Print control
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O Manager
26   USE lib_mpp        ! MPP library
27   USE wrk_nemo       ! work arrays
28   USE timing         ! Timing
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   zdf_tmx         ! called in step module
35   PUBLIC   zdf_tmx_init    ! called in opa module
36   PUBLIC   zdf_tmx_alloc   ! called in nemogcm module
37
38   LOGICAL, PUBLIC, PARAMETER ::   lk_zdftmx = .TRUE.    !: tidal mixing flag
39
40   !                              !!* Namelist  namzdf_tmx : tidal mixing *
41   REAL(wp)        ::  rn_htmx     ! vertical decay scale for turbulence (meters)
42   REAL(wp)        ::  rn_n2min    ! threshold of the Brunt-Vaisala frequency (s-1)
43   REAL(wp)        ::  rn_tfe      ! tidal dissipation efficiency (St Laurent et al. 2002)
44   REAL(wp)        ::  rn_me       ! mixing efficiency (Osborn 1980)
45   LOGICAL, PUBLIC ::  ln_tmx_itf  ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization
46   REAL(wp)        ::  rn_tfe_itf  ! ITF tidal dissipation efficiency (St Laurent et al. 2002)
47
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)         ::   en_tmx     ! energy available for tidal mixing (W/m2)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::   mask_itf   ! mask to use over Indonesian area
50   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:)       ::   az_tmx     ! coefficient used to evaluate the tidal induced Kz
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   INTEGER FUNCTION zdf_tmx_alloc()
63      !!----------------------------------------------------------------------
64      !!                ***  FUNCTION zdf_tmx_alloc  ***
65      !!----------------------------------------------------------------------
66      ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc )
67      !
68      IF( lk_mpp             )   CALL mpp_sum ( zdf_tmx_alloc )
69      IF( zdf_tmx_alloc /= 0 )   CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays')
70   END FUNCTION zdf_tmx_alloc
71
72
73   SUBROUTINE zdf_tmx( kt )
74      !!----------------------------------------------------------------------
75      !!                  ***  ROUTINE zdf_tmx  ***
76      !!                   
77      !! ** Purpose :   add to the vertical mixing coefficients the effect of
78      !!              tidal mixing (Simmons et al 2004).
79      !!
80      !! ** Method  : - tidal-induced vertical mixing is given by:
81      !!                  Kz_tides = az_tmx / max( rn_n2min, N^2 )
82      !!              where az_tmx is a coefficient that specified the 3D space
83      !!              distribution of the faction of tidal energy taht is used
84      !!              for mixing. Its expression is set in zdf_tmx_init routine,
85      !!              following Simmons et al. 2004.
86      !!                NB: a specific bounding procedure is performed on av_tide
87      !!              so that the input tidal energy is actually almost used. The
88      !!              basic maximum value is 60 cm2/s, but values of 300 cm2/s
89      !!              can be reached in area where bottom stratification is too
90      !!              weak.
91      !!
92      !!              - update av_tide in the Indonesian Through Flow area
93      !!              following Koch-Larrouy et al. (2007) parameterisation
94      !!              (see tmx_itf routine).
95      !!
96      !!              - update the model vertical eddy viscosity and diffusivity:
97      !!                     avt  = avt  +    av_tides
98      !!                     avm  = avm  +    av_tides
99      !!                     avmu = avmu + mi(av_tides)
100      !!                     avmv = avmv + mj(av_tides)
101      !!
102      !! ** Action  :   avt, avm, avmu, avmv   increased by tidal mixing
103      !!
104      !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263.
105      !!              Koch-Larrouy et al. 2007, GRL.
106      !!----------------------------------------------------------------------
107      USE oce, zav_tide  =>   ua    ! use ua as workspace
108      !!
109      INTEGER, INTENT(in) ::   kt   ! ocean time-step
110      !!
111      INTEGER  ::   ji, jj, jk   ! dummy loop indices
112      REAL(wp) ::   ztpc         ! scalar workspace
113      REAL(wp), POINTER, DIMENSION(:,:) ::   zkz
114      !!----------------------------------------------------------------------
115      !
116      IF( nn_timing == 1 )  CALL timing_start('zdf_tmx')
117      !
118      CALL wrk_alloc( jpi,jpj, zkz )
119
120      !                          ! ----------------------- !
121      !                          !  Standard tidal mixing  !  (compute zav_tide)
122      !                          ! ----------------------- !
123      !                             !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s
124      zav_tide(:,:,:) = MIN(  60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) )  )
125
126      zkz(:,:) = 0.e0               !* Associated potential energy consummed over the whole water column
127      DO jk = 2, jpkm1
128         zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk)
129      END DO
130
131      DO jj = 1, jpj                !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
132         DO ji = 1, jpi
133            IF( zkz(ji,jj) /= 0.e0 )   zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj)
134         END DO
135      END DO
136
137      DO jk = 2, jpkm1     !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s
138         DO jj = 1, jpj                !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
139            DO ji = 1, jpi
140               zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk)  !kz max = 300 cm2/s
141            END DO
142         END DO
143      END DO
144
145      IF( kt == nit000 ) THEN       !* check at first time-step: diagnose the energy consumed by zav_tide
146         ztpc = 0.e0
147         DO jk= 1, jpk
148            DO jj= 1, jpj
149               DO ji= 1, jpi
150                  ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj)   &
151                     &         * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj)
152               END DO
153            END DO
154         END DO
155         ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc
156         IF(lwp) WRITE(numout,*) 
157         IF(lwp) WRITE(numout,*) '          N Total power consumption by av_tide    : ztpc = ', ztpc * 1.e-12 ,'TW'
158      ENDIF
159       
160      !                          ! ----------------------- !
161      !                          !    ITF  tidal mixing    !  (update zav_tide)
162      !                          ! ----------------------- !
163      IF( ln_tmx_itf )   CALL tmx_itf( kt, zav_tide )
164
165      !                          ! ----------------------- !
166      !                          !   Update  mixing coefs  !                         
167      !                          ! ----------------------- !
168      DO jk = 2, jpkm1              !* update momentum & tracer diffusivity with tidal mixing
169         DO jj = 1, jpj                !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
170            DO ji = 1, jpi
171               avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
172               avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
173            END DO
174         END DO
175      END DO
176     
177      DO jk = 2, jpkm1              !* update momentum & tracer diffusivity with tidal mixing
178         DO jj = 2, jpjm1
179            DO ji = fs_2, fs_jpim1  ! vector opt.
180               avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj  ,jk) ) * wumask(ji,jj,jk)
181               avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji  ,jj+1,jk) ) * wvmask(ji,jj,jk)
182            END DO
183         END DO
184      END DO
185      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )      ! lateral boundary condition
186
187      !                             !* output tidal mixing coefficient
188      CALL iom_put( "av_tide", zav_tide )
189
190      IF(ln_ctl)   CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
191      !
192      CALL wrk_dealloc( jpi,jpj, zkz )
193      !
194      IF( nn_timing == 1 )  CALL timing_stop('zdf_tmx')
195      !
196   END SUBROUTINE zdf_tmx
197
198
199   SUBROUTINE tmx_itf( kt, pav )
200      !!----------------------------------------------------------------------
201      !!                  ***  ROUTINE tmx_itf  ***
202      !!                   
203      !! ** Purpose :   modify the vertical eddy diffusivity coefficients
204      !!              (pav) in the Indonesian Through Flow area (ITF).
205      !!
206      !! ** Method  : - Following Koch-Larrouy et al. (2007), in the ITF defined
207      !!                by msk_itf (read in a file, see tmx_init), the tidal
208      !!                mixing coefficient is computed with :
209      !!                  * q=1 (i.e. all the tidal energy remains trapped in
210      !!                         the area and thus is used for mixing)
211      !!                  * the vertical distribution of the tifal energy is a
212      !!                    proportional to N above the thermocline (d(N^2)/dz > 0)
213      !!                    and to N^2 below the thermocline (d(N^2)/dz < 0)
214      !!
215      !! ** Action  :   av_tide   updated in the ITF area (msk_itf)
216      !!
217      !! References :  Koch-Larrouy et al. 2007, GRL
218      !!----------------------------------------------------------------------
219      INTEGER , INTENT(in   )                         ::   kt   ! ocean time-step
220      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   pav  ! Tidal mixing coef.
221      !!
222      INTEGER  ::   ji, jj, jk    ! dummy loop indices
223      REAL(wp) ::   zcoef, ztpc   ! temporary scalar
224      REAL(wp), DIMENSION(:,:)  , POINTER ::   zkz                        ! 2D workspace
225      REAL(wp), DIMENSION(:,:)  , POINTER ::   zsum1 , zsum2 , zsum       !  -      -
226      REAL(wp), DIMENSION(:,:,:), POINTER ::   zempba_3d_1, zempba_3d_2   ! 3D workspace
227      REAL(wp), DIMENSION(:,:,:), POINTER ::   zempba_3d  , zdn2dz        !  -      -
228      REAL(wp), DIMENSION(:,:,:), POINTER ::   zavt_itf                   !  -      -
229      !!----------------------------------------------------------------------
230      !
231      IF( nn_timing == 1 )  CALL timing_start('tmx_itf')
232      !
233      CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum )
234      CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf )
235
236      !                             ! compute the form function using N2 at each time step
237      zempba_3d_1(:,:,jpk) = 0.e0
238      zempba_3d_2(:,:,jpk) = 0.e0
239      DO jk = 1, jpkm1             
240         zdn2dz     (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1)           ! Vertical profile of dN2/dz
241!CDIR NOVERRCHK
242         zempba_3d_1(:,:,jk) = SQRT(  MAX( 0.e0, rn2(:,:,jk) )  )    !    -        -    of N
243         zempba_3d_2(:,:,jk) =        MAX( 0.e0, rn2(:,:,jk) )       !    -        -    of N^2
244      END DO
245      !
246      zsum (:,:) = 0.e0
247      zsum1(:,:) = 0.e0
248      zsum2(:,:) = 0.e0
249      DO jk= 2, jpk
250         zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)
251         zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)               
252      END DO
253      DO jj = 1, jpj
254         DO ji = 1, jpi
255            IF( zsum1(ji,jj) /= 0.e0 )   zsum1(ji,jj) = 1.e0 / zsum1(ji,jj)
256            IF( zsum2(ji,jj) /= 0.e0 )   zsum2(ji,jj) = 1.e0 / zsum2(ji,jj)               
257         END DO
258      END DO
259
260      DO jk= 1, jpk
261         DO jj = 1, jpj
262            DO ji = 1, jpi
263               zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) )       ! =0 if dN2/dz > 0, =1 otherwise
264               ztpc  = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) *        zcoef     &
265                  &  + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef )
266               !
267               zempba_3d(ji,jj,jk) =               ztpc 
268               zsum     (ji,jj)    = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk)
269            END DO
270         END DO
271       END DO
272       DO jj = 1, jpj
273          DO ji = 1, jpi
274             IF( zsum(ji,jj) > 0.e0 )   zsum(ji,jj) = 1.e0 / zsum(ji,jj)               
275          END DO
276       END DO
277
278      !                             ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min)
279      zcoef = rn_tfe_itf / ( rn_tfe * rau0 )
280      DO jk = 1, jpk
281         zavt_itf(:,:,jk) = MIN(  10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk)   &
282            &                                      / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk)  )
283      END DO           
284
285      zkz(:,:) = 0.e0               ! Associated potential energy consummed over the whole water column
286      DO jk = 2, jpkm1
287         zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1)
288      END DO
289
290      DO jj = 1, jpj                ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx
291         DO ji = 1, jpi
292            IF( zkz(ji,jj) /= 0.e0 )   zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj)
293         END DO
294      END DO
295
296      DO jk = 2, jpkm1              ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s
297         zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * tmask(:,:,jk) * tmask(:,:,jk-1)   ! kz max = 120 cm2/s
298      END DO
299
300      IF( kt == nit000 ) THEN       ! diagnose the nergy consumed by zavt_itf
301         ztpc = 0.e0
302         DO jk= 1, jpk
303            DO jj= 1, jpj
304               DO ji= 1, jpi
305                  ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) )   &
306                     &                     * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj)
307               END DO
308            END DO
309         END DO
310         ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf )
311         IF(lwp) WRITE(numout,*) '          N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW'
312      ENDIF
313
314      !                             ! Update pav with the ITF mixing coefficient
315      DO jk = 2, jpkm1
316         pav(:,:,jk) = pav     (:,:,jk) * ( 1.e0 - mask_itf(:,:) )   &
317            &        + zavt_itf(:,:,jk) *          mask_itf(:,:) 
318      END DO
319      !
320      CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum )
321      CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf )
322      !
323      IF( nn_timing == 1 )  CALL timing_stop('tmx_itf')
324      !
325   END SUBROUTINE tmx_itf
326
327
328   SUBROUTINE zdf_tmx_init
329      !!----------------------------------------------------------------------
330      !!                  ***  ROUTINE zdf_tmx_init  ***
331      !!                     
332      !! ** Purpose :   Initialization of the vertical tidal mixing, Reading
333      !!              of M2 and K1 tidal energy in nc files
334      !!
335      !! ** Method  : - Read the namtmx namelist and check the parameters
336      !!
337      !!              - Read the input data in NetCDF files :
338      !!              M2 and K1 tidal energy. The total tidal energy, en_tmx,
339      !!              is the sum of M2, K1 and S2 energy where S2 is assumed
340      !!              to be: S2=(1/2)^2 * M2
341      !!              mask_itf, a mask array that determine where substituing
342      !!              the standard Simmons et al. (2005) formulation with the
343      !!              one of Koch_Larrouy et al. (2007).
344      !!
345      !!              - Compute az_tmx, a 3D coefficient that allows to compute
346      !!             the standard tidal-induced vertical mixing as follows:
347      !!                  Kz_tides = az_tmx / max( rn_n2min, N^2 )
348      !!             with az_tmx a bottom intensified coefficient is given by:
349      !!                 az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx )
350      !!                                                  / ( 1. - EXP( - H   /rn_htmx ) )
351      !!             where rn_htmx the characteristic length scale of the bottom
352      !!             intensification, en_tmx the tidal energy, and H the ocean depth
353      !!
354      !! ** input   :   - Namlist namtmx
355      !!                - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc
356      !!
357      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
358      !!              - defined az_tmx used to compute tidal-induced mixing
359      !!
360      !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263.
361      !!              Koch-Larrouy et al. 2007, GRL.
362      !!----------------------------------------------------------------------
363      USE oce     ,         zav_tide =>  ua         ! ua used as workspace
364      !!
365      INTEGER  ::   ji, jj, jk   ! dummy loop indices
366      INTEGER  ::   inum         ! local integer
367      INTEGER  ::   ios
368      REAL(wp) ::   ztpc, ze_z   ! local scalars
369      REAL(wp), DIMENSION(:,:)  , POINTER ::  zem2, zek1   ! read M2 and K1 tidal energy
370      REAL(wp), DIMENSION(:,:)  , POINTER ::  zkz          ! total M2, K1 and S2 tidal energy
371      REAL(wp), DIMENSION(:,:)  , POINTER ::  zfact        ! used for vertical structure function
372      REAL(wp), DIMENSION(:,:)  , POINTER ::  zhdep        ! Ocean depth
373      REAL(wp), DIMENSION(:,:,:), POINTER ::  zpc      ! power consumption
374      !!
375      NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf
376      !!----------------------------------------------------------------------
377      !
378      IF( nn_timing == 1 )  CALL timing_start('zdf_tmx_init')
379      !
380      CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep )
381      CALL wrk_alloc( jpi,jpj,jpk, zpc )
382     
383      REWIND( numnam_ref )              ! Namelist namzdf_tmx in reference namelist : Tidal Mixing
384      READ  ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901)
385901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp )
386
387      REWIND( numnam_cfg )              ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing
388      READ  ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 )
389902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp )
390      IF(lwm) WRITE ( numond, namzdf_tmx )
391
392      IF(lwp) THEN                   ! Control print
393         WRITE(numout,*)
394         WRITE(numout,*) 'zdf_tmx_init : tidal mixing'
395         WRITE(numout,*) '~~~~~~~~~~~~'
396         WRITE(numout,*) '   Namelist namzdf_tmx : set tidal mixing parameters'
397         WRITE(numout,*) '      Vertical decay scale for turbulence   = ', rn_htmx 
398         WRITE(numout,*) '      Brunt-Vaisala frequency threshold     = ', rn_n2min
399         WRITE(numout,*) '      Tidal dissipation efficiency          = ', rn_tfe
400         WRITE(numout,*) '      Mixing efficiency                     = ', rn_me
401         WRITE(numout,*) '      ITF specific parameterisation         = ', ln_tmx_itf
402         WRITE(numout,*) '      ITF tidal dissipation efficiency      = ', rn_tfe_itf
403      ENDIF
404
405      !                              ! allocate tmx arrays
406      IF( zdf_tmx_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' )
407
408      IF( ln_tmx_itf ) THEN          ! read the Indonesian Through Flow mask
409         CALL iom_open('mask_itf',inum)
410         CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) !
411         CALL iom_close(inum)
412      ENDIF
413
414      ! read M2 tidal energy flux : W/m2  ( zem2 < 0 )
415      CALL iom_open('M2rowdrg',inum)
416      CALL iom_get (inum, jpdom_data, 'field',zem2,1) !
417      CALL iom_close(inum)
418
419      ! read K1 tidal energy flux : W/m2  ( zek1 < 0 )
420      CALL iom_open('K1rowdrg',inum)
421      CALL iom_get (inum, jpdom_data, 'field',zek1,1) !
422      CALL iom_close(inum)
423 
424      ! Total tidal energy ( M2, S2 and K1  with S2=(1/2)^2 * M2 )
425      ! only the energy available for mixing is taken into account,
426      ! (mixing efficiency tidal dissipation efficiency)
427      en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:)
428
429!============
430!TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep?
431      ! Vertical structure (az_tmx)
432      DO jj = 1, jpj                ! part independent of the level
433         DO ji = 1, jpi
434            zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
435            zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) )
436            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj)
437         END DO
438      END DO
439      DO jk= 1, jpk                 ! complete with the level-dependent part
440         DO jj = 1, jpj
441            DO ji = 1, jpi
442               az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk)
443            END DO
444         END DO
445      END DO
446!===========
447
448      IF( nprint == 1 .AND. lwp ) THEN
449         ! Control print
450         ! Total power consumption due to vertical mixing
451         ! zpc = rau0 * 1/rn_me * rn2 * zav_tide
452         zav_tide(:,:,:) = 0.e0
453         DO jk = 2, jpkm1
454            zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) )
455         END DO
456
457         ztpc = 0.e0
458         zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:)
459         DO jk= 2, jpkm1
460            DO jj = 1, jpj
461               DO ji = 1, jpi
462                  ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
463               END DO
464            END DO
465         END DO
466         ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc
467
468         WRITE(numout,*) 
469         WRITE(numout,*) '          Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW'
470
471
472         ! control print 2
473         zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 )   
474         zkz(:,:) = 0.e0
475         DO jk = 2, jpkm1
476            DO jj = 1, jpj
477               DO ji = 1, jpi
478                  zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX(0.e0, rn2(ji,jj,jk)) * rau0 * zav_tide(ji,jj,jk) * wmask(ji,jj,jk)
479               END DO
480            END DO
481         END DO
482         ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz
483         DO jj = 1, jpj
484            DO ji = 1, jpi
485               IF( zkz(ji,jj) /= 0.e0 )   THEN
486                   zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj)
487               ENDIF
488            END DO
489         END DO
490         ztpc = 1.e50
491         DO jj = 1, jpj
492            DO ji = 1, jpi
493               IF( zkz(ji,jj) /= 0.e0 )   THEN
494                   ztpc = Min( zkz(ji,jj), ztpc)
495               ENDIF
496            END DO
497         END DO
498         WRITE(numout,*) '          Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) )
499
500         DO jk = 2, jpkm1
501            DO jj = 1, jpj
502               DO ji = 1, jpi
503                  zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk)  !kz max = 300 cm2/s
504               END DO
505            END DO
506         END DO
507         ztpc = 0.e0
508         zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:)
509         DO jk= 1, jpk
510            DO jj = 1, jpj
511               DO ji = 1, jpi
512                  ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
513               END DO
514            END DO
515         END DO
516         ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc
517         WRITE(numout,*) '          2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW'
518
519         DO jk = 1, jpk
520            ze_z =                  SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk)     * tmask_i(:,:) )   &
521               &     / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
522            ztpc = 1.E50
523            DO jj = 1, jpj
524               DO ji = 1, jpi
525                  IF( zav_tide(ji,jj,jk) /= 0.e0 )   ztpc =Min( ztpc, zav_tide(ji,jj,jk) )
526               END DO
527            END DO
528            WRITE(numout,*) '            N2 min - jk= ', jk,'   ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4,   &
529               &       'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s'
530         END DO
531
532         WRITE(numout,*) '          e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW'
533         WRITE(numout,*) 
534         WRITE(numout,*) '          Initial profile of tidal vertical mixing'
535         DO jk = 1, jpk
536            DO jj = 1,jpj
537               DO ji = 1,jpi
538                  zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) )
539               END DO
540            END DO
541            ze_z =                  SUM( e1t(:,:) * e2t(:,:) * zkz(:,:)     * tmask_i(:,:) )   &
542               &     / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
543            WRITE(numout,*) '                jk= ', jk,'   ', ze_z * 1.e4,' cm2/s'
544         END DO
545         DO jk = 1, jpk
546            zkz(:,:) = az_tmx(:,:,jk) /rn_n2min
547            ze_z =                  SUM( e1t(:,:) * e2t(:,:) * zkz(:,:)     * tmask_i(:,:) )   &
548               &     / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) )
549            WRITE(numout,*) 
550            WRITE(numout,*) '          N2 min - jk= ', jk,'   ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4,   &
551               &       'max= ', MAXVAL(zkz)*1.e4, ' cm2/s'
552         END DO
553         !
554      ENDIF
555      !
556      CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep )
557      CALL wrk_dealloc( jpi,jpj,jpk, zpc )
558      !
559      IF( nn_timing == 1 )  CALL timing_stop('zdf_tmx_init')
560      !
561   END SUBROUTINE zdf_tmx_init
562
563#elif defined key_zdftmx_new
564   !!----------------------------------------------------------------------
565   !!   'key_zdftmx_new'               Internal wave-driven vertical mixing
566   !!----------------------------------------------------------------------
567   !!   zdf_tmx       : global     momentum & tracer Kz with wave induced Kz
568   !!   zdf_tmx_init  : global     momentum & tracer Kz with wave induced Kz
569   !!----------------------------------------------------------------------
570   USE oce            ! ocean dynamics and tracers variables
571   USE dom_oce        ! ocean space and time domain variables
572   USE zdf_oce        ! ocean vertical physics variables
573   USE zdfddm         ! ocean vertical physics: double diffusive mixing
574   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
575   USE eosbn2         ! ocean equation of state
576   USE phycst         ! physical constants
577   USE prtctl         ! Print control
578   USE in_out_manager ! I/O manager
579   USE iom            ! I/O Manager
580   USE lib_mpp        ! MPP library
581   USE wrk_nemo       ! work arrays
582   USE timing         ! Timing
583   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
584
585   IMPLICIT NONE
586   PRIVATE
587
588   PUBLIC   zdf_tmx         ! called in step module
589   PUBLIC   zdf_tmx_init    ! called in nemogcm module
590   PUBLIC   zdf_tmx_alloc   ! called in nemogcm module
591
592   LOGICAL, PUBLIC, PARAMETER ::   lk_zdftmx = .TRUE.    !: wave-driven mixing flag
593
594   !                       !!* Namelist  namzdf_tmx : internal wave-driven mixing *
595   INTEGER  ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
596   LOGICAL  ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
597   LOGICAL  ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
598
599   REAL(wp) ::  r1_6 = 1._wp / 6._wp
600
601   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ebot_tmx     ! power available from high-mode wave breaking (W/m2)
602   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   epyc_tmx     ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
603   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ecri_tmx     ! power available from low-mode, critical slope wave breaking (W/m2)
604   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hbot_tmx     ! WKB decay scale for high-mode energy dissipation (m)
605   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hcri_tmx     ! decay scale for low-mode critical slope dissipation (m)
606   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   emix_tmx     ! local energy density available for mixing (W/kg)
607   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   bflx_tmx     ! buoyancy flux Kz * N^2 (W/kg)
608   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   pcmap_tmx    ! vertically integrated buoyancy flux (W/m2)
609   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_ratio    ! S/T diffusivity ratio (only for ln_tsdiff=T)
610   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_wave     ! Internal wave-induced diffusivity
611
612   !! * Substitutions
613#  include "zdfddm_substitute.h90"
614#  include "domzgr_substitute.h90"
615#  include "vectopt_loop_substitute.h90"
616   !!----------------------------------------------------------------------
617   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
618   !! $Id$
619   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
620   !!----------------------------------------------------------------------
621CONTAINS
622
623   INTEGER FUNCTION zdf_tmx_alloc()
624      !!----------------------------------------------------------------------
625      !!                ***  FUNCTION zdf_tmx_alloc  ***
626      !!----------------------------------------------------------------------
627      ALLOCATE(     ebot_tmx(jpi,jpj),  epyc_tmx(jpi,jpj),  ecri_tmx(jpi,jpj)    ,   &
628      &             hbot_tmx(jpi,jpj),  hcri_tmx(jpi,jpj),  emix_tmx(jpi,jpj,jpk),   &
629      &         bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk),   & 
630      &         zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc     )
631      !
632      IF( lk_mpp             )   CALL mpp_sum ( zdf_tmx_alloc )
633      IF( zdf_tmx_alloc /= 0 )   CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays')
634   END FUNCTION zdf_tmx_alloc
635
636
637   SUBROUTINE zdf_tmx( kt )
638      !!----------------------------------------------------------------------
639      !!                  ***  ROUTINE zdf_tmx  ***
640      !!                   
641      !! ** Purpose :   add to the vertical mixing coefficients the effect of
642      !!              breaking internal waves.
643      !!
644      !! ** Method  : - internal wave-driven vertical mixing is given by:
645      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = emix_tmx /( Nu * N^2 )  )
646      !!              where emix_tmx is the 3D space distribution of the wave-breaking
647      !!              energy and Nu the molecular kinematic viscosity.
648      !!              The function f(Reb) is linear (constant mixing efficiency)
649      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
650      !!
651      !!              - Compute emix_tmx, the 3D power density that allows to compute
652      !!              Reb and therefrom the wave-induced vertical diffusivity.
653      !!              This is divided into three components:
654      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
655      !!                     emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx )
656      !!                                   / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx
657      !!              where hcri_tmx is the characteristic length scale of the bottom
658      !!              intensification, ecri_tmx a map of available power, and H the ocean depth.
659      !!                 2. Pycnocline-intensified low-mode dissipation
660      !!                     emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
661      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
662      !!              where epyc_tmx is a map of available power, and nn_zpyc
663      !!              is the chosen stratification-dependence of the internal wave
664      !!              energy dissipation.
665      !!                 3. WKB-height dependent high mode dissipation
666      !!                     emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx)
667      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) )
668      !!              where hbot_tmx is the characteristic length scale of the WKB bottom
669      !!              intensification, ebot_tmx is a map of available power, and z_wkb is the
670      !!              WKB-stretched height above bottom defined as
671      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
672      !!                                 / SUM( sqrt(rn2(z'))    * e3w(z')    )
673      !!
674      !!              - update the model vertical eddy viscosity and diffusivity:
675      !!                     avt  = avt  +    av_wave
676      !!                     avm  = avm  +    av_wave
677      !!                     avmu = avmu + mi(av_wave)
678      !!                     avmv = avmv + mj(av_wave)
679      !!
680      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
681      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
682      !!
683      !! ** Action  : - Define emix_tmx used to compute internal wave-induced mixing
684      !!              - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing   
685      !!
686      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
687      !!----------------------------------------------------------------------
688      INTEGER, INTENT(in) ::   kt   ! ocean time-step
689      !
690      INTEGER  ::   ji, jj, jk   ! dummy loop indices
691      REAL(wp) ::   ztpc         ! scalar workspace
692      REAL(wp), DIMENSION(:,:)  , POINTER ::  zfact     ! Used for vertical structure
693      REAL(wp), DIMENSION(:,:)  , POINTER ::  zhdep     ! Ocean depth
694      REAL(wp), DIMENSION(:,:,:), POINTER ::  zwkb      ! WKB-stretched height above bottom
695      REAL(wp), DIMENSION(:,:,:), POINTER ::  zweight   ! Weight for high mode vertical distribution
696      REAL(wp), DIMENSION(:,:,:), POINTER ::  znu_t     ! Molecular kinematic viscosity (T grid)
697      REAL(wp), DIMENSION(:,:,:), POINTER ::  znu_w     ! Molecular kinematic viscosity (W grid)
698      REAL(wp), DIMENSION(:,:,:), POINTER ::  zReb      ! Turbulence intensity parameter
699      !!----------------------------------------------------------------------
700      !
701      IF( nn_timing == 1 )   CALL timing_start('zdf_tmx')
702      !
703      CALL wrk_alloc( jpi,jpj,       zfact, zhdep )
704      CALL wrk_alloc( jpi,jpj,jpk,   zwkb, zweight, znu_t, znu_w, zReb )
705
706      !                          ! ----------------------------- !
707      !                          !  Internal wave-driven mixing  !  (compute zav_wave)
708      !                          ! ----------------------------- !
709      !                             
710      !                        !* Critical slope mixing: distribute energy over the time-varying ocean depth,
711      !                                                 using an exponential decay from the seafloor.
712      DO jj = 1, jpj                ! part independent of the level
713         DO ji = 1, jpi
714            zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
715            zfact(ji,jj) = rau0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) )  )
716            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj)
717         END DO
718      END DO
719
720      DO jk = 2, jpkm1              ! complete with the level-dependent part
721         emix_tmx(:,:,jk) = zfact(:,:) * (  EXP( ( fsde3w(:,:,jk  ) - zhdep(:,:) ) / hcri_tmx(:,:) )                      &
722            &                             - EXP( ( fsde3w(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) )  ) * wmask(:,:,jk)   &
723            &                          / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) )
724      END DO
725
726      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
727      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
728
729      SELECT CASE ( nn_zpyc )
730
731      CASE ( 1 )               ! Dissipation scales as N (recommended)
732
733         zfact(:,:) = 0._wp
734         DO jk = 2, jpkm1              ! part independent of the level
735            zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
736         END DO
737
738         DO jj = 1, jpj
739            DO ji = 1, jpi
740               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
741            END DO
742         END DO
743
744         DO jk = 2, jpkm1              ! complete with the level-dependent part
745            emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
746         END DO
747
748      CASE ( 2 )               ! Dissipation scales as N^2
749
750         zfact(:,:) = 0._wp
751         DO jk = 2, jpkm1              ! part independent of the level
752            zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
753         END DO
754
755         DO jj= 1, jpj
756            DO ji = 1, jpi
757               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
758            END DO
759         END DO
760
761         DO jk = 2, jpkm1              ! complete with the level-dependent part
762            emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
763         END DO
764
765      END SELECT
766
767      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
768      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
769     
770      zwkb(:,:,:) = 0._wp
771      zfact(:,:) = 0._wp
772      DO jk = 2, jpkm1
773         zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
774         zwkb(:,:,jk) = zfact(:,:)
775      END DO
776
777      DO jk = 2, jpkm1
778         DO jj = 1, jpj
779            DO ji = 1, jpi
780               IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
781                                            &           * tmask(ji,jj,jk) / zfact(ji,jj)
782            END DO
783         END DO
784      END DO
785      zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1)
786
787      zweight(:,:,:) = 0._wp
788      DO jk = 2, jpkm1
789         zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk)                    &
790            &   * (  EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) )  )
791      END DO
792
793      zfact(:,:) = 0._wp
794      DO jk = 2, jpkm1              ! part independent of the level
795         zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
796      END DO
797
798      DO jj = 1, jpj
799         DO ji = 1, jpi
800            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) )
801         END DO
802      END DO
803
804      DO jk = 2, jpkm1              ! complete with the level-dependent part
805         emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk)   &
806            &                                / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) )
807      END DO
808
809
810      ! Calculate molecular kinematic viscosity
811      znu_t(:,:,:) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem)  &
812         &                                  + 0.02305_wp * tsn(:,:,:,jp_sal)  ) * tmask(:,:,:) * r1_rau0
813      DO jk = 2, jpkm1
814         znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
815      END DO
816
817      ! Calculate turbulence intensity parameter Reb
818      DO jk = 2, jpkm1
819         zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
820      END DO
821
822      ! Define internal wave-induced diffusivity
823      DO jk = 2, jpkm1
824         zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
825      END DO
826
827      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
828         DO jk = 2, jpkm1              ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
829            DO jj = 1, jpj
830               DO ji = 1, jpi
831                  IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
832                     zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
833                  ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
834                     zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
835                  ENDIF
836               END DO
837            END DO
838         END DO
839      ENDIF
840
841      DO jk = 2, jpkm1                 ! Bound diffusivity by molecular value and 100 cm2/s
842         zav_wave(:,:,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp  ) * wmask(:,:,jk)
843      END DO
844
845      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
846         ztpc = 0._wp
847         DO jk = 2, jpkm1
848            DO jj = 1, jpj
849               DO ji = 1, jpi
850                  ztpc = ztpc + fse3w(ji,jj,jk) * e1e2t(ji,jj)   &
851                     &         * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
852               END DO
853            END DO
854         END DO
855         IF( lk_mpp )   CALL mpp_sum( ztpc )
856         ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing
857 
858         IF(lwp) THEN
859            WRITE(numout,*)
860            WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)'
861            WRITE(numout,*) '~~~~~~~ '
862            WRITE(numout,*)
863            WRITE(numout,*) '      Total power consumption by av_wave: ztpc =  ', ztpc * 1.e-12_wp, 'TW'
864         ENDIF
865      ENDIF
866
867      !                          ! ----------------------- !
868      !                          !   Update  mixing coefs  !                         
869      !                          ! ----------------------- !
870      !     
871      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
872         DO jk = 2, jpkm1              ! Calculate S/T diffusivity ratio as a function of Reb
873            DO jj = 1, jpj
874               DO ji = 1, jpi
875                  zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp *                                                                  &
876                      &   TANH(    0.92_wp * (   LOG10(  MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 )  ) - 0.60_wp   )    )   &
877                      &                 ) * wmask(ji,jj,jk)
878               END DO
879            END DO
880         END DO
881         CALL iom_put( "av_ratio", zav_ratio )
882         DO jk = 2, jpkm1           !* update momentum & tracer diffusivity with wave-driven mixing
883            fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
884            avt  (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
885            avm  (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
886         END DO
887         !
888      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
889         DO jk = 2, jpkm1
890            fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
891            avt  (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk)
892            avm  (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk)
893         END DO
894      ENDIF
895
896      DO jk = 2, jpkm1              !* update momentum diffusivity at wu and wv points
897         DO jj = 2, jpjm1
898            DO ji = fs_2, fs_jpim1  ! vector opt.
899               avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj  ,jk) ) * wumask(ji,jj,jk)
900               avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji  ,jj+1,jk) ) * wvmask(ji,jj,jk)
901            END DO
902         END DO
903      END DO
904      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )      ! lateral boundary condition
905
906      !                             !* output internal wave-driven mixing coefficient
907      CALL iom_put( "av_wave", zav_wave )
908                                    !* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx),
909                                    !  vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx)
910      IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN
911         bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
912         pcmap_tmx(:,:) = 0._wp
913         DO jk = 2, jpkm1
914            pcmap_tmx(:,:) = pcmap_tmx(:,:) + fse3w(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk)
915         END DO
916         pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:)
917         CALL iom_put( "bflx_tmx", bflx_tmx )
918         CALL iom_put( "pcmap_tmx", pcmap_tmx )
919      ENDIF
920      CALL iom_put( "emix_tmx", emix_tmx )
921     
922      CALL wrk_dealloc( jpi,jpj,       zfact, zhdep )
923      CALL wrk_dealloc( jpi,jpj,jpk,   zwkb, zweight, znu_t, znu_w, zReb )
924
925      IF(ln_ctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
926      !
927      IF( nn_timing == 1 )   CALL timing_stop('zdf_tmx')
928      !
929   END SUBROUTINE zdf_tmx
930
931
932   SUBROUTINE zdf_tmx_init
933      !!----------------------------------------------------------------------
934      !!                  ***  ROUTINE zdf_tmx_init  ***
935      !!                     
936      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
937      !!              of input power maps and decay length scales in netcdf files.
938      !!
939      !! ** Method  : - Read the namzdf_tmx namelist and check the parameters
940      !!
941      !!              - Read the input data in NetCDF files :
942      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
943      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
944      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
945      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
946      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
947      !!
948      !! ** input   : - Namlist namzdf_tmx
949      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
950      !!              decay_scale_bot.nc decay_scale_cri.nc
951      !!
952      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
953      !!              - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx
954      !!
955      !! References : de Lavergne et al. 2015, JPO; 2016, in prep.
956      !!         
957      !!----------------------------------------------------------------------
958      INTEGER  ::   ji, jj, jk   ! dummy loop indices
959      INTEGER  ::   inum         ! local integer
960      INTEGER  ::   ios
961      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
962      !!
963      NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff
964      !!----------------------------------------------------------------------
965      !
966      IF( nn_timing == 1 )  CALL timing_start('zdf_tmx_init')
967      !
968      REWIND( numnam_ref )              ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing
969      READ  ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901)
970901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp )
971      !
972      REWIND( numnam_cfg )              ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing
973      READ  ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 )
974902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp )
975      IF(lwm) WRITE ( numond, namzdf_tmx_new )
976      !
977      IF(lwp) THEN                  ! Control print
978         WRITE(numout,*)
979         WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing'
980         WRITE(numout,*) '~~~~~~~~~~~~'
981         WRITE(numout,*) '   Namelist namzdf_tmx_new : set wave-driven mixing parameters'
982         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
983         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
984         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
985      ENDIF
986     
987      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
988      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
989      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
990      avmb(:) = 1.4e-6_wp        ! viscous molecular value
991      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_tmx)   
992      avtb_2d(:,:) = 1.e0_wp     ! uniform
993      IF(lwp) THEN                  ! Control print
994         WRITE(numout,*)
995         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
996            &               'the viscous molecular value & a very small diffusive value, resp.'
997      ENDIF
998     
999      IF( .NOT.lk_zdfddm )   CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' )
1000     
1001      !                             ! allocate tmx arrays
1002      IF( zdf_tmx_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' )
1003      !
1004      !                             ! read necessary fields
1005      CALL iom_open('mixing_power_bot',inum)       ! energy flux for high-mode wave breaking [W/m2]
1006      CALL iom_get  (inum, jpdom_data, 'field', ebot_tmx, 1 ) 
1007      CALL iom_close(inum)
1008      !
1009      CALL iom_open('mixing_power_pyc',inum)       ! energy flux for pynocline-intensified wave breaking [W/m2]
1010      CALL iom_get  (inum, jpdom_data, 'field', epyc_tmx, 1 )
1011      CALL iom_close(inum)
1012      !
1013      CALL iom_open('mixing_power_cri',inum)       ! energy flux for critical slope wave breaking [W/m2]
1014      CALL iom_get  (inum, jpdom_data, 'field', ecri_tmx, 1 )
1015      CALL iom_close(inum)
1016      !
1017      CALL iom_open('decay_scale_bot',inum)        ! spatially variable decay scale for high-mode wave breaking [m]
1018      CALL iom_get  (inum, jpdom_data, 'field', hbot_tmx, 1 )
1019      CALL iom_close(inum)
1020      !
1021      CALL iom_open('decay_scale_cri',inum)        ! spatially variable decay scale for critical slope wave breaking [m]
1022      CALL iom_get  (inum, jpdom_data, 'field', hcri_tmx, 1 )
1023      CALL iom_close(inum)
1024
1025      ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:)
1026      epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:)
1027      ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:)
1028
1029      ! Set once for all to zero the first and last vertical levels of appropriate variables
1030      emix_tmx (:,:, 1 ) = 0._wp
1031      emix_tmx (:,:,jpk) = 0._wp
1032      zav_ratio(:,:, 1 ) = 0._wp
1033      zav_ratio(:,:,jpk) = 0._wp
1034      zav_wave (:,:, 1 ) = 0._wp
1035      zav_wave (:,:,jpk) = 0._wp
1036
1037      zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) )
1038      zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) )
1039      zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) )
1040      IF(lwp) THEN
1041         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
1042         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
1043         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
1044      ENDIF
1045      !
1046      IF( nn_timing == 1 )  CALL timing_stop('zdf_tmx_init')
1047      !
1048   END SUBROUTINE zdf_tmx_init
1049
1050#else
1051   !!----------------------------------------------------------------------
1052   !!   Default option          Dummy module                NO Tidal MiXing
1053   !!----------------------------------------------------------------------
1054   LOGICAL, PUBLIC, PARAMETER ::   lk_zdftmx = .FALSE.   !: tidal mixing flag
1055CONTAINS
1056   SUBROUTINE zdf_tmx_init           ! Dummy routine
1057      WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?'
1058   END SUBROUTINE zdf_tmx_init
1059   SUBROUTINE zdf_tmx( kt )          ! Dummy routine
1060      WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt
1061   END SUBROUTINE zdf_tmx
1062#endif
1063
1064   !!======================================================================
1065END MODULE zdftmx
Note: See TracBrowser for help on using the repository browser.