source: branches/UKMO/dev_r5518_GO6_package_text_diagnostics/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 10774

Last change on this file since 10774 was 10774, checked in by andmirek, 19 months ago

GMED 450 add flush after prints

File size: 44.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE asmbgc          ! biogeochemical assimilation increments
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71   USE sbccpl 
72   USE cpl_oasis3      ! OASIS3 coupling
73   USE c1d             ! 1D configuration
74   USE step_c1d        ! Time stepping loop for the 1D configuration
75   USE dyndmp          ! Momentum damping
76#if defined key_top
77   USE trcini          ! passive tracer initialisation
78   USE trc, ONLY: numstr  ! tracer stats unit number
79#endif
80   USE lib_mpp         ! distributed memory computing
81#if defined key_iomput
82   USE xios
83#endif
84   USE sbctide, ONLY: lk_tide
85   USE crsini          ! initialise grid coarsening utility
86   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87   USE sbc_oce, ONLY: lk_oasis
88   USE stopar
89   USE stopts
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
99
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE nemo_gcm
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE nemo_gcm  ***
110      !!
111      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
112      !!              curvilinear mesh on the sphere.
113      !!
114      !! ** Method  : - model general initialization
115      !!              - launch the time-stepping (stp routine)
116      !!              - finalize the run by closing files and communications
117      !!
118      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
119      !!              Madec, 2008, internal report, IPSL.
120      !!----------------------------------------------------------------------
121      INTEGER ::   istp       ! time step index
122      !!----------------------------------------------------------------------
123      !
124#if defined key_agrif
125      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
126#endif
127
128      !                            !-----------------------!
129      CALL nemo_init               !==  Initialisations  ==!
130      !                            !-----------------------!
131#if defined key_agrif
132      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
133      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
134# if defined key_top
135      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
136# endif
137# if defined key_lim2
138      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
139# endif
140#endif
141      ! check that all process are still there... If some process have an error,
142      ! they will never enter in step and other processes will wait until the end of the cpu time!
143      IF( lk_mpp )   CALL mpp_max( nstop )
144
145      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
146
147      !                            !-----------------------!
148      !                            !==   time stepping   ==!
149      !                            !-----------------------!
150      istp = nit000
151#if defined key_c1d
152         DO WHILE ( istp <= nitend .AND. nstop == 0 )
153            CALL stp_c1d( istp )
154            istp = istp + 1
155         END DO
156#else
157          IF( lk_asminc ) THEN
158             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
159             IF( ln_asmdin ) THEN                        ! Direct initialization
160                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
161                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
162                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
163                IF( lk_bgcinc ) CALL bgc_asm_inc( nit000 - 1 )    ! BGC
164             ENDIF
165          ENDIF
166
167#if defined key_agrif
168          CALL Agrif_Regrid()
169#endif
170
171         DO WHILE ( istp <= nitend .AND. nstop == 0 )
172#if defined key_agrif
173            CALL stp                         ! AGRIF: time stepping
174#else
175            IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
176       CALL stp( istp )
177            ! We don't couple on the final timestep because
178            ! our restart file has already been written
179            ! and contains all the necessary data for a
180            ! restart. sbc_cpl_snd could be called here
181            ! but it would require
182            ! a) A test to ensure it was not performed
183            !    on the very last time-step
184            ! b) the presence of another call to
185            !    sbc_cpl_snd call prior to the main DO loop
186            ! This solution produces identical results
187            ! with fewer lines of code.
188#endif
189            istp = istp + 1
190            IF( lk_mpp )   CALL mpp_max( nstop )
191         END DO
192#endif
193
194      IF( lk_diaobs   )   CALL dia_obs_wri
195      !
196      IF( ( lk_asminc ).AND.( ln_balwri ) ) CALL asm_bgc_bal_wri( nitend )  ! Output balancing increments
197      !
198      IF( ln_icebergs )   CALL icb_end( nitend )
199
200      !                            !------------------------!
201      !                            !==  finalize the run  ==!
202      !                            !------------------------!
203      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
204      !
205      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
206         WRITE(numout,cform_err)
207         WRITE(numout,*) nstop, ' error have been found'
208      ENDIF
209      !
210#if defined key_agrif
211      IF( .NOT. Agrif_Root() ) THEN
212         CALL Agrif_ParentGrid_To_ChildGrid()
213         IF( lk_diaobs ) CALL dia_obs_wri
214         IF( nn_timing > 0 )   CALL timing_finalize
215         CALL Agrif_ChildGrid_To_ParentGrid()
216      ENDIF
217#endif
218      IF( nn_timing > 0 )   CALL timing_finalize
219      !
220      CALL nemo_closefile
221      !
222#if defined key_iomput
223      CALL xios_finalize                ! end mpp communications with xios
224      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
225#else
226      IF( lk_oasis ) THEN
227         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
228      ELSE
229         IF( lk_mpp )   CALL mppstop    ! end mpp communications
230      ENDIF
231#endif
232      !
233      ! Met Office addition: if failed, return non-zero exit code
234      IF( nstop /= 0 )  CALL exit( 9 ) 
235      !
236   END SUBROUTINE nemo_gcm
237
238
239   SUBROUTINE nemo_init
240      !!----------------------------------------------------------------------
241      !!                     ***  ROUTINE nemo_init  ***
242      !!
243      !! ** Purpose :   initialization of the NEMO GCM
244      !!----------------------------------------------------------------------
245      INTEGER ::   ji            ! dummy loop indices
246      INTEGER ::   ilocal_comm   ! local integer
247      INTEGER ::   ios
248      CHARACTER(len=80), DIMENSION(16) ::   cltxt
249      !
250      NAMELIST/namctl/ ln_ctl  ,sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
251         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
252         &             nn_bench, nn_timing, ln_flush
253      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
254         &             jpizoom, jpjzoom, jperio, ln_use_jattr
255      !!----------------------------------------------------------------------
256      !
257      cltxt = ''
258      cxios_context = 'nemo'
259      !
260      !                             ! Open reference namelist and configuration namelist files
261      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
262      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
263      !
264      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
265      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
266901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
267
268      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
269      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
270902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
271
272      !
273      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
274      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
275903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
276
277      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
278      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
279904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
280
281! Force values for AGRIF zoom (cf. agrif_user.F90)
282#if defined key_agrif
283   IF( .NOT. Agrif_Root() ) THEN
284      jpiglo  = nbcellsx + 2 + 2*nbghostcells
285      jpjglo  = nbcellsy + 2 + 2*nbghostcells
286      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
287      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
288      jpidta  = jpiglo
289      jpjdta  = jpjglo
290      jpizoom = 1
291      jpjzoom = 1
292      nperio  = 0
293      jperio  = 0
294      ln_use_jattr = .false.
295   ENDIF
296#endif
297      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
298      lflush    = ln_flush          ! convert namelist variable to model variable
299      !do it here because output.namelist.dyn is opened before nprint was set earlier
300      !
301      !                             !--------------------------------------------!
302      !                             !  set communicator & select the local node  !
303      !                             !  NB: mynode also opens output.namelist.dyn !
304      !                             !      on unit number numond on first proc   !
305      !                             !--------------------------------------------!
306#if defined key_iomput
307      IF( Agrif_Root() ) THEN
308         IF( lk_oasis ) THEN
309            CALL cpl_init( "toyoce", ilocal_comm )                     ! nemo local communicator given by oasis
310            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
311         ELSE
312            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
313         ENDIF
314      ENDIF
315      ! Nodes selection (control print return in cltxt)
316      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
317#else
318      IF( lk_oasis ) THEN
319         IF( Agrif_Root() ) THEN
320            CALL cpl_init( "toyoce", ilocal_comm )                      ! nemo local communicator given by oasis
321         ENDIF
322         ! Nodes selection (control print return in cltxt)
323         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
324      ELSE
325         ilocal_comm = 0
326         ! Nodes selection (control print return in cltxt)
327         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
328      ENDIF
329#endif
330      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
331
332      IF( sn_cfctl%l_config ) THEN
333         ! Activate finer control of report outputs
334         ! optionally switch off output from selected areas (note this only
335         ! applies to output which does not involve global communications)
336         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
337           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
338           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
339      ELSE
340         ! Use ln_ctl to turn on or off all options.
341         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
342      ENDIF
343
344      lwm = (narea == 1)                                    ! control of output namelists
345      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
346
347      IF(lwm .AND. nprint > 2) THEN
348         ! write merged namelists from earlier to output namelist now that the
349         ! file has been opened in call to mynode. nammpp has already been
350         ! written in mynode (if lk_mpp_mpi)
351         WRITE( numond, namctl )
352         WRITE( numond, namcfg )
353      ENDIF
354
355      ! If dimensions of processor grid weren't specified in the namelist file
356      ! then we calculate them here now that we have our communicator size
357      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
358#if   defined key_mpp_mpi
359         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
360#else
361         jpni  = 1
362         jpnj  = 1
363         jpnij = jpni*jpnj
364#endif
365      END IF
366
367      ! Calculate domain dimensions given calculated jpni and jpnj
368      ! This used to be done in par_oce.F90 when they were parameters rather
369      ! than variables
370      IF( Agrif_Root() ) THEN
371#if defined key_nemocice_decomp
372         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
373         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
374#else
375         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
376         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
377#endif
378      ENDIF         
379         jpk = jpkdta                                             ! third dim
380#if defined key_agrif
381         ! simple trick to use same vertical grid as parent
382         ! but different number of levels:
383         ! Save maximum number of levels in jpkdta, then define all vertical grids
384         ! with this number.
385         ! Suppress once vertical online interpolation is ok
386         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
387#endif
388         jpim1 = jpi-1                                            ! inner domain indices
389         jpjm1 = jpj-1                                            !   "           "
390         jpkm1 = jpk-1                                            !   "           "
391         jpij  = jpi*jpj                                          !  jpi x j
392
393      IF(lwp) THEN                            ! open listing units
394         !
395         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
396         !
397         WRITE(numout,*)
398         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
399         WRITE(numout,*) '                       NEMO team'
400         WRITE(numout,*) '            Ocean General Circulation Model'
401         WRITE(numout,*) '                  version 3.6  (2015) '
402         WRITE(numout,*)
403         WRITE(numout,*)
404         DO ji = 1, SIZE(cltxt)
405            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
406         END DO
407         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
408         IF(lflush) CALL flush(numout)
409         !
410      ENDIF
411
412      ! Now we know the dimensions of the grid and numout has been set we can
413      ! allocate arrays
414      CALL nemo_alloc()
415
416      !                             !-------------------------------!
417      !                             !  NEMO general initialization  !
418      !                             !-------------------------------!
419
420      CALL nemo_ctl                          ! Control prints & Benchmark
421
422      !                                      ! Domain decomposition
423      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
424      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
425      ENDIF
426      !
427      IF( nn_timing > 0 )  CALL timing_init
428      !
429      !                                      ! General initialization
430                            CALL     phy_cst    ! Physical constants
431                            CALL     eos_init   ! Equation of state
432      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
433                            CALL     dom_cfg    ! Domain configuration
434                            CALL     dom_init   ! Domain
435
436      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
437
438      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
439
440                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
441
442      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
443
444                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
445
446      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
447      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
448      IF( lk_bdy .AND. lk_tide )   &
449         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
450
451                            CALL dyn_nept_init  ! simplified form of Neptune effect
452      !     
453      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
454      !
455                                ! Ocean physics
456      !                                         ! Vertical physics
457                            CALL     zdf_init      ! namelist read
458                            CALL zdf_bfr_init      ! bottom friction
459      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
460      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
461      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
462      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
463      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
464      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
465         &                  CALL zdf_ddm_init      ! double diffusive mixing
466      !                                         ! Lateral physics
467                            CALL ldf_tra_init      ! Lateral ocean tracer physics
468                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
469      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
470
471      !                                     ! Active tracers
472                            CALL tra_qsr_init   ! penetrative solar radiation qsr
473                            CALL tra_bbc_init   ! bottom heat flux
474      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
475                            CALL tra_dmp_init   ! internal damping trends- tracers
476                            CALL tra_adv_init   ! horizontal & vertical advection
477                            CALL tra_ldf_init   ! lateral mixing
478                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
479
480      !                                     ! Dynamics
481      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
482                            CALL dyn_adv_init   ! advection (vector or flux form)
483                            CALL dyn_vor_init   ! vorticity term including Coriolis
484                            CALL dyn_ldf_init   ! lateral mixing
485                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
486                            CALL dyn_zdf_init   ! vertical diffusion
487                            CALL dyn_spg_init   ! surface pressure gradient
488
489      !                                     ! Misc. options
490      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
491                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
492                            CALL sto_par_init   ! Stochastic parametrization
493      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
494     
495#if defined key_top
496      !                                     ! Passive tracers
497                            CALL     trc_init
498#endif
499      !                                     ! Diagnostics
500      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
501                            CALL dia_ptr_init   ! Poleward TRansports initialization
502      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
503                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
504                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
505                            CALL     bias_init  ! Pressure correction bias
506      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
507                            CALL dia_obs_init            ! Initialize observational data
508                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
509      ENDIF
510
511      !                                     ! Assimilation increments
512      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
513      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
514      IF(lwp .AND. lflush) CALL flush(numout)
515     
516      IF (nstop > 0) THEN
517        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
518      END IF
519
520      !
521   END SUBROUTINE nemo_init
522
523
524   SUBROUTINE nemo_ctl
525      !!----------------------------------------------------------------------
526      !!                     ***  ROUTINE nemo_ctl  ***
527      !!
528      !! ** Purpose :   control print setting
529      !!
530      !! ** Method  : - print namctl information and check some consistencies
531      !!----------------------------------------------------------------------
532      !
533      IF(lwp) THEN                  ! control print
534         WRITE(numout,*)
535         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
536         WRITE(numout,*) '~~~~~~~ '
537         WRITE(numout,*) '   Namelist namctl'
538         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
539         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
540         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
541         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
542         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
543         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
544         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
545         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
546         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
547         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
548         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
549         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
550         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
551         WRITE(numout,*) '      flush numout/stat               ln_flush   = ', ln_flush
552         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
553         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
554         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
555         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
556         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
557         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
558         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
559         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
560         IF(lflush) CALL flush(numout)
561      ENDIF
562      !
563      nictls    = nn_ictls
564      nictle    = nn_ictle
565      njctls    = nn_jctls
566      njctle    = nn_jctle
567      isplt     = nn_isplt
568      jsplt     = nn_jsplt
569      nbench    = nn_bench
570
571      IF(lwp) THEN                  ! control print
572         WRITE(numout,*)
573         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
574         WRITE(numout,*) '~~~~~~~ '
575         WRITE(numout,*) '   Namelist namcfg'
576         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
577         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
578         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
579         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
580         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
581         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
582         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
583         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
584         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
585         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
586         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
587         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
588         IF(lflush) CALL flush(numout)
589      ENDIF
590      !                             ! Parameter control
591      !
592      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
593         IF( lk_mpp .AND. jpnij > 1 ) THEN
594            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
595         ELSE
596            IF( isplt == 1 .AND. jsplt == 1  ) THEN
597               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
598                  &           ' - the print control will be done over the whole domain' )
599            ENDIF
600            ijsplt = isplt * jsplt            ! total number of processors ijsplt
601         ENDIF
602         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
603         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
604         IF(lwp .AND. lflush) CALL flush(numout)
605         !
606         !                              ! indices used for the SUM control
607         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
608            lsp_area = .FALSE.
609         ELSE                                             ! print control done over a specific  area
610            lsp_area = .TRUE.
611            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
612               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
613               nictls = 1
614            ENDIF
615            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
616               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
617               nictle = jpiglo
618            ENDIF
619            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
620               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
621               njctls = 1
622            ENDIF
623            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
624               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
625               njctle = jpjglo
626            ENDIF
627         ENDIF
628      ENDIF
629      !
630      IF( nbench == 1 ) THEN              ! Benchmark
631         SELECT CASE ( cp_cfg )
632         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
633         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
634            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
635         END SELECT
636      ENDIF
637      !
638      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
639         &                                               'f2003 standard. '                              ,  &
640         &                                               'Compile with key_nosignedzero enabled' )
641      !
642   END SUBROUTINE nemo_ctl
643
644
645   SUBROUTINE nemo_closefile
646      !!----------------------------------------------------------------------
647      !!                     ***  ROUTINE nemo_closefile  ***
648      !!
649      !! ** Purpose :   Close the files
650      !!----------------------------------------------------------------------
651      !
652      IF( lk_mpp )   CALL mppsync
653      !
654      CALL iom_close                                 ! close all input/output files managed by iom_*
655      !
656      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
657      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
658      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
659      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
660      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
661      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
662      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
663      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
664      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
665      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
666      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
667      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
668      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
669#if defined key_top
670      IF( numstr          /= -1 )   CLOSE( numstr          )   ! tracer statistics
671#endif
672      !
673      numout = 6                                     ! redefine numout in case it is used after this point...
674      !
675   END SUBROUTINE nemo_closefile
676
677
678   SUBROUTINE nemo_alloc
679      !!----------------------------------------------------------------------
680      !!                     ***  ROUTINE nemo_alloc  ***
681      !!
682      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
683      !!
684      !! ** Method  :
685      !!----------------------------------------------------------------------
686      USE diawri    , ONLY: dia_wri_alloc
687      USE insitu_tem, ONLY: insitu_tem_alloc
688      USE dom_oce   , ONLY: dom_oce_alloc
689      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
690      USE ldftra_oce, ONLY: ldftra_oce_alloc
691      USE trc_oce   , ONLY: trc_oce_alloc
692#if defined key_diadct 
693      USE diadct    , ONLY: diadct_alloc 
694#endif 
695#if defined key_bdy
696      USE bdy_oce   , ONLY: bdy_oce_alloc
697#endif
698      !
699      INTEGER :: ierr
700      !!----------------------------------------------------------------------
701      !
702      ierr =        oce_alloc       ()          ! ocean
703      ierr = ierr + dia_wri_alloc   ()
704      ierr = ierr + insitu_tem_alloc()
705      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
706      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
707      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
708      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
709      !
710      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
711      !
712#if defined key_diadct 
713      ierr = ierr + diadct_alloc    ()          !
714#endif 
715#if defined key_bdy
716      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
717#endif
718      !
719      IF( lk_mpp    )   CALL mpp_sum( ierr )
720      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
721      !
722   END SUBROUTINE nemo_alloc
723
724   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
725      !!----------------------------------------------------------------------
726      !!                     ***  ROUTINE nemo_set_cfctl  ***
727      !!
728      !! ** Purpose :   Set elements of the output control structure to setto.
729      !!                for_all should be .false. unless all areas are to be
730      !!                treated identically.
731      !!
732      !! ** Method  :   Note this routine can be used to switch on/off some
733      !!                types of output for selected areas but any output types
734      !!                that involve global communications (e.g. mpp_max, glob_sum)
735      !!                should be protected from selective switching by the
736      !!                for_all argument
737      !!----------------------------------------------------------------------
738      LOGICAL :: setto, for_all
739      TYPE(sn_ctl) :: sn_cfctl
740      !!----------------------------------------------------------------------
741      IF( for_all ) THEN
742         sn_cfctl%l_runstat = setto
743         sn_cfctl%l_trcstat = setto
744      ENDIF
745      sn_cfctl%l_oceout  = setto
746      sn_cfctl%l_layout  = setto
747      sn_cfctl%l_mppout  = setto
748      sn_cfctl%l_mpptop  = setto
749   END SUBROUTINE nemo_set_cfctl
750
751   SUBROUTINE nemo_partition( num_pes )
752      !!----------------------------------------------------------------------
753      !!                 ***  ROUTINE nemo_partition  ***
754      !!
755      !! ** Purpose :
756      !!
757      !! ** Method  :
758      !!----------------------------------------------------------------------
759      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
760      !
761      INTEGER, PARAMETER :: nfactmax = 20
762      INTEGER :: nfact ! The no. of factors returned
763      INTEGER :: ierr  ! Error flag
764      INTEGER :: ji
765      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
766      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
767      !!----------------------------------------------------------------------
768      !
769      ierr = 0
770      !
771      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
772      !
773      IF( nfact <= 1 ) THEN
774         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
775         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
776         IF(lflush) CALL flush(numout)
777         jpnj = 1
778         jpni = num_pes
779      ELSE
780         ! Search through factors for the pair that are closest in value
781         mindiff = 1000000
782         imin    = 1
783         DO ji = 1, nfact-1, 2
784            idiff = ABS( ifact(ji) - ifact(ji+1) )
785            IF( idiff < mindiff ) THEN
786               mindiff = idiff
787               imin = ji
788            ENDIF
789         END DO
790         jpnj = ifact(imin)
791         jpni = ifact(imin + 1)
792      ENDIF
793      !
794      jpnij = jpni*jpnj
795      !
796   END SUBROUTINE nemo_partition
797
798
799   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
800      !!----------------------------------------------------------------------
801      !!                     ***  ROUTINE factorise  ***
802      !!
803      !! ** Purpose :   return the prime factors of n.
804      !!                knfax factors are returned in array kfax which is of
805      !!                maximum dimension kmaxfax.
806      !! ** Method  :
807      !!----------------------------------------------------------------------
808      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
809      INTEGER                    , INTENT(  out) ::   kerr, knfax
810      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
811      !
812      INTEGER :: ifac, jl, inu
813      INTEGER, PARAMETER :: ntest = 14
814      INTEGER, DIMENSION(ntest) :: ilfax
815      !
816      ! ilfax contains the set of allowed factors.
817      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
818      !!----------------------------------------------------------------------
819      ! ilfax contains the set of allowed factors.
820      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
821
822      ! Clear the error flag and initialise output vars
823      kerr = 0
824      kfax = 1
825      knfax = 0
826
827      ! Find the factors of n.
828      IF( kn == 1 )   GOTO 20
829
830      ! nu holds the unfactorised part of the number.
831      ! knfax holds the number of factors found.
832      ! l points to the allowed factor list.
833      ! ifac holds the current factor.
834
835      inu   = kn
836      knfax = 0
837
838      DO jl = ntest, 1, -1
839         !
840         ifac = ilfax(jl)
841         IF( ifac > inu )   CYCLE
842
843         ! Test whether the factor will divide.
844
845         IF( MOD(inu,ifac) == 0 ) THEN
846            !
847            knfax = knfax + 1            ! Add the factor to the list
848            IF( knfax > kmaxfax ) THEN
849               kerr = 6
850               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
851               return
852            ENDIF
853            kfax(knfax) = ifac
854            ! Store the other factor that goes with this one
855            knfax = knfax + 1
856            kfax(knfax) = inu / ifac
857            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
858         ENDIF
859         !
860      END DO
861
862   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
863      !
864   END SUBROUTINE factorise
865
866#if defined key_mpp_mpi
867
868   SUBROUTINE nemo_northcomms
869      !!======================================================================
870      !!                     ***  ROUTINE  nemo_northcomms  ***
871      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
872      !!                       point-to-point messaging
873      !!=====================================================================
874      !!----------------------------------------------------------------------
875      !!
876      !! ** Purpose :   Initialization of the northern neighbours lists.
877      !!----------------------------------------------------------------------
878      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
879      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
880      !!----------------------------------------------------------------------
881
882      INTEGER  ::   sxM, dxM, sxT, dxT, jn
883      INTEGER  ::   njmppmax
884
885      njmppmax = MAXVAL( njmppt )
886   
887      !initializes the north-fold communication variables
888      isendto(:) = 0
889      nsndto = 0
890
891      !if I am a process in the north
892      IF ( njmpp == njmppmax ) THEN
893          !sxM is the first point (in the global domain) needed to compute the
894          !north-fold for the current process
895          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
896          !dxM is the last point (in the global domain) needed to compute the
897          !north-fold for the current process
898          dxM = jpiglo - nimppt(narea) + 2
899
900          !loop over the other north-fold processes to find the processes
901          !managing the points belonging to the sxT-dxT range
902 
903          DO jn = 1, jpni
904                !sxT is the first point (in the global domain) of the jn
905                !process
906                sxT = nfiimpp(jn, jpnj)
907                !dxT is the last point (in the global domain) of the jn
908                !process
909                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
910                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
911                   nsndto = nsndto + 1
912                     isendto(nsndto) = jn
913                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
914                   nsndto = nsndto + 1
915                     isendto(nsndto) = jn
916                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
917                   nsndto = nsndto + 1
918                     isendto(nsndto) = jn
919                END IF
920          END DO
921          nfsloop = 1
922          nfeloop = nlci
923          DO jn = 2,jpni-1
924           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
925              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
926                 nfsloop = nldi
927              ENDIF
928              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
929                 nfeloop = nlei
930              ENDIF
931           ENDIF
932        END DO
933
934      ENDIF
935      l_north_nogather = .TRUE.
936   END SUBROUTINE nemo_northcomms
937#else
938   SUBROUTINE nemo_northcomms      ! Dummy routine
939      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
940   END SUBROUTINE nemo_northcomms
941#endif
942
943   !!======================================================================
944END MODULE nemogcm
945
946
Note: See TracBrowser for help on using the repository browser.