source: branches/UKMO/dev_r5518_MEDUSA_optim_RH/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 7693

Last change on this file since 7693 was 7693, checked in by frrh, 4 years ago

Merge in branches/NERC/dev_r5518_NOC_MEDUSA_Stable from revision range
r 5711:7611 (i.e. the entire branch)

File size: 8.5 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp           ! passive tracers transport
16   USE trcsms           ! passive tracers sources and sinks
17   USE prtctl_trc       ! Print control for debbuging
18   USE trcdia
19   USE trcwri
20   USE trcrst
21   USE trdtrc_oce
22   USE trdmxl_trc
23   USE iom
24   USE in_out_manager
25   USE trcsub
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_stp    ! called by step
31
32   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
33   REAL(wp) :: rdt_sampl
34   INTEGER  :: nb_rec_per_days
35   INTEGER  :: isecfst, iseclast
36   LOGICAL  :: llnew
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE trc_stp( kt )
48      !!-------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_stp  ***
50      !!                     
51      !! ** Purpose : Time loop of opa for passive tracer
52      !!
53      !! ** Method  :
54      !!              Compute the passive tracers trends
55      !!              Update the passive tracers
56      !!-------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
58      INTEGER               ::  jk, jn  ! dummy loop indices
59      REAL(wp)              ::  ztrai
60      CHARACTER (len=25)    ::  charout 
61
62      !!-------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
65      !
66      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
67      !
68      IF( lk_vvl ) THEN                                                   ! update ocean volume due to ssh temporal evolution
69         DO jk = 1, jpk
70            cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
71         END DO
72         IF( lk_degrad )  cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)       ! degrad option: reduction by facvol
73         areatot         = glob_sum( cvol(:,:,:) )
74      ENDIF
75      !
76      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
77      !   
78      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
79      !   
80      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
81         !
82         IF(ln_ctl) THEN
83            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
84            CALL prt_ctl_trc_info(charout)
85         ENDIF
86         !
87         tra(:,:,:,:) = 0.e0
88         !
89# if defined key_debug_medusa
90         IF(lwp) WRITE(numout,*) ' MEDUSA trc_stp begins at kt =', kt
91         CALL flush(numout)
92# endif
93                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
94# if defined key_debug_medusa
95                                   CALL trc_rst_stat 
96                                   CALL trc_rst_tra_stat
97# endif
98         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
99         IF( lk_iomput ) THEN  ;   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
100         ELSE                  ;   CALL trc_dia      ( kt )       ! output of passive tracers with old I/O manager
101         ENDIF
102                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
103# if defined key_debug_medusa
104         IF(lwp) WRITE(numout,*) ' MEDUSA trc_stp SMS complete at kt =', kt
105         CALL trc_rst_stat
106         CALL trc_rst_tra_stat
107         CALL flush(numout)
108# endif
109                                   CALL trc_trp      ( kt )       ! transport of passive tracers
110# if defined key_debug_medusa
111         IF(lwp) WRITE(numout,*) ' MEDUSA trc_stp transport complete at kt =', kt
112         CALL trc_rst_stat
113         CALL trc_rst_tra_stat
114         CALL flush(numout)
115# endif
116         IF( kt == nittrc000 ) THEN
117            CALL iom_close( numrtr )       ! close input tracer restart file
118            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
119         ENDIF
120         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
121         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
122         !
123         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
124# if defined key_debug_medusa
125         IF(lwp) WRITE(numout,*) ' MEDUSA trc_stp ends at kt =', kt
126         CALL flush(numout)
127# endif
128         !
129      ENDIF
130      !
131      ztrai = 0._wp                                                   !  content of all tracers
132      DO jn = 1, jptra
133         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
134      END DO
135      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1369300  FORMAT(i10,e18.10)
137      !
138      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
139      !
140   END SUBROUTINE trc_stp
141
142   SUBROUTINE trc_mean_qsr( kt )
143      !!----------------------------------------------------------------------
144      !!             ***  ROUTINE trc_mean_qsr  ***
145      !!
146      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
147      !!               of diurnal cycle
148      !!
149      !! ** Method  : store in TOP the qsr every hour ( or every time-step the latter
150      !!              is greater than 1 hour ) and then, compute the  mean with
151      !!              a moving average over 24 hours.
152      !!              In coupled mode, the sampling is done at every coupling frequency
153      !!----------------------------------------------------------------------
154      INTEGER, INTENT(in) ::   kt
155      INTEGER  :: jn
156
157      IF( kt == nittrc000 ) THEN
158         IF( ln_cpl )  THEN 
159            rdt_sampl = 86400. / ncpl_qsr_freq
160            nb_rec_per_days = ncpl_qsr_freq
161         ELSE 
162            rdt_sampl = MAX( 3600., rdt * nn_dttrc )
163            nb_rec_per_days = INT( 86400 / rdt_sampl )
164         ENDIF
165         !
166         IF( lwp ) THEN
167            WRITE(numout,*) 
168            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_days
169            WRITE(numout,*) 
170         ENDIF
171         !
172         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_days ) )
173         DO jn = 1, nb_rec_per_days
174            qsr_arr(:,:,jn) = qsr(:,:)
175         ENDDO
176         qsr_mean(:,:) = qsr(:,:)
177         !
178         isecfst  = nsec_year + nsec1jan000   !   number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
179         iseclast = isecfst
180         !
181      ENDIF
182      !
183      iseclast = nsec_year + nsec1jan000
184      llnew   = ( iseclast - isecfst )  > INT( rdt_sampl )   !   new shortwave to store
185      IF( kt /= nittrc000 .AND. llnew ) THEN
186          IF( lwp ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', kt, &
187             &                      ' time = ', (iseclast+rdt*nn_dttrc/2.)/3600.,'hours '
188          isecfst = iseclast
189          DO jn = 1, nb_rec_per_days - 1
190             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
191          ENDDO
192          qsr_arr (:,:,nb_rec_per_days) = qsr(:,:)
193          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_days
194      ENDIF
195      !
196   END SUBROUTINE trc_mean_qsr
197
198#else
199   !!----------------------------------------------------------------------
200   !!   Default key                                     NO passive tracers
201   !!----------------------------------------------------------------------
202CONTAINS
203   SUBROUTINE trc_stp( kt )        ! Empty routine
204      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
205   END SUBROUTINE trc_stp
206#endif
207
208   !!======================================================================
209END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.