| 1 | MODULE dynzdf_exp |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE dynzdf_exp *** |
|---|
| 4 | !! Ocean dynamics: vertical component(s) of the momentum mixing trend |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 8.0 ! 1997-05 (G. Madec) vertical component of isopycnal |
|---|
| 8 | !! NEMO 0.5 ! 2002-08 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! dyn_zdf_exp : update the momentum trend with the vertical diffu- |
|---|
| 14 | !! sion using an explicit time-stepping scheme. |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE oce ! ocean dynamics and tracers |
|---|
| 17 | USE dom_oce ! ocean space and time domain |
|---|
| 18 | USE phycst ! physical constants |
|---|
| 19 | USE zdf_oce ! ocean vertical physics |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE lib_mpp ! MPP library |
|---|
| 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | USE lib_mpp ! MPP library |
|---|
| 24 | USE wrk_nemo ! Memory Allocation |
|---|
| 25 | USE timing ! Timing |
|---|
| 26 | |
|---|
| 27 | |
|---|
| 28 | USE yomhook, ONLY: lhook, dr_hook |
|---|
| 29 | USE parkind1, ONLY: jprb, jpim |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC dyn_zdf_exp ! called by step.F90 |
|---|
| 35 | |
|---|
| 36 | !! * Substitutions |
|---|
| 37 | # include "domzgr_substitute.h90" |
|---|
| 38 | # include "vectopt_loop_substitute.h90" |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 41 | !! $Id$ |
|---|
| 42 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | CONTAINS |
|---|
| 45 | |
|---|
| 46 | SUBROUTINE dyn_zdf_exp( kt, p2dt ) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | !! *** ROUTINE dyn_zdf_exp *** |
|---|
| 49 | !! |
|---|
| 50 | !! ** Purpose : Compute the trend due to the vert. momentum diffusion |
|---|
| 51 | !! |
|---|
| 52 | !! ** Method : Explicit forward time stepping with a time splitting |
|---|
| 53 | !! technique. The vertical diffusion of momentum is given by: |
|---|
| 54 | !! diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) ) |
|---|
| 55 | !! Surface boundary conditions: wind stress input (averaged over kt-1/2 & kt+1/2) |
|---|
| 56 | !! Bottom boundary conditions : bottom stress (cf zdfbfr.F90) |
|---|
| 57 | !! Add this trend to the general trend ua : |
|---|
| 58 | !! ua = ua + dz( avmu dz(u) ) |
|---|
| 59 | !! |
|---|
| 60 | !! ** Action : - Update (ua,va) with the vertical diffusive trend |
|---|
| 61 | !!--------------------------------------------------------------------- |
|---|
| 62 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 63 | REAL(wp), INTENT(in) :: p2dt ! time-step |
|---|
| 64 | ! |
|---|
| 65 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
|---|
| 66 | REAL(wp) :: zlavmr, zua, zva ! local scalars |
|---|
| 67 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zwx, zwy, zwz, zww |
|---|
| 68 | INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0 |
|---|
| 69 | INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1 |
|---|
| 70 | REAL(KIND=jprb) :: zhook_handle |
|---|
| 71 | |
|---|
| 72 | CHARACTER(LEN=*), PARAMETER :: RoutineName='DYN_ZDF_EXP' |
|---|
| 73 | |
|---|
| 74 | IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle) |
|---|
| 75 | |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | ! |
|---|
| 78 | IF( nn_timing == 1 ) CALL timing_start('dyn_zdf_exp') |
|---|
| 79 | ! |
|---|
| 80 | CALL wrk_alloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) |
|---|
| 81 | ! |
|---|
| 82 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 83 | WRITE(numout,*) |
|---|
| 84 | WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion - explicit operator' |
|---|
| 85 | WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 86 | ENDIF |
|---|
| 87 | |
|---|
| 88 | zlavmr = 1. / REAL( nn_zdfexp ) |
|---|
| 89 | |
|---|
| 90 | |
|---|
| 91 | DO jj = 2, jpjm1 ! Surface boundary condition |
|---|
| 92 | DO ji = 2, jpim1 |
|---|
| 93 | zwy(ji,jj,1) = ( utau_b(ji,jj) + utau(ji,jj) ) * r1_rau0 |
|---|
| 94 | zww(ji,jj,1) = ( vtau_b(ji,jj) + vtau(ji,jj) ) * r1_rau0 |
|---|
| 95 | END DO |
|---|
| 96 | END DO |
|---|
| 97 | DO jk = 1, jpk ! Initialization of x, z and contingently trends array |
|---|
| 98 | DO jj = 2, jpjm1 |
|---|
| 99 | DO ji = 2, jpim1 |
|---|
| 100 | zwx(ji,jj,jk) = ub(ji,jj,jk) |
|---|
| 101 | zwz(ji,jj,jk) = vb(ji,jj,jk) |
|---|
| 102 | END DO |
|---|
| 103 | END DO |
|---|
| 104 | END DO |
|---|
| 105 | ! |
|---|
| 106 | DO jl = 1, nn_zdfexp ! Time splitting loop |
|---|
| 107 | ! |
|---|
| 108 | DO jk = 2, jpk ! First vertical derivative |
|---|
| 109 | DO jj = 2, jpjm1 |
|---|
| 110 | DO ji = 2, jpim1 |
|---|
| 111 | zwy(ji,jj,jk) = avmu(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) / fse3uw(ji,jj,jk) |
|---|
| 112 | zww(ji,jj,jk) = avmv(ji,jj,jk) * ( zwz(ji,jj,jk-1) - zwz(ji,jj,jk) ) / fse3vw(ji,jj,jk) |
|---|
| 113 | END DO |
|---|
| 114 | END DO |
|---|
| 115 | END DO |
|---|
| 116 | DO jk = 1, jpkm1 ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp |
|---|
| 117 | DO jj = 2, jpjm1 |
|---|
| 118 | DO ji = 2, jpim1 |
|---|
| 119 | zua = zlavmr * ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) / fse3u(ji,jj,jk) |
|---|
| 120 | zva = zlavmr * ( zww(ji,jj,jk) - zww(ji,jj,jk+1) ) / fse3v(ji,jj,jk) |
|---|
| 121 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
|---|
| 122 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
|---|
| 123 | ! |
|---|
| 124 | zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt * zua * umask(ji,jj,jk) |
|---|
| 125 | zwz(ji,jj,jk) = zwz(ji,jj,jk) + p2dt * zva * vmask(ji,jj,jk) |
|---|
| 126 | END DO |
|---|
| 127 | END DO |
|---|
| 128 | END DO |
|---|
| 129 | ! |
|---|
| 130 | END DO ! End of time splitting |
|---|
| 131 | ! |
|---|
| 132 | CALL wrk_dealloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) |
|---|
| 133 | ! |
|---|
| 134 | IF( nn_timing == 1 ) CALL timing_stop('dyn_zdf_exp') |
|---|
| 135 | ! |
|---|
| 136 | IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle) |
|---|
| 137 | END SUBROUTINE dyn_zdf_exp |
|---|
| 138 | |
|---|
| 139 | !!============================================================================== |
|---|
| 140 | END MODULE dynzdf_exp |
|---|
