source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 11738

Last change on this file since 11738 was 11738, checked in by marc, 12 months ago

The Dr Hook changes from my perl code.

File size: 76.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE biaspar         ! bias correction variables
47
48   USE yomhook, ONLY: lhook, dr_hook
49   USE parkind1, ONLY: jprb, jpim
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
59   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
60   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
61   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
64   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
65
66   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
67
68   !! * Substitutions
69#  include "domzgr_substitute.h90"
70#  include "vectopt_loop_substitute.h90"
71   !!----------------------------------------------------------------------
72   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
73   !! $Id$
74   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE dyn_hpg( kt )
79      !!---------------------------------------------------------------------
80      !!                  ***  ROUTINE dyn_hpg  ***
81      !!
82      !! ** Method  :   Call the hydrostatic pressure gradient routine
83      !!              using the scheme defined in the namelist
84      !!
85      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
86      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
87      !!----------------------------------------------------------------------
88      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
89      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
90      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   z_rhd_st  ! tmp density storage for pressure corr
91      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_gru_st  ! tmp ua trends storage for pressure corr
92      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     ::   z_grv_st  ! tmp va trends storage for pressure corr
93      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
94      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
95      REAL(KIND=jprb)               :: zhook_handle
96
97      CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_HPG'
98
99      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
100
101      !!----------------------------------------------------------------------
102      !
103      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
104      !
105      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
106         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
107         ztrdu(:,:,:) = ua(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:)
109      ENDIF
110      !
111      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
112
113         !Allocate space for tempory variables
114         ALLOCATE( z_rhd_st(jpi,jpj,jpk), &
115            &      z_gru_st(jpi,jpj),     &
116            &      z_grv_st(jpi,jpj)      )
117
118         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
119         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
120         z_gru_st(:,:)   = gru(:,:)
121         gru(:,:)        = gru_pc(:,:)
122         z_grv_st(:,:)   = grv(:,:)
123         grv(:,:)        = grv_pc(:,:)
124
125      ENDIF
126
127      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
128      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
129      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
130      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
131      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
132      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
133      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
134      END SELECT
135      !
136      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
137         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
138         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
139         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
140         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
141      ENDIF
142      !
143      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
144         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
145      !
146      IF ( ln_bias .AND. ln_bias_pc_app )  THEN
147         IF(lwp) THEN
148         WRITE(numout,*) " ! restore original density"
149         ENDIF
150         rhd(:,:,:) = z_rhd_st(:,:,:)     ! restore original density
151         gru(:,:)   = z_gru_st(:,:)
152         grv(:,:)   = z_grv_st(:,:)
153
154         !Deallocate tempory variables
155         DEALLOCATE( z_rhd_st,     &
156            &        z_gru_st,     &
157            &        z_grv_st      )
158      ENDIF
159      !
160      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
161      !
162      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
163   END SUBROUTINE dyn_hpg
164
165
166   SUBROUTINE dyn_hpg_init
167      !!----------------------------------------------------------------------
168      !!                 ***  ROUTINE dyn_hpg_init  ***
169      !!
170      !! ** Purpose :   initializations for the hydrostatic pressure gradient
171      !!              computation and consistency control
172      !!
173      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
174      !!      with the type of vertical coordinate used (zco, zps, sco)
175      !!----------------------------------------------------------------------
176      INTEGER ::   ioptio = 0      ! temporary integer
177      INTEGER ::   ios             ! Local integer output status for namelist read
178      !!
179      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
180         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
181         INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
182         INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
183         REAL(KIND=jprb)               :: zhook_handle
184
185         CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_HPG_INIT'
186
187         IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
188
189      !!----------------------------------------------------------------------
190      !
191      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
192      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
193901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
194
195      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
196      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
197902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
198      IF(lwm) WRITE ( numond, namdyn_hpg )
199      !
200      IF(lwp) THEN                   ! Control print
201         WRITE(numout,*)
202         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
203         WRITE(numout,*) '~~~~~~~~~~~~'
204         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
205         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
206         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
207         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
208         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
209         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
210         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
211         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
212      ENDIF
213      !
214      IF( ln_hpg_djc )   &
215         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
216                           & currently disabled (bugs under investigation). Please select &
217                           & either  ln_hpg_sco or  ln_hpg_prj instead')
218      !
219      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
220         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
221                           & the standard jacobian formulation hpg_sco or &
222                           & the pressure jacobian formulation hpg_prj')
223
224      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
225         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
226      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
227         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
228      !
229      !                               ! Set nhpg from ln_hpg_... flags
230      IF( ln_hpg_zco )   nhpg = 0
231      IF( ln_hpg_zps )   nhpg = 1
232      IF( ln_hpg_sco )   nhpg = 2
233      IF( ln_hpg_djc )   nhpg = 3
234      IF( ln_hpg_prj )   nhpg = 4
235      IF( ln_hpg_isf )   nhpg = 5
236      !
237      !                               ! Consistency check
238      ioptio = 0
239      IF( ln_hpg_zco )   ioptio = ioptio + 1
240      IF( ln_hpg_zps )   ioptio = ioptio + 1
241      IF( ln_hpg_sco )   ioptio = ioptio + 1
242      IF( ln_hpg_djc )   ioptio = ioptio + 1
243      IF( ln_hpg_prj )   ioptio = ioptio + 1
244      IF( ln_hpg_isf )   ioptio = ioptio + 1
245      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
246      !
247      ! initialisation of ice load
248      riceload(:,:)=0.0
249      !
250         IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
251   END SUBROUTINE dyn_hpg_init
252
253
254   SUBROUTINE hpg_zco( kt )
255      !!---------------------------------------------------------------------
256      !!                  ***  ROUTINE hpg_zco  ***
257      !!
258      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
259      !!      The now hydrostatic pressure gradient at a given level, jk,
260      !!      is computed by taking the vertical integral of the in-situ
261      !!      density gradient along the model level from the suface to that
262      !!      level:    zhpi = grav .....
263      !!                zhpj = grav .....
264      !!      add it to the general momentum trend (ua,va).
265      !!            ua = ua - 1/e1u * zhpi
266      !!            va = va - 1/e2v * zhpj
267      !!
268      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
269      !!----------------------------------------------------------------------
270      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
271      !!
272      INTEGER  ::   ji, jj, jk       ! dummy loop indices
273      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
274      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
275      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
276      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
277      REAL(KIND=jprb)               :: zhook_handle
278
279      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_ZCO'
280
281      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
282
283      !!----------------------------------------------------------------------
284      !
285      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
286      !
287      IF( kt == nit000 ) THEN
288         IF(lwp) WRITE(numout,*)
289         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
290         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
291      ENDIF
292
293      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
294
295      ! Surface value
296      DO jj = 2, jpjm1
297         DO ji = fs_2, fs_jpim1   ! vector opt.
298            zcoef1 = zcoef0 * fse3w(ji,jj,1)
299            ! hydrostatic pressure gradient
300            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
301            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
302            ! add to the general momentum trend
303            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
304            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
305         END DO
306      END DO
307
308      !
309      ! interior value (2=<jk=<jpkm1)
310      DO jk = 2, jpkm1
311         DO jj = 2, jpjm1
312            DO ji = fs_2, fs_jpim1   ! vector opt.
313               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
314               ! hydrostatic pressure gradient
315               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
316                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
317                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
318
319               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
320                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
321                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
322               ! add to the general momentum trend
323               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
324               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
325            END DO
326         END DO
327      END DO
328      !
329      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
330      !
331      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
332   END SUBROUTINE hpg_zco
333
334
335   SUBROUTINE hpg_zps( kt )
336      !!---------------------------------------------------------------------
337      !!                 ***  ROUTINE hpg_zps  ***
338      !!
339      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
340      !!
341      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
342      !!----------------------------------------------------------------------
343      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
344      !!
345      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
346      INTEGER  ::   iku, ikv                         ! temporary integers
347      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
348      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
349      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
350      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
351      REAL(KIND=jprb)               :: zhook_handle
352
353      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_ZPS'
354
355      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
356
357      !!----------------------------------------------------------------------
358      !
359      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
360      !
361      IF( kt == nit000 ) THEN
362         IF(lwp) WRITE(numout,*)
363         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
364         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
365      ENDIF
366
367
368      ! Local constant initialization
369      zcoef0 = - grav * 0.5_wp
370
371      !  Surface value (also valid in partial step case)
372      DO jj = 2, jpjm1
373         DO ji = fs_2, fs_jpim1   ! vector opt.
374            zcoef1 = zcoef0 * fse3w(ji,jj,1)
375            ! hydrostatic pressure gradient
376            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
377            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
378            ! add to the general momentum trend
379            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
380            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
381         END DO
382      END DO
383
384
385      ! interior value (2=<jk=<jpkm1)
386      DO jk = 2, jpkm1
387         DO jj = 2, jpjm1
388            DO ji = fs_2, fs_jpim1   ! vector opt.
389               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
390               ! hydrostatic pressure gradient
391               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
392                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
393                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
394
395               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
396                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
397                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
398               ! add to the general momentum trend
399               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
400               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
401            END DO
402         END DO
403      END DO
404
405
406      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
407      DO jj = 2, jpjm1
408         DO ji = 2, jpim1
409            iku = mbku(ji,jj)
410            ikv = mbkv(ji,jj)
411            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
412            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
413            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
414               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
415               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
416                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
417               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
418            ENDIF
419            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
420               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
421               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
422                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
423               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
424            ENDIF
425         END DO
426      END DO
427      !
428      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
429      !
430      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
431   END SUBROUTINE hpg_zps
432
433   SUBROUTINE hpg_sco( kt )
434      !!---------------------------------------------------------------------
435      !!                  ***  ROUTINE hpg_sco  ***
436      !!
437      !! ** Method  :   s-coordinate case. Jacobian scheme.
438      !!      The now hydrostatic pressure gradient at a given level, jk,
439      !!      is computed by taking the vertical integral of the in-situ
440      !!      density gradient along the model level from the suface to that
441      !!      level. s-coordinates (ln_sco): a corrective term is added
442      !!      to the horizontal pressure gradient :
443      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
444      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
445      !!      add it to the general momentum trend (ua,va).
446      !!         ua = ua - 1/e1u * zhpi
447      !!         va = va - 1/e2v * zhpj
448      !!
449      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
450      !!----------------------------------------------------------------------
451      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
452      !!
453      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
454      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
455      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
456      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
457      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
458      REAL(KIND=jprb)               :: zhook_handle
459
460      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_SCO'
461
462      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
463
464      !!----------------------------------------------------------------------
465      !
466      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
467      !
468      IF( kt == nit000 ) THEN
469         IF(lwp) WRITE(numout,*)
470         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
471         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
472      ENDIF
473
474      ! Local constant initialization
475      zcoef0 = - grav * 0.5_wp
476      ! To use density and not density anomaly
477      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
478      ELSE                 ;     znad = 0._wp         ! Fixed volume
479      ENDIF
480
481      ! Surface value
482      DO jj = 2, jpjm1
483         DO ji = fs_2, fs_jpim1   ! vector opt.
484            ! hydrostatic pressure gradient along s-surfaces
485            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
486               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
487            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
488               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
489            ! s-coordinate pressure gradient correction
490            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
491               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
492            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
493               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
494            ! add to the general momentum trend
495            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
496            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
497         END DO
498      END DO
499
500      ! interior value (2=<jk=<jpkm1)
501      DO jk = 2, jpkm1
502         DO jj = 2, jpjm1
503            DO ji = fs_2, fs_jpim1   ! vector opt.
504               ! hydrostatic pressure gradient along s-surfaces
505               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
506                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
507                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
508               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
509                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
510                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
511               ! s-coordinate pressure gradient correction
512               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
513                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
514               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
515                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
516               ! add to the general momentum trend
517               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
518               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
519            END DO
520         END DO
521      END DO
522      !
523      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
524      !
525      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
526   END SUBROUTINE hpg_sco
527
528   SUBROUTINE hpg_isf( kt )
529      !!---------------------------------------------------------------------
530      !!                  ***  ROUTINE hpg_sco  ***
531      !!
532      !! ** Method  :   s-coordinate case. Jacobian scheme.
533      !!      The now hydrostatic pressure gradient at a given level, jk,
534      !!      is computed by taking the vertical integral of the in-situ
535      !!      density gradient along the model level from the suface to that
536      !!      level. s-coordinates (ln_sco): a corrective term is added
537      !!      to the horizontal pressure gradient :
538      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
539      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
540      !!      add it to the general momentum trend (ua,va).
541      !!         ua = ua - 1/e1u * zhpi
542      !!         va = va - 1/e2v * zhpj
543      !!      iceload is added and partial cell case are added to the top and bottom
544      !!     
545      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
546      !!----------------------------------------------------------------------
547      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
548      !!
549      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
550      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
551      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
552      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
553      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
554      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
555      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
556      REAL(KIND=jprb)               :: zhook_handle
557
558      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_ISF'
559
560      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
561
562      !!----------------------------------------------------------------------
563      !
564      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
565      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
566      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
567      !
568     IF( kt == nit000 ) THEN
569         IF(lwp) WRITE(numout,*)
570         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
571         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
572      ENDIF
573
574      ! Local constant initialization
575      zcoef0 = - grav * 0.5_wp
576      ! To use density and not density anomaly
577!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
578!      ELSE                 ;     znad = 0._wp         ! Fixed volume
579!      ENDIF
580      znad=1._wp
581      ! iniitialised to 0. zhpi zhpi
582      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
583
584!==================================================================================     
585!=====Compute iceload and contribution of the half first wet layer =================
586!===================================================================================
587
588      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
589      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
590
591      ! compute density of the water displaced by the ice shelf
592      zrhd = rhd ! save rhd
593      DO jk = 1, jpk
594           zdept(:,:)=gdept_1d(jk)
595           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
596      END DO
597      WHERE ( tmask(:,:,:) == 1._wp)
598        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
599      END WHERE
600     
601      ! compute rhd at the ice/oce interface (ice shelf side)
602      CALL eos(ztstop,risfdep,zrhdtop_isf)
603
604      ! compute rhd at the ice/oce interface (ocean side)
605      DO ji=1,jpi
606        DO jj=1,jpj
607          ikt=mikt(ji,jj)
608          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
609          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
610        END DO
611      END DO
612      CALL eos(ztstop,risfdep,zrhdtop_oce)
613      !
614      ! Surface value + ice shelf gradient
615      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
616      ziceload = 0._wp
617      DO jj = 1, jpj
618         DO ji = 1, jpi   ! vector opt.
619            ikt=mikt(ji,jj)
620            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
621            DO jk=2,ikt-1
622               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
623                  &                              * (1._wp - tmask(ji,jj,jk))
624            END DO
625            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
626                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
627         END DO
628      END DO
629      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
630      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
631      DO jj = 2, jpjm1
632         DO ji = fs_2, fs_jpim1   ! vector opt.
633            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
634            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
635            ! we assume ISF is in isostatic equilibrium
636            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
637               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
638               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
639               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
640               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
641            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
642               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
643               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
644               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
645               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
646            ! s-coordinate pressure gradient correction (=0 if z coordinate)
647            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
648               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
649            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
650               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
651            ! add to the general momentum trend
652            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
653            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
654         END DO
655      END DO
656!==================================================================================     
657!===== Compute partial cell contribution for the top cell =========================
658!==================================================================================
659      DO jj = 2, jpjm1
660         DO ji = fs_2, fs_jpim1   ! vector opt.
661            iku = miku(ji,jj) ; 
662            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
663            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
664            ! u direction
665            IF ( iku .GT. 1 ) THEN
666               ! case iku
667               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
668                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
669                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
670               ! corrective term ( = 0 if z coordinate )
671               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
672               ! zhpi will be added in interior loop
673               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
674               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
675               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
676
677               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
678               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
679                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
680                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
681                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
682                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
683               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
684            END IF
685               
686            ! v direction
687            ikv = mikv(ji,jj)
688            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
689            IF ( ikv .GT. 1 ) THEN
690               ! case ikv
691               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
692                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
693                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
694               ! corrective term ( = 0 if z coordinate )
695               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
696               ! zhpi will be added in interior loop
697               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
698               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
699               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
700               
701               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
702               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
703                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
704                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
705                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
706                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
707               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
708            END IF
709         END DO
710      END DO
711
712!==================================================================================     
713!===== Compute interior value =====================================================
714!==================================================================================
715
716      DO jj = 2, jpjm1
717         DO ji = fs_2, fs_jpim1   ! vector opt.
718            iku=miku(ji,jj); ikv=mikv(ji,jj)
719            DO jk = 2, jpkm1
720               ! hydrostatic pressure gradient along s-surfaces
721               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
722               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
723                  &                            + zcoef0 / e1u(ji,jj)                                                           &
724                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
725                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
726                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
727                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
728               ! s-coordinate pressure gradient correction
729               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
730               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
731                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
732               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
733
734               ! hydrostatic pressure gradient along s-surfaces
735               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
736               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
737                  &                            + zcoef0 / e2v(ji,jj)                                                           &
738                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
739                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
740                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
741                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
742               ! s-coordinate pressure gradient correction
743               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
744               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
745                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
746               ! add to the general momentum trend
747               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
748            END DO
749         END DO
750      END DO
751
752!==================================================================================     
753!===== Compute bottom cell contribution (partial cell) ============================
754!==================================================================================
755
756      DO jj = 2, jpjm1
757         DO ji = 2, jpim1
758            iku = mbku(ji,jj)
759            ikv = mbkv(ji,jj)
760
761            IF (iku .GT. 1) THEN
762               ! remove old value (interior case)
763               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
764                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
765               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
766               ! put new value
767               ! -zpshpi to avoid double contribution of the partial step in the top layer
768               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
769               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
770               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
771            END IF
772            ! v direction
773            IF (ikv .GT. 1) THEN
774               ! remove old value (interior case)
775               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
776                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
777               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
778               ! put new value
779               ! -zpshpj to avoid double contribution of the partial step in the top layer
780               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
781               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
782               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
783            END IF
784         END DO
785      END DO
786     
787      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
788      rhd = zrhd
789      !
790      CALL wrk_dealloc( jpi,jpj,2, ztstop)
791      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
792      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
793      !
794      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
795   END SUBROUTINE hpg_isf
796
797
798   SUBROUTINE hpg_djc( kt )
799      !!---------------------------------------------------------------------
800      !!                  ***  ROUTINE hpg_djc  ***
801      !!
802      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
803      !!
804      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
805      !!----------------------------------------------------------------------
806      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
807      !!
808      INTEGER  ::   ji, jj, jk          ! dummy loop indices
809      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
810      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
811      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
812      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
813      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
814      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
815      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
816      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
817      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
818      REAL(KIND=jprb)               :: zhook_handle
819
820      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_DJC'
821
822      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
823
824      !!----------------------------------------------------------------------
825      !
826      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
827      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
828      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
829      !
830
831      IF( kt == nit000 ) THEN
832         IF(lwp) WRITE(numout,*)
833         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
834         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
835      ENDIF
836
837      ! Local constant initialization
838      zcoef0 = - grav * 0.5_wp
839      z1_10  = 1._wp / 10._wp
840      z1_12  = 1._wp / 12._wp
841
842      !----------------------------------------------------------------------------------------
843      !  compute and store in provisional arrays elementary vertical and horizontal differences
844      !----------------------------------------------------------------------------------------
845
846!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
847
848      DO jk = 2, jpkm1
849         DO jj = 2, jpjm1
850            DO ji = fs_2, fs_jpim1   ! vector opt.
851               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
852               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
853               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
854               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
855               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
856               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
857            END DO
858         END DO
859      END DO
860
861      !-------------------------------------------------------------------------
862      ! compute harmonic averages using eq. 5.18
863      !-------------------------------------------------------------------------
864      zep = 1.e-15
865
866!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
867!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
868
869      DO jk = 2, jpkm1
870         DO jj = 2, jpjm1
871            DO ji = fs_2, fs_jpim1   ! vector opt.
872               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
873
874               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
875               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
876
877               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
878               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
879
880               IF( cffw > zep) THEN
881                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
882                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
883               ELSE
884                  drhow(ji,jj,jk) = 0._wp
885               ENDIF
886
887               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
888                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
889
890               IF( cffu > zep ) THEN
891                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
892                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
893               ELSE
894                  drhou(ji,jj,jk ) = 0._wp
895               ENDIF
896
897               IF( cffx > zep ) THEN
898                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
899                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
900               ELSE
901                  dzu(ji,jj,jk) = 0._wp
902               ENDIF
903
904               IF( cffv > zep ) THEN
905                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
906                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
907               ELSE
908                  drhov(ji,jj,jk) = 0._wp
909               ENDIF
910
911               IF( cffy > zep ) THEN
912                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
913                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
914               ELSE
915                  dzv(ji,jj,jk) = 0._wp
916               ENDIF
917
918            END DO
919         END DO
920      END DO
921
922      !----------------------------------------------------------------------------------
923      ! apply boundary conditions at top and bottom using 5.36-5.37
924      !----------------------------------------------------------------------------------
925      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
926      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
927      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
928
929      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
930      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
931      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
932
933
934      !--------------------------------------------------------------
935      ! Upper half of top-most grid box, compute and store
936      !-------------------------------------------------------------
937
938!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
939!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
940
941      DO jj = 2, jpjm1
942         DO ji = fs_2, fs_jpim1   ! vector opt.
943            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
944               &                   * (  rhd(ji,jj,1)                                    &
945               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
946               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
947               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
948         END DO
949      END DO
950
951!!bug gm    : here also, simplification is possible
952!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
953
954      DO jk = 2, jpkm1
955         DO jj = 2, jpjm1
956            DO ji = fs_2, fs_jpim1   ! vector opt.
957
958               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
959                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
960                  &            - grav * z1_10 * (                                                                     &
961                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
962                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
963                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
964                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
965                  &                             )
966
967               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
968                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
969                  &            - grav* z1_10 * (                                                                      &
970                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
971                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
972                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
973                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
974                  &                            )
975
976               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
977                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
978                  &            - grav* z1_10 * (                                                                      &
979                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
980                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
981                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
982                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
983                  &                            )
984
985            END DO
986         END DO
987      END DO
988      CALL lbc_lnk(rho_k,'W',1.)
989      CALL lbc_lnk(rho_i,'U',1.)
990      CALL lbc_lnk(rho_j,'V',1.)
991
992
993      ! ---------------
994      !  Surface value
995      ! ---------------
996      DO jj = 2, jpjm1
997         DO ji = fs_2, fs_jpim1   ! vector opt.
998            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
999            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
1000            ! add to the general momentum trend
1001            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
1002            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
1003         END DO
1004      END DO
1005
1006      ! ----------------
1007      !  interior value   (2=<jk=<jpkm1)
1008      ! ----------------
1009      DO jk = 2, jpkm1
1010         DO jj = 2, jpjm1
1011            DO ji = fs_2, fs_jpim1   ! vector opt.
1012               ! hydrostatic pressure gradient along s-surfaces
1013               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
1014                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
1015                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
1016               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
1017                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
1018                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
1019               ! add to the general momentum trend
1020               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
1021               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
1022            END DO
1023         END DO
1024      END DO
1025      !
1026      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
1027      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
1028      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
1029      !
1030      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1031   END SUBROUTINE hpg_djc
1032
1033
1034   SUBROUTINE hpg_prj( kt )
1035      !!---------------------------------------------------------------------
1036      !!                  ***  ROUTINE hpg_prj  ***
1037      !!
1038      !! ** Method  :   s-coordinate case.
1039      !!      A Pressure-Jacobian horizontal pressure gradient method
1040      !!      based on the constrained cubic-spline interpolation for
1041      !!      all vertical coordinate systems
1042      !!
1043      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
1044      !!----------------------------------------------------------------------
1045      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
1046      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
1047      !!
1048      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
1049      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
1050      !!
1051      !! The local variables for the correction term
1052      INTEGER  :: jk1, jis, jid, jjs, jjd
1053      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
1054      REAL(wp) :: zrhdt1
1055      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
1056      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
1057      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
1058      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
1059      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1060      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1061      REAL(KIND=jprb)               :: zhook_handle
1062
1063      CHARACTER(LEN=*), PARAMETER :: RoutineName='HPG_PRJ'
1064
1065      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1066
1067      !!----------------------------------------------------------------------
1068      !
1069      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1070      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
1071      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
1072      !
1073      IF( kt == nit000 ) THEN
1074         IF(lwp) WRITE(numout,*)
1075         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1076         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
1077      ENDIF
1078
1079      !!----------------------------------------------------------------------
1080      ! Local constant initialization
1081      zcoef0 = - grav
1082      znad = 0.0_wp
1083      IF( lk_vvl ) znad = 1._wp
1084
1085      ! Clean 3-D work arrays
1086      zhpi(:,:,:) = 0._wp
1087      zrhh(:,:,:) = rhd(:,:,:)
1088
1089      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1090      DO jj = 1, jpj
1091        DO ji = 1, jpi
1092          jk = mbathy(ji,jj)
1093          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1094          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1095          ELSE IF(jk < jpkm1) THEN
1096             DO jkk = jk+1, jpk
1097                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1098                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1099             END DO
1100          ENDIF
1101        END DO
1102      END DO
1103
1104      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1105      DO jj = 1, jpj
1106         DO ji = 1, jpi
1107            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1108         END DO
1109      END DO
1110
1111      DO jk = 2, jpk
1112         DO jj = 1, jpj
1113            DO ji = 1, jpi
1114               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1115            END DO
1116         END DO
1117      END DO
1118
1119      fsp(:,:,:) = zrhh (:,:,:)
1120      xsp(:,:,:) = zdept(:,:,:)
1121
1122      ! Construct the vertical density profile with the
1123      ! constrained cubic spline interpolation
1124      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1125      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1126
1127      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1128      DO jj = 2, jpj
1129        DO ji = 2, jpi
1130          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1131                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1132                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1133
1134          ! assuming linear profile across the top half surface layer
1135          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1136        END DO
1137      END DO
1138
1139      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1140      DO jk = 2, jpkm1
1141        DO jj = 2, jpj
1142          DO ji = 2, jpi
1143            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1144                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1145                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1146                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1147          END DO
1148        END DO
1149      END DO
1150
1151      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1152
1153      ! Prepare zsshu_n and zsshv_n
1154      DO jj = 2, jpjm1
1155        DO ji = 2, jpim1
1156          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1157                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1158          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1159                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1160        END DO
1161      END DO
1162
1163      DO jj = 2, jpjm1
1164        DO ji = 2, jpim1
1165          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1166          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1167        END DO
1168      END DO
1169
1170      DO jk = 2, jpkm1
1171        DO jj = 2, jpjm1
1172          DO ji = 2, jpim1
1173            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1174            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1175          END DO
1176        END DO
1177      END DO
1178
1179      DO jk = 1, jpkm1
1180        DO jj = 2, jpjm1
1181          DO ji = 2, jpim1
1182            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1183            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1184          END DO
1185        END DO
1186      END DO
1187
1188      DO jk = 1, jpkm1
1189        DO jj = 2, jpjm1
1190          DO ji = 2, jpim1
1191            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1192            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1193            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1194            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1195          END DO
1196        END DO
1197      END DO
1198
1199
1200      DO jk = 1, jpkm1
1201        DO jj = 2, jpjm1
1202          DO ji = 2, jpim1
1203            zpwes = 0._wp; zpwed = 0._wp
1204            zpnss = 0._wp; zpnsd = 0._wp
1205            zuijk = zu(ji,jj,jk)
1206            zvijk = zv(ji,jj,jk)
1207
1208            !!!!!     for u equation
1209            IF( jk <= mbku(ji,jj) ) THEN
1210               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1211                 jis = ji + 1; jid = ji
1212               ELSE
1213                 jis = ji;     jid = ji +1
1214               ENDIF
1215
1216               ! integrate the pressure on the shallow side
1217               jk1 = jk
1218               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1219                 IF( jk1 == mbku(ji,jj) ) THEN
1220                   zuijk = -zdept(jis,jj,jk1)
1221                   EXIT
1222                 ENDIF
1223                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1224                 zpwes = zpwes +                                    &
1225                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1226                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1227                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1228                 jk1 = jk1 + 1
1229               END DO
1230
1231               ! integrate the pressure on the deep side
1232               jk1 = jk
1233               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1234                 IF( jk1 == 1 ) THEN
1235                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1236                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1237                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1238                                                     dsp(jid,jj,1)) * zdeps
1239                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1240                   EXIT
1241                 ENDIF
1242                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1243                 zpwed = zpwed +                                        &
1244                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1245                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1246                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1247                 jk1 = jk1 - 1
1248               END DO
1249
1250               ! update the momentum trends in u direction
1251
1252               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1253               IF( lk_vvl ) THEN
1254                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1255                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1256                ELSE
1257                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1258               ENDIF
1259
1260               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1261               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1262            ENDIF
1263
1264            !!!!!     for v equation
1265            IF( jk <= mbkv(ji,jj) ) THEN
1266               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1267                 jjs = jj + 1; jjd = jj
1268               ELSE
1269                 jjs = jj    ; jjd = jj + 1
1270               ENDIF
1271
1272               ! integrate the pressure on the shallow side
1273               jk1 = jk
1274               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1275                 IF( jk1 == mbkv(ji,jj) ) THEN
1276                   zvijk = -zdept(ji,jjs,jk1)
1277                   EXIT
1278                 ENDIF
1279                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1280                 zpnss = zpnss +                                      &
1281                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1282                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1283                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1284                 jk1 = jk1 + 1
1285               END DO
1286
1287               ! integrate the pressure on the deep side
1288               jk1 = jk
1289               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1290                 IF( jk1 == 1 ) THEN
1291                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1292                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1293                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1294                                                     dsp(ji,jjd,1) ) * zdeps
1295                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1296                   EXIT
1297                 ENDIF
1298                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1299                 zpnsd = zpnsd +                                        &
1300                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1301                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1302                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1303                 jk1 = jk1 - 1
1304               END DO
1305
1306
1307               ! update the momentum trends in v direction
1308
1309               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1310               IF( lk_vvl ) THEN
1311                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1312                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1313               ELSE
1314                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1315               ENDIF
1316
1317               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1318               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1319            ENDIF
1320
1321
1322           END DO
1323        END DO
1324      END DO
1325      !
1326      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1327      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1328      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1329      !
1330      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1331   END SUBROUTINE hpg_prj
1332
1333
1334   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1335      !!----------------------------------------------------------------------
1336      !!                 ***  ROUTINE cspline  ***
1337      !!
1338      !! ** Purpose :   constrained cubic spline interpolation
1339      !!
1340      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1341      !!
1342      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1343      !!----------------------------------------------------------------------
1344      USE yomhook, ONLY: lhook, dr_hook
1345      USE parkind1, ONLY: jprb, jpim
1346
1347      IMPLICIT NONE
1348      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1349      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1350                                                                    ! the interpoated function
1351      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1352                                                                    ! 2: Linear
1353      !
1354      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1355      INTEGER  ::   jpi, jpj, jpkm1
1356      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1357      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1358      REAL(wp) ::   zdf(size(fsp,3))
1359      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1360      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1361      REAL(KIND=jprb)               :: zhook_handle
1362
1363      CHARACTER(LEN=*), PARAMETER :: RoutineName='CSPLINE'
1364
1365      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1366
1367      !!----------------------------------------------------------------------
1368
1369      jpi   = size(fsp,1)
1370      jpj   = size(fsp,2)
1371      jpkm1 = size(fsp,3) - 1
1372
1373
1374      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1375         DO ji = 1, jpi
1376            DO jj = 1, jpj
1377           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1378           !    DO jk = 2, jpkm1-1
1379           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1380           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1381           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1382           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1383           !
1384           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1385           !
1386           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1387           !           zdf(jk) = 0._wp
1388           !       ELSE
1389           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1390           !       ENDIF
1391           !    END DO
1392
1393           !!Simply geometric average
1394               DO jk = 2, jpkm1-1
1395                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1396                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1397
1398                  IF(zdf1 * zdf2 <= 0._wp) THEN
1399                     zdf(jk) = 0._wp
1400                  ELSE
1401                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1402                  ENDIF
1403               END DO
1404
1405               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1406                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1407               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1408                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1409                          & 0.5_wp * zdf(jpkm1 - 1)
1410
1411               DO jk = 1, jpkm1 - 1
1412                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1413                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1414                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1415                 zddf1  = -2._wp * ztmp1 + ztmp2
1416                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1417                 zddf2  =  2._wp * ztmp1 - ztmp2
1418
1419                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1420                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1421                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1422                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1423                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1424                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1425                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1426                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1427                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1428               END DO
1429            END DO
1430         END DO
1431
1432      ELSE IF (polynomial_type == 2) THEN     ! Linear
1433         DO ji = 1, jpi
1434            DO jj = 1, jpj
1435               DO jk = 1, jpkm1-1
1436                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1437                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1438
1439                  dsp(ji,jj,jk) = 0._wp
1440                  csp(ji,jj,jk) = 0._wp
1441                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1442                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1443               END DO
1444            END DO
1445         END DO
1446
1447      ELSE
1448           CALL ctl_stop( 'invalid polynomial type in cspline' )
1449      ENDIF
1450
1451      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1452   END SUBROUTINE cspline
1453
1454
1455   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1456      !!----------------------------------------------------------------------
1457      !!                 ***  ROUTINE interp1  ***
1458      !!
1459      !! ** Purpose :   1-d linear interpolation
1460      !!
1461      !! ** Method  :   interpolation is straight forward
1462      !!                extrapolation is also permitted (no value limit)
1463      !!----------------------------------------------------------------------
1464      USE yomhook, ONLY: lhook, dr_hook
1465      USE parkind1, ONLY: jprb, jpim
1466
1467      IMPLICIT NONE
1468      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1469      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1470      REAL(wp)             ::  zdeltx
1471      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1472      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1473      REAL(KIND=jprb)               :: zhook_handle
1474
1475      CHARACTER(LEN=*), PARAMETER :: RoutineName='INTERP1'
1476
1477      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1478
1479      !!----------------------------------------------------------------------
1480
1481      zdeltx = xr - xl
1482      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1483        f = 0.5_wp * (fl + fr)
1484      ELSE
1485        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1486      ENDIF
1487
1488      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1489   END FUNCTION interp1
1490
1491
1492   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1493      !!----------------------------------------------------------------------
1494      !!                 ***  ROUTINE interp1  ***
1495      !!
1496      !! ** Purpose :   1-d constrained cubic spline interpolation
1497      !!
1498      !! ** Method  :  cubic spline interpolation
1499      !!
1500      !!----------------------------------------------------------------------
1501      USE yomhook, ONLY: lhook, dr_hook
1502      USE parkind1, ONLY: jprb, jpim
1503
1504      IMPLICIT NONE
1505      REAL(wp), INTENT(in) ::  x, a, b, c, d
1506      REAL(wp)             ::  f ! value from the interpolation
1507      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1508      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1509      REAL(KIND=jprb)               :: zhook_handle
1510
1511      CHARACTER(LEN=*), PARAMETER :: RoutineName='INTERP2'
1512
1513      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1514
1515      !!----------------------------------------------------------------------
1516
1517      f = a + x* ( b + x * ( c + d * x ) )
1518
1519      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1520   END FUNCTION interp2
1521
1522
1523   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1524      !!----------------------------------------------------------------------
1525      !!                 ***  ROUTINE interp1  ***
1526      !!
1527      !! ** Purpose :   Calculate the first order of deriavtive of
1528      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1529      !!
1530      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1531      !!
1532      !!----------------------------------------------------------------------
1533      USE yomhook, ONLY: lhook, dr_hook
1534      USE parkind1, ONLY: jprb, jpim
1535
1536      IMPLICIT NONE
1537      REAL(wp), INTENT(in) ::  x, a, b, c, d
1538      REAL(wp)             ::  f ! value from the interpolation
1539      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1540      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1541      REAL(KIND=jprb)               :: zhook_handle
1542
1543      CHARACTER(LEN=*), PARAMETER :: RoutineName='INTERP3'
1544
1545      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1546
1547      !!----------------------------------------------------------------------
1548
1549      f = b + x * ( 2._wp * c + 3._wp * d * x)
1550
1551      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1552   END FUNCTION interp3
1553
1554
1555   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1556      !!----------------------------------------------------------------------
1557      !!                 ***  ROUTINE interp1  ***
1558      !!
1559      !! ** Purpose :   1-d constrained cubic spline integration
1560      !!
1561      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1562      !!
1563      !!----------------------------------------------------------------------
1564      USE yomhook, ONLY: lhook, dr_hook
1565      USE parkind1, ONLY: jprb, jpim
1566
1567      IMPLICIT NONE
1568      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1569      REAL(wp)             ::  za1, za2, za3
1570      REAL(wp)             ::  f                   ! integration result
1571      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
1572      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
1573      REAL(KIND=jprb)               :: zhook_handle
1574
1575      CHARACTER(LEN=*), PARAMETER :: RoutineName='INTEG_SPLINE'
1576
1577      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
1578
1579      !!----------------------------------------------------------------------
1580
1581      za1 = 0.5_wp * b
1582      za2 = c / 3.0_wp
1583      za3 = 0.25_wp * d
1584
1585      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1586         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1587
1588      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
1589   END FUNCTION integ_spline
1590
1591   !!======================================================================
1592END MODULE dynhpg
1593
Note: See TracBrowser for help on using the repository browser.