New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in branches/UKMO/dev_r5518_GO6_package_rigorous_compile_fix/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_rigorous_compile_fix/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 9563

Last change on this file since 9563 was 9563, checked in by stephenhaddad, 6 years ago

MOCI #310: Update GO6 package branch to build with rigorous optimisation level compiler option.

File size: 32.0 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limhdf          ! Ice horizontal diffusion
40   USE limthd          ! Ice thermodynamics
41   USE limitd_me       ! Mechanics on ice thickness distribution
42   USE limsbc          ! sea surface boundary condition
43   USE limdiahsb       ! Ice budget diagnostics
44   USE limwri          ! Ice outputs
45   USE limrst          ! Ice restarts
46   USE limupdate1      ! update of global variables
47   USE limupdate2      ! update of global variables
48   USE limvar          ! Ice variables switch
49
50   USE limmsh          ! LIM mesh
51   USE limistate       ! LIM initial state
52   USE limthd_sal      ! LIM ice thermodynamics: salinity
53
54   USE c1d             ! 1D vertical configuration
55   USE lbclnk          ! lateral boundary condition - MPP link
56   USE lib_mpp         ! MPP library
57   USE wrk_nemo        ! work arrays
58   USE timing          ! Timing
59   USE iom             ! I/O manager library
60   USE in_out_manager  ! I/O manager
61   USE prtctl          ! Print control
62   USE lib_fortran     !
63   USE limctl
64
65#if defined key_bdy 
66   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
67#endif
68
69   IMPLICIT NONE
70   PRIVATE
71
72   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
73   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
74   
75   !! * Substitutions
76#  include "domzgr_substitute.h90"
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
80   !! $Id$
81   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   !!======================================================================
86
87   SUBROUTINE sbc_ice_lim( kt, kblk )
88      !!---------------------------------------------------------------------
89      !!                  ***  ROUTINE sbc_ice_lim  ***
90      !!                   
91      !! ** Purpose :   update the ocean surface boundary condition via the
92      !!                Louvain la Neuve Sea Ice Model time stepping
93      !!
94      !! ** Method  :   ice model time stepping
95      !!              - call the ice dynamics routine
96      !!              - call the ice advection/diffusion routine
97      !!              - call the ice thermodynamics routine
98      !!              - call the routine that computes mass and
99      !!                heat fluxes at the ice/ocean interface
100      !!              - save the outputs
101      !!              - save the outputs for restart when necessary
102      !!
103      !! ** Action  : - time evolution of the LIM sea-ice model
104      !!              - update all sbc variables below sea-ice:
105      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
106      !!---------------------------------------------------------------------
107      INTEGER, INTENT(in) ::   kt      ! ocean time step
108      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
109      !!
110      INTEGER  ::   jl                 ! dummy loop index
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
112      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zutau_ice, zvtau_ice 
113      !!----------------------------------------------------------------------
114
115      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
116
117      !-----------------------!
118      ! --- Ice time step --- !
119      !-----------------------!
120      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
121
122         ! mean surface ocean current at ice velocity point (C-grid dynamics :  U- & V-points as the ocean)
123         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
124         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
125         
126         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
127         CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
128         t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
129         
130         ! Mask sea ice surface temperature (set to rt0 over land)
131         DO jl = 1, jpl
132            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
133         END DO     
134         !
135         !------------------------------------------------!                                           
136         ! --- Dynamical coupling with the atmosphere --- !                                           
137         !------------------------------------------------!
138         ! It provides the following fields:
139         ! utau_ice, vtau_ice : surface ice stress (U- & V-points)   [N/m2]
140         !-----------------------------------------------------------------
141         SELECT CASE( kblk )
142         CASE( jp_clio    )   ;   CALL blk_ice_clio_tau                         ! CLIO bulk formulation           
143         CASE( jp_core    )   ;   CALL blk_ice_core_tau                         ! CORE bulk formulation
144         CASE( jp_purecpl )   ;   CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled   formulation
145         END SELECT
146         
147         IF( ln_mixcpl) THEN   ! Case of a mixed Bulk/Coupled formulation
148            CALL wrk_alloc( jpi,jpj    , zutau_ice, zvtau_ice)
149            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
150            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
151            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
152            CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
153         ENDIF
154
155         !-------------------------------------------------------!
156         ! --- ice dynamics and transport (except in 1D case) ---!
157         !-------------------------------------------------------!
158         numit = numit + nn_fsbc                  ! Ice model time step
159         !                                                   
160         CALL sbc_lim_bef                         ! Store previous ice values
161         CALL sbc_lim_diag0                       ! set diag of mass, heat and salt fluxes to 0
162         CALL lim_rst_opn( kt )                   ! Open Ice restart file
163         !
164         IF( .NOT. lk_c1d ) THEN
165            !
166            CALL lim_dyn( kt )                    ! Ice dynamics    ( rheology/dynamics )   
167            !
168            CALL lim_trp( kt )                    ! Ice transport   ( Advection/diffusion )
169            !
170            IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
171            !
172#if defined key_bdy
173            CALL bdy_ice_lim( kt )                ! bdy ice thermo
174            IF( ln_icectl )       CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
175#endif
176            !
177            CALL lim_update1( kt )                ! Corrections
178            !
179         ENDIF
180         
181         ! previous lead fraction and ice volume for flux calculations
182         CALL sbc_lim_bef                       
183         CALL lim_var_glo2eqv                     ! ht_i and ht_s for ice albedo calculation
184         CALL lim_var_agg(1)                      ! at_i for coupling (via pfrld)
185         pfrld(:,:)   = 1._wp - at_i(:,:)
186         phicif(:,:)  = vt_i(:,:)
187         
188         !------------------------------------------------------!                                           
189         ! --- Thermodynamical coupling with the atmosphere --- !                                           
190         !------------------------------------------------------!
191         ! It provides the following fields:
192         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
193         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
194         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
195         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
196         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
197         !----------------------------------------------------------------------------------------
198         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
199         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
200
201         SELECT CASE( kblk )
202         CASE( jp_clio )                                       ! CLIO bulk formulation
203            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
204            ! (alb_ice) is computed within the bulk routine
205                                 CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
206            IF( ln_mixcpl      ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
207            IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
208         CASE( jp_core )                                       ! CORE bulk formulation
209            ! albedo depends on cloud fraction because of non-linear spectral effects
210            alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
211                                 CALL blk_ice_core_flx( t_su, alb_ice )
212            IF( ln_mixcpl      ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
213            IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
214         CASE ( jp_purecpl )
215            ! albedo depends on cloud fraction because of non-linear spectral effects
216            alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
217                                 CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
218            IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
219         END SELECT
220         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
221
222         !----------------------------!
223         ! --- ice thermodynamics --- !
224         !----------------------------!
225         CALL lim_thd( kt )                         ! Ice thermodynamics     
226         !
227         CALL lim_update2( kt )                     ! Corrections
228         !
229         CALL lim_sbc_flx( kt )                     ! Update surface ocean mass, heat and salt fluxes
230         !
231         IF(ln_limdiaout) CALL lim_diahsb           ! Diagnostics and outputs
232         !
233         CALL lim_wri( 1 )                          ! Ice outputs
234         !
235         IF( kt == nit000 .AND. ln_rstart )   &
236            &             CALL iom_close( numrir )  ! close input ice restart file
237         !
238         IF( lrst_ice )   CALL lim_rst_write( kt )  ! Ice restart file
239         !
240         IF( ln_icectl )  CALL lim_ctl( kt )        ! alerts in case of model crash
241         !
242      ENDIF   ! End sea-ice time step only
243
244      !-------------------------!
245      ! --- Ocean time step --- !
246      !-------------------------!
247      ! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
248      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
249!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
250      !
251      IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
252      !
253   END SUBROUTINE sbc_ice_lim
254   
255
256   SUBROUTINE sbc_lim_init
257      !!----------------------------------------------------------------------
258      !!                  ***  ROUTINE sbc_lim_init  ***
259      !!
260      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
261      !!----------------------------------------------------------------------
262      INTEGER :: ierr
263      INTEGER :: ji, jj
264      !!----------------------------------------------------------------------
265      IF(lwp) WRITE(numout,*)
266      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
267      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
268      !
269                                       ! Open the reference and configuration namelist files and namelist output file
270      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
271      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
272      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
273
274      CALL ice_run                     ! set some ice run parameters
275      !
276      !                                ! Allocate the ice arrays
277      ierr =        ice_alloc        ()      ! ice variables
278      ierr = ierr + dom_ice_alloc    ()      ! domain
279      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
280      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
281      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
282      !
283      IF( lk_mpp    )   CALL mpp_sum( ierr )
284      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
285      !
286      !                                ! adequation jpk versus ice/snow layers/categories
287      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
288         &      CALL ctl_stop( 'STOP',                          &
289         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
290         &     'use more ocean levels or less ice/snow layers/categories.' )
291      !
292      CALL lim_itd_init                ! ice thickness distribution initialization
293      !
294      CALL lim_hdf_init                ! set ice horizontal diffusion computation parameters
295      !
296      CALL lim_thd_init                ! set ice thermodynics parameters
297      !
298      CALL lim_thd_sal_init            ! set ice salinity parameters
299      !
300      CALL lim_msh                     ! ice mesh initialization
301      !
302      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
303      !                                ! Initial sea-ice state
304      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
305         numit = 0
306         numit = nit000 - 1
307         CALL lim_istate
308      ELSE                                    ! start from a restart file
309         CALL lim_rst_read
310         numit = nit000 - 1
311      ENDIF
312      CALL lim_var_agg(1)
313      CALL lim_var_glo2eqv
314      !
315      CALL lim_sbc_init                 ! ice surface boundary condition   
316      !
317      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
318      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
319      !
320      DO jj = 1, jpj
321         DO ji = 1, jpi
322            IF( gphit(ji,jj) > 0._wp ) THEN  ;  rn_amax_2d(ji,jj) = rn_amax_n  ! NH
323            ELSE                             ;  rn_amax_2d(ji,jj) = rn_amax_s  ! SH
324            ENDIF
325        ENDDO
326      ENDDO 
327      !
328      nstart = numit  + nn_fsbc     
329      nitrun = nitend - nit000 + 1 
330      nlast  = numit  + nitrun 
331      !
332      IF( nstock == 0 )   nstock = nlast + 1
333      !
334   END SUBROUTINE sbc_lim_init
335
336
337   SUBROUTINE ice_run
338      !!-------------------------------------------------------------------
339      !!                  ***  ROUTINE ice_run ***
340      !!                 
341      !! ** Purpose :   Definition some run parameter for ice model
342      !!
343      !! ** Method  :   Read the namicerun namelist and check the parameter
344      !!              values called at the first timestep (nit000)
345      !!
346      !! ** input   :   Namelist namicerun
347      !!-------------------------------------------------------------------
348      INTEGER  ::   ios                 ! Local integer output status for namelist read
349      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir,  &
350         &                ln_limdyn, rn_amax_n, rn_amax_s, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt 
351      !!-------------------------------------------------------------------
352      !                   
353      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
354      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
355901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
356
357      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
358      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
359902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
360      IF(lwm) WRITE ( numoni, namicerun )
361      !
362      !
363      IF(lwp) THEN                        ! control print
364         WRITE(numout,*)
365         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
366         WRITE(numout,*) ' ~~~~~~'
367         WRITE(numout,*) '   number of ice  categories                               = ', jpl
368         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
369         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
370         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
371         WRITE(numout,*) '   maximum ice concentration for NH                        = ', rn_amax_n 
372         WRITE(numout,*) '   maximum ice concentration for SH                        = ', rn_amax_s
373         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
374         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
375         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
376         WRITE(numout,*) '   i-index for control prints (ln_icectl=true)             = ', iiceprt
377         WRITE(numout,*) '   j-index for control prints (ln_icectl=true)             = ', jiceprt
378      ENDIF
379      !
380      ! sea-ice timestep and inverse
381      rdt_ice   = nn_fsbc * rdttra(1) 
382      r1_rdtice = 1._wp / rdt_ice 
383
384      ! inverse of nlay_i and nlay_s
385      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
386      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
387      !
388#if defined key_bdy
389      IF( lwp .AND. ln_limdiahsb )  CALL ctl_warn('online conservation check activated but it does not work with BDY')
390#endif
391      !
392   END SUBROUTINE ice_run
393
394
395   SUBROUTINE lim_itd_init
396      !!------------------------------------------------------------------
397      !!                ***  ROUTINE lim_itd_init ***
398      !!
399      !! ** Purpose :   Initializes the ice thickness distribution
400      !! ** Method  :   ...
401      !! ** input   :   Namelist namiceitd
402      !!-------------------------------------------------------------------
403      INTEGER  ::   ios                 ! Local integer output status for namelist read
404      NAMELIST/namiceitd/ nn_catbnd, rn_himean
405      !
406      INTEGER  ::   jl                   ! dummy loop index
407      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
408      REAL(wp) ::   zhmax, znum, zden, zalpha !
409      !!------------------------------------------------------------------
410      !
411      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
412      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
413903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
414
415      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
416      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
417904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
418      IF(lwm) WRITE ( numoni, namiceitd )
419      !
420      !
421      IF(lwp) THEN                        ! control print
422         WRITE(numout,*)
423         WRITE(numout,*) 'ice_itd : ice cat distribution'
424         WRITE(numout,*) ' ~~~~~~'
425         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
426         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
427      ENDIF
428
429      !----------------------------------
430      !- Thickness categories boundaries
431      !----------------------------------
432      IF(lwp) WRITE(numout,*)
433      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
434      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
435
436      hi_max(:) = 0._wp
437
438      SELECT CASE ( nn_catbnd  )       
439                                   !----------------------
440         CASE (1)                  ! tanh function (CICE)
441                                   !----------------------
442         zc1 =  3._wp / REAL( jpl, wp )
443         zc2 = 10._wp * zc1
444         zc3 =  3._wp
445
446         DO jl = 1, jpl
447            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
448            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
449         END DO
450
451                                   !----------------------
452         CASE (2)                  ! h^(-alpha) function
453                                   !----------------------
454         zalpha = 0.05             ! exponent of the transform function
455
456         zhmax  = 3.*rn_himean
457
458         DO jl = 1, jpl 
459            znum = jpl * ( zhmax+1 )**zalpha
460            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
461            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
462         END DO
463
464      END SELECT
465
466      DO jl = 1, jpl
467         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
468      END DO
469
470      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
471      hi_max(jpl) = 99._wp
472
473      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
474      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
475      !
476   END SUBROUTINE lim_itd_init
477
478   
479   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
480      !!---------------------------------------------------------------------
481      !!                  ***  ROUTINE ice_lim_flx  ***
482      !!                   
483      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
484      !!                redistributing fluxes on ice categories                   
485      !!
486      !! ** Method  :   average then redistribute
487      !!
488      !! ** Action  :   
489      !!---------------------------------------------------------------------
490      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
491                                                                ! =1 average and redistribute ; =2 redistribute
492      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
493      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
494      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
495      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
496      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
497      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
498      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
499      !
500      INTEGER  ::   jl      ! dummy loop index
501      !
502      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
503      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
504      !
505      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
506      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
507      REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m  ! Mean sublimation over all categories
508      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
509      REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
510      !!----------------------------------------------------------------------
511
512      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
513      !
514      !
515      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
516      CASE( 0 , 1 )
517         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
518         !
519         z_qns_m  (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
520         z_qsr_m  (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
521         z_dqn_m  (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
522         z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
523         z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
524         DO jl = 1, jpl
525            pdqn_ice  (:,:,jl) = z_dqn_m(:,:)
526            pdevap_ice(:,:,jl) = z_devap_m(:,:)
527         END DO
528         !
529         DO jl = 1, jpl
530            pqns_ice (:,:,jl) = z_qns_m(:,:)
531            pqsr_ice (:,:,jl) = z_qsr_m(:,:)
532            pevap_ice(:,:,jl) = z_evap_m(:,:)
533         END DO
534         !
535         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
536      END SELECT
537
538      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
539      CASE( 1 , 2 )
540         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
541         !
542         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
543         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
544         DO jl = 1, jpl
545            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
546            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
547            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
548         END DO
549         !
550         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
551      END SELECT
552      !
553      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
554      !
555   END SUBROUTINE ice_lim_flx
556
557   SUBROUTINE sbc_lim_bef
558      !!----------------------------------------------------------------------
559      !!                  ***  ROUTINE sbc_lim_bef  ***
560      !!
561      !! ** purpose :  store ice variables at "before" time step
562      !!----------------------------------------------------------------------
563      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
564      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
565      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
566      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
567      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
568      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
569      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
570      u_ice_b(:,:)     = u_ice(:,:)
571      v_ice_b(:,:)     = v_ice(:,:)
572     
573   END SUBROUTINE sbc_lim_bef
574
575   SUBROUTINE sbc_lim_diag0
576      !!----------------------------------------------------------------------
577      !!                  ***  ROUTINE sbc_lim_diag0  ***
578      !!
579      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
580      !!               of the time step
581      !!----------------------------------------------------------------------
582      sfx    (:,:) = 0._wp   ;
583      sfx_bri(:,:) = 0._wp   ; 
584      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
585      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
586      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
587      sfx_res(:,:) = 0._wp   ;   sfx_sub(:,:) = 0._wp
588     
589      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
590      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
591      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
592      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
593      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
594      wfx_spr(:,:) = 0._wp   ;   
595     
596      hfx_thd(:,:) = 0._wp   ;   
597      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
598      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
599      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
600      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
601      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
602      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
603      hfx_err_dif(:,:) = 0._wp
604      wfx_err_sub(:,:) = 0._wp
605     
606      afx_tot(:,:) = 0._wp   ;
607      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
608
609      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp ;
610      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp ;
611     
612   END SUBROUTINE sbc_lim_diag0
613
614     
615   FUNCTION fice_cell_ave ( ptab )
616      !!--------------------------------------------------------------------------
617      !! * Compute average over categories, for grid cell (ice covered and free ocean)
618      !!--------------------------------------------------------------------------
619      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
620      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
621      INTEGER :: jl ! Dummy loop index
622     
623      fice_cell_ave (:,:) = 0.0_wp
624      DO jl = 1, jpl
625         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
626      END DO
627     
628   END FUNCTION fice_cell_ave
629   
630   
631   FUNCTION fice_ice_ave ( ptab )
632      !!--------------------------------------------------------------------------
633      !! * Compute average over categories, for ice covered part of grid cell
634      !!--------------------------------------------------------------------------
635      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
636      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
637
638      fice_ice_ave (:,:) = 0.0_wp
639      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
640
641   END FUNCTION fice_ice_ave
642
643
644#else
645   !!----------------------------------------------------------------------
646   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
647   !!----------------------------------------------------------------------
648CONTAINS
649   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
650      INTEGER, INTENT(in) ::   kt      ! ocean time step
651      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
652      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
653   END SUBROUTINE sbc_ice_lim
654   SUBROUTINE sbc_lim_init                 ! Dummy routine
655   END SUBROUTINE sbc_lim_init
656#endif
657
658   !!======================================================================
659END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.