source: branches/UKMO/dev_r5518_obs_oper_update_SlaAssim/NEMOGCM/NEMO/OPA_SRC/OBS/obs_read_surf.F90 @ 12036

Last change on this file since 12036 was 12036, checked in by kingr, 10 months ago

Fix to update times only when bkg time-averged.

File size: 21.2 KB
Line 
1MODULE obs_read_surf
2   !!======================================================================
3   !!                       ***  MODULE obs_read_surf  ***
4   !! Observation diagnostics: Read the surface data from feedback files
5   !!======================================================================
6
7   !!----------------------------------------------------------------------
8   !!   obs_rea_surf : Driver for reading surface data from feedback files
9   !!----------------------------------------------------------------------
10
11   !! * Modules used
12   USE par_kind                 ! Precision variables
13   USE in_out_manager           ! I/O manager
14   USE dom_oce                  ! Ocean space and time domain variables
15   USE obs_mpp                  ! MPP support routines for observation diagnostics
16   USE julian                   ! Julian date routines
17   USE obs_utils                ! Observation operator utility functions
18   USE obs_grid                 ! Grid search
19   USE obs_sort                 ! Sorting observation arrays
20   USE obs_surf_def             ! Surface observation definitions
21   USE obs_types                ! Observation type definitions
22   USE obs_fbm                  ! Feedback routines
23   USE netcdf                   ! NetCDF library
24
25   IMPLICIT NONE
26
27   !! * Routine accessibility
28   PRIVATE
29
30   PUBLIC obs_rea_surf      ! Read the surface observations from the point data
31
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE obs_rea_surf( surfdata, knumfiles, cdfilenames, &
41      &                     kvars, kextr, kstp, ddobsini, ddobsend, MeanPeriodHours, &
42      &                     ldignmis, ldmod, ldnightav, ldclim, ln_time_mean_sla_bkg, cdvars )
43      !!---------------------------------------------------------------------
44      !!
45      !!                   *** ROUTINE obs_rea_surf ***
46      !!
47      !! ** Purpose : Read from file the surface data
48      !!
49      !! ** Method  : Read in the data from feedback format files and
50      !!              put into the NEMO internal surface data structure
51      !!
52      !! ** Action  :
53      !!
54      !!
55      !! History : 
56      !!      ! :  2009-01 (K. Mogensen) Initial version based on old versions
57      !!      ! :  2015-02 (M. Martin)   Unify the different surface data type reading.
58      !!----------------------------------------------------------------------
59      !! * Modules used
60
61      !! * Arguments
62      TYPE(obs_surf), INTENT(INOUT) :: &
63         & surfdata                     ! Surface data to be read
64      INTEGER, INTENT(IN) :: knumfiles  ! Number of corio format files to read
65      CHARACTER(LEN=128), INTENT(IN) :: &
66         & cdfilenames(knumfiles)       ! File names to read in
67      INTEGER, INTENT(IN) :: kvars      ! Number of variables in surfdata
68      INTEGER, INTENT(IN) :: kextr      ! Number of extra fields for each var
69      INTEGER, INTENT(IN) :: kstp       ! Ocean time-step index
70      LOGICAL, INTENT(IN) :: ldignmis   ! Ignore missing files
71      LOGICAL, INTENT(IN) :: ldmod      ! Initialize model from input data
72      LOGICAL, INTENT(IN) :: ldnightav  ! Observations represent a night-time average
73      LOGICAL, INTENT(IN) :: ldclim     ! Will include climatology at obs points.
74      LOGICAL, INTENT(IN) :: ln_time_mean_sla_bkg     ! Will reset times to end of averaging period.
75      REAL(dp), INTENT(IN) :: ddobsini   ! Obs. ini time in YYYYMMDD.HHMMSS
76      REAL(dp), INTENT(IN) :: ddobsend   ! Obs. end time in YYYYMMDD.HHMMSS
77      REAL(wp), INTENT(IN) :: MeanPeriodHours ! Averaging period in hours
78      CHARACTER(len=8), DIMENSION(kvars), INTENT(IN) :: cdvars
79
80      !! * Local declarations
81      CHARACTER(LEN=11), PARAMETER :: cpname='obs_rea_surf'
82      CHARACTER(len=8) :: clrefdate
83      CHARACTER(len=8), DIMENSION(:), ALLOCATABLE :: clvarsin
84      INTEGER :: ji
85      INTEGER :: jj
86      INTEGER :: jk
87      INTEGER :: iflag
88      INTEGER :: inobf
89      INTEGER :: i_file_id
90      INTEGER :: inowin
91      INTEGER :: iyea
92      INTEGER :: imon
93      INTEGER :: iday
94      INTEGER :: ihou
95      INTEGER :: imin
96      INTEGER :: isec
97      INTEGER :: itype
98      INTEGER :: iobsmpp
99      INTEGER :: iobs
100      INTEGER :: iobstot
101      INTEGER :: ios
102      INTEGER :: ioserrcount
103      INTEGER :: iextr
104      INTEGER, PARAMETER :: jpsurfmaxtype = 1024
105      INTEGER, DIMENSION(knumfiles) :: irefdate
106      INTEGER, DIMENSION(jpsurfmaxtype+1) :: &
107         & ityp, &
108         & itypmpp
109      INTEGER, DIMENSION(:), ALLOCATABLE :: &
110         & iobsi,    &
111         & iobsj,    &
112         & iproc,    &
113         & iindx,    &
114         & ifileidx, &
115         & isurfidx, &
116         & iadd_std
117      REAL(wp), DIMENSION(:), ALLOCATABLE :: &
118         & zphi, &
119         & zlam
120      REAL(wp), DIMENSION(:), ALLOCATABLE :: &
121         & zdat
122      REAL(wp), DIMENSION(knumfiles) :: &
123         & djulini, &
124         & djulend
125      LOGICAL :: llvalprof
126      TYPE(obfbdata), POINTER, DIMENSION(:) :: &
127         & inpfiles
128
129      ! Local initialization
130      iobs  = 0
131      iextr = kextr
132      !-----------------------------------------------------------------------
133      ! Count the number of files needed and allocate the obfbdata type
134      !-----------------------------------------------------------------------
135
136      inobf = knumfiles
137
138      ALLOCATE( inpfiles(inobf) )
139      ALLOCATE( iadd_std(inobf) )
140
141      surf_files : DO jj = 1, inobf
142
143         !---------------------------------------------------------------------
144         ! Prints
145         !---------------------------------------------------------------------
146         IF(lwp) THEN
147            WRITE(numout,*)
148            WRITE(numout,*) ' obs_rea_surf : Reading from file = ', &
149               & TRIM( TRIM( cdfilenames(jj) ) )
150            WRITE(numout,*) ' ~~~~~~~~~~~'
151            WRITE(numout,*)
152         ENDIF
153
154         !---------------------------------------------------------------------
155         !  Initialization: Open file and get dimensions only
156         !---------------------------------------------------------------------
157
158         iflag = nf90_open( TRIM( TRIM( cdfilenames(jj) ) ), nf90_nowrite, &
159            &                      i_file_id )
160
161         IF ( iflag /= nf90_noerr ) THEN
162
163            IF ( ldignmis ) THEN
164               inpfiles(jj)%nobs = 0
165               CALL ctl_warn( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
166                  &           ' not found' )
167            ELSE
168               CALL ctl_stop( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
169                  &           ' not found' )
170            ENDIF
171
172         ELSE 
173
174            !------------------------------------------------------------------
175            !  Close the file since it is opened in read_obfbdata
176            !------------------------------------------------------------------
177
178            iflag = nf90_close( i_file_id )
179
180            !------------------------------------------------------------------
181            !  Read the surface file into inpfiles
182            !------------------------------------------------------------------
183            CALL init_obfbdata( inpfiles(jj) )
184            CALL read_obfbdata( TRIM( cdfilenames(jj) ), inpfiles(jj), &
185               &                ldgrid = .TRUE. )
186
187            IF ( inpfiles(jj)%nvar /= kvars ) THEN
188               CALL ctl_stop( 'Feedback format error: ', &
189                  &           ' unexpected number of vars in feedback file' )
190            ENDIF
191
192            IF ( ldmod .AND. ( inpfiles(jj)%nadd == 0 ) ) THEN
193               CALL ctl_stop( 'Model not in input data' )
194               RETURN
195            ENDIF
196
197            IF ( jj == 1 ) THEN
198               ALLOCATE( clvarsin( inpfiles(jj)%nvar ) )
199               DO ji = 1, inpfiles(jj)%nvar
200                 clvarsin(ji) = inpfiles(jj)%cname(ji)
201                 IF ( clvarsin(ji) /= cdvars(ji) ) THEN
202                    CALL ctl_stop( 'Feedback file variables do not match', &
203                        &           ' expected variable names for this type' )
204                 ENDIF
205               END DO
206            ELSE
207               DO ji = 1, inpfiles(jj)%nvar
208                  IF ( inpfiles(jj)%cname(ji) /= clvarsin(ji) ) THEN
209                     CALL ctl_stop( 'Feedback file variables not consistent', &
210                        &           ' with previous files for this type' )
211                  ENDIF
212               END DO
213            ENDIF
214
215            iadd_std(jj) = -1
216            IF ( inpfiles(jj)%nadd > 0 ) THEN
217               DO ji = 1, inpfiles(jj)%nadd
218                  IF ( TRIM( inpfiles(jj)%caddname(ji) ) == 'STD' ) THEN
219                     iextr = kextr + 1
220                     iadd_std(jj) = ji
221                  ENDIF
222               END DO
223            ENDIF
224
225            IF(lwp) THEN
226               IF ( iadd_std(jj) /= -1 ) THEN
227                  WRITE(numout,*) ' STD variable available in input file so passing it through the obs oper'
228                  WRITE(numout,*)
229               ENDIF
230            ENDIF
231
232            !------------------------------------------------------------------
233            !  Change longitude (-180,180)
234            !------------------------------------------------------------------
235
236            DO ji = 1, inpfiles(jj)%nobs
237
238               IF ( inpfiles(jj)%plam(ji) < -180. ) &
239                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) + 360.
240
241               IF ( inpfiles(jj)%plam(ji) >  180. ) &
242                  &   inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) - 360.
243
244            END DO
245
246            !------------------------------------------------------------------
247            !  Calculate the date  (change eventually)
248            !------------------------------------------------------------------
249            clrefdate=inpfiles(jj)%cdjuldref(1:8)
250            READ(clrefdate,'(I8)') irefdate(jj)
251
252            CALL ddatetoymdhms( ddobsini, iyea, imon, iday, ihou, imin, isec )
253            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulini(jj), &
254               &           krefdate = irefdate(jj) )
255            CALL ddatetoymdhms( ddobsend, iyea, imon, iday, ihou, imin, isec )
256            CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulend(jj), &
257               &           krefdate = irefdate(jj) )
258
259            IF ( ldnightav ) THEN
260
261               IF ( lwp ) THEN
262                  WRITE(numout,*)'Resetting time of night-time averaged observations', &
263                     &             ' to the end of the day'
264               ENDIF
265
266               DO ji = 1, inpfiles(jj)%nobs
267                  !  for night-time averaged data force the time
268                  !  to be the last time-step of the day, but still within the day.
269                  IF ( inpfiles(jj)%ptim(ji) >= 0. ) THEN
270                     inpfiles(jj)%ptim(ji) = &
271                        & INT(inpfiles(jj)%ptim(ji)) + 0.9999
272                  ELSE
273                     inpfiles(jj)%ptim(ji) = &
274                        & INT(inpfiles(jj)%ptim(ji)) - 0.0001
275                  ENDIF
276               END DO
277            ENDIF
278
279            IF ( inpfiles(jj)%nobs > 0 ) THEN
280               inpfiles(jj)%iproc = -1
281               inpfiles(jj)%iobsi = -1
282               inpfiles(jj)%iobsj = -1
283            ENDIF
284
285            !If the observations are representing a time mean then set the time
286            !of the obs to the end of that meaning period relative to the start of the run
287            IF ( MeanPeriodHours > 0._wp .AND. ln_time_mean_sla_bkg ) THEN
288               DO ji = 1, inpfiles(jj)%nobs
289                  inpfiles(jj)%ptim(ji) = &
290                        & djulini(jj) + (MeanPeriodHours/24.)
291               END DO
292            ENDIF   
293
294            inowin = 0
295            DO ji = 1, inpfiles(jj)%nobs
296               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
297                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
298                  inowin = inowin + 1
299               ENDIF
300            END DO
301            ALLOCATE( zlam(inowin)  )
302            ALLOCATE( zphi(inowin)  )
303            ALLOCATE( iobsi(inowin) )
304            ALLOCATE( iobsj(inowin) )
305            ALLOCATE( iproc(inowin) )
306            inowin = 0
307            DO ji = 1, inpfiles(jj)%nobs
308               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
309                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
310                  inowin = inowin + 1
311                  zlam(inowin) = inpfiles(jj)%plam(ji)
312                  zphi(inowin) = inpfiles(jj)%pphi(ji)
313               ENDIF
314            END DO
315
316            CALL obs_grid_search( inowin, zlam, zphi, iobsi, iobsj, iproc, 'T' )
317
318            inowin = 0
319            DO ji = 1, inpfiles(jj)%nobs
320               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
321                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
322                  inowin = inowin + 1
323                  inpfiles(jj)%iproc(ji,1) = iproc(inowin)
324                  inpfiles(jj)%iobsi(ji,1) = iobsi(inowin)
325                  inpfiles(jj)%iobsj(ji,1) = iobsj(inowin)
326               ENDIF
327            END DO
328            DEALLOCATE( zlam, zphi, iobsi, iobsj, iproc )
329
330            DO ji = 1, inpfiles(jj)%nobs
331               IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
332                  & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
333                  IF ( nproc == 0 ) THEN
334                     IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
335                  ELSE
336                     IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
337                  ENDIF
338                  llvalprof = .FALSE.
339                  IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
340                     iobs = iobs + 1
341                  ENDIF
342               ENDIF
343            END DO
344
345         ENDIF
346
347      END DO surf_files
348
349      !-----------------------------------------------------------------------
350      ! Get the time ordered indices of the input data
351      !-----------------------------------------------------------------------
352
353      !---------------------------------------------------------------------
354      !  Loop over input data files to count total number of profiles
355      !---------------------------------------------------------------------
356      iobstot = 0
357      DO jj = 1, inobf
358         DO ji = 1, inpfiles(jj)%nobs
359            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
360               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
361               iobstot = iobstot + 1
362            ENDIF
363         END DO
364      END DO
365
366      ALLOCATE( iindx(iobstot), ifileidx(iobstot), &
367         &      isurfidx(iobstot), zdat(iobstot) )
368      jk = 0
369      DO jj = 1, inobf
370         DO ji = 1, inpfiles(jj)%nobs
371            IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND. &
372               & ( inpfiles(jj)%ptim(ji) <= djulend(jj) )       ) THEN
373               jk = jk + 1
374               ifileidx(jk) = jj
375               isurfidx(jk) = ji
376               zdat(jk)     = inpfiles(jj)%ptim(ji)
377            ENDIF
378         END DO
379      END DO
380      CALL sort_dp_indx( iobstot, &
381         &               zdat,     &
382         &               iindx   )
383
384      CALL obs_surf_alloc( surfdata, iobs, kvars, iextr, kstp, jpi, jpj, ldclim )
385
386      ! Read obs/positions, QC, all variable and assign to surfdata
387
388      iobs = 0
389      surfdata%cvars(:)  = clvarsin(:)
390      IF ( ldmod .AND. ( TRIM( surfdata%cvars(1) ) == 'SLA' ) ) THEN
391         surfdata%cext(1) = 'SSH'
392         surfdata%cext(2) = 'MDT'
393      ENDIF
394      IF ( iextr > kextr ) surfdata%cext(iextr) = 'STD'
395
396      ityp   (:) = 0
397      itypmpp(:) = 0
398
399      ioserrcount = 0
400
401      DO jk = 1, iobstot
402
403         jj = ifileidx(iindx(jk))
404         ji = isurfidx(iindx(jk))
405         IF ( ( inpfiles(jj)%ptim(ji) >  djulini(jj) ) .AND.  &
406            & ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
407
408            IF ( nproc == 0 ) THEN
409               IF ( inpfiles(jj)%iproc(ji,1) >  nproc ) CYCLE
410            ELSE
411               IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
412            ENDIF
413
414            ! Set observation information
415
416            IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
417
418               iobs = iobs + 1
419
420               CALL jul2greg( isec,                   &
421                  &           imin,                   &
422                  &           ihou,                   &
423                  &           iday,                   &
424                  &           imon,                   &
425                  &           iyea,                   &
426                  &           inpfiles(jj)%ptim(ji), &
427                  &           irefdate(jj) )
428
429
430               ! Surface time coordinates
431               surfdata%nyea(iobs) = iyea
432               surfdata%nmon(iobs) = imon
433               surfdata%nday(iobs) = iday
434               surfdata%nhou(iobs) = ihou
435               surfdata%nmin(iobs) = imin
436
437               ! Surface space coordinates
438               surfdata%rlam(iobs) = inpfiles(jj)%plam(ji)
439               surfdata%rphi(iobs) = inpfiles(jj)%pphi(ji)
440
441               ! Coordinate search parameters
442               surfdata%mi  (iobs) = inpfiles(jj)%iobsi(ji,1)
443               surfdata%mj  (iobs) = inpfiles(jj)%iobsj(ji,1)
444
445               ! WMO number
446               surfdata%cwmo(iobs) = inpfiles(jj)%cdwmo(ji)
447
448               ! Instrument type
449               READ( inpfiles(jj)%cdtyp(ji), '(I4)', IOSTAT = ios, ERR = 901 ) itype
450901            IF ( ios /= 0 ) THEN
451                  IF (ioserrcount == 0) THEN
452                     CALL ctl_warn ( 'Problem converting an instrument type ', &
453                        &            'to integer. Setting type to zero' )
454                  ENDIF
455                  ioserrcount = ioserrcount + 1
456                  itype = 0
457               ENDIF
458               surfdata%ntyp(iobs) = itype
459               IF ( itype < jpsurfmaxtype + 1 ) THEN
460                  ityp(itype+1) = ityp(itype+1) + 1
461               ELSE
462                  IF(lwp)WRITE(numout,*)'WARNING:Increase jpsurfmaxtype in ',&
463                     &                  cpname
464               ENDIF
465
466               ! Bookkeeping data to match observations
467               surfdata%nsidx(iobs) = iobs
468               surfdata%nsfil(iobs) = iindx(jk)
469
470               ! QC flags
471               surfdata%nqc(iobs) = inpfiles(jj)%ivqc(ji,1)
472
473               ! Observed value
474               surfdata%robs(iobs,1) = inpfiles(jj)%pob(1,ji,1)
475
476               ! Model and MDT is set to fbrmdi unless read from file
477               IF ( ldmod ) THEN
478                  surfdata%rmod(iobs,1) = inpfiles(jj)%padd(1,ji,1,1)
479                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) THEN
480                     surfdata%rext(iobs,1) = inpfiles(jj)%padd(1,ji,2,1)
481                     surfdata%rext(iobs,2) = inpfiles(jj)%pext(1,ji,1)
482                  ENDIF
483                ELSE
484                  surfdata%rmod(iobs,1) = fbrmdi
485                  IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) surfdata%rext(iobs,:) = fbrmdi
486               ENDIF
487               
488               ! Initialise climatology if set
489               IF ( surfdata%lclim ) surfdata%rclm(iobs,1) = fbrmdi
490               
491               ! STD (obs error standard deviation) read from file and passed through obs operator
492               IF ( iadd_std(jj) /= -1 ) THEN
493                  surfdata%rext(iobs,iextr) = inpfiles(jj)%padd(1,ji,iadd_std(jj),1)
494               ENDIF
495            ENDIF
496         ENDIF
497
498      END DO
499
500      !-----------------------------------------------------------------------
501      ! Sum up over processors
502      !-----------------------------------------------------------------------
503
504      CALL obs_mpp_sum_integer( iobs, iobsmpp )
505      CALL obs_mpp_sum_integers( ityp, itypmpp, jpsurfmaxtype + 1 )
506
507      !-----------------------------------------------------------------------
508      ! Output number of observations.
509      !-----------------------------------------------------------------------
510      IF (lwp) THEN
511
512         WRITE(numout,*)
513         WRITE(numout,'(1X,A)')TRIM( surfdata%cvars(1) )//' data'
514         WRITE(numout,'(1X,A)')'--------------'
515         DO jj = 1,8
516            IF ( itypmpp(jj) > 0 ) THEN
517               WRITE(numout,'(1X,A4,I4,A3,I10)')'Type ', jj,' = ',itypmpp(jj)
518            ENDIF
519         END DO
520         WRITE(numout,'(1X,A)') &
521            & '---------------------------------------------------------------'
522         WRITE(numout,'(1X,A,I8)') &
523            & 'Total data for variable '//TRIM( surfdata%cvars(1) )// &
524            & '           = ', iobsmpp
525         WRITE(numout,'(1X,A)') &
526            & '---------------------------------------------------------------'
527         WRITE(numout,*)
528
529      ENDIF
530
531      !-----------------------------------------------------------------------
532      ! Deallocate temporary data
533      !-----------------------------------------------------------------------
534      DEALLOCATE( ifileidx, isurfidx, zdat, clvarsin )
535
536      !-----------------------------------------------------------------------
537      ! Deallocate input data
538      !-----------------------------------------------------------------------
539      DO jj = 1, inobf
540         IF ( inpfiles(jj)%lalloc ) THEN
541            CALL dealloc_obfbdata( inpfiles(jj) )
542         ENDIF
543      END DO
544      DEALLOCATE( inpfiles )
545      DEALLOCATE( iadd_std )
546
547   END SUBROUTINE obs_rea_surf
548
549END MODULE obs_read_surf
Note: See TracBrowser for help on using the repository browser.