New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 11738

Last change on this file since 11738 was 11738, checked in by marc, 4 years ago

The Dr Hook changes from my perl code.
File size: 8.8 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trd_oce        ! trends: ocean variables
18   USE trddyn         ! trend manager: dynamics
19   !
20   USE in_out_manager ! I/O manager
21   USE lib_mpp        ! MPP library
22   USE prtctl         ! Print control
23   USE wrk_nemo       ! Memory Allocation
24   USE timing         ! Timing
25
26   USE yomhook, ONLY: lhook, dr_hook
27   USE parkind1, ONLY: jprb, jpim
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dyn_adv_cen2( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE dyn_adv_cen2  ***
47      !!
48      !! ** Purpose :   Compute the now momentum advection trend in flux form
49      !!              and the general trend of the momentum equation.
50      !!
51      !! ** Method  :   Trend evaluated using now fields (centered in time)
52      !!
53      !! ** Action  :   (ua,va) updated with the now vorticity term trend
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !
57      INTEGER  ::   ji, jj, jk   ! dummy loop indices
58      REAL(wp) ::   zbu, zbv     ! local scalars
59      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
60      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
61      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
62      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
63      REAL(KIND=jprb)               :: zhook_handle
64
65      CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_ADV_CEN2'
66
67      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
68
69      !!----------------------------------------------------------------------
70      !
71      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
72      !
73      CALL wrk_alloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
74      !
75      IF( kt == nit000 .AND. lwp ) THEN
76         WRITE(numout,*)
77         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
78         WRITE(numout,*) '~~~~~~~~~~~~'
79      ENDIF
80      !
81      IF( l_trddyn ) THEN           ! Save ua and va trends
82         zfu_uw(:,:,:) = ua(:,:,:)
83         zfv_vw(:,:,:) = va(:,:,:)
84      ENDIF
85
86      !                                      ! ====================== !
87      !                                      !  Horizontal advection  !
88      DO jk = 1, jpkm1                       ! ====================== !
89         !                                         ! horizontal volume fluxes
90         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
91         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
92         !
93         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
94            DO ji = 1, fs_jpim1   ! vector opt.
95               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
96               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
97               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
98               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
99            END DO
100         END DO
101         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
102            DO ji = fs_2, fs_jpim1   ! vector opt.
103               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
104               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
105               !
106               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
107                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
108               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
109                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
110            END DO
111         END DO
112      END DO
113      !
114      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
115         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
116         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
117         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
118         zfu_t(:,:,:) = ua(:,:,:)
119         zfv_t(:,:,:) = va(:,:,:)
120      ENDIF
121      !
122
123      !                                      ! ==================== !
124      !                                      !  Vertical advection  !
125      DO jk = 1, jpkm1                       ! ==================== !
126         !                                         ! Vertical volume fluxesÊ
127         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
128         !
129         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
130            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
131            zfv_vw(:,:,jpk) = 0.e0
132            !                                           ! Surface value :
133            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
134               zfu_uw(:,:, 1 ) = 0.e0   
135               zfv_vw(:,:, 1 ) = 0.e0
136            ELSE                                             ! constant volume : advection through the surface
137               DO jj = 2, jpjm1
138                  DO ji = fs_2, fs_jpim1
139                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
140                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
141                  END DO
142               END DO
143            ENDIF
144         ELSE                                      ! interior fluxes
145            DO jj = 2, jpjm1
146               DO ji = fs_2, fs_jpim1   ! vector opt.
147                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
148                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
149               END DO
150            END DO
151         ENDIF
152      END DO
153      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
154         DO jj = 2, jpjm1 
155            DO ji = fs_2, fs_jpim1   ! vector opt.
156               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
157                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
158               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
159                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
160            END DO
161         END DO
162      END DO
163      !
164      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
165         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
166         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
167         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
168      ENDIF
169      !                                            ! Control print
170      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
171         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
172      !
173      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
174      !
175      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
176      !
177      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
178   END SUBROUTINE dyn_adv_cen2
179
180   !!==============================================================================
181END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.