source: branches/UKMO/dev_r5518_GO6_package_text_diagnostics/NEMOGCM/NEMO/OPA_SRC/stpctl.F90 @ 10748

Last change on this file since 10748 was 10748, checked in by andmirek, 20 months ago

GMED 450 fix issue with solver.stat openning

File size: 11.3 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   stp_ctl      : Control the run
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers variables
17   USE dom_oce         ! ocean space and time domain variables
18   USE sol_oce         ! ocean space and time domain variables
19   USE sbc_oce         ! surface boundary conditions variables
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! distributed memory computing
23   USE dynspg_oce      ! pressure gradient schemes
24   USE c1d             ! 1D vertical configuration
25
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC stp_ctl           ! routine called by step.F90
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE stp_ctl( kt, kindic )
40      !!----------------------------------------------------------------------
41      !!                    ***  ROUTINE stp_ctl  ***
42      !!                     
43      !! ** Purpose :   Control the run
44      !!
45      !! ** Method  : - Save the time step in numstp
46      !!              - Print it each 50 time steps
47      !!              - Print solver statistics in numsol
48      !!              - Stop the run IF problem for the solver ( indec < 0 )
49      !!
50      !! ** Actions :   'time.step' file containing the last ocean time-step
51      !!               
52      !!----------------------------------------------------------------------
53      INTEGER, INTENT( in ) ::   kt         ! ocean time-step index
54      INTEGER, INTENT( inout ) ::   kindic  ! indicator of solver convergence
55      !!
56      CHARACTER(len = 32) ::        clfname ! time stepping output file name
57      INTEGER  ::   ji, jj, jk              ! dummy loop indices
58      INTEGER  ::   ii, ij, ik              ! temporary integers
59      REAL(wp) ::   zumax, zsmin, zssh2     ! temporary scalars
60      REAL(wp) ::   ztmax, ztmin            ! Scalar to get temperature extreme
61                                            ! values and warn if they're out of Range
62      INTEGER, DIMENSION(3) ::   ilocu      !
63      INTEGER, DIMENSION(2) ::   ilocs      !
64      LOGICAL                ::   ll_wrtstp, ll_colruns, ll_wrtruns
65      !!----------------------------------------------------------------------
66      ll_wrtstp  = ( MOD( kt, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
67      ll_colruns = ll_wrtstp .AND. ( ln_ctl .OR. sn_cfctl%l_runstat )
68      ll_wrtruns = ll_colruns .AND. lwm
69      IF( kt == nit000 .AND. lwp ) THEN
70         WRITE(numout,*)
71         WRITE(numout,*) 'stp_ctl : time-stepping control'
72         WRITE(numout,*) '~~~~~~~'
73         ! open time.step file with special treatment for SAS
74         IF ( nn_components == jp_iam_sas ) THEN
75            clfname = 'time.step.sas'
76         ELSE
77            clfname = 'time.step'
78         ENDIF
79         IF( lwm ) &
80     &    CALL ctl_opn( numstp, TRIM(clfname), 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
81      ENDIF
82
83      IF(lwp .AND. ll_wrtstp) THEN
84         WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
85         REWIND( numstp )                       !  --------------------------
86      ENDIF
87
88      !                                              !* Test maximum of velocity (zonal only)
89      !                                              !  ------------------------
90      !! zumax = MAXVAL( ABS( un(:,:,:) ) )                ! slower than the following loop on NEC SX5
91      zumax = 0.e0
92      DO jk = 1, jpk
93         DO jj = 1, jpj
94            DO ji = 1, jpi
95               zumax = MAX(zumax,ABS(un(ji,jj,jk)))
96          END DO
97        END DO
98      END DO       
99      IF( lk_mpp )   CALL mpp_max( zumax )                 ! max over the global domain
100      !
101      IF( ll_colruns )   WRITE(numout,*) ' ==>> time-step= ',kt,' abs(U) max: ', zumax
102      !
103      IF( zumax > 20.e0 ) THEN
104         IF( lk_mpp ) THEN
105            CALL mpp_maxloc(ABS(un),umask,zumax,ii,ij,ik)
106         ELSE
107            ilocu = MAXLOC( ABS( un(:,:,:) ) )
108            ii = ilocu(1) + nimpp - 1
109            ij = ilocu(2) + njmpp - 1
110            ik = ilocu(3)
111         ENDIF
112         IF(lwp) THEN
113            WRITE(numout,cform_err)
114            WRITE(numout,*) ' stpctl: the zonal velocity is larger than 20 m/s'
115            WRITE(numout,*) ' ====== '
116            WRITE(numout,9400) kt, zumax, ii, ij, ik
117            WRITE(numout,*)
118            WRITE(numout,*) '          output of last fields in numwso'
119         ENDIF
120         kindic = -3
121      ENDIF
1229400  FORMAT (' kt=',i6,' max abs(U): ',1pg11.4,', i j k: ',3i5)
123
124      !                                              !* Test minimum of salinity
125      !                                              !  ------------------------
126      !! zsmin = MINVAL( tsn(:,:,1,jp_sal), mask = tmask(:,:,1) == 1.e0 )  slower than the following loop on NEC SX5
127      zsmin = 100.e0
128      DO jj = 2, jpjm1
129         DO ji = 1, jpi
130            IF( tmask(ji,jj,1) == 1) zsmin = MIN(zsmin,tsn(ji,jj,1,jp_sal))
131         END DO
132      END DO
133      IF( lk_mpp )   CALL mpp_min( zsmin )                ! min over the global domain
134      !
135      IF( MOD( kt, nwrite ) == 1 .AND. lwp )   WRITE(numout,*) ' ==>> time-step= ',kt,' SSS min:', zsmin
136      !
137      IF( zsmin < 0.) THEN
138         IF (lk_mpp) THEN
139            CALL mpp_minloc ( tsn(:,:,1,jp_sal),tmask(:,:,1), zsmin, ii,ij )
140         ELSE
141            ilocs = MINLOC( tsn(:,:,1,jp_sal), mask = tmask(:,:,1) == 1.e0 )
142            ii = ilocs(1) + nimpp - 1
143            ij = ilocs(2) + njmpp - 1
144         ENDIF
145         !
146         IF(lwp) THEN
147            WRITE(numout,cform_err)
148            WRITE(numout,*) 'stp_ctl : NEGATIVE sea surface salinity'
149            WRITE(numout,*) '======= '
150            WRITE(numout,9500) kt, zsmin, ii, ij
151            WRITE(numout,*)
152            WRITE(numout,*) '          output of last fields in numwso'
153         ENDIF
154         kindic = -3
155      ENDIF
1569500  FORMAT (' kt=',i6,' min SSS: ',1pg11.4,', i j: ',2i5)
157
158! ====================================================================================================
159! ====================================================================================================
160      !                                              !AXY (25/10/17)
161      !                                              !* Test max/min limits of temperature
162      !                                              !  ----------------------------------
163      ztmax =  -5.e0  ! arbitrary  low maximum value
164      ztmin = 100.e0  ! arbitrary high minimum value
165      DO jj = 2, jpjm1
166         DO ji = 2, jpim1
167            IF( tmask(ji,jj,1) == 1) THEN
168               ztmax = MAX(ztmax,tsn(ji,jj,1,jp_tem))     ! find local maximum
169               ztmin = MIN(ztmin,tsn(ji,jj,1,jp_tem))     ! find local minimum
170            ENDIF
171         END DO
172      END DO
173      IF( lk_mpp )   CALL mpp_max( ztmax )                ! max over the global domain
174      IF( lk_mpp )   CALL mpp_min( ztmin )                ! min over the global domain
175      !
176      IF( ztmax > 40.) THEN  ! we've got a problem
177         IF (lk_mpp) THEN
178            CALL mpp_maxloc ( tsn(:,:,1,jp_tem),tmask(:,:,1), ztmax, ii,ij )
179         ELSE
180            ilocs = MAXLOC( tsn(:,:,1,jp_tem), mask = tmask(:,:,1) == 1.e0 )
181            ii = ilocs(1) + nimpp - 1
182            ij = ilocs(2) + njmpp - 1
183         ENDIF
184         !
185         IF(lwp) THEN
186            WRITE(numout,*) 'stp_ctl:tracer anomaly: *****    WARNING     *****'
187            WRITE(numout,*) 'stp_ctl:tracer anomaly: sea surface temperature > 40C'
188            WRITE(numout,9600) kt, ztmax, ii, ij
189            WRITE(numout,*) 'stp_ctl:tracer anomaly: ***** END OF WARNING *****'
190         ENDIF
191      ENDIF
192      !
193      IF( ztmin < -10.) THEN  ! we've got a problem
194         IF (lk_mpp) THEN
195            CALL mpp_minloc ( tsn(:,:,1,jp_tem),tmask(:,:,1), ztmin, ii,ij )
196         ELSE
197            ilocs = MINLOC( tsn(:,:,1,jp_tem), mask = tmask(:,:,1) == 1.e0 )
198            ii = ilocs(1) + nimpp - 1
199            ij = ilocs(2) + njmpp - 1
200         ENDIF
201         !
202         IF(lwp) THEN
203            WRITE(numout,*) 'stp_ctl:tracer anomaly: *****    WARNING     *****'
204            WRITE(numout,*) 'stp_ctl:tracer anomaly: sea surface temperature < -10C'
205            WRITE(numout,9700) kt, ztmin, ii, ij
206            WRITE(numout,*) 'stp_ctl:tracer anomaly: ***** END OF WARNING *****'
207         ENDIF
208      ENDIF
2099600  FORMAT ('stp_ctl:tracer anomaly: kt=',i6,' max SST: ',f16.10,', i j: ',2i5)
2109700  FORMAT ('stp_ctl:tracer anomaly: kt=',i6,' min SST: ',f16.10,', i j: ',2i5)
211! ====================================================================================================
212! ====================================================================================================
213     
214      IF( lk_c1d )  RETURN          ! No log file in case of 1D vertical configuration
215
216      ! log file (solver or ssh statistics)
217      ! --------
218      IF( lk_dynspg_flt ) THEN      ! elliptic solver statistics (if required)
219         !
220         IF(ll_wrtruns) WRITE(numsol,9200) kt, niter, res, SQRT(epsr)/eps       ! Solver
221         !
222         IF( kindic < 0 .AND. zsmin > 0.e0 .AND. zumax <= 20.e0 ) THEN   ! create a abort file if problem found
223            IF(lwp) THEN
224               WRITE(numout,*) ' stpctl: the elliptic solver DO not converge or explode'
225               WRITE(numout,*) ' ====== '
226               WRITE(numout,9200) kt, niter, res, sqrt(epsr)/eps
227               WRITE(numout,*)
228               WRITE(numout,*) ' stpctl: output of last fields'
229               WRITE(numout,*) ' ======  '
230            ENDIF
231         ENDIF
232         !
233      ELSE                                   !* ssh statistics (and others...)
234         IF( kt == nit000 .AND. lwp .AND. (ln_ctl .OR. sn_cfctl%l_runstat)) THEN   ! open ssh statistics file (put in solver.stat file)
235            CALL ctl_opn( numsol, 'solver.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
236         ENDIF
237         !
238         IF( ll_colruns ) THEN
239            zssh2 = SUM( sshn(:,:) * sshn(:,:) * tmask_i(:,:) )
240            IF( lk_mpp )   CALL mpp_sum( zssh2 )      ! sum over the global domain
241         !
242            WRITE(numsol,9300) kt, zssh2, zumax, zsmin      ! ssh statistics
243         ENDIF
244         !
245      ENDIF
246
2479200  FORMAT('it:', i8, ' iter:', i4, ' r: ',e16.10, ' b: ',e16.10 )
2489300  FORMAT(' it :', i8, ' ssh2: ', e16.10, ' Umax: ',e16.10,' Smin: ',e16.10)
249      !
250   END SUBROUTINE stp_ctl
251
252   !!======================================================================
253END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.