New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 12555

Last change on this file since 12555 was 12555, checked in by charris, 4 years ago

Changes from GO6 package branch (GMED ticket 450):

svn merge -r 11035:11101 svn+ssh://charris@forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/UKMO/dev_r5518_GO6_package

File size: 15.0 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!             -   ! 2014-06 (A. Yool, J. Palmieri) adding MEDUSA-2
11   !!----------------------------------------------------------------------
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_init  :   Initialization for passive tracer
17   !!   top_alloc :   allocate the TOP arrays
18   !!----------------------------------------------------------------------
19   USE oce_trc         ! shared variables between ocean and passive tracers
20   USE trc             ! passive tracers common variables
21   USE trcrst          ! passive tracers restart
22   USE trcnam          ! Namelist read
23   USE trcini_cfc      ! CFC      initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_age      ! AGE      initialisation
27   USE trcini_my_trc   ! MY_TRC   initialisation
28   USE trcini_idtra    ! idealize tracer initialisation
29   USE trcini_medusa   ! MEDUSA   initialisation
30   USE par_medusa      ! MEDUSA   parameters (needed for elemental cycles)
31   USE trcdta          ! initialisation from files
32   USE daymod          ! calendar manager
33   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
34   USE trcsub          ! variables to substep passive tracers
35   USE lib_mpp         ! distribued memory computing library
36   USE sbc_oce
37   USE trcice          ! tracers in sea ice
38   USE sms_medusa      ! MEDUSA   initialisation
39   IMPLICIT NONE
40   PRIVATE
41   
42   PUBLIC   trc_init   ! called by opa
43
44    !! * Substitutions
45#  include "domzgr_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52   
53   SUBROUTINE trc_init
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE trc_init  ***
56      !!
57      !! ** Purpose :   Initialization of the passive tracer fields
58      !!
59      !! ** Method  : - read namelist
60      !!              - control the consistancy
61      !!              - compute specific initialisations
62      !!              - set initial tracer fields (either read restart
63      !!                or read data or analytical formulation
64      !!---------------------------------------------------------------------
65      INTEGER ::   ji, jj, jk, jn, jl    ! dummy loop indices
66# if defined key_medusa && defined key_roam
67      !! AXY (23/11/2017)
68      REAL(wp)                         :: zsum3d, zsum2d
69      REAL(wp)                         :: zq1, zq2, loc_vol, loc_area
70      REAL(wp), DIMENSION(6)           :: loc_cycletot3, loc_cycletot2
71      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztot3d
72      REAL(wp), DIMENSION(jpi,jpj)     :: ztot2d, carea
73# endif
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )   CALL timing_start('trc_init')
78      !
79      IF(lwp) WRITE(numout,*)
80      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
81      IF(lwp) WRITE(numout,*) '~~~~~~~'
82
83      CALL top_alloc()              ! allocate TOP arrays
84
85      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
86      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
87      IF( l_trcdm2dc .AND. lwp ) &
88         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
89         & Computation of a daily mean shortwave for some biogeochemical models) ')
90
91      IF( nn_cla == 1 )   &
92         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
93
94      CALL trc_nam      ! read passive tracers namelists
95      !
96      IF(lwp) WRITE(numout,*)
97      !
98      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
99      !
100      IF(lwp) WRITE(numout,*)
101                                                              ! masked grid volume
102      !                                                              ! masked grid volume
103      DO jk = 1, jpk
104         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
105      END DO
106      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
107      !                                                              ! total volume of the ocean
108      areatot = glob_sum( cvol(:,:,:) )
109      carea(:,:) = e1e2t(:,:) * tmask(:,:,1) 
110
111      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
112      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
113      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
114      IF( lk_age     )       CALL trc_ini_age          ! AGE       tracer
115      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
116      IF( lk_idtra   )       CALL trc_ini_idtra        ! Idealize tracers
117      IF( lk_medusa  )       CALL trc_ini_medusa       ! MEDUSA  tracers
118
119      CALL trc_ice_ini                                 ! Tracers in sea ice
120
121      !
122      IF (lwm .AND. sn_cfctl%l_trcstat) THEN 
123         ! The tracer.stat file only contains global tracer sum values, if
124         ! it contains anything at all. Hence it only needs to be opened
125         ! and written to on the master PE, not on all PEs. 
126         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE','FORMATTED',  & 
127                       'SEQUENTIAL', -1, numout, lwp , narea ) 
128      ENDIF 
129      !
130
131      IF( ln_trcdta ) THEN
132         CALL trc_dta_init(jptra)
133      ENDIF
134
135      IF( ln_rsttr ) THEN
136        !
137        CALL trc_rst_read              ! restart from a file
138        !
139      ELSE
140        !
141        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
142            !
143            DO jn = 1, jptra
144               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
145                  jl = n_trc_index(jn) 
146                  CALL trc_dta( nit000, sf_trcdta(jl), rf_trfac(jl) )   ! read tracer data at nit000
147                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) 
148                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
149                     !                                                    (data used only for initialisation)
150                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
151                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
152                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
153                     !
154                  ENDIF
155               ENDIF
156            ENDDO
157            !
158        ENDIF
159        !
160        trb(:,:,:,:) = trn(:,:,:,:)
161        !
162      ENDIF
163 
164      tra(:,:,:,:) = 0._wp
165      !
166      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
167      !
168
169      trai(:) = 0._wp                                                   ! initial content of all tracers
170      DO jn = 1, jptra
171         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
172      END DO
173
174      IF(lwp) THEN               ! control print
175         WRITE(numout,*)
176         WRITE(numout,*)
177         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
178         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
179         WRITE(numout,*) '          *** Total inital content of all tracers '
180         WRITE(numout,*)
181# if defined key_debug_medusa
182         CALL flush(numout)
183# endif
184         !
185# if defined key_debug_medusa
186         WRITE(numout,*) ' litle check :  ', ctrcnm(1)
187         CALL flush(numout)
188# endif
189         DO jn = 1, jptra
190            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
191         ENDDO
192         WRITE(numout,*)
193      ENDIF
194      IF(lwp) WRITE(numout,*)
195      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
196         CALL prt_ctl_trc_init
197         WRITE(charout, FMT="('ini ')")
198         CALL prt_ctl_trc_info( charout )
199         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
200      ENDIF
201
202# if defined key_medusa && defined key_roam
203      ! AXY (17/11/2017): calculate initial totals of elemental cycles
204      !
205      ! This is done in a very hard-wired way here; in future, this could be
206      ! replaced with loops and using a 2D array; one dimension would cover
207      ! the tracers, the other would be for the elements; each tracer would
208      ! have a factor for each element to say how much of that element was
209      ! in that tracer; for example, PHN would be 1.0 for N, xrfn for Fe and
210      ! xthetapn for C, with the other elements 0.0; the array entry for PHN
211      ! would then be (1. 0. xrfn xthetapn 0. 0.) for (N, Si, Fe, C, A, O2);
212      ! saving this for the next iteration
213      !
214      cycletot(:) = 0._wp
215      ! report elemental totals at initialisation as we go along
216      IF ( lwp ) WRITE(numout,*)
217      IF ( lwp ) WRITE(numout,*)    ' Elemental cycle totals: '
218      ! nitrogen
219      ztot3d(:,:,:) = trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
220                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet) + trn(:,:,:,jpdin)
221      ztot2d(:,:)   = zn_sed_n(:,:)
222      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
223      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
224      cycletot(1)   = zsum3d + zsum2d
225      IF ( lwp ) WRITE(numout,9010) 'nitrogen', zsum3d, zsum2d, cycletot(1)
226      ! silicon
227      ztot3d(:,:,:) = trn(:,:,:,jppds) + trn(:,:,:,jpsil)
228      ztot2d(:,:)   = zn_sed_si(:,:)
229      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
230      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
231      cycletot(2)   = zsum3d + zsum2d
232      IF ( lwp ) WRITE(numout,9010) 'silicon', zsum3d, zsum2d, cycletot(2)
233      ! iron
234      ztot3d(:,:,:) = ((trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
235                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet)) * xrfn) + trn(:,:,:,jpfer)
236      ztot2d(:,:)   = zn_sed_fe(:,:)
237      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
238      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
239      cycletot(3)   = zsum3d + zsum2d
240      IF ( lwp ) WRITE(numout,9010) 'iron', zsum3d, zsum2d, cycletot(3)
241      ! carbon (uses fixed C:N ratios on plankton tracers)
242      ztot3d(:,:,:) = (trn(:,:,:,jpphn) * xthetapn)  + (trn(:,:,:,jpphd) * xthetapd)  +  &
243                      (trn(:,:,:,jpzmi) * xthetazmi) + (trn(:,:,:,jpzme) * xthetazme) +  &
244                      trn(:,:,:,jpdtc) + trn(:,:,:,jpdic)
245      ztot2d(:,:)   = zn_sed_c(:,:) + zn_sed_ca(:,:)
246      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
247      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
248      cycletot(4)   = zsum3d + zsum2d
249      IF ( lwp ) WRITE(numout,9010) 'carbon', zsum3d, zsum2d, cycletot(4)
250      ! alkalinity (note benthic correction)
251      ztot3d(:,:,:) = trn(:,:,:,jpalk)
252      ztot2d(:,:)   = zn_sed_ca(:,:) * 2._wp
253      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
254      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
255      cycletot(5)   = zsum3d + zsum2d
256      IF ( lwp ) WRITE(numout,9010) 'alkalinity', zsum3d, zsum2d, cycletot(5)
257      ! oxygen (note no benthic)
258      ztot3d(:,:,:) = trn(:,:,:,jpoxy)
259      ztot2d(:,:)   = 0._wp
260      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
261      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
262      cycletot(6)   = zsum3d + zsum2d
263      IF ( lwp ) WRITE(numout,9010) 'oxygen', zsum3d, zsum2d, cycletot(6)
264      ! Check
265      zsum3d        = glob_sum( cvol(:,:,:) )
266      zsum2d        = glob_sum( carea(:,:) )     
267      IF ( lwp ) THEN
268         WRITE(numout,*)
269         WRITE(numout,*) ' check : cvol    : ', zsum3d
270         WRITE(numout,*) ' check : carea   : ', zsum2d
271         WRITE(numout,*)
272      ENDIF
273      !
274# endif
275
276      IF(lwp) THEN
277          WRITE(numout,*)
278          WRITE(numout,*) 'trc_init : passive tracer set up completed'
279          WRITE(numout,*) '~~~~~~~'
280      ENDIF 
281# if defined key_debug_medusa
282         CALL trc_rst_stat
283         CALL flush(numout)
284# endif
285
2869000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
2879010  FORMAT(' element:',a10,                     &
288             ' 3d sum:',e18.10,' 2d sum:',e18.10, &
289             ' total:',e18.10)
290      !
291      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
292      !
293   END SUBROUTINE trc_init
294
295
296   SUBROUTINE top_alloc
297      !!----------------------------------------------------------------------
298      !!                     ***  ROUTINE top_alloc  ***
299      !!
300      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
301      !!----------------------------------------------------------------------
302      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
303      USE trc           , ONLY:   trc_alloc
304      USE trcnxt        , ONLY:   trc_nxt_alloc
305      USE trczdf        , ONLY:   trc_zdf_alloc
306      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
307#if defined key_trdmxl_trc 
308      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
309#endif
310# if defined key_medusa
311      USE bio_medusa_mod, ONLY:   bio_medusa_alloc
312# endif
313
314      !
315      INTEGER :: ierr
316      !!----------------------------------------------------------------------
317      !
318      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
319      ierr = ierr + trc_alloc    ()
320      ierr = ierr + trc_nxt_alloc()
321      ierr = ierr + trc_zdf_alloc()
322      ierr = ierr + trd_trc_oce_alloc()
323#if defined key_trdmxl_trc 
324      ierr = ierr + trd_mxl_trc_alloc()
325#endif
326#if defined key_medusa
327      ierr = ierr + bio_medusa_alloc()
328#endif
329      !
330      IF( lk_mpp    )   CALL mpp_sum( ierr )
331      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
332      !
333   END SUBROUTINE top_alloc
334
335#else
336   !!----------------------------------------------------------------------
337   !!  Empty module :                                     No passive tracer
338   !!----------------------------------------------------------------------
339CONTAINS
340   SUBROUTINE trc_init                      ! Dummy routine   
341   END SUBROUTINE trc_init
342#endif
343
344   !!======================================================================
345END MODULE trcini
Note: See TracBrowser for help on using the repository browser.