source: branches/UKMO/dev_r5518_GO6_package_inc_asm/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8036

Last change on this file since 8036 was 8036, checked in by jwhile, 3 years ago

Further merge of r5518_pcbias

File size: 70.8 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE biaspar         ! bias correction variables
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   z_rhd_st  ! tmp density storage for pressure corr
88      REAL(wp), DIMENSION(jpi,jpj)     ::   z_gru_st  ! tmp ua trends storage for pressure corr
89      REAL(wp), DIMENSION(jpi,jpj)     ::   z_grv_st  ! tmp va trends storage for pressure corr
90      !!----------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
93      !
94      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
95         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
96         ztrdu(:,:,:) = ua(:,:,:)
97         ztrdv(:,:,:) = va(:,:,:)
98      ENDIF
99      !
100      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
101         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
102         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
103         z_gru_st(:,:)   = gru(:,:)
104         gru(:,:)        = gru_pc(:,:)
105         z_grv_st(:,:)   = grv(:,:)
106         grv(:,:)        = grv_pc(:,:)
107      ENDIF
108      !
109      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
110      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
111      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
112      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
113      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
114      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
115      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
116      END SELECT
117      !
118      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
119         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
120         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
121         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
122         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
123      ENDIF
124      !
125      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
126         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
127      !
128      IF ( ln_bias .AND. ln_bias_pc_app )  THEN
129         rhd(:,:,:) = z_rhd_st(:,:,:)     ! restore original density
130         gru(:,:)   = z_gru_st(:,:)
131         grv(:,:)   = z_grv_st(:,:)
132      ENDIF
133      !
134      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
135      !
136   END SUBROUTINE dyn_hpg
137
138
139   SUBROUTINE dyn_hpg_init
140      !!----------------------------------------------------------------------
141      !!                 ***  ROUTINE dyn_hpg_init  ***
142      !!
143      !! ** Purpose :   initializations for the hydrostatic pressure gradient
144      !!              computation and consistency control
145      !!
146      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
147      !!      with the type of vertical coordinate used (zco, zps, sco)
148      !!----------------------------------------------------------------------
149      INTEGER ::   ioptio = 0      ! temporary integer
150      INTEGER ::   ios             ! Local integer output status for namelist read
151      !!
152      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
153         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
154      !!----------------------------------------------------------------------
155      !
156      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
157      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
158901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
159
160      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
161      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
162902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
163      IF(lwm) WRITE ( numond, namdyn_hpg )
164      !
165      IF(lwp) THEN                   ! Control print
166         WRITE(numout,*)
167         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
168         WRITE(numout,*) '~~~~~~~~~~~~'
169         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
170         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
171         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
172         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
173         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
174         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
175         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
176         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
177      ENDIF
178      !
179      IF( ln_hpg_djc )   &
180         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
181                           & currently disabled (bugs under investigation). Please select &
182                           & either  ln_hpg_sco or  ln_hpg_prj instead')
183      !
184      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
185         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
186                           & the standard jacobian formulation hpg_sco or &
187                           & the pressure jacobian formulation hpg_prj')
188
189      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
190         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
191      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
192         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
193      !
194      !                               ! Set nhpg from ln_hpg_... flags
195      IF( ln_hpg_zco )   nhpg = 0
196      IF( ln_hpg_zps )   nhpg = 1
197      IF( ln_hpg_sco )   nhpg = 2
198      IF( ln_hpg_djc )   nhpg = 3
199      IF( ln_hpg_prj )   nhpg = 4
200      IF( ln_hpg_isf )   nhpg = 5
201      !
202      !                               ! Consistency check
203      ioptio = 0
204      IF( ln_hpg_zco )   ioptio = ioptio + 1
205      IF( ln_hpg_zps )   ioptio = ioptio + 1
206      IF( ln_hpg_sco )   ioptio = ioptio + 1
207      IF( ln_hpg_djc )   ioptio = ioptio + 1
208      IF( ln_hpg_prj )   ioptio = ioptio + 1
209      IF( ln_hpg_isf )   ioptio = ioptio + 1
210      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
211      !
212      ! initialisation of ice load
213      riceload(:,:)=0.0
214      !
215   END SUBROUTINE dyn_hpg_init
216
217
218   SUBROUTINE hpg_zco( kt )
219      !!---------------------------------------------------------------------
220      !!                  ***  ROUTINE hpg_zco  ***
221      !!
222      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
223      !!      The now hydrostatic pressure gradient at a given level, jk,
224      !!      is computed by taking the vertical integral of the in-situ
225      !!      density gradient along the model level from the suface to that
226      !!      level:    zhpi = grav .....
227      !!                zhpj = grav .....
228      !!      add it to the general momentum trend (ua,va).
229      !!            ua = ua - 1/e1u * zhpi
230      !!            va = va - 1/e2v * zhpj
231      !!
232      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
233      !!----------------------------------------------------------------------
234      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
235      !!
236      INTEGER  ::   ji, jj, jk       ! dummy loop indices
237      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
238      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
239      !!----------------------------------------------------------------------
240      !
241      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
242      !
243      IF( kt == nit000 ) THEN
244         IF(lwp) WRITE(numout,*)
245         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
246         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
247      ENDIF
248
249      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
250
251      ! Surface value
252      DO jj = 2, jpjm1
253         DO ji = fs_2, fs_jpim1   ! vector opt.
254            zcoef1 = zcoef0 * fse3w(ji,jj,1)
255            ! hydrostatic pressure gradient
256            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
257            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
258            ! add to the general momentum trend
259            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
260            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
261         END DO
262      END DO
263
264      !
265      ! interior value (2=<jk=<jpkm1)
266      DO jk = 2, jpkm1
267         DO jj = 2, jpjm1
268            DO ji = fs_2, fs_jpim1   ! vector opt.
269               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
270               ! hydrostatic pressure gradient
271               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
272                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
273                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
274
275               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
276                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
277                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
278               ! add to the general momentum trend
279               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
280               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
281            END DO
282         END DO
283      END DO
284      !
285      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
286      !
287   END SUBROUTINE hpg_zco
288
289
290   SUBROUTINE hpg_zps( kt )
291      !!---------------------------------------------------------------------
292      !!                 ***  ROUTINE hpg_zps  ***
293      !!
294      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
295      !!
296      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
297      !!----------------------------------------------------------------------
298      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
299      !!
300      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
301      INTEGER  ::   iku, ikv                         ! temporary integers
302      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
303      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
304      !!----------------------------------------------------------------------
305      !
306      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
307      !
308      IF( kt == nit000 ) THEN
309         IF(lwp) WRITE(numout,*)
310         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
311         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
312      ENDIF
313
314
315      ! Local constant initialization
316      zcoef0 = - grav * 0.5_wp
317
318      !  Surface value (also valid in partial step case)
319      DO jj = 2, jpjm1
320         DO ji = fs_2, fs_jpim1   ! vector opt.
321            zcoef1 = zcoef0 * fse3w(ji,jj,1)
322            ! hydrostatic pressure gradient
323            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
324            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
325            ! add to the general momentum trend
326            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
327            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
328         END DO
329      END DO
330
331
332      ! interior value (2=<jk=<jpkm1)
333      DO jk = 2, jpkm1
334         DO jj = 2, jpjm1
335            DO ji = fs_2, fs_jpim1   ! vector opt.
336               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
337               ! hydrostatic pressure gradient
338               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
339                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
340                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
341
342               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
343                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
344                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
345               ! add to the general momentum trend
346               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
347               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
348            END DO
349         END DO
350      END DO
351
352
353      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
354      DO jj = 2, jpjm1
355         DO ji = 2, jpim1
356            iku = mbku(ji,jj)
357            ikv = mbkv(ji,jj)
358            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
359            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
360            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
361               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
362               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
363                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
364               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
365            ENDIF
366            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
367               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
368               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
369                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
370               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
371            ENDIF
372         END DO
373      END DO
374      !
375      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
376      !
377   END SUBROUTINE hpg_zps
378
379   SUBROUTINE hpg_sco( kt )
380      !!---------------------------------------------------------------------
381      !!                  ***  ROUTINE hpg_sco  ***
382      !!
383      !! ** Method  :   s-coordinate case. Jacobian scheme.
384      !!      The now hydrostatic pressure gradient at a given level, jk,
385      !!      is computed by taking the vertical integral of the in-situ
386      !!      density gradient along the model level from the suface to that
387      !!      level. s-coordinates (ln_sco): a corrective term is added
388      !!      to the horizontal pressure gradient :
389      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
390      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
391      !!      add it to the general momentum trend (ua,va).
392      !!         ua = ua - 1/e1u * zhpi
393      !!         va = va - 1/e2v * zhpj
394      !!
395      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
396      !!----------------------------------------------------------------------
397      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
398      !!
399      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
400      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
401      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
402      !!----------------------------------------------------------------------
403      !
404      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
405      !
406      IF( kt == nit000 ) THEN
407         IF(lwp) WRITE(numout,*)
408         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
409         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
410      ENDIF
411
412      ! Local constant initialization
413      zcoef0 = - grav * 0.5_wp
414      ! To use density and not density anomaly
415      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
416      ELSE                 ;     znad = 0._wp         ! Fixed volume
417      ENDIF
418
419      ! Surface value
420      DO jj = 2, jpjm1
421         DO ji = fs_2, fs_jpim1   ! vector opt.
422            ! hydrostatic pressure gradient along s-surfaces
423            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
424               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
425            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
426               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
427            ! s-coordinate pressure gradient correction
428            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
429               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
430            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
431               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
432            ! add to the general momentum trend
433            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
434            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
435         END DO
436      END DO
437
438      ! interior value (2=<jk=<jpkm1)
439      DO jk = 2, jpkm1
440         DO jj = 2, jpjm1
441            DO ji = fs_2, fs_jpim1   ! vector opt.
442               ! hydrostatic pressure gradient along s-surfaces
443               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
444                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
445                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
446               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
447                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
448                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
449               ! s-coordinate pressure gradient correction
450               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
451                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
452               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
453                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
454               ! add to the general momentum trend
455               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
456               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
457            END DO
458         END DO
459      END DO
460      !
461      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
462      !
463   END SUBROUTINE hpg_sco
464
465   SUBROUTINE hpg_isf( kt )
466      !!---------------------------------------------------------------------
467      !!                  ***  ROUTINE hpg_sco  ***
468      !!
469      !! ** Method  :   s-coordinate case. Jacobian scheme.
470      !!      The now hydrostatic pressure gradient at a given level, jk,
471      !!      is computed by taking the vertical integral of the in-situ
472      !!      density gradient along the model level from the suface to that
473      !!      level. s-coordinates (ln_sco): a corrective term is added
474      !!      to the horizontal pressure gradient :
475      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
476      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
477      !!      add it to the general momentum trend (ua,va).
478      !!         ua = ua - 1/e1u * zhpi
479      !!         va = va - 1/e2v * zhpj
480      !!      iceload is added and partial cell case are added to the top and bottom
481      !!     
482      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
483      !!----------------------------------------------------------------------
484      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
485      !!
486      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
487      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
488      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
489      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
490      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
491      !!----------------------------------------------------------------------
492      !
493      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
494      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
495      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
496      !
497     IF( kt == nit000 ) THEN
498         IF(lwp) WRITE(numout,*)
499         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
500         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
501      ENDIF
502
503      ! Local constant initialization
504      zcoef0 = - grav * 0.5_wp
505      ! To use density and not density anomaly
506!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
507!      ELSE                 ;     znad = 0._wp         ! Fixed volume
508!      ENDIF
509      znad=1._wp
510      ! iniitialised to 0. zhpi zhpi
511      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
512
513!==================================================================================     
514!=====Compute iceload and contribution of the half first wet layer =================
515!===================================================================================
516
517      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
518      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
519
520      ! compute density of the water displaced by the ice shelf
521      zrhd = rhd ! save rhd
522      DO jk = 1, jpk
523           zdept(:,:)=gdept_1d(jk)
524           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
525      END DO
526      WHERE ( tmask(:,:,:) == 1._wp)
527        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
528      END WHERE
529     
530      ! compute rhd at the ice/oce interface (ice shelf side)
531      CALL eos(ztstop,risfdep,zrhdtop_isf)
532
533      ! compute rhd at the ice/oce interface (ocean side)
534      DO ji=1,jpi
535        DO jj=1,jpj
536          ikt=mikt(ji,jj)
537          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
538          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
539        END DO
540      END DO
541      CALL eos(ztstop,risfdep,zrhdtop_oce)
542      !
543      ! Surface value + ice shelf gradient
544      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
545      ziceload = 0._wp
546      DO jj = 1, jpj
547         DO ji = 1, jpi   ! vector opt.
548            ikt=mikt(ji,jj)
549            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
550            DO jk=2,ikt-1
551               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
552                  &                              * (1._wp - tmask(ji,jj,jk))
553            END DO
554            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
555                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
556         END DO
557      END DO
558      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
559      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
560      DO jj = 2, jpjm1
561         DO ji = fs_2, fs_jpim1   ! vector opt.
562            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
563            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
564            ! we assume ISF is in isostatic equilibrium
565            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
566               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
567               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
568               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
569               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
570            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
571               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
572               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
573               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
574               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
575            ! s-coordinate pressure gradient correction (=0 if z coordinate)
576            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
577               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
578            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
579               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
580            ! add to the general momentum trend
581            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
582            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
583         END DO
584      END DO
585!==================================================================================     
586!===== Compute partial cell contribution for the top cell =========================
587!==================================================================================
588      DO jj = 2, jpjm1
589         DO ji = fs_2, fs_jpim1   ! vector opt.
590            iku = miku(ji,jj) ; 
591            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
592            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
593            ! u direction
594            IF ( iku .GT. 1 ) THEN
595               ! case iku
596               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
597                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
598                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
599               ! corrective term ( = 0 if z coordinate )
600               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
601               ! zhpi will be added in interior loop
602               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
603               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
604               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
605
606               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
607               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
608                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
609                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
610                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
611                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
612               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
613            END IF
614               
615            ! v direction
616            ikv = mikv(ji,jj)
617            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
618            IF ( ikv .GT. 1 ) THEN
619               ! case ikv
620               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
621                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
622                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
623               ! corrective term ( = 0 if z coordinate )
624               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
625               ! zhpi will be added in interior loop
626               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
627               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
628               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
629               
630               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
631               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
632                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
633                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
634                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
635                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
636               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
637            END IF
638         END DO
639      END DO
640
641!==================================================================================     
642!===== Compute interior value =====================================================
643!==================================================================================
644
645      DO jj = 2, jpjm1
646         DO ji = fs_2, fs_jpim1   ! vector opt.
647            iku=miku(ji,jj); ikv=mikv(ji,jj)
648            DO jk = 2, jpkm1
649               ! hydrostatic pressure gradient along s-surfaces
650               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
651               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
652                  &                            + zcoef0 / e1u(ji,jj)                                                           &
653                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
654                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
655                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
656                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
657               ! s-coordinate pressure gradient correction
658               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
659               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
660                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
661               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
662
663               ! hydrostatic pressure gradient along s-surfaces
664               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
665               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
666                  &                            + zcoef0 / e2v(ji,jj)                                                           &
667                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
668                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
669                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
670                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
671               ! s-coordinate pressure gradient correction
672               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
673               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
674                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
675               ! add to the general momentum trend
676               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
677            END DO
678         END DO
679      END DO
680
681!==================================================================================     
682!===== Compute bottom cell contribution (partial cell) ============================
683!==================================================================================
684
685      DO jj = 2, jpjm1
686         DO ji = 2, jpim1
687            iku = mbku(ji,jj)
688            ikv = mbkv(ji,jj)
689
690            IF (iku .GT. 1) THEN
691               ! remove old value (interior case)
692               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
693                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
694               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
695               ! put new value
696               ! -zpshpi to avoid double contribution of the partial step in the top layer
697               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
698               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
699               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
700            END IF
701            ! v direction
702            IF (ikv .GT. 1) THEN
703               ! remove old value (interior case)
704               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
705                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
706               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
707               ! put new value
708               ! -zpshpj to avoid double contribution of the partial step in the top layer
709               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
710               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
711               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
712            END IF
713         END DO
714      END DO
715     
716      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
717      rhd = zrhd
718      !
719      CALL wrk_dealloc( jpi,jpj,2, ztstop)
720      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
721      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
722      !
723   END SUBROUTINE hpg_isf
724
725
726   SUBROUTINE hpg_djc( kt )
727      !!---------------------------------------------------------------------
728      !!                  ***  ROUTINE hpg_djc  ***
729      !!
730      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
731      !!
732      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
733      !!----------------------------------------------------------------------
734      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
735      !!
736      INTEGER  ::   ji, jj, jk          ! dummy loop indices
737      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
738      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
739      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
740      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
741      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
742      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
743      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
744      !!----------------------------------------------------------------------
745      !
746      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
747      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
748      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
749      !
750
751      IF( kt == nit000 ) THEN
752         IF(lwp) WRITE(numout,*)
753         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
754         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
755      ENDIF
756
757      ! Local constant initialization
758      zcoef0 = - grav * 0.5_wp
759      z1_10  = 1._wp / 10._wp
760      z1_12  = 1._wp / 12._wp
761
762      !----------------------------------------------------------------------------------------
763      !  compute and store in provisional arrays elementary vertical and horizontal differences
764      !----------------------------------------------------------------------------------------
765
766!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
767
768      DO jk = 2, jpkm1
769         DO jj = 2, jpjm1
770            DO ji = fs_2, fs_jpim1   ! vector opt.
771               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
772               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
773               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
774               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
775               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
776               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
777            END DO
778         END DO
779      END DO
780
781      !-------------------------------------------------------------------------
782      ! compute harmonic averages using eq. 5.18
783      !-------------------------------------------------------------------------
784      zep = 1.e-15
785
786!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
787!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
788
789      DO jk = 2, jpkm1
790         DO jj = 2, jpjm1
791            DO ji = fs_2, fs_jpim1   ! vector opt.
792               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
793
794               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
795               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
796
797               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
798               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
799
800               IF( cffw > zep) THEN
801                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
802                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
803               ELSE
804                  drhow(ji,jj,jk) = 0._wp
805               ENDIF
806
807               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
808                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
809
810               IF( cffu > zep ) THEN
811                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
812                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
813               ELSE
814                  drhou(ji,jj,jk ) = 0._wp
815               ENDIF
816
817               IF( cffx > zep ) THEN
818                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
819                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
820               ELSE
821                  dzu(ji,jj,jk) = 0._wp
822               ENDIF
823
824               IF( cffv > zep ) THEN
825                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
826                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
827               ELSE
828                  drhov(ji,jj,jk) = 0._wp
829               ENDIF
830
831               IF( cffy > zep ) THEN
832                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
833                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
834               ELSE
835                  dzv(ji,jj,jk) = 0._wp
836               ENDIF
837
838            END DO
839         END DO
840      END DO
841
842      !----------------------------------------------------------------------------------
843      ! apply boundary conditions at top and bottom using 5.36-5.37
844      !----------------------------------------------------------------------------------
845      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
846      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
847      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
848
849      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
850      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
851      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
852
853
854      !--------------------------------------------------------------
855      ! Upper half of top-most grid box, compute and store
856      !-------------------------------------------------------------
857
858!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
859!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
860
861      DO jj = 2, jpjm1
862         DO ji = fs_2, fs_jpim1   ! vector opt.
863            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
864               &                   * (  rhd(ji,jj,1)                                    &
865               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
866               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
867               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
868         END DO
869      END DO
870
871!!bug gm    : here also, simplification is possible
872!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
873
874      DO jk = 2, jpkm1
875         DO jj = 2, jpjm1
876            DO ji = fs_2, fs_jpim1   ! vector opt.
877
878               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
879                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
880                  &            - grav * z1_10 * (                                                                     &
881                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
882                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
883                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
884                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
885                  &                             )
886
887               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
888                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
889                  &            - grav* z1_10 * (                                                                      &
890                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
891                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
892                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
893                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
894                  &                            )
895
896               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
897                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
898                  &            - grav* z1_10 * (                                                                      &
899                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
900                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
901                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
902                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
903                  &                            )
904
905            END DO
906         END DO
907      END DO
908      CALL lbc_lnk(rho_k,'W',1.)
909      CALL lbc_lnk(rho_i,'U',1.)
910      CALL lbc_lnk(rho_j,'V',1.)
911
912
913      ! ---------------
914      !  Surface value
915      ! ---------------
916      DO jj = 2, jpjm1
917         DO ji = fs_2, fs_jpim1   ! vector opt.
918            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
919            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
920            ! add to the general momentum trend
921            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
922            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
923         END DO
924      END DO
925
926      ! ----------------
927      !  interior value   (2=<jk=<jpkm1)
928      ! ----------------
929      DO jk = 2, jpkm1
930         DO jj = 2, jpjm1
931            DO ji = fs_2, fs_jpim1   ! vector opt.
932               ! hydrostatic pressure gradient along s-surfaces
933               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
934                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
935                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
936               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
937                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
938                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
939               ! add to the general momentum trend
940               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
941               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
942            END DO
943         END DO
944      END DO
945      !
946      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
947      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
948      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
949      !
950   END SUBROUTINE hpg_djc
951
952
953   SUBROUTINE hpg_prj( kt )
954      !!---------------------------------------------------------------------
955      !!                  ***  ROUTINE hpg_prj  ***
956      !!
957      !! ** Method  :   s-coordinate case.
958      !!      A Pressure-Jacobian horizontal pressure gradient method
959      !!      based on the constrained cubic-spline interpolation for
960      !!      all vertical coordinate systems
961      !!
962      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
963      !!----------------------------------------------------------------------
964      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
965      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
966      !!
967      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
968      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
969      !!
970      !! The local variables for the correction term
971      INTEGER  :: jk1, jis, jid, jjs, jjd
972      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
973      REAL(wp) :: zrhdt1
974      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
975      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
976      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
977      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
978      !!----------------------------------------------------------------------
979      !
980      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
981      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
982      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
983      !
984      IF( kt == nit000 ) THEN
985         IF(lwp) WRITE(numout,*)
986         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
987         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
988      ENDIF
989
990      !!----------------------------------------------------------------------
991      ! Local constant initialization
992      zcoef0 = - grav
993      znad = 0.0_wp
994      IF( lk_vvl ) znad = 1._wp
995
996      ! Clean 3-D work arrays
997      zhpi(:,:,:) = 0._wp
998      zrhh(:,:,:) = rhd(:,:,:)
999
1000      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1001      DO jj = 1, jpj
1002        DO ji = 1, jpi
1003          jk = mbathy(ji,jj)
1004          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1005          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1006          ELSE IF(jk < jpkm1) THEN
1007             DO jkk = jk+1, jpk
1008                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1009                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1010             END DO
1011          ENDIF
1012        END DO
1013      END DO
1014
1015      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1016      DO jj = 1, jpj
1017         DO ji = 1, jpi
1018            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1019         END DO
1020      END DO
1021
1022      DO jk = 2, jpk
1023         DO jj = 1, jpj
1024            DO ji = 1, jpi
1025               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1026            END DO
1027         END DO
1028      END DO
1029
1030      fsp(:,:,:) = zrhh (:,:,:)
1031      xsp(:,:,:) = zdept(:,:,:)
1032
1033      ! Construct the vertical density profile with the
1034      ! constrained cubic spline interpolation
1035      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1036      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1037
1038      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1039      DO jj = 2, jpj
1040        DO ji = 2, jpi
1041          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1042                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1043                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1044
1045          ! assuming linear profile across the top half surface layer
1046          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1047        END DO
1048      END DO
1049
1050      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1051      DO jk = 2, jpkm1
1052        DO jj = 2, jpj
1053          DO ji = 2, jpi
1054            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1055                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1056                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1057                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1058          END DO
1059        END DO
1060      END DO
1061
1062      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1063
1064      ! Prepare zsshu_n and zsshv_n
1065      DO jj = 2, jpjm1
1066        DO ji = 2, jpim1
1067          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1068                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1069          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1070                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1071        END DO
1072      END DO
1073
1074      DO jj = 2, jpjm1
1075        DO ji = 2, jpim1
1076          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1077          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1078        END DO
1079      END DO
1080
1081      DO jk = 2, jpkm1
1082        DO jj = 2, jpjm1
1083          DO ji = 2, jpim1
1084            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1085            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1086          END DO
1087        END DO
1088      END DO
1089
1090      DO jk = 1, jpkm1
1091        DO jj = 2, jpjm1
1092          DO ji = 2, jpim1
1093            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1094            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1095          END DO
1096        END DO
1097      END DO
1098
1099      DO jk = 1, jpkm1
1100        DO jj = 2, jpjm1
1101          DO ji = 2, jpim1
1102            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1103            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1104            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1105            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1106          END DO
1107        END DO
1108      END DO
1109
1110
1111      DO jk = 1, jpkm1
1112        DO jj = 2, jpjm1
1113          DO ji = 2, jpim1
1114            zpwes = 0._wp; zpwed = 0._wp
1115            zpnss = 0._wp; zpnsd = 0._wp
1116            zuijk = zu(ji,jj,jk)
1117            zvijk = zv(ji,jj,jk)
1118
1119            !!!!!     for u equation
1120            IF( jk <= mbku(ji,jj) ) THEN
1121               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1122                 jis = ji + 1; jid = ji
1123               ELSE
1124                 jis = ji;     jid = ji +1
1125               ENDIF
1126
1127               ! integrate the pressure on the shallow side
1128               jk1 = jk
1129               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1130                 IF( jk1 == mbku(ji,jj) ) THEN
1131                   zuijk = -zdept(jis,jj,jk1)
1132                   EXIT
1133                 ENDIF
1134                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1135                 zpwes = zpwes +                                    &
1136                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1137                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1138                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1139                 jk1 = jk1 + 1
1140               END DO
1141
1142               ! integrate the pressure on the deep side
1143               jk1 = jk
1144               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1145                 IF( jk1 == 1 ) THEN
1146                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1147                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1148                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1149                                                     dsp(jid,jj,1)) * zdeps
1150                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1151                   EXIT
1152                 ENDIF
1153                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1154                 zpwed = zpwed +                                        &
1155                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1156                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1157                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1158                 jk1 = jk1 - 1
1159               END DO
1160
1161               ! update the momentum trends in u direction
1162
1163               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1164               IF( lk_vvl ) THEN
1165                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1166                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1167                ELSE
1168                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1169               ENDIF
1170
1171               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1172               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1173            ENDIF
1174
1175            !!!!!     for v equation
1176            IF( jk <= mbkv(ji,jj) ) THEN
1177               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1178                 jjs = jj + 1; jjd = jj
1179               ELSE
1180                 jjs = jj    ; jjd = jj + 1
1181               ENDIF
1182
1183               ! integrate the pressure on the shallow side
1184               jk1 = jk
1185               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1186                 IF( jk1 == mbkv(ji,jj) ) THEN
1187                   zvijk = -zdept(ji,jjs,jk1)
1188                   EXIT
1189                 ENDIF
1190                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1191                 zpnss = zpnss +                                      &
1192                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1193                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1194                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1195                 jk1 = jk1 + 1
1196               END DO
1197
1198               ! integrate the pressure on the deep side
1199               jk1 = jk
1200               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1201                 IF( jk1 == 1 ) THEN
1202                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1203                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1204                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1205                                                     dsp(ji,jjd,1) ) * zdeps
1206                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1207                   EXIT
1208                 ENDIF
1209                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1210                 zpnsd = zpnsd +                                        &
1211                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1212                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1213                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1214                 jk1 = jk1 - 1
1215               END DO
1216
1217
1218               ! update the momentum trends in v direction
1219
1220               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1221               IF( lk_vvl ) THEN
1222                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1223                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1224               ELSE
1225                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1226               ENDIF
1227
1228               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1229               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1230            ENDIF
1231
1232
1233           END DO
1234        END DO
1235      END DO
1236      !
1237      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1238      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1239      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1240      !
1241   END SUBROUTINE hpg_prj
1242
1243
1244   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1245      !!----------------------------------------------------------------------
1246      !!                 ***  ROUTINE cspline  ***
1247      !!
1248      !! ** Purpose :   constrained cubic spline interpolation
1249      !!
1250      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1251      !!
1252      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1253      !!----------------------------------------------------------------------
1254      IMPLICIT NONE
1255      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1256      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1257                                                                    ! the interpoated function
1258      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1259                                                                    ! 2: Linear
1260      !
1261      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1262      INTEGER  ::   jpi, jpj, jpkm1
1263      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1264      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1265      REAL(wp) ::   zdf(size(fsp,3))
1266      !!----------------------------------------------------------------------
1267
1268      jpi   = size(fsp,1)
1269      jpj   = size(fsp,2)
1270      jpkm1 = size(fsp,3) - 1
1271
1272
1273      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1274         DO ji = 1, jpi
1275            DO jj = 1, jpj
1276           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1277           !    DO jk = 2, jpkm1-1
1278           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1279           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1280           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1281           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1282           !
1283           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1284           !
1285           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1286           !           zdf(jk) = 0._wp
1287           !       ELSE
1288           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1289           !       ENDIF
1290           !    END DO
1291
1292           !!Simply geometric average
1293               DO jk = 2, jpkm1-1
1294                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1295                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1296
1297                  IF(zdf1 * zdf2 <= 0._wp) THEN
1298                     zdf(jk) = 0._wp
1299                  ELSE
1300                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1301                  ENDIF
1302               END DO
1303
1304               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1305                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1306               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1307                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1308                          & 0.5_wp * zdf(jpkm1 - 1)
1309
1310               DO jk = 1, jpkm1 - 1
1311                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1312                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1313                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1314                 zddf1  = -2._wp * ztmp1 + ztmp2
1315                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1316                 zddf2  =  2._wp * ztmp1 - ztmp2
1317
1318                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1319                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1320                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1321                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1322                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1323                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1324                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1325                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1326                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1327               END DO
1328            END DO
1329         END DO
1330
1331      ELSE IF (polynomial_type == 2) THEN     ! Linear
1332         DO ji = 1, jpi
1333            DO jj = 1, jpj
1334               DO jk = 1, jpkm1-1
1335                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1336                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1337
1338                  dsp(ji,jj,jk) = 0._wp
1339                  csp(ji,jj,jk) = 0._wp
1340                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1341                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1342               END DO
1343            END DO
1344         END DO
1345
1346      ELSE
1347           CALL ctl_stop( 'invalid polynomial type in cspline' )
1348      ENDIF
1349
1350   END SUBROUTINE cspline
1351
1352
1353   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1354      !!----------------------------------------------------------------------
1355      !!                 ***  ROUTINE interp1  ***
1356      !!
1357      !! ** Purpose :   1-d linear interpolation
1358      !!
1359      !! ** Method  :   interpolation is straight forward
1360      !!                extrapolation is also permitted (no value limit)
1361      !!----------------------------------------------------------------------
1362      IMPLICIT NONE
1363      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1364      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1365      REAL(wp)             ::  zdeltx
1366      !!----------------------------------------------------------------------
1367
1368      zdeltx = xr - xl
1369      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1370        f = 0.5_wp * (fl + fr)
1371      ELSE
1372        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1373      ENDIF
1374
1375   END FUNCTION interp1
1376
1377
1378   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1379      !!----------------------------------------------------------------------
1380      !!                 ***  ROUTINE interp1  ***
1381      !!
1382      !! ** Purpose :   1-d constrained cubic spline interpolation
1383      !!
1384      !! ** Method  :  cubic spline interpolation
1385      !!
1386      !!----------------------------------------------------------------------
1387      IMPLICIT NONE
1388      REAL(wp), INTENT(in) ::  x, a, b, c, d
1389      REAL(wp)             ::  f ! value from the interpolation
1390      !!----------------------------------------------------------------------
1391
1392      f = a + x* ( b + x * ( c + d * x ) )
1393
1394   END FUNCTION interp2
1395
1396
1397   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1398      !!----------------------------------------------------------------------
1399      !!                 ***  ROUTINE interp1  ***
1400      !!
1401      !! ** Purpose :   Calculate the first order of deriavtive of
1402      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1403      !!
1404      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1405      !!
1406      !!----------------------------------------------------------------------
1407      IMPLICIT NONE
1408      REAL(wp), INTENT(in) ::  x, a, b, c, d
1409      REAL(wp)             ::  f ! value from the interpolation
1410      !!----------------------------------------------------------------------
1411
1412      f = b + x * ( 2._wp * c + 3._wp * d * x)
1413
1414   END FUNCTION interp3
1415
1416
1417   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1418      !!----------------------------------------------------------------------
1419      !!                 ***  ROUTINE interp1  ***
1420      !!
1421      !! ** Purpose :   1-d constrained cubic spline integration
1422      !!
1423      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1424      !!
1425      !!----------------------------------------------------------------------
1426      IMPLICIT NONE
1427      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1428      REAL(wp)             ::  za1, za2, za3
1429      REAL(wp)             ::  f                   ! integration result
1430      !!----------------------------------------------------------------------
1431
1432      za1 = 0.5_wp * b
1433      za2 = c / 3.0_wp
1434      za3 = 0.25_wp * d
1435
1436      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1437         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1438
1439   END FUNCTION integ_spline
1440
1441   !!======================================================================
1442END MODULE dynhpg
1443
Note: See TracBrowser for help on using the repository browser.