New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in branches/UKMO/dev_r5518_GO6_package_netcdf4/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/dev_r5518_GO6_package_netcdf4/NEMOGCM/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 7896

Last change on this file since 7896 was 7896, checked in by andmirek, 7 years ago

change in structure
File size: 34.2 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE lbclnk          ! lateal boundary condition / mpp exchanges
22   USE iom_def         ! iom variables definitions
23   USE netcdf          ! NetCDF library
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
31   PUBLIC iom_nf90_getatt
32
33   INTERFACE iom_nf90_get
34      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
35   END INTERFACE
36   INTERFACE iom_nf90_getatt
37      MODULE PROCEDURE iom_nf90_intatt
38   END INTERFACE
39   INTERFACE iom_nf90_rstput
40      MODULE PROCEDURE iom_nf90_rp0123d
41   END INTERFACE
42
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
52      !!---------------------------------------------------------------------
53      !!                   ***  SUBROUTINE  iom_open  ***
54      !!
55      !! ** Purpose : open an input file with NF90
56      !!---------------------------------------------------------------------
57      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
58      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
59      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
60      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
61      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
62
63      CHARACTER(LEN=256) ::   clinfo           ! info character
64      CHARACTER(LEN=256) ::   cltmp            ! temporary character
65      INTEGER            ::   iln              ! lengths of character
66      INTEGER            ::   istop            ! temporary storage of nstop
67      INTEGER            ::   if90id           ! nf90 identifier of the opened file
68      INTEGER            ::   idmy             ! dummy variable
69      INTEGER            ::   jl               ! loop variable
70      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
71      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
72      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
73      LOGICAL            ::   llclobber        ! local definition of ln_clobber
74      !---------------------------------------------------------------------
75
76      clinfo = '                    iom_nf90_open ~~~  '
77      istop = nstop   ! store the actual value of nstop
78      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
79      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
80      ENDIF
81      !
82      llclobber = ldwrt .AND. ln_clobber
83      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
84         !                 ! =============
85         IF( ldwrt ) THEN  ! ... in write mode
86            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
87            IF( snc4set%luse ) THEN
88               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
89            ELSE
90               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
91            ENDIF
92            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
93         ELSE              ! ... in read mode
94            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
95            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
96         ENDIF
97      ELSE                                       ! the file does not exist (or we overwrite it)
98         !                 ! =============
99         iln = INDEX( cdname, '.nc' )
100         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
101            IF( jpnij > 1 ) THEN
102               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
103               cdname = TRIM(cltmp)
104            ENDIF
105            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
106
107            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
108            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
109            ENDIF
110
111#if defined key_netcdf4
112            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
113            CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
114            IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
115            ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
116            ENDIF
117            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
118#else
119            CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
120#endif
121
122            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
123            ! define dimensions
124            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
125            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
126            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
127            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
128            ! global attributes
129            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
130            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
131            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
132            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
133            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
134            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
135            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
136            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
137            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
139         ELSE              ! the file should be open for read mode so it must exist...
140            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
141         ENDIF
142      ENDIF
143      ! start to fill file informations
144      ! =============
145      IF( istop == nstop ) THEN   ! no error within this routine
146!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
147         kiomid = 0
148         DO jl = jpmax_files, 1, -1
149            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
150         ENDDO
151         iom_file(kiomid)%name   = TRIM(cdname)
152         iom_file(kiomid)%nfid   = if90id
153         iom_file(kiomid)%iolib  = jpnf90
154         iom_file(kiomid)%nvars  = 0
155         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
156         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
157         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
158           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,     & 
159        &                                               name = iom_file(kiomid)%uldname,  &
160        &                                               len  = iom_file(kiomid)%lenuld ), clinfo )
161         ENDIF
162         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
163      ELSE
164         kiomid = 0               ! return error flag
165      ENDIF
166      !
167   END SUBROUTINE iom_nf90_open
168
169
170   SUBROUTINE iom_nf90_close( kiomid )
171      !!--------------------------------------------------------------------
172      !!                   ***  SUBROUTINE  iom_nf90_close  ***
173      !!
174      !! ** Purpose : close an input file with NF90
175      !!--------------------------------------------------------------------
176      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
177      CHARACTER(LEN=100)  ::   clinfo   ! info character
178      !---------------------------------------------------------------------
179      !
180      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
181      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
182      !   
183   END SUBROUTINE iom_nf90_close
184
185
186   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
187      !!-----------------------------------------------------------------------
188      !!                  ***  FUNCTION  iom_varid  ***
189      !!
190      !! ** Purpose : get the id of a variable in a file with NF90
191      !!-----------------------------------------------------------------------
192      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
193      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
194      INTEGER              , INTENT(in   )           ::   kiv   !
195      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
196      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
197      !
198      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
199      INTEGER                        ::   if90id           ! nf90 file identifier
200      INTEGER                        ::   ji               ! dummy loop index
201      INTEGER                        ::   ivarid           ! NetCDF  variable Id
202      INTEGER                        ::   i_nvd            ! number of dimension of the variable
203      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
204      LOGICAL                        ::   llok             ! ok  test
205      CHARACTER(LEN=100)             ::   clinfo           ! info character
206      !!-----------------------------------------------------------------------
207      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
208      iom_nf90_varid = 0                    ! default definition
209      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
210      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
211      !
212      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
213      IF( llok ) THEN
214         iom_nf90_varid = kiv
215         iom_file(kiomid)%nvars       = kiv
216         iom_file(kiomid)%nvid(kiv)   = ivarid
217         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
218         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
219         iom_file(kiomid)%ndims(kiv)  = i_nvd
220         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
221         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
222         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
223         DO ji = 1, i_nvd                       ! dimensions size
224            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
225            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
226         END DO
227         !---------- Deal with scale_factor and add_offset
228         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
229         IF( llok) THEN
230            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
231         ELSE
232            iom_file(kiomid)%scf(kiv) = 1.
233         END IF
234         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
235         IF( llok ) THEN
236            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
237         ELSE
238            iom_file(kiomid)%ofs(kiv) = 0.
239         END IF
240         ! return the simension size
241         IF( PRESENT(kdimsz) ) THEN
242            IF( i_nvd == SIZE(kdimsz) ) THEN
243               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
244            ELSE
245               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
246               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
247            ENDIF
248         ENDIF
249         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
250      ELSE 
251         iom_nf90_varid = -1   !   variable not found, return error code: -1
252      ENDIF
253      !
254   END FUNCTION iom_nf90_varid
255
256
257   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
258      !!-----------------------------------------------------------------------
259      !!                  ***  ROUTINE  iom_nf90_g0d  ***
260      !!
261      !! ** Purpose : read a scalar with NF90
262      !!-----------------------------------------------------------------------
263      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
264      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
265      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
266      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
267      !
268      CHARACTER(LEN=100)      ::   clinfo   ! info character
269      !---------------------------------------------------------------------
270      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
271      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
272      !
273   END SUBROUTINE iom_nf90_g0d
274
275
276   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
277         &                    pv_r1d, pv_r2d, pv_r3d )
278      !!-----------------------------------------------------------------------
279      !!                  ***  ROUTINE  iom_nf90_g123d  ***
280      !!
281      !! ** Purpose : read a 1D/2D/3D variable with NF90
282      !!
283      !! ** Method : read ONE record at each CALL
284      !!-----------------------------------------------------------------------
285      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
286      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
287      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
288      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
289      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
290      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
291      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
292      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
293      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
294      !
295      CHARACTER(LEN=100) ::   clinfo               ! info character
296      INTEGER            ::   if90id               ! nf90 identifier of the opened file
297      INTEGER            ::   ivid                 ! nf90 variable id
298      !---------------------------------------------------------------------
299      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
300      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
301      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
302      !
303      IF(     PRESENT(pv_r1d) ) THEN
304         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
305            &                                                                       count = kcount(1:knbdim)), clinfo )
306      ELSEIF( PRESENT(pv_r2d) ) THEN
307         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
308            &                                                                       count = kcount(1:knbdim)), clinfo )
309      ELSEIF( PRESENT(pv_r3d) ) THEN
310         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
311            &                                                                       count = kcount(1:knbdim)), clinfo )
312      ENDIF
313      !
314   END SUBROUTINE iom_nf90_g123d
315
316
317   SUBROUTINE iom_nf90_intatt( kiomid, cdatt, pvar )
318      !!-----------------------------------------------------------------------
319      !!                  ***  ROUTINE  iom_nf90_intatt  ***
320      !!
321      !! ** Purpose : read an integer attribute with NF90
322      !!-----------------------------------------------------------------------
323      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
324      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
325      INTEGER         , INTENT(  out) ::   pvar     ! read field
326      !
327      INTEGER                         ::   if90id   ! temporary integer
328      LOGICAL                         ::   llok     ! temporary logical
329      CHARACTER(LEN=100)              ::   clinfo   ! info character
330      !---------------------------------------------------------------------
331      !
332      if90id = iom_file(kiomid)%nfid
333      llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
334      IF( llok) THEN
335         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
336         CALL iom_nf90_check(NF90_GET_ATT(if90id, NF90_GLOBAL, cdatt, values=pvar), clinfo)
337      ELSE
338         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
339         pvar = -999
340      ENDIF
341      !
342   END SUBROUTINE iom_nf90_intatt
343
344
345   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
346      !!--------------------------------------------------------------------
347      !!                   ***  SUBROUTINE iom_gettime  ***
348      !!
349      !! ** Purpose : read the time axis kvid in the file with NF90
350      !!--------------------------------------------------------------------
351      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
352      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
353      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
354      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
355      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
356      !
357      CHARACTER(LEN=100) ::   clinfo     ! info character
358      !---------------------------------------------------------------------
359      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
360      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
361            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
362      IF ( PRESENT(cdunits) ) THEN
363         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
364            &                           values=cdunits), clinfo)
365      ENDIF
366      IF ( PRESENT(cdcalendar) ) THEN
367         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
368            &                           values=cdcalendar), clinfo)
369      ENDIF
370      !
371   END SUBROUTINE iom_nf90_gettime
372
373
374   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
375         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
376      !!--------------------------------------------------------------------
377      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
378      !!
379      !! ** Purpose : read the time axis cdvar in the file
380      !!--------------------------------------------------------------------
381      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
382      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
383      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
384      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
385      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
386      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
387      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
388      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
389      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
390      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
391      !
392      INTEGER               :: idims                ! number of dimension
393      INTEGER               :: idvar                ! variable id
394      INTEGER               :: jd                   ! dimension loop counter   
395      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
396      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
397      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
398      CHARACTER(LEN=256)    :: clinfo               ! info character
399      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
400      INTEGER               :: if90id               ! nf90 file identifier
401      INTEGER               :: idmy                 ! dummy variable
402      INTEGER               :: itype                ! variable type
403      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
404                                                    ! nn_nchunks_[i,j,k,t] namelist parameters
405      INTEGER               :: ichunkalg, ishuffle,&
406                               ideflate, ideflate_level
407                                                    ! NetCDF4 internally fixed parameters
408      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
409                                                    ! when appropriate (currently chunking is applied to 4d fields only)
410      !---------------------------------------------------------------------
411      !
412      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
413      if90id = iom_file(kiomid)%nfid
414      !
415      ! define dimension variables if it is not already done
416      ! ==========================
417      IF( iom_file(kiomid)%nvars == 0 ) THEN
418         ! are we in define mode?
419         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
420            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
421         ENDIF
422         ! define the dimension variables if it is not already done
423         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
424         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
425         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
426         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
427         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
428         ! update informations structure related the dimension variable we just added...
429         iom_file(kiomid)%nvars       = 4
430         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
431         iom_file(kiomid)%cn_var(1:4) = cltmp
432         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
433         ! trick: defined to 0 to say that dimension variables are defined but not yet written
434         iom_file(kiomid)%dimsz(1, 1)  = 0   
435         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
436      ENDIF
437      ! define the data if it is not already done
438      ! ===============
439      IF( kvid <= 0 ) THEN
440         !
441         ! NetCDF4 chunking and compression fixed settings
442         ichunkalg = 0
443         ishuffle = 1
444         ideflate = 1
445         ideflate_level = 1
446         !
447         idvar = iom_file(kiomid)%nvars + 1
448         ! are we in define mode?
449         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
450            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
451         ENDIF
452         ! variable definition
453         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
454         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
455         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
456         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
457         ENDIF
458         IF( PRESENT(ktype) ) THEN   ! variable external type
459            SELECT CASE (ktype)
460            CASE (jp_r8)  ;   itype = NF90_DOUBLE
461            CASE (jp_r4)  ;   itype = NF90_FLOAT
462            CASE (jp_i4)  ;   itype = NF90_INT
463            CASE (jp_i2)  ;   itype = NF90_SHORT
464            CASE (jp_i1)  ;   itype = NF90_BYTE
465            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
466            END SELECT
467         ELSE
468            itype = NF90_DOUBLE
469         ENDIF
470         IF( PRESENT(pv_r0d) ) THEN
471            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
472                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
473         ELSE
474            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
475                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
476         ENDIF
477         lchunk = .false.
478         IF( snc4set%luse .AND. idims.eq.4 ) lchunk = .true.
479         ! update informations structure related the new variable we want to add...
480         iom_file(kiomid)%nvars         = idvar
481         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
482         iom_file(kiomid)%scf(idvar)    = 1.
483         iom_file(kiomid)%ofs(idvar)    = 0.
484         iom_file(kiomid)%ndims(idvar)  = idims
485         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
486         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
487         ENDIF
488         DO jd = 1, idims
489            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
490            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
491         END DO
492         IF ( lchunk ) THEN
493            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
494            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
495            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
496            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
497            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
498            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
499                                                                                       ! unlimited dimension
500            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
501            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
502            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
503         ENDIF
504         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
505      ELSE
506         idvar = kvid
507      ENDIF
508
509      ! time step kwrite : write the variable
510      IF( kt == kwrite ) THEN
511         ! are we in write mode?
512         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
513            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
514         ENDIF
515         ! on what kind of domain must the data be written?
516         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
517            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
518            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
519               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
520            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
521               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
522            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
523               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
524            ELSE
525               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
526            ENDIF
527
528            ! write dimension variables if it is not already done
529            ! =============
530            ! trick: is defined to 0 => dimension variable are defined but not yet written
531            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
532               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
533               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
534               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
535               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
536               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
537               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_1d                ), clinfo)
538               ! +++ WRONG VALUE: to be improved but not really useful...
539               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
540               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
541               ! update the values of the variables dimensions size
542               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
543               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
544               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
545               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
546               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
547               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
548            ENDIF
549         ENDIF
550
551         ! write the data
552         ! =============
553         IF(     PRESENT(pv_r0d) ) THEN
554            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
555         ELSEIF( PRESENT(pv_r1d) ) THEN
556            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
557         ELSEIF( PRESENT(pv_r2d) ) THEN
558            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
559         ELSEIF( PRESENT(pv_r3d) ) THEN
560            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
561         ENDIF
562         ! add 1 to the size of the temporal dimension (not really useful...)
563         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
564               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
565         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
566      ENDIF
567      !     
568   END SUBROUTINE iom_nf90_rp0123d
569
570
571   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
572      !!--------------------------------------------------------------------
573      !!                   ***  SUBROUTINE iom_nf90_check  ***
574      !!
575      !! ** Purpose :   check nf90 errors
576      !!--------------------------------------------------------------------
577      INTEGER,          INTENT(in) :: kstatus
578      CHARACTER(LEN=*), INTENT(in) :: cdinfo
579      !---------------------------------------------------------------------
580      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
581   END SUBROUTINE iom_nf90_check
582
583   !!======================================================================
584END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.