New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 12555

Last change on this file since 12555 was 12555, checked in by charris, 4 years ago

Changes from GO6 package branch (GMED ticket 450):

svn merge -r 11035:11101 ​svn+ssh://charris@forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/UKMO/dev_r5518_GO6_package
File size: 20.9 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !!
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !!
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE trc_oce, ONLY : lk_offline ! offline flag
35   USE timing          ! Timing
36   USE restart         ! restart
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   day        ! called by step.F90
42   PUBLIC   day_init   ! called by istate.F90
43   PUBLIC   day_mth    ! Needed by TAM
44
45   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05 ! (PUBLIC for TAM)
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE day_init
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE day_init  ***
57      !!
58      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
59      !!                because day will be called at the beginning of step
60      !!
61      !! ** Action  : - nyear        : current year
62      !!              - nmonth       : current month of the year nyear
63      !!              - nday         : current day of the month nmonth
64      !!              - nday_year    : current day of the year nyear
65      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
66      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
67      !!              - nsec_day     : current time step counted in second since 00h of the current day
68      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
69      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
70      !!----------------------------------------------------------------------
71      INTEGER  ::   inbday, idweek
72      REAL(wp) ::   zjul
73      !!----------------------------------------------------------------------
74      !
75      ! max number of seconds between each restart
76      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
77         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
78            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
79      ENDIF
80      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
81      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
82      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
83      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
84      nsecd   = NINT(rday           )
85      nsecd05 = NINT(0.5 * rday     )
86      ndt     = NINT(      rdttra(1))
87      ndt05   = NINT(0.5 * rdttra(1))
88
89      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' )
90
91      ! set the calandar from ndastp (read in restart file and namelist)
92
93      nyear   =   ndastp / 10000
94      nmonth  = ( ndastp - (nyear * 10000) ) / 100
95      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
96
97      nhour   =   nn_time0 / 100
98      nminute = ( nn_time0 - nhour * 100 )
99
100      CALL ymds2ju( nyear, nmonth, nday, nhour*3600._wp+nminute*60._wp, fjulday ) 
101      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
102      IF(nhour*3600 + nminute*60 - ndt05 .lt. 0)   fjulday = fjulday + 1.                    ! move back to the day at nit000 (and not at nit000 - 1)
103
104      nsec1jan000 = 0
105      CALL day_mth
106
107      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
108         nmonth = nmonth - 1
109         nday = nmonth_len(nmonth)
110      ENDIF
111      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
112         nmonth = 12
113         nyear = nyear - 1
114         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
115         IF( nleapy == 1 )   CALL day_mth
116      ENDIF
117
118      ! day since january 1st
119      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
120
121      !compute number of days between last monday and today
122      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
123      inbday = FLOOR(fjulday - zjul)            ! compute nb day between  01.01.1900 and start of current day
124      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
125      IF (idweek .lt. 0) idweek=idweek+7       ! Avoid negative values for dates before 01.01.1900
126
127      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
128      IF (nhour*3600+nminute*60-ndt05 .gt. 0) THEN
129         ! 1 timestep before current middle of first time step is still the same day
130         nsec_year  = (nday_year-1) * nsecd + nhour*3600+nminute*60 - ndt05 
131         nsec_month = (nday-1)      * nsecd + nhour*3600+nminute*60 - ndt05   
132      ELSE
133         ! 1 time step before the middle of the first time step is the previous day
134         nsec_year  = nday_year * nsecd + nhour*3600+nminute*60 - ndt05 
135         nsec_month = nday      * nsecd + nhour*3600+nminute*60 - ndt05   
136      ENDIF
137      nsec_week  = idweek    * nsecd + nhour*3600+nminute*60 - ndt05
138      nsec_day   =             nhour*3600+nminute*60 - ndt05 
139      IF( nsec_day .lt. 0 ) nsec_day = nsec_day + nsecd
140      IF( nsec_week .lt. 0 ) nsec_week = nsec_week + nsecd*7
141
142      ! control print
143      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
144           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week, '  &
145           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
146      IF(lwp .AND. lflush) CALL flush(numout)
147
148      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
149      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
150      CALL day( nit000 )
151      !
152   END SUBROUTINE day_init
153
154
155   SUBROUTINE day_mth
156      !!----------------------------------------------------------------------
157      !!                   ***  ROUTINE day_init  ***
158      !!
159      !! ** Purpose :   calendar values related to the months
160      !!
161      !! ** Action  : - nmonth_len    : length in days of the months of the current year
162      !!              - nyear_len     : length in days of the previous/current year
163      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
164      !!              - nmonth_end    : second since the beginning of the year and the end of the months
165      !!----------------------------------------------------------------------
166      INTEGER  ::   jm               ! dummy loop indice
167      !!----------------------------------------------------------------------
168
169      ! length of the month of the current year (from nleapy, read in namelist)
170      IF ( nleapy < 2 ) THEN
171         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
172         nyear_len(:) = 365
173         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
174            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
175               nyear_len(0)  = 366
176            ENDIF
177            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
178               nmonth_len(2) = 29
179               nyear_len(1)  = 366
180            ENDIF
181            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
182               nyear_len(2)  = 366
183            ENDIF
184         ENDIF
185      ELSE
186         nmonth_len(:) = nleapy   ! all months with nleapy days per year
187         nyear_len(:) = 12 * nleapy
188      ENDIF
189
190      ! half month in second since the begining of the year:
191      ! time since Jan 1st   0     1     2    ...    11    12    13
192      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
193      !                 <---> <---> <--->  ...  <---> <---> <--->
194      ! month number      0     1     2    ...    11    12    13
195      !
196      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
197      nmonth_half(0) = - nsecd05 * nmonth_len(0)
198      DO jm = 1, 13
199         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
200      END DO
201
202      nmonth_end(0) = 0
203      DO jm = 1, 13
204         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
205      END DO
206      !
207   END SUBROUTINE
208
209
210   SUBROUTINE day( kt )
211      !!----------------------------------------------------------------------
212      !!                      ***  ROUTINE day  ***
213      !!
214      !! ** Purpose :   Compute the date with a day iteration IF necessary.
215      !!
216      !! ** Method  : - ???
217      !!
218      !! ** Action  : - nyear     : current year
219      !!              - nmonth    : current month of the year nyear
220      !!              - nday      : current day of the month nmonth
221      !!              - nday_year : current day of the year nyear
222      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
223      !!              - adatrj    : date in days since the beginning of the run
224      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
225      !!----------------------------------------------------------------------
226      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
227      !
228      CHARACTER (len=25) ::   charout
229      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
230      !!----------------------------------------------------------------------
231      !
232      IF( nn_timing == 1 )  CALL timing_start('day')
233      !
234      zprec = 0.1 / rday
235      !                                                 ! New time-step
236      nsec_year  = nsec_year  + ndt
237      nsec_month = nsec_month + ndt
238      nsec_week  = nsec_week  + ndt
239      nsec_day   = nsec_day   + ndt
240      adatrj  = adatrj  + rdttra(1) / rday
241      fjulday = fjulday + rdttra(1) / rday
242      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
243      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
244
245      IF( nsec_day > nsecd ) THEN                       ! New day
246         !
247         nday      = nday + 1
248         nday_year = nday_year + 1
249         nsec_day  = ndt05
250         !
251         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
252            nday   = 1
253            nmonth = nmonth + 1
254            nsec_month = ndt05
255            IF( nmonth == 13 ) THEN                     ! New year
256               nyear     = nyear + 1
257               nmonth    = 1
258               nday_year = 1
259               nsec_year = ndt05
260               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
261               IF( nleapy == 1 )   CALL day_mth
262            ENDIF
263         ENDIF
264         !
265         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
266         !
267         !compute first day of the year in julian days
268         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
269         !
270         IF(lwp .AND. nprint > 0) THEN
271             WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
272              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
273             WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
274              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
275             IF(lflush) CALL flush(numout)
276         ENDIF
277      ENDIF
278
279      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
280
281      IF(ln_ctl) THEN
282         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
283         CALL prt_ctl_info(charout)
284      ENDIF
285
286      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
287      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
288      !
289      IF( nn_timing == 1 )  CALL timing_stop('day')
290      !
291   END SUBROUTINE day
292
293
294   SUBROUTINE day_rst( kt, cdrw )
295      !!---------------------------------------------------------------------
296      !!                   ***  ROUTINE ts_rst  ***
297      !!
298      !!  ** Purpose : Read or write calendar in restart file:
299      !!
300      !!  WRITE(READ) mode:
301      !!       kt        : number of time step since the begining of the experiment at the
302      !!                   end of the current(previous) run
303      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
304      !!                   end of the current(previous) run (REAL -> keep fractions of day)
305      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
306      !!
307      !!   According to namelist parameter nrstdt,
308      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
309      !!       nrstdt = 1  we verify that nit000 is equal to the last
310      !!                   time step of previous run + 1.
311      !!       In both those options, the  exact duration of the experiment
312      !!       since the beginning (cumulated duration of all previous restart runs)
313      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
314      !!       This is valid is the time step has remained constant.
315      !!
316      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
317      !!                    has been stored in the restart file.
318      !!----------------------------------------------------------------------
319      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
320      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
321      !
322      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
323      INTEGER  ::   ihour, iminute
324      !!----------------------------------------------------------------------
325
326      IF( TRIM(cdrw) == 'READ' ) THEN
327
328         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
329            ! Get Calendar informations
330            IF(nn_timing == 2)  CALL timing_start('iom_rstget')
331            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
332            IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
333            IF(lwp) THEN
334               WRITE(numout,*) ' *** Info read in restart : '
335               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
336               WRITE(numout,*) ' *** restart option'
337               SELECT CASE ( nrstdt )
338               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
339               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
340               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
341               END SELECT
342               WRITE(numout,*) ' '
343               IF(lflush) CALL flush(numout)
344            ENDIF
345            ! Control of date
346            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
347                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
348                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
349            ! define ndastp and adatrj
350            IF ( nrstdt == 2 ) THEN
351               IF(nn_timing == 2)  CALL timing_start('iom_rstget')
352               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
353               CALL iom_get( numror, 'ndastp', zndastp )
354               ndastp = NINT( zndastp )
355               CALL iom_get( numror, 'adatrj', adatrj  )
356          CALL iom_get( numror, 'ntime', ktime )
357               IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
358          nn_time0=INT(ktime)
359               ! calculate start time in hours and minutes
360          zdayfrac=adatrj-INT(adatrj)
361          ksecs = NINT(zdayfrac*86400)        ! Nearest second to catch rounding errors in adatrj         
362          ihour = INT(ksecs/3600)
363          iminute = ksecs/60-ihour*60
364           
365               ! Add to nn_time0
366               nhour   =   nn_time0 / 100
367               nminute = ( nn_time0 - nhour * 100 )
368          nminute=nminute+iminute
369         
370          IF( nminute >= 60 ) THEN
371             nminute=nminute-60
372        nhour=nhour+1
373          ENDIF
374          nhour=nhour+ihour
375          IF( nhour >= 24 ) THEN
376        nhour=nhour-24
377             adatrj=adatrj+1
378          ENDIF         
379          nn_time0 = nhour * 100 + nminute
380          adatrj = INT(adatrj)                    ! adatrj set to integer as nn_time0 updated         
381            ELSE
382               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
383               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
384               nhour   =   nn_time0 / 100
385               nminute = ( nn_time0 - nhour * 100 )
386               IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
387               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
388               ! note this is wrong if time step has changed during run
389            ENDIF
390         ELSE
391            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
392            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
393            nhour   =   nn_time0 / 100
394            nminute = ( nn_time0 - nhour * 100 )
395            IF( nhour*3600+nminute*60-ndt05 .lt. 0 )  ndastp=ndastp-1      ! Start hour is specified in the namelist (default 0)
396            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
397         ENDIF
398         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
399         !
400         IF(lwp) THEN
401            WRITE(numout,*) ' *** Info used values : '
402            WRITE(numout,*) '   date ndastp                                      : ', ndastp
403            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
404            WRITE(numout,*) '   nn_time0                                         : ',nn_time0
405            WRITE(numout,*)
406            IF(lflush) CALL flush(numout)
407         ENDIF
408         !
409      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
410         !
411         IF( kt == nitrst .AND. lwp .AND. nprint > 0) THEN
412            WRITE(numout,*)
413            WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
414            WRITE(numout,*) '~~~~~~~'
415            IF(lflush) CALL flush(numout)
416         ENDIF
417         ! calendar control
418         IF(nn_timing == 2)  CALL timing_start('iom_rstput')
419         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
420         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
421         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
422         !                                                                     ! the begining of the run [s]
423         CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp) ) ! time
424         IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
425      ENDIF
426      !
427   END SUBROUTINE day_rst
428
429   !!======================================================================
430END MODULE daymod
Note: See TracBrowser for help on using the repository browser.