New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/UKMO/dev_r5518_medusa_fix_restart/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_medusa_fix_restart/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 7865

Last change on this file since 7865 was 7865, checked in by marc, 7 years ago

Adding extra arguments to ZPS_HDE
File size: 32.9 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE zps_hde( kt, kjpt, pta, fse3w, fsdept, pgtu, pgtv,   &
43      &                          prd, pgru, pgrv    )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE zps_hde  ***
46      !!                   
47      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
48      !!      at u- and v-points with a linear interpolation for z-coordinate
49      !!      with partial steps.
50      !!
51      !! ** Method  :   In z-coord with partial steps, scale factors on last
52      !!      levels are different for each grid point, so that T, S and rd
53      !!      points are not at the same depth as in z-coord. To have horizontal
54      !!      gradients again, we interpolate T and S at the good depth :
55      !!      Linear interpolation of T, S   
56      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
57      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
58      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
59      !!         This formulation computes the two cases:
60      !!                 CASE 1                   CASE 2 
61      !!         k-1  ___ ___________   k-1   ___ ___________
62      !!                    Ti  T~                  T~  Ti+1
63      !!                  _____                        _____
64      !!         k        |   |Ti+1     k           Ti |   |
65      !!                  |   |____                ____|   |
66      !!              ___ |   |   |           ___  |   |   |
67      !!                 
68      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
69      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
70      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
71      !!          or
72      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
73      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
74      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
75      !!          Idem for di(s) and dj(s)         
76      !!
77      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
78      !!      depth zh from interpolated T and S for the different formulations
79      !!      of the equation of state (eos).
80      !!      Gradient formulation for rho :
81      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
82      !!
83      !! ** Action  : compute for top interfaces
84      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
85      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
86      !!----------------------------------------------------------------------
87      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
88      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
89      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
90      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   )           ::  fse3w       ! Vertical scale factor on w pts
91      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   )           ::  fsdept      !  Depth now at t pts
92      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
93      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
94      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
95      !
96      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
97      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
98      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
99      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
100      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
101      !!----------------------------------------------------------------------
102      !
103      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
104      !
105      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
106      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
107      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
108      !
109      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
110         !
111         DO jj = 1, jpjm1
112            DO ji = 1, jpim1
113               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
114               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
115               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
116               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
117               !
118               ! i- direction
119               IF( ze3wu >= 0._wp ) THEN      ! case 1
120                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
121                  ! interpolated values of tracers
122                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
123                  ! gradient of  tracers
124                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
125               ELSE                           ! case 2
126                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
127                  ! interpolated values of tracers
128                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
129                  ! gradient of tracers
130                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
131               ENDIF
132               !
133               ! j- direction
134               IF( ze3wv >= 0._wp ) THEN      ! case 1
135                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
136                  ! interpolated values of tracers
137                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
138                  ! gradient of tracers
139                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
140               ELSE                           ! case 2
141                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
142                  ! interpolated values of tracers
143                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
144                  ! gradient of tracers
145                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
146               ENDIF
147            END DO
148         END DO
149         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
150         !
151      END DO
152
153      ! horizontal derivative of density anomalies (rd)
154      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
155         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
156         DO jj = 1, jpjm1
157            DO ji = 1, jpim1
158               iku = mbku(ji,jj)
159               ikv = mbkv(ji,jj)
160               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
161               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
162               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
163               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
164               ENDIF
165               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
166               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
167               ENDIF
168            END DO
169         END DO
170
171         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
172         ! step and store it in  zri, zrj for each  case
173         CALL eos( zti, zhi, zri ) 
174         CALL eos( ztj, zhj, zrj )
175
176         ! Gradient of density at the last level
177         DO jj = 1, jpjm1
178            DO ji = 1, jpim1
179               iku = mbku(ji,jj)
180               ikv = mbkv(ji,jj)
181               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
182               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
183               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
184               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
185               ENDIF
186               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
187               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
188               ENDIF
189            END DO
190         END DO
191         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
192         !
193      END IF
194      !
195      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
196      !
197   END SUBROUTINE zps_hde
198   !
199   SUBROUTINE zps_hde_isf( kt, kjpt, pta, fse3w, fsdept, fsde3w, pgtu, pgtv,  &
200      &                          prd, pgru, pgrv, pmru, pmrv, pgzu, pgzv, pge3ru, pge3rv,  &
201      &                   pgtui, pgtvi, pgrui, pgrvi, pmrui, pmrvi, pgzui, pgzvi, pge3rui, pge3rvi )
202      !!----------------------------------------------------------------------
203      !!                     ***  ROUTINE zps_hde  ***
204      !!                   
205      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
206      !!      at u- and v-points with a linear interpolation for z-coordinate
207      !!      with partial steps.
208      !!
209      !! ** Method  :   In z-coord with partial steps, scale factors on last
210      !!      levels are different for each grid point, so that T, S and rd
211      !!      points are not at the same depth as in z-coord. To have horizontal
212      !!      gradients again, we interpolate T and S at the good depth :
213      !!      Linear interpolation of T, S   
214      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
215      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
216      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
217      !!         This formulation computes the two cases:
218      !!                 CASE 1                   CASE 2 
219      !!         k-1  ___ ___________   k-1   ___ ___________
220      !!                    Ti  T~                  T~  Ti+1
221      !!                  _____                        _____
222      !!         k        |   |Ti+1     k           Ti |   |
223      !!                  |   |____                ____|   |
224      !!              ___ |   |   |           ___  |   |   |
225      !!                 
226      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
227      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
228      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
229      !!          or
230      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
231      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
232      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
233      !!          Idem for di(s) and dj(s)         
234      !!
235      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
236      !!      depth zh from interpolated T and S for the different formulations
237      !!      of the equation of state (eos).
238      !!      Gradient formulation for rho :
239      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
240      !!
241      !! ** Action  : compute for top and bottom interfaces
242      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
243      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
244      !!              - pmru, pmrv, pmrui, pmrvi: horizontal sum of rho at u- & v- point (used in dynhpg with vvl)
245      !!              - pgzu, pgzv, pgzui, pgzvi: horizontal gradient of z at u- and v- point (used in dynhpg with vvl)
246      !!              - pge3ru, pge3rv, pge3rui, pge3rvi: horizontal gradient of rho weighted by local e3w at u- & v-points
247      !!----------------------------------------------------------------------
248      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
249      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
250      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
251      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   )           ::  fse3w       ! Vertical scale factor on w pts
252      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   )           ::  fsdept      !  Depth now at t pts
253      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   )           ::  fsde3w      ! Now depth of t pts (sum of e3w) (m)
254      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
255      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi  ! hor. grad. of stra at u- & v-pts (ISF)
256      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
257      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv      ! hor. grad of prd at u- & v-pts (bottom)
258      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pmru, pmrv      ! hor. sum  of prd at u- & v-pts (bottom)
259      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgzu, pgzv      ! hor. grad of z   at u- & v-pts (bottom)
260      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pge3ru, pge3rv  ! hor. grad of prd weighted by local e3w at u- & v-pts (bottom)
261      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi      ! hor. grad of prd at u- & v-pts (top)
262      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pmrui, pmrvi      ! hor. sum  of prd at u- & v-pts (top)
263      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgzui, pgzvi      ! hor. grad of z   at u- & v-pts (top)
264      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pge3rui, pge3rvi  ! hor. grad of prd weighted by local e3w at u- & v-pts (top)
265      !
266      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
267      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
268      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv, zdzwu, zdzwv, zdzwuip1, zdzwvjp1  ! temporary scalars
269      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
270      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
271      !!----------------------------------------------------------------------
272      !
273      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
274      !
275      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
276      pgtui(:,:,:)=0.0_wp ; pgtvi(:,:,:)=0.0_wp ;
277      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
278      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
279      !
280      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
281         !
282         DO jj = 1, jpjm1
283            DO ji = 1, jpim1
284               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
285               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
286               ! (ISF) case partial step top and bottom in adjacent cell in vertical
287               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
288               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
289               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
290               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
291               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
292               !
293               ! i- direction
294               IF( ze3wu >= 0._wp ) THEN      ! case 1
295                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
296                  ! interpolated values of tracers
297                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
298                  ! gradient of  tracers
299                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
300               ELSE                           ! case 2
301                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
302                  ! interpolated values of tracers
303                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
304                  ! gradient of tracers
305                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
306               ENDIF
307               !
308               ! j- direction
309               IF( ze3wv >= 0._wp ) THEN      ! case 1
310                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
311                  ! interpolated values of tracers
312                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
313                  ! gradient of tracers
314                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
315               ELSE                           ! case 2
316                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
317                  ! interpolated values of tracers
318                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
319                  ! gradient of tracers
320                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
321               ENDIF
322            END DO
323         END DO
324         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
325         !
326      END DO
327
328      ! horizontal derivative of density anomalies (rd)
329      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
330         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
331         pgzu(:,:)=0.0_wp   ; pgzv(:,:)=0.0_wp ;
332         pmru(:,:)=0.0_wp   ; pmru(:,:)=0.0_wp ;
333         pge3ru(:,:)=0.0_wp ; pge3rv(:,:)=0.0_wp ;
334         DO jj = 1, jpjm1
335            DO ji = 1, jpim1
336               iku = mbku(ji,jj)
337               ikv = mbkv(ji,jj)
338               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
339               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
340
341               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) - ze3wu     ! i-direction: case 1
342               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) + ze3wu    ! -     -      case 2
343               ENDIF
344               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) - ze3wv    ! j-direction: case 1
345               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) + ze3wv    ! -     -      case 2
346               ENDIF
347            END DO
348         END DO
349         
350         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
351         ! step and store it in  zri, zrj for each  case
352         CALL eos( zti, zhi, zri ) 
353         CALL eos( ztj, zhj, zrj )
354
355         ! Gradient of density at the last level
356         DO jj = 1, jpjm1
357            DO ji = 1, jpim1
358               iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
359               ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 )    ! last and before last ocean level at u- & v-points
360               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
361               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
362               IF( ze3wu >= 0._wp ) THEN
363                  pgzu(ji,jj) = (fsde3w(ji+1,jj,iku) - ze3wu) - fsde3w(ji,jj,iku)
364                  pgru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
365                  pmru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) + prd(ji,jj,iku) )   ! i: 1
366                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
367                                * ( (fse3w(ji+1,jj,iku) - ze3wu )* ( zri(ji  ,jj    ) + prd(ji+1,jj,ikum1) + 2._wp) &
368                                   - fse3w(ji  ,jj,iku)          * ( prd(ji  ,jj,iku) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
369               ELSE 
370                  pgzu(ji,jj) = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) + ze3wu)
371                  pgru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
372                  pmru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) + zri(ji,jj) )   ! i: 2
373                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
374                                * (  fse3w(ji+1,jj,iku)          * ( prd(ji+1,jj,iku) + prd(ji+1,jj,ikum1) + 2._wp) &
375                                   -(fse3w(ji  ,jj,iku) + ze3wu) * ( zri(ji  ,jj    ) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
376               ENDIF
377               IF( ze3wv >= 0._wp ) THEN
378                  pgzv(ji,jj) = (fsde3w(ji,jj+1,ikv) - ze3wv) - fsde3w(ji,jj,ikv) 
379                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
380                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )   ! j: 1
381                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
382                                * ( (fse3w(ji,jj+1,ikv) - ze3wv )* ( zrj(ji,jj      ) + prd(ji,jj+1,ikvm1) + 2._wp) &
383                                   - fse3w(ji,jj  ,ikv)          * ( prd(ji,jj  ,ikv) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
384               ELSE
385                  pgzv(ji,jj) = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) + ze3wv)
386                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
387                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )   ! j: 2
388                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
389                                * (  fse3w(ji,jj+1,ikv)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikvm1) + 2._wp) &
390                                   -(fse3w(ji,jj  ,ikv) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
391               ENDIF
392            END DO
393         END DO
394         CALL lbc_lnk( pgru   , 'U', -1. )   ;   CALL lbc_lnk( pgrv   , 'V', -1. )   ! Lateral boundary conditions
395         CALL lbc_lnk( pmru   , 'U',  1. )   ;   CALL lbc_lnk( pmrv   , 'V',  1. )   ! Lateral boundary conditions
396         CALL lbc_lnk( pgzu   , 'U', -1. )   ;   CALL lbc_lnk( pgzv   , 'V', -1. )   ! Lateral boundary conditions
397         CALL lbc_lnk( pge3ru , 'U', -1. )   ;   CALL lbc_lnk( pge3rv , 'V', -1. )   ! Lateral boundary conditions
398         !
399      END IF
400         ! (ISH)  compute grui and gruvi
401      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
402         DO jj = 1, jpjm1
403            DO ji = 1, jpim1
404               iku = miku(ji,jj)   ;  ikup1 = miku(ji,jj) + 1
405               ikv = mikv(ji,jj)   ;  ikvp1 = mikv(ji,jj) + 1
406               !
407               ! (ISF) case partial step top and bottom in adjacent cell in vertical
408               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
409               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
410               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
411               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku)) 
412               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
413               ! i- direction
414               IF( ze3wu >= 0._wp ) THEN      ! case 1
415                  zmaxu = ze3wu / fse3w(ji+1,jj,iku+1)
416                  ! interpolated values of tracers
417                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,iku+1,jn) - pta(ji+1,jj,iku,jn) )
418                  ! gradient of tracers
419                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
420               ELSE                           ! case 2
421                  zmaxu = - ze3wu / fse3w(ji,jj,iku+1)
422                  ! interpolated values of tracers
423                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,iku+1,jn) - pta(ji,jj,iku,jn) )
424                  ! gradient of  tracers
425                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
426               ENDIF
427               !
428               ! j- direction
429               IF( ze3wv >= 0._wp ) THEN      ! case 1
430                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv+1)
431                  ! interpolated values of tracers
432                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikv+1,jn) - pta(ji,jj+1,ikv,jn) )
433                  ! gradient of tracers
434                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
435               ELSE                           ! case 2
436                  zmaxv =  - ze3wv / fse3w(ji,jj,ikv+1)
437                  ! interpolated values of tracers
438                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikv+1,jn) - pta(ji,jj,ikv,jn) )
439                  ! gradient of tracers
440                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
441               ENDIF
442            END DO!!
443         END DO!!
444         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
445         !
446      END DO
447
448      ! horizontal derivative of density anomalies (rd)
449      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
450         pgrui(:,:)  =0.0_wp ; pgrvi(:,:)  =0.0_wp ;
451         pgzui(:,:)  =0.0_wp ; pgzvi(:,:)  =0.0_wp ;
452         pmrui(:,:)  =0.0_wp ; pmrui(:,:)  =0.0_wp ;
453         pge3rui(:,:)=0.0_wp ; pge3rvi(:,:)=0.0_wp ;
454
455         DO jj = 1, jpjm1
456            DO ji = 1, jpim1
457               iku = miku(ji,jj)
458               ikv = mikv(ji,jj)
459               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
460               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
461
462               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) + ze3wu    ! i-direction: case 1
463               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) - ze3wu    ! -     -      case 2
464               ENDIF
465               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) + ze3wv    ! j-direction: case 1
466               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) - ze3wv    ! -     -      case 2
467               ENDIF
468            END DO
469         END DO
470
471         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
472         ! step and store it in  zri, zrj for each  case
473         CALL eos( zti, zhi, zri ) 
474         CALL eos( ztj, zhj, zrj )
475
476         ! Gradient of density at the last level
477         DO jj = 1, jpjm1
478            DO ji = 1, jpim1
479               iku = miku(ji,jj) ; ikup1 = miku(ji,jj) + 1
480               ikv = mikv(ji,jj) ; ikvp1 = mikv(ji,jj) + 1
481               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
482               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
483               IF( ze3wu >= 0._wp ) THEN
484                 pgzui  (ji,jj) = (fsde3w(ji+1,jj,iku) + ze3wu) - fsde3w(ji,jj,iku)
485                 pgrui  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) - prd(ji,jj,iku) )          ! i: 1
486                 pmrui  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) + prd(ji,jj,iku) )          ! i: 1
487                 pge3rui(ji,jj) = umask(ji,jj,iku+1)                                                                  &
488                                * ( (fse3w(ji+1,jj,iku+1) - ze3wu) * (zri(ji,jj    ) + prd(ji+1,jj,iku+1) + 2._wp)   &
489                                   - fse3w(ji  ,jj,iku+1)          * (prd(ji,jj,iku) + prd(ji  ,jj,iku+1) + 2._wp)   ) ! i: 1
490               ELSE
491                 pgzui  (ji,jj) = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) - ze3wu)
492                 pgrui  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) - zri(ji,jj) )      ! i: 2
493                 pmrui  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) + zri(ji,jj) )      ! i: 2
494                 pge3rui(ji,jj) = umask(ji,jj,iku+1)                                                                   &
495                                * (  fse3w(ji+1,jj,iku+1)          * (prd(ji+1,jj,iku) + prd(ji+1,jj,iku+1) + 2._wp)  &
496                                   -(fse3w(ji  ,jj,iku+1) + ze3wu) * (zri(ji,jj      ) + prd(ji  ,jj,iku+1) + 2._wp)  )     ! i: 2
497               ENDIF
498               IF( ze3wv >= 0._wp ) THEN
499                 pgzvi  (ji,jj) = (fsde3w(ji,jj+1,ikv) + ze3wv) - fsde3w(ji,jj,ikv) 
500                 pgrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )        ! j: 1
501                 pmrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )        ! j: 1
502                 pge3rvi(ji,jj) = vmask(ji,jj,ikv+1)                                                                  & 
503                                * ( (fse3w(ji,jj+1,ikv+1) - ze3wv) * ( zrj(ji,jj    ) + prd(ji,jj+1,ikv+1) + 2._wp)  &
504                                   - fse3w(ji,jj  ,ikv+1)          * ( prd(ji,jj,ikv) + prd(ji,jj  ,ikv+1) + 2._wp)  ) ! j: 1
505                                  ! + 2 due to the formulation in density and not in anomalie in hpg sco
506               ELSE
507                 pgzvi  (ji,jj) = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) - ze3wv)
508                 pgrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )     ! j: 2
509                 pmrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )     ! j: 2
510                 pge3rvi(ji,jj) = vmask(ji,jj,ikv+1)                                                                   &
511                                * (  fse3w(ji,jj+1,ikv+1)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikv+1) + 2._wp) &
512                                   -(fse3w(ji,jj  ,ikv+1) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikv+1) + 2._wp) )  ! j: 2
513               ENDIF
514            END DO
515         END DO
516         CALL lbc_lnk( pgrui   , 'U', -1. )   ;   CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
517         CALL lbc_lnk( pmrui   , 'U',  1. )   ;   CALL lbc_lnk( pmrvi   , 'V',  1. )   ! Lateral boundary conditions
518         CALL lbc_lnk( pgzui   , 'U', -1. )   ;   CALL lbc_lnk( pgzvi   , 'V', -1. )   ! Lateral boundary conditions
519         CALL lbc_lnk( pge3rui , 'U', -1. )   ;   CALL lbc_lnk( pge3rvi , 'V', -1. )   ! Lateral boundary conditions
520         !
521      END IF 
522      !
523      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde_isf')
524      !
525   END SUBROUTINE zps_hde_isf
526   !!======================================================================
527END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.