New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90

Last change on this file was 11738, checked in by marc, 5 years ago

The Dr Hook changes from my perl code.
File size: 16.6 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   USE yomhook, ONLY: lhook, dr_hook
27   USE parkind1, ONLY: jprb, jpim
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   dta_tsd_init   ! called by opa.F90
33   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
34
35   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
36   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
37
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE dta_tsd_init( ld_tradmp )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_tsd_init  ***
52      !!                   
53      !! ** Purpose :   initialisation of T & S input data
54      !!
55      !! ** Method  : - Read namtsd namelist
56      !!              - allocates T & S data structure
57      !!----------------------------------------------------------------------
58      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
59      !
60      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
61      !
62      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
63      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
64      TYPE(FLD_N)                   ::   sn_tem, sn_sal
65      !!
66      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
67      INTEGER  ::   ios
68      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
69      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
70      REAL(KIND=jprb)               :: zhook_handle
71
72      CHARACTER(LEN=*), PARAMETER :: RoutineName='DTA_TSD_INIT'
73
74      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
75
76      !!----------------------------------------------------------------------
77      !
78      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
79      !
80      !  Initialisation
81      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
82      !
83      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
84      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
85901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
86
87      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
88      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
89902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
90      IF(lwm) WRITE ( numond, namtsd )
91
92      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
93     
94      IF(lwp) THEN                  ! control print
95         WRITE(numout,*)
96         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
97         WRITE(numout,*) '~~~~~~~~~~~~ '
98         WRITE(numout,*) '   Namelist namtsd'
99         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
100         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
101         WRITE(numout,*)
102         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
103            WRITE(numout,*)
104            WRITE(numout,*) '   T & S data not used'
105         ENDIF
106      ENDIF
107      !
108      IF( ln_rstart .AND. ln_tsd_init ) THEN
109         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
110            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
111         ln_tsd_init = .FALSE.
112      ENDIF
113      !
114      !                             ! allocate the arrays (if necessary)
115      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
116         !
117         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
118         IF( ierr0 > 0 ) THEN
119            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
120         ENDIF
121         !
122                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
123         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
124                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
125         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
126         !
127         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
128            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
129         ENDIF
130         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
131         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
132         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
133         !
134      ENDIF
135      !
136      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
137      !
138      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
139   END SUBROUTINE dta_tsd_init
140
141
142   SUBROUTINE dta_tsd( kt, ptsd )
143      !!----------------------------------------------------------------------
144      !!                   ***  ROUTINE dta_tsd  ***
145      !!                   
146      !! ** Purpose :   provides T and S data at kt
147      !!
148      !! ** Method  : - call fldread routine
149      !!              - ORCA_R2: add some hand made alteration to read data 
150      !!              - 'key_orca_lev10' interpolates on 10 times more levels
151      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
152      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
153      !!                as T-S data are no are used
154      !!
155      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
156      !!----------------------------------------------------------------------
157      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
158      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
159      !
160      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
161      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
162      REAL(wp)::   zl, zi
163      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
164      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
165      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
166      REAL(KIND=jprb)               :: zhook_handle
167
168      CHARACTER(LEN=*), PARAMETER :: RoutineName='DTA_TSD'
169
170      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
171
172      !!----------------------------------------------------------------------
173      !
174      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
175      !
176      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
177      !
178      !
179      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
180      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
181         !
182         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
183         ii0 = 141   ;   ii1 = 155
184         DO jj = mj0(ij0), mj1(ij1)
185            DO ji = mi0(ii0), mi1(ii1)
186               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
187               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
188               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
189               !
190               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
191               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
192               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
193               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
194            END DO
195         END DO
196         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
197            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
198            ij0 = 101   ;   ij1 = 102
199            ii0 = 139   ;   ii1 = 139
200            DO jl = mi0(il0), mi1(il1)
201               DO jj = mj0(ij0), mj1(ij1)
202                  DO ji = mi0(ii0), mi1(ii1)
203                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
204                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
205                  END DO
206               END DO
207            END DO
208            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
209            ij0 =  87   ;   ij1 =  88
210            ii0 = 161   ;   ii1 = 163
211            DO jl = mi0(il0), mi1(il1)
212               DO jj = mj0(ij0), mj1(ij1)
213                  DO ji = mi0(ii0), mi1(ii1)
214                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
215                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
216                  END DO
217               END DO
218            END DO
219         ELSE                                            ! No Cross Land advection
220            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
221            ii0 = 148   ;   ii1 = 160
222            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
223            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
224            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
225         ENDIF
226      ENDIF
227      !
228      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
229      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
230      !
231      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
232         !
233         CALL wrk_alloc( jpk, ztp, zsp )
234         !
235         IF( kt == nit000 .AND. lwp )THEN
236            WRITE(numout,*)
237            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
238         ENDIF
239         !
240         DO jj = 1, jpj                         ! vertical interpolation of T & S
241            DO ji = 1, jpi
242               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
243                  zl = gdept_0(ji,jj,jk)
244                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
245                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
246                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
247                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
248                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
249                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
250                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
251                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
252                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
253                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
254                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
255                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
256                        ENDIF
257                     END DO
258                  ENDIF
259               END DO
260               DO jk = 1, jpkm1
261                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
262                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
263               END DO
264               ptsd(ji,jj,jpk,jp_tem) = 0._wp
265               ptsd(ji,jj,jpk,jp_sal) = 0._wp
266            END DO
267         END DO
268         !
269         CALL wrk_dealloc( jpk, ztp, zsp )
270         !
271      ELSE                                !==   z- or zps- coordinate   ==!
272         !                             
273         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
274         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
275         !
276         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
277            DO jj = 1, jpj
278               DO ji = 1, jpi
279                  ik = mbkt(ji,jj) 
280                  IF( ik > 1 ) THEN
281                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
282                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
283                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
284                  ENDIF
285                  ik = mikt(ji,jj)
286                  IF( ik > 1 ) THEN
287                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
288                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
289                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
290                  END IF
291               END DO
292            END DO
293         ENDIF
294         !
295      ENDIF
296      !
297      IF( lwp .AND. kt == nit000 ) THEN
298         WRITE(numout,*) ' temperature Levitus '
299         WRITE(numout,*)
300         WRITE(numout,*)'  level = 1'
301         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
302         WRITE(numout,*)'  level = ', jpk/2
303         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
304         WRITE(numout,*)'  level = ', jpkm1
305         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
306         WRITE(numout,*)
307         WRITE(numout,*) ' salinity Levitus '
308         WRITE(numout,*)
309         WRITE(numout,*)'  level = 1'
310         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
311         WRITE(numout,*)'  level = ', jpk/2
312         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
313         WRITE(numout,*)'  level = ', jpkm1
314         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
315         WRITE(numout,*)
316      ENDIF
317      !
318      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
319         !                                              (data used only for initialisation)
320         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
321                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
322         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
323                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
324         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
325                                        DEALLOCATE( sf_tsd              )     ! the structure itself
326      ENDIF
327      !
328      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
329      !
330      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
331   END SUBROUTINE dta_tsd
332
333   !!======================================================================
334END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.