| 1 | MODULE divcur |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE divcur *** |
|---|
| 4 | !! Ocean diagnostic variable : horizontal divergence and relative vorticity |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1987-06 (P. Andrich, D. L Hostis) Original code |
|---|
| 7 | !! 4.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! 6.0 ! 1993-03 (M. Guyon) symetrical conditions |
|---|
| 9 | !! 7.0 ! 1996-01 (G. Madec) s-coordinates |
|---|
| 10 | !! 8.0 ! 1997-06 (G. Madec) lateral boundary cond., lbc |
|---|
| 11 | !! 8.1 ! 1997-08 (J.M. Molines) Open boundaries |
|---|
| 12 | !! 8.2 ! 2000-03 (G. Madec) no slip accurate |
|---|
| 13 | !! NEMO 1.0 ! 2002-09 (G. Madec, E. Durand) Free form, F90 |
|---|
| 14 | !! - ! 2005-01 (J. Chanut) Unstructured open boundaries |
|---|
| 15 | !! - ! 2003-08 (G. Madec) merged of cur and div, free form, F90 |
|---|
| 16 | !! - ! 2005-01 (J. Chanut, A. Sellar) unstructured open boundaries |
|---|
| 17 | !! 3.3 ! 2010-09 (D.Storkey and E.O'Dea) bug fixes for BDY module |
|---|
| 18 | !! - ! 2010-10 (R. Furner, G. Madec) runoff and cla added directly here |
|---|
| 19 | !! 3.6 ! 2014-11 (P. Mathiot) isf added directly here |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | !! div_cur : Compute the horizontal divergence and relative |
|---|
| 24 | !! vorticity fields |
|---|
| 25 | !!---------------------------------------------------------------------- |
|---|
| 26 | USE oce ! ocean dynamics and tracers |
|---|
| 27 | USE dom_oce ! ocean space and time domain |
|---|
| 28 | USE sbc_oce, ONLY : ln_rnf, nn_isf ! surface boundary condition: ocean |
|---|
| 29 | USE sbcrnf ! river runoff |
|---|
| 30 | USE sbcisf ! ice shelf |
|---|
| 31 | USE cla ! cross land advection (cla_div routine) |
|---|
| 32 | USE in_out_manager ! I/O manager |
|---|
| 33 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 34 | USE lib_mpp ! MPP library |
|---|
| 35 | USE wrk_nemo ! Memory Allocation |
|---|
| 36 | USE timing ! Timing |
|---|
| 37 | |
|---|
| 38 | USE yomhook, ONLY: lhook, dr_hook |
|---|
| 39 | USE parkind1, ONLY: jprb, jpim |
|---|
| 40 | |
|---|
| 41 | IMPLICIT NONE |
|---|
| 42 | PRIVATE |
|---|
| 43 | |
|---|
| 44 | PUBLIC div_cur ! routine called by step.F90 and istate.F90 |
|---|
| 45 | |
|---|
| 46 | !! * Substitutions |
|---|
| 47 | # include "domzgr_substitute.h90" |
|---|
| 48 | # include "vectopt_loop_substitute.h90" |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 51 | !! $Id$ |
|---|
| 52 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | #if defined key_noslip_accurate |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | !! 'key_noslip_accurate' 2nd order interior + 4th order at the coast |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | |
|---|
| 61 | SUBROUTINE div_cur( kt ) |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** ROUTINE div_cur *** |
|---|
| 64 | !! |
|---|
| 65 | !! ** Purpose : compute the horizontal divergence and the relative |
|---|
| 66 | !! vorticity at before and now time-step |
|---|
| 67 | !! |
|---|
| 68 | !! ** Method : I. divergence : |
|---|
| 69 | !! - save the divergence computed at the previous time-step |
|---|
| 70 | !! (note that the Asselin filter has not been applied on hdivb) |
|---|
| 71 | !! - compute the now divergence given by : |
|---|
| 72 | !! hdivn = 1/(e1t*e2t*e3t) ( di[e2u*e3u un] + dj[e1v*e3v vn] ) |
|---|
| 73 | !! correct hdiv with runoff inflow (div_rnf), ice shelf melting (div_isf) |
|---|
| 74 | !! and cross land flow (div_cla) |
|---|
| 75 | !! II. vorticity : |
|---|
| 76 | !! - save the curl computed at the previous time-step |
|---|
| 77 | !! rotb = rotn |
|---|
| 78 | !! (note that the Asselin time filter has not been applied to rotb) |
|---|
| 79 | !! - compute the now curl in tensorial formalism: |
|---|
| 80 | !! rotn = 1/(e1f*e2f) ( di[e2v vn] - dj[e1u un] ) |
|---|
| 81 | !! - Coastal boundary condition: 'key_noslip_accurate' defined, |
|---|
| 82 | !! the no-slip boundary condition is computed using Schchepetkin |
|---|
| 83 | !! and O'Brien (1996) scheme (i.e. 4th order at the coast). |
|---|
| 84 | !! For example, along east coast, the one-sided finite difference |
|---|
| 85 | !! approximation used for di[v] is: |
|---|
| 86 | !! di[e2v vn] = 1/(e1f*e2f) * ( (e2v vn)(i) + (e2v vn)(i-1) + (e2v vn)(i-2) ) |
|---|
| 87 | !! |
|---|
| 88 | !! ** Action : - update hdivb, hdivn, the before & now hor. divergence |
|---|
| 89 | !! - update rotb , rotn , the before & now rel. vorticity |
|---|
| 90 | !!---------------------------------------------------------------------- |
|---|
| 91 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 92 | ! |
|---|
| 93 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
|---|
| 94 | INTEGER :: ii, ij, ijt, iju, ierr ! local integer |
|---|
| 95 | REAL(wp) :: zraur, zdep ! local scalar |
|---|
| 96 | REAL(wp), POINTER, DIMENSION(:,:) :: zwu ! specific 2D workspace |
|---|
| 97 | REAL(wp), POINTER, DIMENSION(:,:) :: zwv ! specific 2D workspace |
|---|
| 98 | INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0 |
|---|
| 99 | INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1 |
|---|
| 100 | REAL(KIND=jprb) :: zhook_handle |
|---|
| 101 | |
|---|
| 102 | CHARACTER(LEN=*), PARAMETER :: RoutineName='DIV_CUR' |
|---|
| 103 | |
|---|
| 104 | IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle) |
|---|
| 105 | |
|---|
| 106 | !!---------------------------------------------------------------------- |
|---|
| 107 | ! |
|---|
| 108 | IF( nn_timing == 1 ) CALL timing_start('div_cur') |
|---|
| 109 | ! |
|---|
| 110 | CALL wrk_alloc( jpi , jpj+2, zwu ) |
|---|
| 111 | CALL wrk_alloc( jpi+2, jpj , zwv ) |
|---|
| 112 | ! |
|---|
| 113 | IF( kt == nit000 ) THEN |
|---|
| 114 | IF(lwp) WRITE(numout,*) |
|---|
| 115 | IF(lwp) WRITE(numout,*) 'div_cur : horizontal velocity divergence and relative vorticity' |
|---|
| 116 | IF(lwp) WRITE(numout,*) '~~~~~~~ NOT optimal for auto-tasking case' |
|---|
| 117 | ENDIF |
|---|
| 118 | |
|---|
| 119 | ! ! =============== |
|---|
| 120 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 121 | ! ! =============== |
|---|
| 122 | ! |
|---|
| 123 | hdivb(:,:,jk) = hdivn(:,:,jk) ! time swap of div arrays |
|---|
| 124 | rotb (:,:,jk) = rotn (:,:,jk) ! time swap of rot arrays |
|---|
| 125 | ! |
|---|
| 126 | ! ! -------- |
|---|
| 127 | ! Horizontal divergence ! div |
|---|
| 128 | ! ! -------- |
|---|
| 129 | DO jj = 2, jpjm1 |
|---|
| 130 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 131 | hdivn(ji,jj,jk) = & |
|---|
| 132 | ( e2u(ji,jj)*fse3u(ji,jj,jk) * un(ji,jj,jk) - e2u(ji-1,jj )*fse3u(ji-1,jj ,jk) * un(ji-1,jj ,jk) & |
|---|
| 133 | + e1v(ji,jj)*fse3v(ji,jj,jk) * vn(ji,jj,jk) - e1v(ji ,jj-1)*fse3v(ji ,jj-1,jk) * vn(ji ,jj-1,jk) ) & |
|---|
| 134 | / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 135 | END DO |
|---|
| 136 | END DO |
|---|
| 137 | |
|---|
| 138 | IF( .NOT. AGRIF_Root() ) THEN |
|---|
| 139 | IF ((nbondi == 1).OR.(nbondi == 2)) hdivn(nlci-1 , : ,jk) = 0.e0 ! east |
|---|
| 140 | IF ((nbondi == -1).OR.(nbondi == 2)) hdivn(2 , : ,jk) = 0.e0 ! west |
|---|
| 141 | IF ((nbondj == 1).OR.(nbondj == 2)) hdivn(: ,nlcj-1 ,jk) = 0.e0 ! north |
|---|
| 142 | IF ((nbondj == -1).OR.(nbondj == 2)) hdivn(: ,2 ,jk) = 0.e0 ! south |
|---|
| 143 | ENDIF |
|---|
| 144 | |
|---|
| 145 | ! ! -------- |
|---|
| 146 | ! relative vorticity ! rot |
|---|
| 147 | ! ! -------- |
|---|
| 148 | ! contravariant velocity (extended for lateral b.c.) |
|---|
| 149 | ! inside the model domain |
|---|
| 150 | DO jj = 1, jpj |
|---|
| 151 | DO ji = 1, jpi |
|---|
| 152 | zwu(ji,jj) = e1u(ji,jj) * un(ji,jj,jk) |
|---|
| 153 | zwv(ji,jj) = e2v(ji,jj) * vn(ji,jj,jk) |
|---|
| 154 | END DO |
|---|
| 155 | END DO |
|---|
| 156 | |
|---|
| 157 | ! East-West boundary conditions |
|---|
| 158 | IF( nperio == 1 .OR. nperio == 4 .OR. nperio == 6) THEN |
|---|
| 159 | zwv( 0 ,:) = zwv(jpi-2,:) |
|---|
| 160 | zwv( -1 ,:) = zwv(jpi-3,:) |
|---|
| 161 | zwv(jpi+1,:) = zwv( 3 ,:) |
|---|
| 162 | zwv(jpi+2,:) = zwv( 4 ,:) |
|---|
| 163 | ELSE |
|---|
| 164 | zwv( 0 ,:) = 0.e0 |
|---|
| 165 | zwv( -1 ,:) = 0.e0 |
|---|
| 166 | zwv(jpi+1,:) = 0.e0 |
|---|
| 167 | zwv(jpi+2,:) = 0.e0 |
|---|
| 168 | ENDIF |
|---|
| 169 | |
|---|
| 170 | ! North-South boundary conditions |
|---|
| 171 | IF( nperio == 3 .OR. nperio == 4 ) THEN |
|---|
| 172 | ! north fold ( Grid defined with a T-point pivot) ORCA 2 degre |
|---|
| 173 | zwu(jpi,jpj+1) = 0.e0 |
|---|
| 174 | zwu(jpi,jpj+2) = 0.e0 |
|---|
| 175 | DO ji = 1, jpi-1 |
|---|
| 176 | iju = jpi - ji + 1 |
|---|
| 177 | zwu(ji,jpj+1) = - zwu(iju,jpj-3) |
|---|
| 178 | zwu(ji,jpj+2) = - zwu(iju,jpj-4) |
|---|
| 179 | END DO |
|---|
| 180 | ELSEIF( nperio == 5 .OR. nperio == 6 ) THEN |
|---|
| 181 | ! north fold ( Grid defined with a F-point pivot) ORCA 0.5 degre\ |
|---|
| 182 | zwu(jpi,jpj+1) = 0.e0 |
|---|
| 183 | zwu(jpi,jpj+2) = 0.e0 |
|---|
| 184 | DO ji = 1, jpi-1 |
|---|
| 185 | iju = jpi - ji |
|---|
| 186 | zwu(ji,jpj ) = - zwu(iju,jpj-1) |
|---|
| 187 | zwu(ji,jpj+1) = - zwu(iju,jpj-2) |
|---|
| 188 | zwu(ji,jpj+2) = - zwu(iju,jpj-3) |
|---|
| 189 | END DO |
|---|
| 190 | DO ji = -1, jpi+2 |
|---|
| 191 | ijt = jpi - ji + 1 |
|---|
| 192 | zwv(ji,jpj) = - zwv(ijt,jpj-2) |
|---|
| 193 | END DO |
|---|
| 194 | DO ji = jpi/2+1, jpi+2 |
|---|
| 195 | ijt = jpi - ji + 1 |
|---|
| 196 | zwv(ji,jpjm1) = - zwv(ijt,jpjm1) |
|---|
| 197 | END DO |
|---|
| 198 | ELSE |
|---|
| 199 | ! closed |
|---|
| 200 | zwu(:,jpj+1) = 0.e0 |
|---|
| 201 | zwu(:,jpj+2) = 0.e0 |
|---|
| 202 | ENDIF |
|---|
| 203 | |
|---|
| 204 | ! relative vorticity (vertical component of the velocity curl) |
|---|
| 205 | DO jj = 1, jpjm1 |
|---|
| 206 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 207 | rotn(ji,jj,jk) = ( zwv(ji+1,jj ) - zwv(ji,jj) & |
|---|
| 208 | & - zwu(ji ,jj+1) + zwu(ji,jj) ) * fmask(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) ) |
|---|
| 209 | END DO |
|---|
| 210 | END DO |
|---|
| 211 | |
|---|
| 212 | ! second order accurate scheme along straight coast |
|---|
| 213 | DO jl = 1, npcoa(1,jk) |
|---|
| 214 | ii = nicoa(jl,1,jk) |
|---|
| 215 | ij = njcoa(jl,1,jk) |
|---|
| 216 | rotn(ii,ij,jk) = 1. / ( e1f(ii,ij) * e2f(ii,ij) ) & |
|---|
| 217 | * ( + 4. * zwv(ii+1,ij) - zwv(ii+2,ij) + 0.2 * zwv(ii+3,ij) ) |
|---|
| 218 | END DO |
|---|
| 219 | DO jl = 1, npcoa(2,jk) |
|---|
| 220 | ii = nicoa(jl,2,jk) |
|---|
| 221 | ij = njcoa(jl,2,jk) |
|---|
| 222 | rotn(ii,ij,jk) = 1./(e1f(ii,ij)*e2f(ii,ij)) & |
|---|
| 223 | *(-4.*zwv(ii,ij)+zwv(ii-1,ij)-0.2*zwv(ii-2,ij)) |
|---|
| 224 | END DO |
|---|
| 225 | DO jl = 1, npcoa(3,jk) |
|---|
| 226 | ii = nicoa(jl,3,jk) |
|---|
| 227 | ij = njcoa(jl,3,jk) |
|---|
| 228 | rotn(ii,ij,jk) = -1. / ( e1f(ii,ij)*e2f(ii,ij) ) & |
|---|
| 229 | * ( +4. * zwu(ii,ij+1) - zwu(ii,ij+2) + 0.2 * zwu(ii,ij+3) ) |
|---|
| 230 | END DO |
|---|
| 231 | DO jl = 1, npcoa(4,jk) |
|---|
| 232 | ii = nicoa(jl,4,jk) |
|---|
| 233 | ij = njcoa(jl,4,jk) |
|---|
| 234 | rotn(ii,ij,jk) = -1. / ( e1f(ii,ij)*e2f(ii,ij) ) & |
|---|
| 235 | * ( -4. * zwu(ii,ij) + zwu(ii,ij-1) - 0.2 * zwu(ii,ij-2) ) |
|---|
| 236 | END DO |
|---|
| 237 | ! ! =============== |
|---|
| 238 | END DO ! End of slab |
|---|
| 239 | ! ! =============== |
|---|
| 240 | |
|---|
| 241 | IF( ln_rnf ) CALL sbc_rnf_div( hdivn ) ! runoffs (update hdivn field) |
|---|
| 242 | IF( ln_divisf .AND. (nn_isf /= 0) ) CALL sbc_isf_div( hdivn ) ! ice shelf (update hdivn field) |
|---|
| 243 | IF( nn_cla == 1 ) CALL cla_div ( kt ) ! Cross Land Advection (Update Hor. divergence) |
|---|
| 244 | |
|---|
| 245 | ! 4. Lateral boundary conditions on hdivn and rotn |
|---|
| 246 | ! ---------------------------------=======---====== |
|---|
| 247 | CALL lbc_lnk( hdivn, 'T', 1. ) ; CALL lbc_lnk( rotn , 'F', 1. ) ! lateral boundary cond. (no sign change) |
|---|
| 248 | ! |
|---|
| 249 | CALL wrk_dealloc( jpi , jpj+2, zwu ) |
|---|
| 250 | CALL wrk_dealloc( jpi+2, jpj , zwv ) |
|---|
| 251 | ! |
|---|
| 252 | IF( nn_timing == 1 ) CALL timing_stop('div_cur') |
|---|
| 253 | ! |
|---|
| 254 | IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle) |
|---|
| 255 | END SUBROUTINE div_cur |
|---|
| 256 | |
|---|
| 257 | #else |
|---|
| 258 | !!---------------------------------------------------------------------- |
|---|
| 259 | !! Default option 2nd order centered schemes |
|---|
| 260 | !!---------------------------------------------------------------------- |
|---|
| 261 | |
|---|
| 262 | SUBROUTINE div_cur( kt ) |
|---|
| 263 | !!---------------------------------------------------------------------- |
|---|
| 264 | !! *** ROUTINE div_cur *** |
|---|
| 265 | !! |
|---|
| 266 | !! ** Purpose : compute the horizontal divergence and the relative |
|---|
| 267 | !! vorticity at before and now time-step |
|---|
| 268 | !! |
|---|
| 269 | !! ** Method : - Divergence: |
|---|
| 270 | !! - save the divergence computed at the previous time-step |
|---|
| 271 | !! (note that the Asselin filter has not been applied on hdivb) |
|---|
| 272 | !! - compute the now divergence given by : |
|---|
| 273 | !! hdivn = 1/(e1t*e2t*e3t) ( di[e2u*e3u un] + dj[e1v*e3v vn] ) |
|---|
| 274 | !! correct hdiv with runoff inflow (div_rnf) and cross land flow (div_cla) |
|---|
| 275 | !! - Relavtive Vorticity : |
|---|
| 276 | !! - save the curl computed at the previous time-step (rotb = rotn) |
|---|
| 277 | !! (note that the Asselin time filter has not been applied to rotb) |
|---|
| 278 | !! - compute the now curl in tensorial formalism: |
|---|
| 279 | !! rotn = 1/(e1f*e2f) ( di[e2v vn] - dj[e1u un] ) |
|---|
| 280 | !! Note: Coastal boundary condition: lateral friction set through |
|---|
| 281 | !! the value of fmask along the coast (see dommsk.F90) and shlat |
|---|
| 282 | !! (namelist parameter) |
|---|
| 283 | !! |
|---|
| 284 | !! ** Action : - update hdivb, hdivn, the before & now hor. divergence |
|---|
| 285 | !! - update rotb , rotn , the before & now rel. vorticity |
|---|
| 286 | !!---------------------------------------------------------------------- |
|---|
| 287 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 288 | ! |
|---|
| 289 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 290 | REAL(wp) :: zraur, zdep ! local scalars |
|---|
| 291 | INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0 |
|---|
| 292 | INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1 |
|---|
| 293 | REAL(KIND=jprb) :: zhook_handle |
|---|
| 294 | |
|---|
| 295 | CHARACTER(LEN=*), PARAMETER :: RoutineName='DIV_CUR' |
|---|
| 296 | |
|---|
| 297 | IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle) |
|---|
| 298 | |
|---|
| 299 | !!---------------------------------------------------------------------- |
|---|
| 300 | ! |
|---|
| 301 | IF( nn_timing == 1 ) CALL timing_start('div_cur') |
|---|
| 302 | ! |
|---|
| 303 | IF( kt == nit000 ) THEN |
|---|
| 304 | IF(lwp) WRITE(numout,*) |
|---|
| 305 | IF(lwp) WRITE(numout,*) 'div_cur : horizontal velocity divergence and' |
|---|
| 306 | IF(lwp) WRITE(numout,*) '~~~~~~~ relative vorticity' |
|---|
| 307 | ENDIF |
|---|
| 308 | |
|---|
| 309 | ! ! =============== |
|---|
| 310 | DO jk = 1, jpkm1 ! Horizontal slab |
|---|
| 311 | ! ! =============== |
|---|
| 312 | ! |
|---|
| 313 | hdivb(:,:,jk) = hdivn(:,:,jk) ! time swap of div arrays |
|---|
| 314 | rotb (:,:,jk) = rotn (:,:,jk) ! time swap of rot arrays |
|---|
| 315 | ! |
|---|
| 316 | ! ! -------- |
|---|
| 317 | ! Horizontal divergence ! div |
|---|
| 318 | ! ! -------- |
|---|
| 319 | DO jj = 2, jpjm1 |
|---|
| 320 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 321 | hdivn(ji,jj,jk) = & |
|---|
| 322 | ( e2u(ji,jj)*fse3u(ji,jj,jk) * un(ji,jj,jk) - e2u(ji-1,jj)*fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) & |
|---|
| 323 | + e1v(ji,jj)*fse3v(ji,jj,jk) * vn(ji,jj,jk) - e1v(ji,jj-1)*fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) & |
|---|
| 324 | / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | |
|---|
| 328 | IF( .NOT. AGRIF_Root() ) THEN |
|---|
| 329 | IF ((nbondi == 1).OR.(nbondi == 2)) hdivn(nlci-1 , : ,jk) = 0.e0 ! east |
|---|
| 330 | IF ((nbondi == -1).OR.(nbondi == 2)) hdivn(2 , : ,jk) = 0.e0 ! west |
|---|
| 331 | IF ((nbondj == 1).OR.(nbondj == 2)) hdivn(: ,nlcj-1 ,jk) = 0.e0 ! north |
|---|
| 332 | IF ((nbondj == -1).OR.(nbondj == 2)) hdivn(: ,2 ,jk) = 0.e0 ! south |
|---|
| 333 | ENDIF |
|---|
| 334 | |
|---|
| 335 | ! ! -------- |
|---|
| 336 | ! relative vorticity ! rot |
|---|
| 337 | ! ! -------- |
|---|
| 338 | DO jj = 1, jpjm1 |
|---|
| 339 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 340 | rotn(ji,jj,jk) = ( e2v(ji+1,jj ) * vn(ji+1,jj ,jk) - e2v(ji,jj) * vn(ji,jj,jk) & |
|---|
| 341 | & - e1u(ji ,jj+1) * un(ji ,jj+1,jk) + e1u(ji,jj) * un(ji,jj,jk) ) & |
|---|
| 342 | & * fmask(ji,jj,jk) / ( e1f(ji,jj) * e2f(ji,jj) ) |
|---|
| 343 | END DO |
|---|
| 344 | END DO |
|---|
| 345 | ! ! =============== |
|---|
| 346 | END DO ! End of slab |
|---|
| 347 | ! ! =============== |
|---|
| 348 | |
|---|
| 349 | IF( ln_rnf ) CALL sbc_rnf_div( hdivn ) ! runoffs (update hdivn field) |
|---|
| 350 | IF( ln_divisf .AND. (nn_isf .GT. 0) ) CALL sbc_isf_div( hdivn ) ! ice shelf (update hdivn field) |
|---|
| 351 | IF( nn_cla == 1 ) CALL cla_div ( kt ) ! Cross Land Advection (update hdivn field) |
|---|
| 352 | ! |
|---|
| 353 | CALL lbc_lnk( hdivn, 'T', 1. ) ; CALL lbc_lnk( rotn , 'F', 1. ) ! lateral boundary cond. (no sign change) |
|---|
| 354 | ! |
|---|
| 355 | IF( nn_timing == 1 ) CALL timing_stop('div_cur') |
|---|
| 356 | ! |
|---|
| 357 | IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle) |
|---|
| 358 | END SUBROUTINE div_cur |
|---|
| 359 | |
|---|
| 360 | #endif |
|---|
| 361 | !!====================================================================== |
|---|
| 362 | END MODULE divcur |
|---|
