New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 11738

Last change on this file since 11738 was 11738, checked in by marc, 5 years ago

The Dr Hook changes from my perl code.
File size: 9.8 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6   !! History :  OPA  ! 1990-09  (G. Madec)  Original code
7   !!            4.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            6.0  ! 1996-01  (G. Madec)  statement function for e3
9   !!            8.0  ! 1997-07  (G. Madec)  lbc calls
10   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2004-08  (C. Talandier) New trends organization
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
16   !!                   using an iso-level bilaplacian operator
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE ldfdyn_oce      ! ocean dynamics: lateral physics
21   !
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE wrk_nemo        ! Memory Allocation
25   USE timing          ! Timing
26
27   USE yomhook, ONLY: lhook, dr_hook
28   USE parkind1, ONLY: jprb, jpim
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   dyn_ldf_bilap   ! called by step.F90
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldfdyn_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dyn_ldf_bilap( kt )
47      !!----------------------------------------------------------------------
48      !!                     ***  ROUTINE dyn_ldf_bilap  ***
49      !!
50      !! ** Purpose :   Compute the before trend of the lateral momentum
51      !!      diffusion and add it to the general trend of momentum equation.
52      !!
53      !! ** Method  :   The before horizontal momentum diffusion trend is a
54      !!      bi-harmonic operator (bilaplacian type) which separates the
55      !!      divergent and rotational parts of the flow.
56      !!      Its horizontal components are computed as follow:
57      !!      laplacian:
58      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
59      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
60      !!      third derivative:
61      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
62      !!          zlu = ahmu * zlu
63      !!          zlv = ahmv * zlv
64      !!       * curl and divergence of the laplacian
65      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
66      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
67      !!      bilaplacian:
68      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
69      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
70      !!      If ln_sco=F and ln_zps=F, the vertical scale factors in the
71      !!      rotational part of the diffusion are simplified
72      !!      Add this before trend to the general trend (ua,va):
73      !!            (ua,va) = (ua,va) + (diffu,diffv)
74      !!
75      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
76      !!               mixing trend.
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
79      !
80      INTEGER  ::   ji, jj, jk                  ! dummy loop indices
81      REAL(wp) ::   zua, zva, zbt, ze2u, ze2v   ! temporary scalar
82      REAL(wp), POINTER, DIMENSION(:,:  ) :: zcu, zcv
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zuf, zut, zlu, zlv
84      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
85      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
86      REAL(KIND=jprb)               :: zhook_handle
87
88      CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_LDF_BILAP'
89
90      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
91
92      !!----------------------------------------------------------------------
93      !
94      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_bilap')
95      !
96      CALL wrk_alloc( jpi, jpj,      zcu, zcv           )
97      CALL wrk_alloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
98      !
99      IF( kt == nit000 .AND. lwp ) THEN
100         WRITE(numout,*)
101         WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
102         WRITE(numout,*) '~~~~~~~~~~~~~'
103      ENDIF
104
105!!bug gm this should be enough
106!!$      zuf(:,:,jpk) = 0.e0
107!!$      zut(:,:,jpk) = 0.e0
108!!$      zlu(:,:,jpk) = 0.e0
109!!$      zlv(:,:,jpk) = 0.e0
110      zuf(:,:,:) = 0._wp
111      zut(:,:,:) = 0._wp
112      zlu(:,:,:) = 0._wp
113      zlv(:,:,:) = 0._wp
114
115      !                                                ! ===============
116      DO jk = 1, jpkm1                                 ! Horizontal slab
117         !                                             ! ===============
118         ! Laplacian
119         ! ---------
120
121         IF( ln_sco .OR. ln_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
122            zuf(:,:,jk) = rotb(:,:,jk) * fse3f(:,:,jk)
123            DO jj = 2, jpjm1
124               DO ji = fs_2, fs_jpim1   ! vector opt.
125                  zlu(ji,jj,jk) = - ( zuf(ji,jj,jk) - zuf(ji,jj-1,jk) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
126                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
127   
128                  zlv(ji,jj,jk) = + ( zuf(ji,jj,jk) - zuf(ji-1,jj,jk) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
129                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
130               END DO
131            END DO
132         ELSE                            ! z-coordinate - full step
133            DO jj = 2, jpjm1
134               DO ji = fs_2, fs_jpim1   ! vector opt.
135                  zlu(ji,jj,jk) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
136                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
137   
138                  zlv(ji,jj,jk) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
139                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
140               END DO 
141            END DO 
142         ENDIF
143      END DO
144      CALL lbc_lnk( zlu, 'U', -1. )   ;   CALL lbc_lnk( zlv, 'V', -1. )   ! Boundary conditions
145
146         
147      DO jk = 1, jpkm1
148   
149         ! Third derivative
150         ! ----------------
151         
152         ! Multiply by the eddy viscosity coef. (at u- and v-points)
153         zlu(:,:,jk) = zlu(:,:,jk) * ( fsahmu(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
154
155         zlv(:,:,jk) = zlv(:,:,jk) * ( fsahmv(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
156         
157         ! Contravariant "laplacian"
158         zcu(:,:) = e1u(:,:) * zlu(:,:,jk)
159         zcv(:,:) = e2v(:,:) * zlv(:,:,jk)
160         
161         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
162         DO jj = 1, jpjm1
163            DO ji = 1, fs_jpim1   ! vector opt.
164               zuf(ji,jj,jk) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
165                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
166                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
167            END DO 
168         END DO 
169
170         ! Laplacian Horizontal fluxes
171         DO jj = 1, jpjm1
172            DO ji = 1, fs_jpim1   ! vector opt.
173               zlu(ji,jj,jk) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj,jk)
174               zlv(ji,jj,jk) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj,jk)
175            END DO
176         END DO
177
178         ! Laplacian divergence
179         DO jj = 2, jpj
180            DO ji = fs_2, jpi   ! vector opt.
181               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
182               zut(ji,jj,jk) = (  zlu(ji,jj,jk) - zlu(ji-1,jj  ,jk)   &
183                  &             + zlv(ji,jj,jk) - zlv(ji  ,jj-1,jk) ) / zbt
184            END DO
185         END DO
186      END DO
187
188
189      ! boundary conditions on the laplacian curl and div (zuf,zut)
190!!bug gm no need to do this 2 following lbc...
191      CALL lbc_lnk( zuf, 'F', 1. )
192      CALL lbc_lnk( zut, 'T', 1. )
193
194      DO jk = 1, jpkm1     
195   
196         ! Bilaplacian
197         ! -----------
198
199         DO jj = 2, jpjm1
200            DO ji = fs_2, fs_jpim1   ! vector opt.
201               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
202               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
203               ! horizontal biharmonic diffusive trends
204               zua = - ( zuf(ji  ,jj,jk) - zuf(ji,jj-1,jk) ) / ze2u   &
205                  &  + ( zut(ji+1,jj,jk) - zut(ji,jj  ,jk) ) / e1u(ji,jj)
206
207               zva = + ( zuf(ji,jj  ,jk) - zuf(ji-1,jj,jk) ) / ze2v   &
208                  &  + ( zut(ji,jj+1,jk) - zut(ji  ,jj,jk) ) / e2v(ji,jj)
209               ! add it to the general momentum trends
210               ua(ji,jj,jk) = ua(ji,jj,jk) + zua * ( fsahmu(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
211               va(ji,jj,jk) = va(ji,jj,jk) + zva * ( fsahmv(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
212            END DO
213         END DO
214
215         !                                             ! ===============
216      END DO                                           !   End of slab
217      !                                                ! ===============
218      CALL wrk_dealloc( jpi, jpj,      zcu, zcv           )
219      CALL wrk_dealloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
220      !
221      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_bilap')
222      !
223      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
224   END SUBROUTINE dyn_ldf_bilap
225
226   !!======================================================================
227END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.