source: branches/UKMO/dev_r5518_GO6_package_text_diagnostics/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 10759

Last change on this file since 10759 was 10759, checked in by andmirek, 20 months ago

GMED 450 write output.namelist.dyn only for nprint > 2

File size: 71.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE biaspar         ! bias correction variables
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_rhd_st  ! tmp density storage for pressure corr
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_gru_st  ! tmp ua trends storage for pressure corr
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_grv_st  ! tmp va trends storage for pressure corr
90      !!----------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
93      !
94      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
95         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
96         ztrdu(:,:,:) = ua(:,:,:)
97         ztrdv(:,:,:) = va(:,:,:)
98      ENDIF
99      !
100      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
101
102         !Allocate space for tempory variables
103         ALLOCATE( z_rhd_st(jpi,jpj,jpk), &
104            &      z_gru_st(jpi,jpj),     &
105            &      z_grv_st(jpi,jpj)      )
106
107         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
108         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
109         z_gru_st(:,:)   = gru(:,:)
110         gru(:,:)        = gru_pc(:,:)
111         z_grv_st(:,:)   = grv(:,:)
112         grv(:,:)        = grv_pc(:,:)
113
114      ENDIF
115
116      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
117      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
118      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
119      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
120      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
121      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
122      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
123      END SELECT
124      !
125      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
126         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
127         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
128         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
129         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
130      ENDIF
131      !
132      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
133         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
134      !
135      IF ( ln_bias .AND. ln_bias_pc_app )  THEN
136         IF(lwp) THEN
137         WRITE(numout,*) " ! restore original density"
138         ENDIF
139         rhd(:,:,:) = z_rhd_st(:,:,:)     ! restore original density
140         gru(:,:)   = z_gru_st(:,:)
141         grv(:,:)   = z_grv_st(:,:)
142
143         !Deallocate tempory variables
144         DEALLOCATE( z_rhd_st,     &
145            &        z_gru_st,     &
146            &        z_grv_st      )
147      ENDIF
148      !
149      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
150      !
151   END SUBROUTINE dyn_hpg
152
153
154   SUBROUTINE dyn_hpg_init
155      !!----------------------------------------------------------------------
156      !!                 ***  ROUTINE dyn_hpg_init  ***
157      !!
158      !! ** Purpose :   initializations for the hydrostatic pressure gradient
159      !!              computation and consistency control
160      !!
161      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
162      !!      with the type of vertical coordinate used (zco, zps, sco)
163      !!----------------------------------------------------------------------
164      INTEGER ::   ioptio = 0      ! temporary integer
165      INTEGER ::   ios             ! Local integer output status for namelist read
166      !!
167      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
168         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
169      !!----------------------------------------------------------------------
170      !
171      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
172      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
173901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
174
175      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
176      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
177902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
178      IF(lwm .AND. nprint > 2) WRITE ( numond, namdyn_hpg )
179      !
180      IF(lwp) THEN                   ! Control print
181         WRITE(numout,*)
182         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
183         WRITE(numout,*) '~~~~~~~~~~~~'
184         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
185         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
186         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
187         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
188         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
189         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
190         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
191         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
192      ENDIF
193      !
194      IF( ln_hpg_djc )   &
195         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
196                           & currently disabled (bugs under investigation). Please select &
197                           & either  ln_hpg_sco or  ln_hpg_prj instead')
198      !
199      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
200         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
201                           & the standard jacobian formulation hpg_sco or &
202                           & the pressure jacobian formulation hpg_prj')
203
204      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
205         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
206      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
207         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
208      !
209      !                               ! Set nhpg from ln_hpg_... flags
210      IF( ln_hpg_zco )   nhpg = 0
211      IF( ln_hpg_zps )   nhpg = 1
212      IF( ln_hpg_sco )   nhpg = 2
213      IF( ln_hpg_djc )   nhpg = 3
214      IF( ln_hpg_prj )   nhpg = 4
215      IF( ln_hpg_isf )   nhpg = 5
216      !
217      !                               ! Consistency check
218      ioptio = 0
219      IF( ln_hpg_zco )   ioptio = ioptio + 1
220      IF( ln_hpg_zps )   ioptio = ioptio + 1
221      IF( ln_hpg_sco )   ioptio = ioptio + 1
222      IF( ln_hpg_djc )   ioptio = ioptio + 1
223      IF( ln_hpg_prj )   ioptio = ioptio + 1
224      IF( ln_hpg_isf )   ioptio = ioptio + 1
225      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
226      !
227      ! initialisation of ice load
228      riceload(:,:)=0.0
229      !
230   END SUBROUTINE dyn_hpg_init
231
232
233   SUBROUTINE hpg_zco( kt )
234      !!---------------------------------------------------------------------
235      !!                  ***  ROUTINE hpg_zco  ***
236      !!
237      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
238      !!      The now hydrostatic pressure gradient at a given level, jk,
239      !!      is computed by taking the vertical integral of the in-situ
240      !!      density gradient along the model level from the suface to that
241      !!      level:    zhpi = grav .....
242      !!                zhpj = grav .....
243      !!      add it to the general momentum trend (ua,va).
244      !!            ua = ua - 1/e1u * zhpi
245      !!            va = va - 1/e2v * zhpj
246      !!
247      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
248      !!----------------------------------------------------------------------
249      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
250      !!
251      INTEGER  ::   ji, jj, jk       ! dummy loop indices
252      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
253      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
254      !!----------------------------------------------------------------------
255      !
256      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
257      !
258      IF( kt == nit000 ) THEN
259         IF(lwp) WRITE(numout,*)
260         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
261         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
262      ENDIF
263
264      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
265
266      ! Surface value
267      DO jj = 2, jpjm1
268         DO ji = fs_2, fs_jpim1   ! vector opt.
269            zcoef1 = zcoef0 * fse3w(ji,jj,1)
270            ! hydrostatic pressure gradient
271            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
272            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
273            ! add to the general momentum trend
274            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
275            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
276         END DO
277      END DO
278
279      !
280      ! interior value (2=<jk=<jpkm1)
281      DO jk = 2, jpkm1
282         DO jj = 2, jpjm1
283            DO ji = fs_2, fs_jpim1   ! vector opt.
284               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
285               ! hydrostatic pressure gradient
286               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
287                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
288                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
289
290               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
291                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
292                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
293               ! add to the general momentum trend
294               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
295               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
296            END DO
297         END DO
298      END DO
299      !
300      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
301      !
302   END SUBROUTINE hpg_zco
303
304
305   SUBROUTINE hpg_zps( kt )
306      !!---------------------------------------------------------------------
307      !!                 ***  ROUTINE hpg_zps  ***
308      !!
309      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
310      !!
311      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
312      !!----------------------------------------------------------------------
313      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
314      !!
315      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
316      INTEGER  ::   iku, ikv                         ! temporary integers
317      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
318      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
319      !!----------------------------------------------------------------------
320      !
321      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
322      !
323      IF( kt == nit000 ) THEN
324         IF(lwp) WRITE(numout,*)
325         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
326         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
327      ENDIF
328
329
330      ! Local constant initialization
331      zcoef0 = - grav * 0.5_wp
332
333      !  Surface value (also valid in partial step case)
334      DO jj = 2, jpjm1
335         DO ji = fs_2, fs_jpim1   ! vector opt.
336            zcoef1 = zcoef0 * fse3w(ji,jj,1)
337            ! hydrostatic pressure gradient
338            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
339            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
340            ! add to the general momentum trend
341            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
342            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
343         END DO
344      END DO
345
346
347      ! interior value (2=<jk=<jpkm1)
348      DO jk = 2, jpkm1
349         DO jj = 2, jpjm1
350            DO ji = fs_2, fs_jpim1   ! vector opt.
351               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
352               ! hydrostatic pressure gradient
353               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
354                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
355                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
356
357               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
358                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
359                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
360               ! add to the general momentum trend
361               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
362               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
363            END DO
364         END DO
365      END DO
366
367
368      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
369      DO jj = 2, jpjm1
370         DO ji = 2, jpim1
371            iku = mbku(ji,jj)
372            ikv = mbkv(ji,jj)
373            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
374            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
375            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
376               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
377               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
378                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
379               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
380            ENDIF
381            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
382               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
383               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
384                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
385               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
386            ENDIF
387         END DO
388      END DO
389      !
390      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
391      !
392   END SUBROUTINE hpg_zps
393
394   SUBROUTINE hpg_sco( kt )
395      !!---------------------------------------------------------------------
396      !!                  ***  ROUTINE hpg_sco  ***
397      !!
398      !! ** Method  :   s-coordinate case. Jacobian scheme.
399      !!      The now hydrostatic pressure gradient at a given level, jk,
400      !!      is computed by taking the vertical integral of the in-situ
401      !!      density gradient along the model level from the suface to that
402      !!      level. s-coordinates (ln_sco): a corrective term is added
403      !!      to the horizontal pressure gradient :
404      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
405      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
406      !!      add it to the general momentum trend (ua,va).
407      !!         ua = ua - 1/e1u * zhpi
408      !!         va = va - 1/e2v * zhpj
409      !!
410      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
411      !!----------------------------------------------------------------------
412      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
413      !!
414      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
415      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
416      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
417      !!----------------------------------------------------------------------
418      !
419      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
420      !
421      IF( kt == nit000 ) THEN
422         IF(lwp) WRITE(numout,*)
423         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
424         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
425      ENDIF
426
427      ! Local constant initialization
428      zcoef0 = - grav * 0.5_wp
429      ! To use density and not density anomaly
430      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
431      ELSE                 ;     znad = 0._wp         ! Fixed volume
432      ENDIF
433
434      ! Surface value
435      DO jj = 2, jpjm1
436         DO ji = fs_2, fs_jpim1   ! vector opt.
437            ! hydrostatic pressure gradient along s-surfaces
438            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
439               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
440            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
441               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
442            ! s-coordinate pressure gradient correction
443            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
444               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
445            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
446               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
447            ! add to the general momentum trend
448            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
449            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
450         END DO
451      END DO
452
453      ! interior value (2=<jk=<jpkm1)
454      DO jk = 2, jpkm1
455         DO jj = 2, jpjm1
456            DO ji = fs_2, fs_jpim1   ! vector opt.
457               ! hydrostatic pressure gradient along s-surfaces
458               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
459                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
460                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
461               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
462                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
463                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
464               ! s-coordinate pressure gradient correction
465               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
466                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
467               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
468                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
469               ! add to the general momentum trend
470               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
471               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
472            END DO
473         END DO
474      END DO
475      !
476      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
477      !
478   END SUBROUTINE hpg_sco
479
480   SUBROUTINE hpg_isf( kt )
481      !!---------------------------------------------------------------------
482      !!                  ***  ROUTINE hpg_sco  ***
483      !!
484      !! ** Method  :   s-coordinate case. Jacobian scheme.
485      !!      The now hydrostatic pressure gradient at a given level, jk,
486      !!      is computed by taking the vertical integral of the in-situ
487      !!      density gradient along the model level from the suface to that
488      !!      level. s-coordinates (ln_sco): a corrective term is added
489      !!      to the horizontal pressure gradient :
490      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
491      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
492      !!      add it to the general momentum trend (ua,va).
493      !!         ua = ua - 1/e1u * zhpi
494      !!         va = va - 1/e2v * zhpj
495      !!      iceload is added and partial cell case are added to the top and bottom
496      !!     
497      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
498      !!----------------------------------------------------------------------
499      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
500      !!
501      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
502      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
503      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
504      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
505      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
506      !!----------------------------------------------------------------------
507      !
508      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
509      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
510      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
511      !
512     IF( kt == nit000 ) THEN
513         IF(lwp) WRITE(numout,*)
514         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
515         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
516      ENDIF
517
518      ! Local constant initialization
519      zcoef0 = - grav * 0.5_wp
520      ! To use density and not density anomaly
521!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
522!      ELSE                 ;     znad = 0._wp         ! Fixed volume
523!      ENDIF
524      znad=1._wp
525      ! iniitialised to 0. zhpi zhpi
526      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
527
528!==================================================================================     
529!=====Compute iceload and contribution of the half first wet layer =================
530!===================================================================================
531
532      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
533      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
534
535      ! compute density of the water displaced by the ice shelf
536      zrhd = rhd ! save rhd
537      DO jk = 1, jpk
538           zdept(:,:)=gdept_1d(jk)
539           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
540      END DO
541      WHERE ( tmask(:,:,:) == 1._wp)
542        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
543      END WHERE
544     
545      ! compute rhd at the ice/oce interface (ice shelf side)
546      CALL eos(ztstop,risfdep,zrhdtop_isf)
547
548      ! compute rhd at the ice/oce interface (ocean side)
549      DO ji=1,jpi
550        DO jj=1,jpj
551          ikt=mikt(ji,jj)
552          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
553          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
554        END DO
555      END DO
556      CALL eos(ztstop,risfdep,zrhdtop_oce)
557      !
558      ! Surface value + ice shelf gradient
559      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
560      ziceload = 0._wp
561      DO jj = 1, jpj
562         DO ji = 1, jpi   ! vector opt.
563            ikt=mikt(ji,jj)
564            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
565            DO jk=2,ikt-1
566               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
567                  &                              * (1._wp - tmask(ji,jj,jk))
568            END DO
569            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
570                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
571         END DO
572      END DO
573      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
574      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
575      DO jj = 2, jpjm1
576         DO ji = fs_2, fs_jpim1   ! vector opt.
577            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
578            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
579            ! we assume ISF is in isostatic equilibrium
580            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
581               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
582               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
583               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
584               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
585            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
586               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
587               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
588               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
589               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
590            ! s-coordinate pressure gradient correction (=0 if z coordinate)
591            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
592               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
593            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
594               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
595            ! add to the general momentum trend
596            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
597            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
598         END DO
599      END DO
600!==================================================================================     
601!===== Compute partial cell contribution for the top cell =========================
602!==================================================================================
603      DO jj = 2, jpjm1
604         DO ji = fs_2, fs_jpim1   ! vector opt.
605            iku = miku(ji,jj) ; 
606            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
607            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
608            ! u direction
609            IF ( iku .GT. 1 ) THEN
610               ! case iku
611               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
612                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
613                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
614               ! corrective term ( = 0 if z coordinate )
615               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
616               ! zhpi will be added in interior loop
617               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
618               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
619               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
620
621               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
622               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
623                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
624                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
625                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
626                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
627               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
628            END IF
629               
630            ! v direction
631            ikv = mikv(ji,jj)
632            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
633            IF ( ikv .GT. 1 ) THEN
634               ! case ikv
635               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
636                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
637                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
638               ! corrective term ( = 0 if z coordinate )
639               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
640               ! zhpi will be added in interior loop
641               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
642               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
643               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
644               
645               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
646               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
647                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
648                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
649                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
650                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
651               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
652            END IF
653         END DO
654      END DO
655
656!==================================================================================     
657!===== Compute interior value =====================================================
658!==================================================================================
659
660      DO jj = 2, jpjm1
661         DO ji = fs_2, fs_jpim1   ! vector opt.
662            iku=miku(ji,jj); ikv=mikv(ji,jj)
663            DO jk = 2, jpkm1
664               ! hydrostatic pressure gradient along s-surfaces
665               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
666               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
667                  &                            + zcoef0 / e1u(ji,jj)                                                           &
668                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
669                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
670                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
671                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
672               ! s-coordinate pressure gradient correction
673               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
674               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
675                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
676               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
677
678               ! hydrostatic pressure gradient along s-surfaces
679               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
680               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
681                  &                            + zcoef0 / e2v(ji,jj)                                                           &
682                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
683                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
684                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
685                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
686               ! s-coordinate pressure gradient correction
687               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
688               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
689                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
690               ! add to the general momentum trend
691               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
692            END DO
693         END DO
694      END DO
695
696!==================================================================================     
697!===== Compute bottom cell contribution (partial cell) ============================
698!==================================================================================
699
700      DO jj = 2, jpjm1
701         DO ji = 2, jpim1
702            iku = mbku(ji,jj)
703            ikv = mbkv(ji,jj)
704
705            IF (iku .GT. 1) THEN
706               ! remove old value (interior case)
707               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
708                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
709               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
710               ! put new value
711               ! -zpshpi to avoid double contribution of the partial step in the top layer
712               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
713               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
714               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
715            END IF
716            ! v direction
717            IF (ikv .GT. 1) THEN
718               ! remove old value (interior case)
719               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
720                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
721               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
722               ! put new value
723               ! -zpshpj to avoid double contribution of the partial step in the top layer
724               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
725               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
726               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
727            END IF
728         END DO
729      END DO
730     
731      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
732      rhd = zrhd
733      !
734      CALL wrk_dealloc( jpi,jpj,2, ztstop)
735      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
736      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
737      !
738   END SUBROUTINE hpg_isf
739
740
741   SUBROUTINE hpg_djc( kt )
742      !!---------------------------------------------------------------------
743      !!                  ***  ROUTINE hpg_djc  ***
744      !!
745      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
746      !!
747      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
748      !!----------------------------------------------------------------------
749      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
750      !!
751      INTEGER  ::   ji, jj, jk          ! dummy loop indices
752      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
753      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
754      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
755      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
756      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
757      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
758      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
759      !!----------------------------------------------------------------------
760      !
761      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
762      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
763      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
764      !
765
766      IF( kt == nit000 ) THEN
767         IF(lwp) WRITE(numout,*)
768         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
769         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
770      ENDIF
771
772      ! Local constant initialization
773      zcoef0 = - grav * 0.5_wp
774      z1_10  = 1._wp / 10._wp
775      z1_12  = 1._wp / 12._wp
776
777      !----------------------------------------------------------------------------------------
778      !  compute and store in provisional arrays elementary vertical and horizontal differences
779      !----------------------------------------------------------------------------------------
780
781!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
782
783      DO jk = 2, jpkm1
784         DO jj = 2, jpjm1
785            DO ji = fs_2, fs_jpim1   ! vector opt.
786               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
787               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
788               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
789               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
790               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
791               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
792            END DO
793         END DO
794      END DO
795
796      !-------------------------------------------------------------------------
797      ! compute harmonic averages using eq. 5.18
798      !-------------------------------------------------------------------------
799      zep = 1.e-15
800
801!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
802!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
803
804      DO jk = 2, jpkm1
805         DO jj = 2, jpjm1
806            DO ji = fs_2, fs_jpim1   ! vector opt.
807               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
808
809               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
810               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
811
812               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
813               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
814
815               IF( cffw > zep) THEN
816                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
817                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
818               ELSE
819                  drhow(ji,jj,jk) = 0._wp
820               ENDIF
821
822               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
823                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
824
825               IF( cffu > zep ) THEN
826                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
827                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
828               ELSE
829                  drhou(ji,jj,jk ) = 0._wp
830               ENDIF
831
832               IF( cffx > zep ) THEN
833                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
834                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
835               ELSE
836                  dzu(ji,jj,jk) = 0._wp
837               ENDIF
838
839               IF( cffv > zep ) THEN
840                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
841                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
842               ELSE
843                  drhov(ji,jj,jk) = 0._wp
844               ENDIF
845
846               IF( cffy > zep ) THEN
847                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
848                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
849               ELSE
850                  dzv(ji,jj,jk) = 0._wp
851               ENDIF
852
853            END DO
854         END DO
855      END DO
856
857      !----------------------------------------------------------------------------------
858      ! apply boundary conditions at top and bottom using 5.36-5.37
859      !----------------------------------------------------------------------------------
860      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
861      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
862      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
863
864      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
865      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
866      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
867
868
869      !--------------------------------------------------------------
870      ! Upper half of top-most grid box, compute and store
871      !-------------------------------------------------------------
872
873!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
874!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
875
876      DO jj = 2, jpjm1
877         DO ji = fs_2, fs_jpim1   ! vector opt.
878            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
879               &                   * (  rhd(ji,jj,1)                                    &
880               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
881               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
882               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
883         END DO
884      END DO
885
886!!bug gm    : here also, simplification is possible
887!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
888
889      DO jk = 2, jpkm1
890         DO jj = 2, jpjm1
891            DO ji = fs_2, fs_jpim1   ! vector opt.
892
893               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
894                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
895                  &            - grav * z1_10 * (                                                                     &
896                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
897                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
898                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
899                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
900                  &                             )
901
902               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
903                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
904                  &            - grav* z1_10 * (                                                                      &
905                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
906                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
907                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
908                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
909                  &                            )
910
911               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
912                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
913                  &            - grav* z1_10 * (                                                                      &
914                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
915                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
916                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
917                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
918                  &                            )
919
920            END DO
921         END DO
922      END DO
923      CALL lbc_lnk(rho_k,'W',1.)
924      CALL lbc_lnk(rho_i,'U',1.)
925      CALL lbc_lnk(rho_j,'V',1.)
926
927
928      ! ---------------
929      !  Surface value
930      ! ---------------
931      DO jj = 2, jpjm1
932         DO ji = fs_2, fs_jpim1   ! vector opt.
933            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
934            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
935            ! add to the general momentum trend
936            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
937            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
938         END DO
939      END DO
940
941      ! ----------------
942      !  interior value   (2=<jk=<jpkm1)
943      ! ----------------
944      DO jk = 2, jpkm1
945         DO jj = 2, jpjm1
946            DO ji = fs_2, fs_jpim1   ! vector opt.
947               ! hydrostatic pressure gradient along s-surfaces
948               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
949                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
950                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
951               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
952                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
953                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
954               ! add to the general momentum trend
955               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
956               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
957            END DO
958         END DO
959      END DO
960      !
961      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
962      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
963      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
964      !
965   END SUBROUTINE hpg_djc
966
967
968   SUBROUTINE hpg_prj( kt )
969      !!---------------------------------------------------------------------
970      !!                  ***  ROUTINE hpg_prj  ***
971      !!
972      !! ** Method  :   s-coordinate case.
973      !!      A Pressure-Jacobian horizontal pressure gradient method
974      !!      based on the constrained cubic-spline interpolation for
975      !!      all vertical coordinate systems
976      !!
977      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
978      !!----------------------------------------------------------------------
979      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
980      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
981      !!
982      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
983      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
984      !!
985      !! The local variables for the correction term
986      INTEGER  :: jk1, jis, jid, jjs, jjd
987      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
988      REAL(wp) :: zrhdt1
989      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
990      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
991      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
992      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
993      !!----------------------------------------------------------------------
994      !
995      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
996      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
997      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
998      !
999      IF( kt == nit000 ) THEN
1000         IF(lwp) WRITE(numout,*)
1001         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1002         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
1003      ENDIF
1004
1005      !!----------------------------------------------------------------------
1006      ! Local constant initialization
1007      zcoef0 = - grav
1008      znad = 0.0_wp
1009      IF( lk_vvl ) znad = 1._wp
1010
1011      ! Clean 3-D work arrays
1012      zhpi(:,:,:) = 0._wp
1013      zrhh(:,:,:) = rhd(:,:,:)
1014
1015      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1016      DO jj = 1, jpj
1017        DO ji = 1, jpi
1018          jk = mbathy(ji,jj)
1019          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1020          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1021          ELSE IF(jk < jpkm1) THEN
1022             DO jkk = jk+1, jpk
1023                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1024                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1025             END DO
1026          ENDIF
1027        END DO
1028      END DO
1029
1030      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1031      DO jj = 1, jpj
1032         DO ji = 1, jpi
1033            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1034         END DO
1035      END DO
1036
1037      DO jk = 2, jpk
1038         DO jj = 1, jpj
1039            DO ji = 1, jpi
1040               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1041            END DO
1042         END DO
1043      END DO
1044
1045      fsp(:,:,:) = zrhh (:,:,:)
1046      xsp(:,:,:) = zdept(:,:,:)
1047
1048      ! Construct the vertical density profile with the
1049      ! constrained cubic spline interpolation
1050      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1051      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1052
1053      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1054      DO jj = 2, jpj
1055        DO ji = 2, jpi
1056          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1057                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1058                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1059
1060          ! assuming linear profile across the top half surface layer
1061          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1062        END DO
1063      END DO
1064
1065      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1066      DO jk = 2, jpkm1
1067        DO jj = 2, jpj
1068          DO ji = 2, jpi
1069            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1070                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1071                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1072                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1073          END DO
1074        END DO
1075      END DO
1076
1077      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1078
1079      ! Prepare zsshu_n and zsshv_n
1080      DO jj = 2, jpjm1
1081        DO ji = 2, jpim1
1082          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1083                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1084          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1085                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1086        END DO
1087      END DO
1088
1089      DO jj = 2, jpjm1
1090        DO ji = 2, jpim1
1091          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1092          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1093        END DO
1094      END DO
1095
1096      DO jk = 2, jpkm1
1097        DO jj = 2, jpjm1
1098          DO ji = 2, jpim1
1099            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1100            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1101          END DO
1102        END DO
1103      END DO
1104
1105      DO jk = 1, jpkm1
1106        DO jj = 2, jpjm1
1107          DO ji = 2, jpim1
1108            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1109            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1110          END DO
1111        END DO
1112      END DO
1113
1114      DO jk = 1, jpkm1
1115        DO jj = 2, jpjm1
1116          DO ji = 2, jpim1
1117            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1118            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1119            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1120            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1121          END DO
1122        END DO
1123      END DO
1124
1125
1126      DO jk = 1, jpkm1
1127        DO jj = 2, jpjm1
1128          DO ji = 2, jpim1
1129            zpwes = 0._wp; zpwed = 0._wp
1130            zpnss = 0._wp; zpnsd = 0._wp
1131            zuijk = zu(ji,jj,jk)
1132            zvijk = zv(ji,jj,jk)
1133
1134            !!!!!     for u equation
1135            IF( jk <= mbku(ji,jj) ) THEN
1136               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1137                 jis = ji + 1; jid = ji
1138               ELSE
1139                 jis = ji;     jid = ji +1
1140               ENDIF
1141
1142               ! integrate the pressure on the shallow side
1143               jk1 = jk
1144               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1145                 IF( jk1 == mbku(ji,jj) ) THEN
1146                   zuijk = -zdept(jis,jj,jk1)
1147                   EXIT
1148                 ENDIF
1149                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1150                 zpwes = zpwes +                                    &
1151                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1152                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1153                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1154                 jk1 = jk1 + 1
1155               END DO
1156
1157               ! integrate the pressure on the deep side
1158               jk1 = jk
1159               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1160                 IF( jk1 == 1 ) THEN
1161                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1162                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1163                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1164                                                     dsp(jid,jj,1)) * zdeps
1165                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1166                   EXIT
1167                 ENDIF
1168                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1169                 zpwed = zpwed +                                        &
1170                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1171                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1172                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1173                 jk1 = jk1 - 1
1174               END DO
1175
1176               ! update the momentum trends in u direction
1177
1178               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1179               IF( lk_vvl ) THEN
1180                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1181                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1182                ELSE
1183                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1184               ENDIF
1185
1186               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1187               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1188            ENDIF
1189
1190            !!!!!     for v equation
1191            IF( jk <= mbkv(ji,jj) ) THEN
1192               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1193                 jjs = jj + 1; jjd = jj
1194               ELSE
1195                 jjs = jj    ; jjd = jj + 1
1196               ENDIF
1197
1198               ! integrate the pressure on the shallow side
1199               jk1 = jk
1200               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1201                 IF( jk1 == mbkv(ji,jj) ) THEN
1202                   zvijk = -zdept(ji,jjs,jk1)
1203                   EXIT
1204                 ENDIF
1205                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1206                 zpnss = zpnss +                                      &
1207                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1208                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1209                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1210                 jk1 = jk1 + 1
1211               END DO
1212
1213               ! integrate the pressure on the deep side
1214               jk1 = jk
1215               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1216                 IF( jk1 == 1 ) THEN
1217                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1218                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1219                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1220                                                     dsp(ji,jjd,1) ) * zdeps
1221                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1222                   EXIT
1223                 ENDIF
1224                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1225                 zpnsd = zpnsd +                                        &
1226                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1227                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1228                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1229                 jk1 = jk1 - 1
1230               END DO
1231
1232
1233               ! update the momentum trends in v direction
1234
1235               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1236               IF( lk_vvl ) THEN
1237                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1238                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1239               ELSE
1240                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1241               ENDIF
1242
1243               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1244               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1245            ENDIF
1246
1247
1248           END DO
1249        END DO
1250      END DO
1251      !
1252      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1253      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1254      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1255      !
1256   END SUBROUTINE hpg_prj
1257
1258
1259   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1260      !!----------------------------------------------------------------------
1261      !!                 ***  ROUTINE cspline  ***
1262      !!
1263      !! ** Purpose :   constrained cubic spline interpolation
1264      !!
1265      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1266      !!
1267      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1268      !!----------------------------------------------------------------------
1269      IMPLICIT NONE
1270      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1271      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1272                                                                    ! the interpoated function
1273      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1274                                                                    ! 2: Linear
1275      !
1276      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1277      INTEGER  ::   jpi, jpj, jpkm1
1278      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1279      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1280      REAL(wp) ::   zdf(size(fsp,3))
1281      !!----------------------------------------------------------------------
1282
1283      jpi   = size(fsp,1)
1284      jpj   = size(fsp,2)
1285      jpkm1 = size(fsp,3) - 1
1286
1287
1288      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1289         DO ji = 1, jpi
1290            DO jj = 1, jpj
1291           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1292           !    DO jk = 2, jpkm1-1
1293           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1294           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1295           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1296           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1297           !
1298           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1299           !
1300           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1301           !           zdf(jk) = 0._wp
1302           !       ELSE
1303           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1304           !       ENDIF
1305           !    END DO
1306
1307           !!Simply geometric average
1308               DO jk = 2, jpkm1-1
1309                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1310                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1311
1312                  IF(zdf1 * zdf2 <= 0._wp) THEN
1313                     zdf(jk) = 0._wp
1314                  ELSE
1315                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1316                  ENDIF
1317               END DO
1318
1319               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1320                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1321               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1322                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1323                          & 0.5_wp * zdf(jpkm1 - 1)
1324
1325               DO jk = 1, jpkm1 - 1
1326                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1327                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1328                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1329                 zddf1  = -2._wp * ztmp1 + ztmp2
1330                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1331                 zddf2  =  2._wp * ztmp1 - ztmp2
1332
1333                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1334                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1335                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1336                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1337                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1338                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1339                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1340                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1341                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1342               END DO
1343            END DO
1344         END DO
1345
1346      ELSE IF (polynomial_type == 2) THEN     ! Linear
1347         DO ji = 1, jpi
1348            DO jj = 1, jpj
1349               DO jk = 1, jpkm1-1
1350                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1351                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1352
1353                  dsp(ji,jj,jk) = 0._wp
1354                  csp(ji,jj,jk) = 0._wp
1355                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1356                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1357               END DO
1358            END DO
1359         END DO
1360
1361      ELSE
1362           CALL ctl_stop( 'invalid polynomial type in cspline' )
1363      ENDIF
1364
1365   END SUBROUTINE cspline
1366
1367
1368   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1369      !!----------------------------------------------------------------------
1370      !!                 ***  ROUTINE interp1  ***
1371      !!
1372      !! ** Purpose :   1-d linear interpolation
1373      !!
1374      !! ** Method  :   interpolation is straight forward
1375      !!                extrapolation is also permitted (no value limit)
1376      !!----------------------------------------------------------------------
1377      IMPLICIT NONE
1378      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1379      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1380      REAL(wp)             ::  zdeltx
1381      !!----------------------------------------------------------------------
1382
1383      zdeltx = xr - xl
1384      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1385        f = 0.5_wp * (fl + fr)
1386      ELSE
1387        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1388      ENDIF
1389
1390   END FUNCTION interp1
1391
1392
1393   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1394      !!----------------------------------------------------------------------
1395      !!                 ***  ROUTINE interp1  ***
1396      !!
1397      !! ** Purpose :   1-d constrained cubic spline interpolation
1398      !!
1399      !! ** Method  :  cubic spline interpolation
1400      !!
1401      !!----------------------------------------------------------------------
1402      IMPLICIT NONE
1403      REAL(wp), INTENT(in) ::  x, a, b, c, d
1404      REAL(wp)             ::  f ! value from the interpolation
1405      !!----------------------------------------------------------------------
1406
1407      f = a + x* ( b + x * ( c + d * x ) )
1408
1409   END FUNCTION interp2
1410
1411
1412   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1413      !!----------------------------------------------------------------------
1414      !!                 ***  ROUTINE interp1  ***
1415      !!
1416      !! ** Purpose :   Calculate the first order of deriavtive of
1417      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1418      !!
1419      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1420      !!
1421      !!----------------------------------------------------------------------
1422      IMPLICIT NONE
1423      REAL(wp), INTENT(in) ::  x, a, b, c, d
1424      REAL(wp)             ::  f ! value from the interpolation
1425      !!----------------------------------------------------------------------
1426
1427      f = b + x * ( 2._wp * c + 3._wp * d * x)
1428
1429   END FUNCTION interp3
1430
1431
1432   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1433      !!----------------------------------------------------------------------
1434      !!                 ***  ROUTINE interp1  ***
1435      !!
1436      !! ** Purpose :   1-d constrained cubic spline integration
1437      !!
1438      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1439      !!
1440      !!----------------------------------------------------------------------
1441      IMPLICIT NONE
1442      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1443      REAL(wp)             ::  za1, za2, za3
1444      REAL(wp)             ::  f                   ! integration result
1445      !!----------------------------------------------------------------------
1446
1447      za1 = 0.5_wp * b
1448      za2 = c / 3.0_wp
1449      za3 = 0.25_wp * d
1450
1451      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1452         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1453
1454   END FUNCTION integ_spline
1455
1456   !!======================================================================
1457END MODULE dynhpg
1458
Note: See TracBrowser for help on using the repository browser.