New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in branches/UKMO/dev_r5518_GO6_package_netcdf4/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/dev_r5518_GO6_package_netcdf4/NEMOGCM/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 7892

Last change on this file since 7892 was 7892, checked in by andmirek, 7 years ago

if key_netcdf4 is present open restart file in netcdf4 format

File size: 34.5 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE lbclnk          ! lateal boundary condition / mpp exchanges
22   USE iom_def         ! iom variables definitions
23   USE netcdf          ! NetCDF library
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
31   PUBLIC iom_nf90_getatt
32
33   INTERFACE iom_nf90_get
34      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
35   END INTERFACE
36   INTERFACE iom_nf90_getatt
37      MODULE PROCEDURE iom_nf90_intatt
38   END INTERFACE
39   INTERFACE iom_nf90_rstput
40      MODULE PROCEDURE iom_nf90_rp0123d
41   END INTERFACE
42
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
52      !!---------------------------------------------------------------------
53      !!                   ***  SUBROUTINE  iom_open  ***
54      !!
55      !! ** Purpose : open an input file with NF90
56      !!---------------------------------------------------------------------
57      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
58      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
59      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
60      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
61      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
62
63      CHARACTER(LEN=256) ::   clinfo           ! info character
64      CHARACTER(LEN=256) ::   cltmp            ! temporary character
65      INTEGER            ::   iln              ! lengths of character
66      INTEGER            ::   istop            ! temporary storage of nstop
67      INTEGER            ::   if90id           ! nf90 identifier of the opened file
68      INTEGER            ::   idmy             ! dummy variable
69      INTEGER            ::   jl               ! loop variable
70      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
71      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
72      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
73      LOGICAL            ::   llclobber        ! local definition of ln_clobber
74      !---------------------------------------------------------------------
75
76      clinfo = '                    iom_nf90_open ~~~  '
77      istop = nstop   ! store the actual value of nstop
78      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
79      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
80      ENDIF
81      !
82      llclobber = ldwrt .AND. ln_clobber
83      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
84         !                 ! =============
85         IF( ldwrt ) THEN  ! ... in write mode
86            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
87            IF( snc4set%luse ) THEN
88               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
89            ELSE
90               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
91            ENDIF
92            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
93         ELSE              ! ... in read mode
94            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
95            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
96         ENDIF
97      ELSE                                       ! the file does not exist (or we overwrite it)
98         !                 ! =============
99         iln = INDEX( cdname, '.nc' )
100         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
101            IF( jpnij > 1 ) THEN
102               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
103               cdname = TRIM(cltmp)
104            ENDIF
105            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
106
107            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
108            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
109            ENDIF
110            IF( snc4set%luse ) THEN
111               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
112               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
113               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
114               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
115               ENDIF
116               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
117            ELSE
118#if defined key_netcdf4
119               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
120               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
121               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
122               ENDIF
123               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
124#else
125               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
126#endif
127            ENDIF
128            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
129            ! define dimensions
130            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
131            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
132            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
133            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
134            ! global attributes
135            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
136            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
137            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
139            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
141            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
143            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
144            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
145         ELSE              ! the file should be open for read mode so it must exist...
146            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
147         ENDIF
148      ENDIF
149      ! start to fill file informations
150      ! =============
151      IF( istop == nstop ) THEN   ! no error within this routine
152!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
153         kiomid = 0
154         DO jl = jpmax_files, 1, -1
155            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
156         ENDDO
157         iom_file(kiomid)%name   = TRIM(cdname)
158         iom_file(kiomid)%nfid   = if90id
159         iom_file(kiomid)%iolib  = jpnf90
160         iom_file(kiomid)%nvars  = 0
161         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
162         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
163         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
164           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,     & 
165        &                                               name = iom_file(kiomid)%uldname,  &
166        &                                               len  = iom_file(kiomid)%lenuld ), clinfo )
167         ENDIF
168         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
169      ELSE
170         kiomid = 0               ! return error flag
171      ENDIF
172      !
173   END SUBROUTINE iom_nf90_open
174
175
176   SUBROUTINE iom_nf90_close( kiomid )
177      !!--------------------------------------------------------------------
178      !!                   ***  SUBROUTINE  iom_nf90_close  ***
179      !!
180      !! ** Purpose : close an input file with NF90
181      !!--------------------------------------------------------------------
182      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
183      CHARACTER(LEN=100)  ::   clinfo   ! info character
184      !---------------------------------------------------------------------
185      !
186      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
187      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
188      !   
189   END SUBROUTINE iom_nf90_close
190
191
192   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
193      !!-----------------------------------------------------------------------
194      !!                  ***  FUNCTION  iom_varid  ***
195      !!
196      !! ** Purpose : get the id of a variable in a file with NF90
197      !!-----------------------------------------------------------------------
198      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
199      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
200      INTEGER              , INTENT(in   )           ::   kiv   !
201      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
202      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
203      !
204      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
205      INTEGER                        ::   if90id           ! nf90 file identifier
206      INTEGER                        ::   ji               ! dummy loop index
207      INTEGER                        ::   ivarid           ! NetCDF  variable Id
208      INTEGER                        ::   i_nvd            ! number of dimension of the variable
209      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
210      LOGICAL                        ::   llok             ! ok  test
211      CHARACTER(LEN=100)             ::   clinfo           ! info character
212      !!-----------------------------------------------------------------------
213      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
214      iom_nf90_varid = 0                    ! default definition
215      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
216      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
217      !
218      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
219      IF( llok ) THEN
220         iom_nf90_varid = kiv
221         iom_file(kiomid)%nvars       = kiv
222         iom_file(kiomid)%nvid(kiv)   = ivarid
223         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
224         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
225         iom_file(kiomid)%ndims(kiv)  = i_nvd
226         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
227         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
228         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
229         DO ji = 1, i_nvd                       ! dimensions size
230            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
231            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
232         END DO
233         !---------- Deal with scale_factor and add_offset
234         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
235         IF( llok) THEN
236            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
237         ELSE
238            iom_file(kiomid)%scf(kiv) = 1.
239         END IF
240         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
241         IF( llok ) THEN
242            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
243         ELSE
244            iom_file(kiomid)%ofs(kiv) = 0.
245         END IF
246         ! return the simension size
247         IF( PRESENT(kdimsz) ) THEN
248            IF( i_nvd == SIZE(kdimsz) ) THEN
249               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
250            ELSE
251               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
252               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
253            ENDIF
254         ENDIF
255         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
256      ELSE 
257         iom_nf90_varid = -1   !   variable not found, return error code: -1
258      ENDIF
259      !
260   END FUNCTION iom_nf90_varid
261
262
263   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
264      !!-----------------------------------------------------------------------
265      !!                  ***  ROUTINE  iom_nf90_g0d  ***
266      !!
267      !! ** Purpose : read a scalar with NF90
268      !!-----------------------------------------------------------------------
269      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
270      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
271      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
272      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
273      !
274      CHARACTER(LEN=100)      ::   clinfo   ! info character
275      !---------------------------------------------------------------------
276      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
277      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
278      !
279   END SUBROUTINE iom_nf90_g0d
280
281
282   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
283         &                    pv_r1d, pv_r2d, pv_r3d )
284      !!-----------------------------------------------------------------------
285      !!                  ***  ROUTINE  iom_nf90_g123d  ***
286      !!
287      !! ** Purpose : read a 1D/2D/3D variable with NF90
288      !!
289      !! ** Method : read ONE record at each CALL
290      !!-----------------------------------------------------------------------
291      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
292      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
293      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
294      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
295      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
296      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
297      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
298      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
299      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
300      !
301      CHARACTER(LEN=100) ::   clinfo               ! info character
302      INTEGER            ::   if90id               ! nf90 identifier of the opened file
303      INTEGER            ::   ivid                 ! nf90 variable id
304      !---------------------------------------------------------------------
305      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
306      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
307      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
308      !
309      IF(     PRESENT(pv_r1d) ) THEN
310         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
311            &                                                                       count = kcount(1:knbdim)), clinfo )
312      ELSEIF( PRESENT(pv_r2d) ) THEN
313         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
314            &                                                                       count = kcount(1:knbdim)), clinfo )
315      ELSEIF( PRESENT(pv_r3d) ) THEN
316         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
317            &                                                                       count = kcount(1:knbdim)), clinfo )
318      ENDIF
319      !
320   END SUBROUTINE iom_nf90_g123d
321
322
323   SUBROUTINE iom_nf90_intatt( kiomid, cdatt, pvar )
324      !!-----------------------------------------------------------------------
325      !!                  ***  ROUTINE  iom_nf90_intatt  ***
326      !!
327      !! ** Purpose : read an integer attribute with NF90
328      !!-----------------------------------------------------------------------
329      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
330      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
331      INTEGER         , INTENT(  out) ::   pvar     ! read field
332      !
333      INTEGER                         ::   if90id   ! temporary integer
334      LOGICAL                         ::   llok     ! temporary logical
335      CHARACTER(LEN=100)              ::   clinfo   ! info character
336      !---------------------------------------------------------------------
337      !
338      if90id = iom_file(kiomid)%nfid
339      llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
340      IF( llok) THEN
341         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
342         CALL iom_nf90_check(NF90_GET_ATT(if90id, NF90_GLOBAL, cdatt, values=pvar), clinfo)
343      ELSE
344         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
345         pvar = -999
346      ENDIF
347      !
348   END SUBROUTINE iom_nf90_intatt
349
350
351   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
352      !!--------------------------------------------------------------------
353      !!                   ***  SUBROUTINE iom_gettime  ***
354      !!
355      !! ** Purpose : read the time axis kvid in the file with NF90
356      !!--------------------------------------------------------------------
357      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
358      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
359      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
360      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
361      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
362      !
363      CHARACTER(LEN=100) ::   clinfo     ! info character
364      !---------------------------------------------------------------------
365      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
366      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
367            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
368      IF ( PRESENT(cdunits) ) THEN
369         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
370            &                           values=cdunits), clinfo)
371      ENDIF
372      IF ( PRESENT(cdcalendar) ) THEN
373         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
374            &                           values=cdcalendar), clinfo)
375      ENDIF
376      !
377   END SUBROUTINE iom_nf90_gettime
378
379
380   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
381         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
382      !!--------------------------------------------------------------------
383      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
384      !!
385      !! ** Purpose : read the time axis cdvar in the file
386      !!--------------------------------------------------------------------
387      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
388      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
389      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
390      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
391      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
392      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
393      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
394      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
395      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
396      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
397      !
398      INTEGER               :: idims                ! number of dimension
399      INTEGER               :: idvar                ! variable id
400      INTEGER               :: jd                   ! dimension loop counter   
401      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
402      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
403      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
404      CHARACTER(LEN=256)    :: clinfo               ! info character
405      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
406      INTEGER               :: if90id               ! nf90 file identifier
407      INTEGER               :: idmy                 ! dummy variable
408      INTEGER               :: itype                ! variable type
409      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
410                                                    ! nn_nchunks_[i,j,k,t] namelist parameters
411      INTEGER               :: ichunkalg, ishuffle,&
412                               ideflate, ideflate_level
413                                                    ! NetCDF4 internally fixed parameters
414      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
415                                                    ! when appropriate (currently chunking is applied to 4d fields only)
416      !---------------------------------------------------------------------
417      !
418      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
419      if90id = iom_file(kiomid)%nfid
420      !
421      ! define dimension variables if it is not already done
422      ! ==========================
423      IF( iom_file(kiomid)%nvars == 0 ) THEN
424         ! are we in define mode?
425         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
426            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
427         ENDIF
428         ! define the dimension variables if it is not already done
429         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
430         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
431         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
432         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
433         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
434         ! update informations structure related the dimension variable we just added...
435         iom_file(kiomid)%nvars       = 4
436         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
437         iom_file(kiomid)%cn_var(1:4) = cltmp
438         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
439         ! trick: defined to 0 to say that dimension variables are defined but not yet written
440         iom_file(kiomid)%dimsz(1, 1)  = 0   
441         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
442      ENDIF
443      ! define the data if it is not already done
444      ! ===============
445      IF( kvid <= 0 ) THEN
446         !
447         ! NetCDF4 chunking and compression fixed settings
448         ichunkalg = 0
449         ishuffle = 1
450         ideflate = 1
451         ideflate_level = 1
452         !
453         idvar = iom_file(kiomid)%nvars + 1
454         ! are we in define mode?
455         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
456            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
457         ENDIF
458         ! variable definition
459         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
460         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
461         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
462         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
463         ENDIF
464         IF( PRESENT(ktype) ) THEN   ! variable external type
465            SELECT CASE (ktype)
466            CASE (jp_r8)  ;   itype = NF90_DOUBLE
467            CASE (jp_r4)  ;   itype = NF90_FLOAT
468            CASE (jp_i4)  ;   itype = NF90_INT
469            CASE (jp_i2)  ;   itype = NF90_SHORT
470            CASE (jp_i1)  ;   itype = NF90_BYTE
471            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
472            END SELECT
473         ELSE
474            itype = NF90_DOUBLE
475         ENDIF
476         IF( PRESENT(pv_r0d) ) THEN
477            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
478                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
479         ELSE
480            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
481                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
482         ENDIF
483         lchunk = .false.
484         IF( snc4set%luse .AND. idims.eq.4 ) lchunk = .true.
485         ! update informations structure related the new variable we want to add...
486         iom_file(kiomid)%nvars         = idvar
487         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
488         iom_file(kiomid)%scf(idvar)    = 1.
489         iom_file(kiomid)%ofs(idvar)    = 0.
490         iom_file(kiomid)%ndims(idvar)  = idims
491         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
492         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
493         ENDIF
494         DO jd = 1, idims
495            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
496            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
497         END DO
498         IF ( lchunk ) THEN
499            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
500            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
501            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
502            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
503            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
504            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
505                                                                                       ! unlimited dimension
506            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
507            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
508            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
509         ENDIF
510         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
511      ELSE
512         idvar = kvid
513      ENDIF
514
515      ! time step kwrite : write the variable
516      IF( kt == kwrite ) THEN
517         ! are we in write mode?
518         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
519            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
520         ENDIF
521         ! on what kind of domain must the data be written?
522         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
523            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
524            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
525               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
526            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
527               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
528            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
529               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
530            ELSE
531               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
532            ENDIF
533
534            ! write dimension variables if it is not already done
535            ! =============
536            ! trick: is defined to 0 => dimension variable are defined but not yet written
537            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
538               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
539               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
540               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
541               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
542               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
543               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_1d                ), clinfo)
544               ! +++ WRONG VALUE: to be improved but not really useful...
545               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
546               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
547               ! update the values of the variables dimensions size
548               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
549               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
550               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
551               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
552               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
553               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
554            ENDIF
555         ENDIF
556
557         ! write the data
558         ! =============
559         IF(     PRESENT(pv_r0d) ) THEN
560            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
561         ELSEIF( PRESENT(pv_r1d) ) THEN
562            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
563         ELSEIF( PRESENT(pv_r2d) ) THEN
564            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
565         ELSEIF( PRESENT(pv_r3d) ) THEN
566            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
567         ENDIF
568         ! add 1 to the size of the temporal dimension (not really useful...)
569         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
570               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
571         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
572      ENDIF
573      !     
574   END SUBROUTINE iom_nf90_rp0123d
575
576
577   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
578      !!--------------------------------------------------------------------
579      !!                   ***  SUBROUTINE iom_nf90_check  ***
580      !!
581      !! ** Purpose :   check nf90 errors
582      !!--------------------------------------------------------------------
583      INTEGER,          INTENT(in) :: kstatus
584      CHARACTER(LEN=*), INTENT(in) :: cdinfo
585      !---------------------------------------------------------------------
586      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
587   END SUBROUTINE iom_nf90_check
588
589   !!======================================================================
590END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.