source: branches/UKMO/dev_r5518_GO6_package_text_diagnostics/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 10774

Last change on this file since 10774 was 10774, checked in by andmirek, 19 months ago

GMED 450 add flush after prints

File size: 17.0 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE ioipsl, ONLY : ju2ymds    ! for calendar
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   USE divcur          ! hor. divergence and curl      (div & cur routines)
27   USE sbc_oce         ! for icesheet freshwater input variables
28   USE timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn         ! routine called by step module
34   PUBLIC   rst_write       ! routine called by step module
35   PUBLIC   rst_read        ! routine called by istate module
36   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      INTEGER             ::   iyear, imonth, iday
60      REAL (wp)           ::   zsec
61      REAL (wp)           ::   zfjulday
62      !!
63      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
64      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
65      CHARACTER(LEN=150)  ::   clpath   ! full path to ocean output restart file
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         IF( ln_rst_list ) THEN
71            nrst_lst = 1
72            nitrst = nstocklist( nrst_lst )
73         ELSE
74            nitrst = nitend
75         ENDIF
76      ENDIF
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
89            IF ( ln_rstdate ) THEN
90               zfjulday = fjulday + rdttra(1) / rday
91               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
92               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
93               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
94            ELSE
95               ! beware of the format used to write kt (default is i8.8, that should be large enough...)
96               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
97               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
98               ENDIF
99            ENDIF
100            ! create the file
101            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
102            clpath = TRIM(cn_ocerst_outdir)
103            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
104            IF(lwp) THEN
105               WRITE(numout,*)
106               SELECT CASE ( jprstlib )
107               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
108                   '             open ocean restart binary file: ',TRIM(clpath)//clname
109               CASE DEFAULT         ;   WRITE(numout,*)                            &
110                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
111               END SELECT
112               IF(nprint > 1) THEN
113                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
114                  IF( kt == nitrst - 1) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
115                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
116                  ENDIF
117               ENDIF
118               IF(lflush) CALL flush(numout)
119            ENDIF
120            !
121            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
122            lrst_oce = .TRUE.
123         ENDIF
124      ENDIF
125      !
126   END SUBROUTINE rst_opn
127
128
129   SUBROUTINE rst_write( kt )
130      !!---------------------------------------------------------------------
131      !!                   ***  ROUTINE rstwrite  ***
132      !!                     
133      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
134      !!
135      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
136      !!              file, save fields which are necessary for restart
137      !!----------------------------------------------------------------------
138      INTEGER, INTENT(in) ::   kt   ! ocean time-step
139      !!----------------------------------------------------------------------
140                     IF(nn_timing == 2)  CALL timing_start('iom_rstput')
141                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
142                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
143
144                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
145                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
146                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
147                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
148                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
149                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
150                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
151                     !
152                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
153                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
154                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
156                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
157                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
158                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
159                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
160#if defined key_zdfkpp
161                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
162#endif
163                     IF( lk_oasis) THEN
164                     ! nn_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
165                     IF( nn_coupled_iceshelf_fluxes .eq. 1 ) THEN
166                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass )
167                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
168                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
169                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
170                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
171                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
172                     ENDIF
173                     ENDIF
174                     IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
175
176      IF( kt == nitrst ) THEN
177         CALL iom_close( numrow )     ! close the restart file (only at last time step)
178!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
179!!gm  not sure what to do here   ===>>>  ask to Sebastian
180         lrst_oce = .FALSE.
181            IF( ln_rst_list ) THEN
182               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
183               nitrst = nstocklist( nrst_lst )
184            ENDIF
185            lrst_oce = .FALSE.
186      ENDIF
187      !
188   END SUBROUTINE rst_write
189
190
191   SUBROUTINE rst_read_open
192      !!----------------------------------------------------------------------
193      !!                   ***  ROUTINE rst_read_open  ***
194      !!
195      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
196      !!
197      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
198      !!                the file has already been opened
199      !!----------------------------------------------------------------------
200      INTEGER        ::   jlibalt = jprstlib
201      LOGICAL        ::   llok
202      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
203      !!----------------------------------------------------------------------
204      !
205      IF( numror <= 0 ) THEN
206         IF(lwp) THEN                                             ! Contol prints
207            WRITE(numout,*)
208            SELECT CASE ( jprstlib )
209            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
210            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
211            END SELECT
212            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
213            WRITE(numout,*) '~~~~~~~~'
214            IF(lflush) CALL flush(numout)
215         ENDIF
216
217         clpath = TRIM(cn_ocerst_indir)
218         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
219         IF ( jprstlib == jprstdimg ) THEN
220           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
221           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
222           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
223           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
224         ENDIF
225         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
226      ENDIF
227   END SUBROUTINE rst_read_open
228
229   SUBROUTINE rst_read
230      !!----------------------------------------------------------------------
231      !!                   ***  ROUTINE rst_read  ***
232      !!
233      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
234      !!
235      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
236      !!----------------------------------------------------------------------
237      REAL(wp) ::   zrdt, zrdttra1
238      INTEGER  ::   jk
239      LOGICAL  ::   llok
240      !!----------------------------------------------------------------------
241
242      CALL rst_read_open           ! open restart for reading (if not already opened)
243
244      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
245      IF(nn_timing == 2)  CALL timing_start('iom_rstget')
246      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
247         CALL iom_get( numror, 'rdt', zrdt )
248         IF( zrdt /= rdt )   neuler = 0
249      ENDIF
250      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
251         CALL iom_get( numror, 'rdttra1', zrdttra1 )
252         IF( zrdttra1 /= rdttra(1) )   neuler = 0
253      ENDIF
254      !
255      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
256         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
257         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
258         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
259         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
260         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
261         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
262         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
263      ELSE
264         neuler = 0
265      ENDIF
266      !
267      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
268      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
269      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
270      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
271      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
272      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
273         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
274         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
275      ELSE
276         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
277      ENDIF
278      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
279         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
280      ELSE
281         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
282      ENDIF
283#if defined key_zdfkpp
284      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
285         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
286      ELSE
287         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
288      ENDIF
289#endif
290      !
291      IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
292         CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
293         CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
294         CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
295      ELSE
296         greenland_icesheet_mass = 0.0 
297         greenland_icesheet_mass_rate_of_change = 0.0 
298         greenland_icesheet_timelapsed = 0.0
299      ENDIF
300      IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
301         CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
302         CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
303         CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
304      ELSE
305         antarctica_icesheet_mass = 0.0 
306         antarctica_icesheet_mass_rate_of_change = 0.0 
307         antarctica_icesheet_timelapsed = 0.0
308      ENDIF
309      IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
310      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
311         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
312         ub   (:,:,:)   = un   (:,:,:)
313         vb   (:,:,:)   = vn   (:,:,:)
314         rotb (:,:,:)   = rotn (:,:,:)
315         hdivb(:,:,:)   = hdivn(:,:,:)
316         sshb (:,:)     = sshn (:,:)
317
318         IF( lk_vvl ) THEN
319            DO jk = 1, jpk
320               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
321            END DO
322         ENDIF
323
324      ENDIF
325      !
326   END SUBROUTINE rst_read
327
328   !!=====================================================================
329END MODULE restart
Note: See TracBrowser for help on using the repository browser.