Context Navigation

← Previous Revision
Next Revision →
Blame
Revision Log

cpl_oasis3.F90

Last change on this file was 9348, checked in by dancopsey, 6 years ago
Moved USE cpl_rnf_1d as it conflicted with GO6 package branch.
File size: 26.1 KB

Line
1	MODULE cpl_oasis3
2	!!======================================================================
3	!! * MODULE cpl_oasis *
4	!! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5	!!=====================================================================
6	!! History :
7	!! 9.0 ! 04-06 (R. Redler, NEC Laboratories Europe, Germany) Original code
8	!! " " ! 04-11 (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
9	!! " " ! 04-11 (V. Gayler, MPI M&D) Grid writing
10	!! " " ! 05-08 (R. Redler, W. Park) frld initialization, paral(2) revision
11	!! " " ! 05-09 (R. Redler) extended to allow for communication over root only
12	!! " " ! 06-01 (W. Park) modification of physical part
13	!! " " ! 06-02 (R. Redler, W. Park) buffer array fix for root exchange
14	!! 3.4 ! 11-11 (C. Harris) Changes to allow mutiple category fields
15	!!----------------------------------------------------------------------
16	!!----------------------------------------------------------------------
17	!! 'key_oasis3' coupled Ocean/Atmosphere via OASIS3-MCT
18	!! 'key_oa3mct_v3' to be added for OASIS3-MCT version 3
19	!!----------------------------------------------------------------------
20	!! cpl_init : initialization of coupled mode communication
21	!! cpl_define : definition of grid and fields
22	!! cpl_snd : snd out fields in coupled mode
23	!! cpl_rcv : receive fields in coupled mode
24	!! cpl_finalize : finalize the coupled mode communication
25	!!----------------------------------------------------------------------
26	#if defined key_oasis3
27	USE mod_oasis ! OASIS3-MCT module
28	#endif
29	USE par_oce ! ocean parameters
30	USE cpl_rnf_1d, ONLY: nn_cpl_river, runoff_id ! Variables used in 1D river outflow
31	USE dom_oce ! ocean space and time domain
32	USE in_out_manager ! I/O manager
33	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
34
35	IMPLICIT NONE
36	PRIVATE
37
38	PUBLIC cpl_init
39	PUBLIC cpl_define
40	PUBLIC cpl_snd
41	PUBLIC cpl_rcv
42	PUBLIC cpl_freq
43	PUBLIC cpl_finalize
44
45	INTEGER, PUBLIC :: OASIS_Rcv = 1 !: return code if received field
46	INTEGER, PUBLIC :: OASIS_idle = 0 !: return code if nothing done by oasis
47	INTEGER :: ncomp_id ! id returned by oasis_init_comp
48	INTEGER :: nerror ! return error code
49	#if ! defined key_oasis3
50	! OASIS Variables not used. defined only for compilation purpose
51	INTEGER :: OASIS_Out = -1
52	INTEGER :: OASIS_REAL = -1
53	INTEGER :: OASIS_Ok = -1
54	INTEGER :: OASIS_In = -1
55	INTEGER :: OASIS_Sent = -1
56	INTEGER :: OASIS_SentOut = -1
57	INTEGER :: OASIS_ToRest = -1
58	INTEGER :: OASIS_ToRestOut = -1
59	INTEGER :: OASIS_Recvd = -1
60	INTEGER :: OASIS_RecvOut = -1
61	INTEGER :: OASIS_FromRest = -1
62	INTEGER :: OASIS_FromRestOut = -1
63	#endif
64
65	INTEGER :: nrcv ! total number of fields received
66	INTEGER :: nsnd ! total number of fields sent
67	INTEGER :: ncplmodel ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
68	INTEGER, PUBLIC, PARAMETER :: nmaxfld=50 ! Maximum number of coupling fields
69	INTEGER, PUBLIC, PARAMETER :: nmaxcat=5 ! Maximum number of coupling fields
70	INTEGER, PUBLIC, PARAMETER :: nmaxcpl=5 ! Maximum number of coupling fields
71
72
73
74	TYPE, PUBLIC :: FLD_CPL !: Type for coupling field information
75	LOGICAL :: laction ! To be coupled or not
76	CHARACTER(len = 8) :: clname ! Name of the coupling field
77	CHARACTER(len = 1) :: clgrid ! Grid type
78	REAL(wp) :: nsgn ! Control of the sign change
79	INTEGER, DIMENSION(nmaxcat,nmaxcpl) :: nid ! Id of the field (no more than 9 categories and 9 extrena models)
80	INTEGER :: nct ! Number of categories in field
81	INTEGER :: ncplmodel ! Maximum number of models to/from which this variable may be sent/received
82	END TYPE FLD_CPL
83
84	TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC :: srcv, ssnd !: Coupling fields
85
86	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: exfld ! Temporary buffer for receiving
87
88	!!----------------------------------------------------------------------
89	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
90	!! $Id$
91	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
92	!!----------------------------------------------------------------------
93	CONTAINS
94
95	SUBROUTINE cpl_init( cd_modname, kl_comm )
96	!!-------------------------------------------------------------------
97	!! * ROUTINE cpl_init *
98	!!
99	!! ** Purpose : Initialize coupled mode communication for ocean
100	!! exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
101	!!
102	!! ** Method : OASIS3 MPI communication
103	!!--------------------------------------------------------------------
104	CHARACTER(len = *), INTENT(in) :: cd_modname ! model name as set in namcouple file
105	INTEGER , INTENT(out) :: kl_comm ! local communicator of the model
106	!!--------------------------------------------------------------------
107
108	! WARNING: No write in numout in this routine
109	!============================================
110
111	!------------------------------------------------------------------
112	! 1st Initialize the OASIS system for the application
113	!------------------------------------------------------------------
114	CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
115	IF ( nerror /= OASIS_Ok ) &
116	CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
117
118	!------------------------------------------------------------------
119	! 3rd Get an MPI communicator for OPA local communication
120	!------------------------------------------------------------------
121
122	CALL oasis_get_localcomm ( kl_comm, nerror )
123	IF ( nerror /= OASIS_Ok ) &
124	CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
125	!
126	END SUBROUTINE cpl_init
127
128
129	SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
130	!!-------------------------------------------------------------------
131	!! * ROUTINE cpl_define *
132	!!
133	!! ** Purpose : Define grid and field information for ocean
134	!! exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
135	!!
136	!! ** Method : OASIS3 MPI communication
137	!!--------------------------------------------------------------------
138	INTEGER, INTENT(in) :: krcv, ksnd ! Number of received and sent coupling fields
139	INTEGER, INTENT(in) :: kcplmodel ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
140	!
141	INTEGER :: id_part ! Partition for all 2D model fields to be coupled
142	INTEGER :: id_part_rnf_1d ! Partition for river runoff using 1D array
143	INTEGER :: paral(5) ! OASIS3 box partition
144	INTEGER :: ishape(2,2) ! shape of arrays passed to PSMILe
145	INTEGER :: ji,jc,jm ! local loop indicees
146	CHARACTER(LEN=64) :: zclname
147	CHARACTER(LEN=2) :: cli2
148	!!--------------------------------------------------------------------
149
150	IF(lwp) WRITE(numout,*)
151	IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
152	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
153	IF(lwp) WRITE(numout,*)
154
155	ncplmodel = kcplmodel
156	IF( kcplmodel > nmaxcpl ) THEN
157	CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl') ; RETURN
158	ENDIF
159
160	nrcv = krcv
161	IF( nrcv > nmaxfld ) THEN
162	CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld') ; RETURN
163	ENDIF
164
165	nsnd = ksnd
166	IF( nsnd > nmaxfld ) THEN
167	CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld') ; RETURN
168	ENDIF
169
170	!
171	! ... Define the shape for the area that excludes the halo
172	! For serial configuration (key_mpp_mpi not being active)
173	! nl* is set to the global values 1 and jp*glo.
174	!
175	ishape(:,1) = (/ 1, nlei-nldi+1 /)
176	ishape(:,2) = (/ 1, nlej-nldj+1 /)
177	!
178	! ... Allocate memory for data exchange
179	!
180	ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
181	IF( nerror > 0 ) THEN
182	CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld') ; RETURN
183	ENDIF
184	!
185	! -----------------------------------------------------------------
186	! ... Define the partition
187	! -----------------------------------------------------------------
188
189	paral(1) = 2 ! box partitioning
190	paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1) ! NEMO lower left corner global offset
191	paral(3) = nlei-nldi+1 ! local extent in i
192	paral(4) = nlej-nldj+1 ! local extent in j
193	paral(5) = jpiglo ! global extent in x
194
195	IF( ln_ctl ) THEN
196	WRITE(numout,*) ' multiexchg: paral (1:5)', paral
197	WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
198	WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
199	WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
200	ENDIF
201
202	CALL oasis_def_partition ( id_part, paral, nerror )
203	!
204	! Another partition is needed for river runoff when using 1D array
205
206	paral(1) = 0 ! serial partitioning
207	paral(2) = 0
208	paral(3) = nn_cpl_river ! size of array to couple
209	paral(4) = 0
210	paral(5) = 0
211
212	CALL oasis_def_partition ( id_part_rnf_1d, paral, nerror, nn_cpl_river )
213
214	! ... Announce send variables.
215	!
216	ssnd(:)%ncplmodel = kcplmodel
217	!
218	DO ji = 1, ksnd
219	IF ( ssnd(ji)%laction ) THEN
220
221	IF( ssnd(ji)%nct > nmaxcat ) THEN
222	CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '// &
223	& TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
224	RETURN
225	ENDIF
226
227	DO jc = 1, ssnd(ji)%nct
228	DO jm = 1, kcplmodel
229
230	IF ( ssnd(ji)%nct .GT. 1 ) THEN
231	WRITE(cli2,'(i2.2)') jc
232	zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
233	ELSE
234	zclname = ssnd(ji)%clname
235	ENDIF
236	IF ( kcplmodel > 1 ) THEN
237	WRITE(cli2,'(i2.2)') jm
238	zclname = 'model'//cli2//'_'//TRIM(zclname)
239	ENDIF
240	#if defined key_agrif
241	IF( agrif_fixed() /= 0 ) THEN
242	zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
243	END IF
244	#endif
245	IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
246	CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part , (/ 2, 0 /), &
247	& OASIS_Out , ishape , OASIS_REAL, nerror )
248	IF ( nerror /= OASIS_Ok ) THEN
249	WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
250	CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
251	ENDIF
252	IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
253	IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
254	END DO
255	END DO
256	ENDIF
257	END DO
258	!
259	! ... Announce received variables.
260	!
261	srcv(:)%ncplmodel = kcplmodel
262	!
263	DO ji = 1, krcv
264	IF ( srcv(ji)%laction ) THEN
265
266	IF( srcv(ji)%nct > nmaxcat ) THEN
267	CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '// &
268	& TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
269	RETURN
270	ENDIF
271
272	DO jc = 1, srcv(ji)%nct
273	DO jm = 1, kcplmodel
274
275	IF ( srcv(ji)%nct .GT. 1 ) THEN
276	WRITE(cli2,'(i2.2)') jc
277	zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
278	ELSE
279	zclname = srcv(ji)%clname
280	ENDIF
281	IF ( kcplmodel > 1 ) THEN
282	WRITE(cli2,'(i2.2)') jm
283	zclname = 'model'//cli2//'_'//TRIM(zclname)
284	ENDIF
285	#if defined key_agrif
286	IF( agrif_fixed() /= 0 ) THEN
287	zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
288	END IF
289	#endif
290	IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
291	CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part , (/ 2, 0 /), &
292	& OASIS_In , ishape , OASIS_REAL, nerror )
293	IF ( nerror /= OASIS_Ok ) THEN
294	WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
295	CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
296	ENDIF
297	IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
298	IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
299
300	END DO
301	END DO
302	ENDIF
303	END DO
304
305	! Define coupled river runoff using 1D array
306	CALL oasis_def_var (runoff_id, 'runoffo', id_part_rnf_1d , (/ 1, 0 /), &
307	& OASIS_In , (/ 1, nn_cpl_river /) , OASIS_REAL, nerror )
308	IF ( nerror /= OASIS_Ok ) THEN
309	WRITE(numout,*) 'Failed to define transient runoffo'
310	CALL oasis_abort ( runoff_id, 'cpl_define', 'Failure in oasis_def_var' )
311	ENDIF
312
313	!------------------------------------------------------------------
314	! End of definition phase
315	!------------------------------------------------------------------
316
317	CALL oasis_enddef(nerror)
318	IF( nerror /= OASIS_Ok ) CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
319	!
320	END SUBROUTINE cpl_define
321
322
323	SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
324	!!---------------------------------------------------------------------
325	!! * ROUTINE cpl_snd *
326	!!
327	!! ** Purpose : - At each coupling time-step,this routine sends fields
328	!! like sst or ice cover to the coupler or remote application.
329	!!----------------------------------------------------------------------
330	INTEGER , INTENT(in ) :: kid ! variable index in the array
331	INTEGER , INTENT( out) :: kinfo ! OASIS3 info argument
332	INTEGER , INTENT(in ) :: kstep ! ocean time-step in seconds
333	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: pdata
334	!!
335	INTEGER :: jc,jm ! local loop index
336	!!--------------------------------------------------------------------
337	!
338	! snd data to OASIS3
339	!
340	DO jc = 1, ssnd(kid)%nct
341	DO jm = 1, ssnd(kid)%ncplmodel
342
343	IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
344	CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
345
346	IF ( ln_ctl ) THEN
347	IF ( kinfo == OASIS_Sent .OR. kinfo == OASIS_ToRest .OR. &
348	& kinfo == OASIS_SentOut .OR. kinfo == OASIS_ToRestOut ) THEN
349	WRITE(numout,) '***************'
350	WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
351	WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
352	WRITE(numout,*) 'oasis_put: kstep ', kstep
353	WRITE(numout,*) 'oasis_put: info ', kinfo
354	WRITE(numout,*) ' - Minimum value is ', MINVAL(pdata(:,:,jc))
355	WRITE(numout,*) ' - Maximum value is ', MAXVAL(pdata(:,:,jc))
356	WRITE(numout,*) ' - Sum value is ', SUM(pdata(:,:,jc))
357	WRITE(numout,) '***************'
358	ENDIF
359	ENDIF
360
361	ENDIF
362
363	ENDDO
364	ENDDO
365	!
366	END SUBROUTINE cpl_snd
367
368
369	SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
370	!!---------------------------------------------------------------------
371	!! * ROUTINE cpl_rcv *
372	!!
373	!! ** Purpose : - At each coupling time-step,this routine receives fields
374	!! like stresses and fluxes from the coupler or remote application.
375	!!----------------------------------------------------------------------
376	INTEGER , INTENT(in ) :: kid ! variable index in the array
377	INTEGER , INTENT(in ) :: kstep ! ocean time-step in seconds
378	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdata ! IN to keep the value if nothing is done
379	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: pmask ! coupling mask
380	INTEGER , INTENT( out) :: kinfo ! OASIS3 info argument
381	!!
382	INTEGER :: jc,jm ! local loop index
383	LOGICAL :: llaction, llfisrt
384	!!--------------------------------------------------------------------
385	!
386	! receive local data from OASIS3 on every process
387	!
388	kinfo = OASIS_idle
389	!
390	DO jc = 1, srcv(kid)%nct
391	llfisrt = .TRUE.
392
393	DO jm = 1, srcv(kid)%ncplmodel
394
395	IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
396
397	CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )
398
399	llaction = kinfo == OASIS_Recvd .OR. kinfo == OASIS_FromRest .OR. &
400	& kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
401
402	IF ( ln_ctl ) WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
403
404	IF ( llaction ) THEN
405
406	kinfo = OASIS_Rcv
407	IF( llfisrt ) THEN
408	pdata(nldi:nlei,nldj:nlej,jc) = exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
409	llfisrt = .FALSE.
410	ELSE
411	pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
412	ENDIF
413
414	IF ( ln_ctl ) THEN
415	WRITE(numout,) '***************'
416	WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
417	WRITE(numout,*) 'oasis_get: ivarid ' , srcv(kid)%nid(jc,jm)
418	WRITE(numout,*) 'oasis_get: kstep', kstep
419	WRITE(numout,*) 'oasis_get: info ', kinfo
420	WRITE(numout,*) ' - Minimum value is ', MINVAL(pdata(:,:,jc))
421	WRITE(numout,*) ' - Maximum value is ', MAXVAL(pdata(:,:,jc))
422	WRITE(numout,*) ' - Sum value is ', SUM(pdata(:,:,jc))
423	WRITE(numout,) '***************'
424	ENDIF
425
426	ENDIF
427
428	ENDIF
429
430	ENDDO
431
432	!--- Fill the overlap areas and extra hallows (mpp)
433	!--- check periodicity conditions (all cases)
434	IF( .not. llfisrt ) CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )
435
436	ENDDO
437	!
438	END SUBROUTINE cpl_rcv
439
440	INTEGER FUNCTION cpl_freq( cdfieldname )
441	!!---------------------------------------------------------------------
442	!! * ROUTINE cpl_freq *
443	!!
444	!! ** Purpose : - send back the coupling frequency for a particular field
445	!!----------------------------------------------------------------------
446	CHARACTER(len = *), INTENT(in) :: cdfieldname ! field name as set in namcouple file
447	!!
448	INTEGER :: id
449	INTEGER :: info
450	INTEGER, DIMENSION(1) :: itmp
451	INTEGER :: ji,jm ! local loop index
452	INTEGER :: mop
453	!!----------------------------------------------------------------------
454	cpl_freq = 0 ! defaut definition
455	id = -1 ! defaut definition
456	!
457	DO ji = 1, nsnd
458	IF (ssnd(ji)%laction ) THEN
459	DO jm = 1, ncplmodel
460	IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
461	IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
462	id = ssnd(ji)%nid(1,jm)
463	mop = OASIS_Out
464	ENDIF
465	ENDIF
466	ENDDO
467	ENDIF
468	ENDDO
469	DO ji = 1, nrcv
470	IF (srcv(ji)%laction ) THEN
471	DO jm = 1, ncplmodel
472	IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
473	IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
474	id = srcv(ji)%nid(1,jm)
475	mop = OASIS_In
476	ENDIF
477	ENDIF
478	ENDDO
479	ENDIF
480	ENDDO
481	!
482	IF( id /= -1 ) THEN
483	#if defined key_oa3mct_v3
484	CALL oasis_get_freqs(id, mop, 1, itmp, info)
485	#else
486	CALL oasis_get_freqs(id, 1, itmp, info)
487	#endif
488	cpl_freq = itmp(1)
489	ENDIF
490	!
491	END FUNCTION cpl_freq
492
493
494	SUBROUTINE cpl_finalize
495	!!---------------------------------------------------------------------
496	!! * ROUTINE cpl_finalize *
497	!!
498	!! ** Purpose : - Finalizes the coupling. If MPI_init has not been
499	!! called explicitly before cpl_init it will also close
500	!! MPI communication.
501	!!----------------------------------------------------------------------
502	!
503	DEALLOCATE( exfld )
504	IF (nstop == 0) THEN
505	CALL oasis_terminate( nerror )
506	ELSE
507	CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
508	ENDIF
509	!
510	END SUBROUTINE cpl_finalize
511
512	#if ! defined key_oasis3
513
514	!!----------------------------------------------------------------------
515	!! No OASIS Library OASIS3 Dummy module...
516	!!----------------------------------------------------------------------
517
518	SUBROUTINE oasis_init_comp(k1,cd1,k2)
519	CHARACTER(*), INTENT(in ) :: cd1
520	INTEGER , INTENT( out) :: k1,k2
521	k1 = -1 ; k2 = -1
522	WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
523	END SUBROUTINE oasis_init_comp
524
525	SUBROUTINE oasis_abort(k1,cd1,cd2)
526	INTEGER , INTENT(in ) :: k1
527	CHARACTER(*), INTENT(in ) :: cd1,cd2
528	WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
529	END SUBROUTINE oasis_abort
530
531	SUBROUTINE oasis_get_localcomm(k1,k2)
532	INTEGER , INTENT( out) :: k1,k2
533	k1 = -1 ; k2 = -1
534	WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
535	END SUBROUTINE oasis_get_localcomm
536
537	SUBROUTINE oasis_def_partition(k1,k2,k3)
538	INTEGER , INTENT( out) :: k1,k3
539	INTEGER , INTENT(in ) :: k2(5)
540	k1 = k2(1) ; k3 = k2(5)
541	WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
542	END SUBROUTINE oasis_def_partition
543
544	SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
545	CHARACTER(*), INTENT(in ) :: cd1
546	INTEGER , INTENT(in ) :: k2,k3(2),k4,k5(2,2),k6
547	INTEGER , INTENT( out) :: k1,k7
548	k1 = -1 ; k7 = -1
549	WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
550	END SUBROUTINE oasis_def_var
551
552	SUBROUTINE oasis_enddef(k1)
553	INTEGER , INTENT( out) :: k1
554	k1 = -1
555	WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
556	END SUBROUTINE oasis_enddef
557
558	SUBROUTINE oasis_put(k1,k2,p1,k3)
559	REAL(wp), DIMENSION(:,:), INTENT(in ) :: p1
560	INTEGER , INTENT(in ) :: k1,k2
561	INTEGER , INTENT( out) :: k3
562	k3 = -1
563	WRITE(numout,*) 'oasis_put: Error you sould not be there...'
564	END SUBROUTINE oasis_put
565
566	SUBROUTINE oasis_get(k1,k2,p1,k3)
567	REAL(wp), DIMENSION(:,:), INTENT( out) :: p1
568	INTEGER , INTENT(in ) :: k1,k2
569	INTEGER , INTENT( out) :: k3
570	p1(1,1) = -1. ; k3 = -1
571	WRITE(numout,*) 'oasis_get: Error you sould not be there...'
572	END SUBROUTINE oasis_get
573
574	SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
575	INTEGER , INTENT(in ) :: k1,k2
576	INTEGER, DIMENSION(1), INTENT( out) :: k3
577	INTEGER , INTENT( out) :: k4
578	k3(1) = k1 ; k4 = k2
579	WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
580	END SUBROUTINE oasis_get_freqs
581
582	SUBROUTINE oasis_terminate(k1)
583	INTEGER , INTENT( out) :: k1
584	k1 = -1
585	WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
586	END SUBROUTINE oasis_terminate
587
588	#endif
589
590	!!=====================================================================
591	END MODULE cpl_oasis3

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_new_runoff_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90

Download in other formats: