New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_GO6_under_ice_relax_dr_hook/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 11738

Last change on this file since 11738 was 11738, checked in by marc, 4 years ago

The Dr Hook changes from my perl code.
File size: 14.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23   USE timing
24
25   USE yomhook, ONLY: lhook, dr_hook
26   USE parkind1, ONLY: jprb, jpim
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_ssm         ! routine called by step.F90
32   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
33
34   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
35                                                  ! from restart file
36   
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE sbc_ssm( kt )
47      !!---------------------------------------------------------------------
48      !!                     ***  ROUTINE sbc_oce  ***
49      !!                     
50      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
51      !!                condition computation
52      !!               
53      !! ** Method  :   compute mean surface velocity (2 components at U and
54      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
55      !!      the periode (kt - nn_fsbc) to kt
56      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
57      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
58      !!---------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt   ! ocean time step
60      !
61      INTEGER  ::   ji, jj               ! loop index
62      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
63      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
64      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
65      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
66      REAL(KIND=jprb)               :: zhook_handle
67
68      CHARACTER(LEN=*), PARAMETER :: RoutineName='SBC_SSM'
69
70      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
71
72      !!---------------------------------------------------------------------
73
74      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
75      DO jj = 1, jpj
76         DO ji = 1, jpi
77            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
78            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
79         END DO
80      END DO
81      !
82      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
83         !                                                ! ---------------------------------------- !
84         ssu_m(:,:) = ub(:,:,1)
85         ssv_m(:,:) = vb(:,:,1)
86         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
87         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
88         ENDIF
89         sss_m(:,:) = zts(:,:,jp_sal)
90         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
91         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
92         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
93         ENDIF
94         !
95         IF( lk_vvl )   e3t_m(:,:) = fse3t_n(:,:,1)
96         !
97         frq_m(:,:) = fraqsr_1lev(:,:)
98         !
99      ELSE
100         !                                                ! ----------------------------------------------- !
101         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
102            !                                             ! ----------------------------------------------- !
103            IF(lwp) WRITE(numout,*)
104            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
105            zcoef = REAL( nn_fsbc - 1, wp )
106            ssu_m(:,:) = zcoef * ub(:,:,1)
107            ssv_m(:,:) = zcoef * vb(:,:,1)
108            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
109            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
110            ENDIF
111            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
112            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
113            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
114            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
115            ENDIF
116            !
117            IF( lk_vvl )   e3t_m(:,:) = zcoef * fse3t_n(:,:,1)
118            !
119            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
120            !                                             ! ---------------------------------------- !
121         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
122            !                                             ! ---------------------------------------- !
123            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
124            ssv_m(:,:) = 0.e0
125            sst_m(:,:) = 0.e0
126            sss_m(:,:) = 0.e0
127            ssh_m(:,:) = 0.e0
128            IF( lk_vvl )   e3t_m(:,:) = 0.e0
129            frq_m(:,:) = 0.e0
130         ENDIF
131         !                                                ! ---------------------------------------- !
132         !                                                !        Cumulate at each time step        !
133         !                                                ! ---------------------------------------- !
134         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
135         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
136         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
137         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
138         ENDIF
139         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
140         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
141         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
142         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
143         ENDIF
144         !
145         IF( lk_vvl )   e3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
146         !
147         frq_m(:,:) =   frq_m(:,:) + fraqsr_1lev(:,:)
148
149         !                                                ! ---------------------------------------- !
150         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
151            !                                             ! ---------------------------------------- !
152            zcoef = 1. / REAL( nn_fsbc, wp )
153            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
154            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
155            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
156            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
157            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
158            IF( lk_vvl )   e3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
159            frq_m(:,:) = frq_m(:,:) * zcoef   ! mean fraction of solar net radiation absorbed in the 1st T level [-]
160            !
161         ENDIF
162         !                                                ! ---------------------------------------- !
163         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
164            !                                             ! ---------------------------------------- !
165            IF(lwp) WRITE(numout,*)
166            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
167               &                    'at it= ', kt,' date= ', ndastp
168            IF(lwp) WRITE(numout,*) '~~~~~~~'
169            zf_sbc = REAL( nn_fsbc, wp )
170            IF(nn_timing == 2)  CALL timing_start('iom_rstput')
171            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
172            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
173            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
174            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
175            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
176            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
177            IF( lk_vvl )   CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
178            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
179            IF(nn_timing == 2)  CALL timing_stop('iom_rstput') 
180            !
181         ENDIF
182         !
183      ENDIF
184      !
185      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
186         CALL iom_put( 'ssu_m', ssu_m )
187         CALL iom_put( 'ssv_m', ssv_m )
188         CALL iom_put( 'sst_m', sst_m )
189         CALL iom_put( 'sss_m', sss_m )
190         CALL iom_put( 'ssh_m', ssh_m )
191         IF( lk_vvl )   CALL iom_put( 'e3t_m', e3t_m )
192         CALL iom_put( 'frq_m', frq_m )
193      ENDIF
194      !
195      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
196   END SUBROUTINE sbc_ssm
197
198   SUBROUTINE sbc_ssm_init
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE sbc_ssm_init  ***
201      !!
202      !! ** Purpose :   Initialisation of the sbc data
203      !!
204      !! ** Action  : - read parameters
205      !!----------------------------------------------------------------------
206      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
207      INTEGER(KIND=jpim), PARAMETER :: zhook_in = 0
208      INTEGER(KIND=jpim), PARAMETER :: zhook_out = 1
209      REAL(KIND=jprb)               :: zhook_handle
210
211      CHARACTER(LEN=*), PARAMETER :: RoutineName='SBC_SSM_INIT'
212
213      IF (lhook) CALL dr_hook(RoutineName,zhook_in,zhook_handle)
214
215      !!----------------------------------------------------------------------
216
217      IF( nn_fsbc == 1 ) THEN
218         !
219         IF(lwp) WRITE(numout,*)
220         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
221         IF(lwp) WRITE(numout,*) '~~~~~~~ '
222         !
223      ELSE
224         !               
225         IF(lwp) WRITE(numout,*)
226         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
227         IF(lwp) WRITE(numout,*) '~~~~~~~ '
228         !
229         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
230            l_ssm_mean = .TRUE.
231            IF(nn_timing == 2)  CALL timing_start('iom_rstget')
232            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
233            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
234            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
235            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
236            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
237            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
238            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'e3t_m', e3t_m )
239            ! fraction of solar net radiation absorbed in 1st T level
240            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
241               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
242            ELSE
243               frq_m(:,:) = 1._wp   ! default definition
244            ENDIF
245            IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
246            !
247            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
248               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
249                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
250               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
251               ssu_m(:,:) = zcoef * ssu_m(:,:) 
252               ssv_m(:,:) = zcoef * ssv_m(:,:)
253               sst_m(:,:) = zcoef * sst_m(:,:)
254               sss_m(:,:) = zcoef * sss_m(:,:)
255               ssh_m(:,:) = zcoef * ssh_m(:,:)
256               IF( lk_vvl )   e3t_m(:,:) = zcoef * fse3t_m(:,:)
257               frq_m(:,:) = zcoef * frq_m(:,:)
258            ELSE
259               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
260            ENDIF
261         ENDIF
262      ENDIF
263      !
264      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
265         !
266         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
267         ssu_m(:,:) = ub(:,:,1)
268         ssv_m(:,:) = vb(:,:,1)
269         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
270         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
271         ENDIF
272         sss_m(:,:) = tsn(:,:,1,jp_sal)
273         ssh_m(:,:) = sshn(:,:)
274         IF( lk_vvl )   e3t_m(:,:) = fse3t_n(:,:,1)
275         frq_m(:,:) = 1._wp
276         !
277      ENDIF
278      !
279      IF (lhook) CALL dr_hook(RoutineName,zhook_out,zhook_handle)
280   END SUBROUTINE sbc_ssm_init
281
282   !!======================================================================
283END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.