New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limistate_2.F90 in branches/UKMO/dev_r5518_obs_oper_update_icethick/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/UKMO/dev_r5518_obs_oper_update_icethick/NEMOGCM/NEMO/LIM_SRC_2/limistate_2.F90 @ 9987

Last change on this file since 9987 was 9987, checked in by emmafiedler, 6 years ago

Merge with GO6 FOAMv14 package branch r9288

File size: 10.4 KB
Line 
1MODULE limistate_2
2   !!======================================================================
3   !!                     ***  MODULE  limistate_2  ***
4   !!              Initialisation of diagnostics ice variables
5   !!======================================================================
6   !! History :   1.0  !  01-04  (C. Ethe, G. Madec)  Original code
7   !!             2.0  !  03-08  (G. Madec)  add lim_istate_init
8   !!                  !  04-04  (S. Theetten) initialization from a file
9   !!                  !  06-07  (S. Masson)  IOM to read the restart
10   !!                  !  07-10  (G. Madec)  surface module
11   !!--------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!   lim_istate_2      :  Initialisation of diagnostics ice variables
17   !!   lim_istate_init_2 :  initialization of ice state and namelist read
18   !!----------------------------------------------------------------------
19   USE phycst
20   USE par_ice_2       ! ice parameters
21   USE dom_ice_2
22   USE eosbn2          ! equation of state
23   USE lbclnk
24   USE oce
25   USE ice_2
26   USE iom
27   USE in_out_manager
28   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC lim_istate_2      ! routine called by lim_init_2.F90
34
35   !                        !! **  namelist (namiceini) **
36   LOGICAL  ::   ln_limini   ! Ice initialization state
37   REAL(wp) ::   ttest       ! threshold water temperature for initial sea ice
38   REAL(wp) ::   hninn       ! initial snow thickness in the north
39   REAL(wp) ::   hginn       ! initial ice thickness in the north
40   REAL(wp) ::   alinn       ! initial leads area in the north
41   REAL(wp) ::   hnins       ! initial snow thickness in the south
42   REAL(wp) ::   hgins       ! initial ice thickness in the south
43   REAL(wp) ::   alins       ! initial leads area in the south
44   
45   REAL(wp) ::   zero      = 0.e0     ! constant value = 0
46   REAL(wp) ::   zone      = 1.e0     ! constant value = 1
47   !!----------------------------------------------------------------------
48   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE lim_istate_2
55      !!-------------------------------------------------------------------
56      !!                    ***  ROUTINE lim_istate_2  ***
57      !!
58      !! ** Purpose :   defined the sea-ice initial state
59      !!
60      !! ** Method  :   restart from a state defined in a binary file
61      !!                or from arbitrary sea-ice conditions
62      !!--------------------------------------------------------------------
63      INTEGER  ::   ji, jj, jk                ! dummy loop indices
64      REAL(wp) ::   zidto                     ! temporary scalar
65      !--------------------------------------------------------------------
66 
67      CALL lim_istate_init_2     !  reading the initials parameters of the ice
68
69      IF( .NOT. ln_limini ) THEN 
70         
71         CALL eos_fzp( tsn(:,:,1,jp_sal), tfu(:,:) )       ! freezing/melting point of sea water [Celcius]
72         tfu(:,:) = tfu(:,:) *  tmask(:,:,1)
73
74         DO jj = 1, jpj
75            DO ji = 1, jpi
76               !                     ! ice if sst <= t-freez + ttest
77               IF( tsn(ji,jj,1,jp_tem)  - tfu(ji,jj) >= ttest ) THEN   ;   zidto = 0.e0      ! no ice
78               ELSE                                                    ;   zidto = 1.e0      !    ice
79               ENDIF
80               !
81               IF( fcor(ji,jj) >= 0.e0 ) THEN     !--  Northern hemisphere.
82                  hicif(ji,jj)   = zidto * hginn
83                  frld(ji,jj)    = zidto * alinn + ( 1.0 - zidto ) * 1.0
84                  hsnif(ji,jj)   = zidto * hninn
85               ELSE                               !---  Southern hemisphere.
86                  hicif(ji,jj)   = zidto * hgins
87                  frld(ji,jj)    = zidto * alins + ( 1.0 - zidto ) * 1.0
88                  hsnif(ji,jj)   = zidto * hnins
89               ENDIF
90            END DO
91         END DO
92
93         tfu(:,:) = tfu(:,:) + rt0       ! ftu converted from Celsius to Kelvin (rt0 over land)
94         
95         sist  (:,:)   = tfu(:,:)
96         tbif  (:,:,1) = tfu(:,:)
97         tbif  (:,:,2) = tfu(:,:)
98         tbif  (:,:,3) = tfu(:,:)
99
100      ENDIF
101     
102      fsbbq (:,:)   = 0.e0
103      qstoif(:,:)   = 0.e0
104      u_ice (:,:)   = 0.e0
105      v_ice (:,:)   = 0.e0
106
107      !---  Moments for advection.             
108
109      sxice (:,:)  = 0.e0   ;   sxsn (:,:)  = 0.e0   ;   sxa  (:,:)  = 0.e0
110      syice (:,:)  = 0.e0   ;   sysn (:,:)  = 0.e0   ;   sya  (:,:)  = 0.e0
111      sxxice(:,:)  = 0.e0   ;   sxxsn(:,:)  = 0.e0   ;   sxxa (:,:)  = 0.e0
112      syyice(:,:)  = 0.e0   ;   syysn(:,:)  = 0.e0   ;   syya (:,:)  = 0.e0
113      sxyice(:,:)  = 0.e0   ;   sxysn(:,:)  = 0.e0   ;   sxya (:,:)  = 0.e0
114
115      sxc0  (:,:)  = 0.e0   ;   sxc1 (:,:)  = 0.e0   ;   sxc2 (:,:)  = 0.e0
116      syc0  (:,:)  = 0.e0   ;   syc1 (:,:)  = 0.e0   ;   syc2 (:,:)  = 0.e0
117      sxxc0 (:,:)  = 0.e0   ;   sxxc1(:,:)  = 0.e0   ;   sxxc2(:,:)  = 0.e0
118      syyc0 (:,:)  = 0.e0   ;   syyc1(:,:)  = 0.e0   ;   syyc2(:,:)  = 0.e0
119      sxyc0 (:,:)  = 0.e0   ;   sxyc1(:,:)  = 0.e0   ;   sxyc2(:,:)  = 0.e0
120
121      sxst  (:,:)  = 0.e0
122      syst  (:,:)  = 0.e0
123      sxxst (:,:)  = 0.e0
124      syyst (:,:)  = 0.e0
125      sxyst (:,:)  = 0.e0
126#if ! defined key_lim2_vp
127      stress1_i (:,:) = 0._wp                          ! EVP rheology
128      stress2_i (:,:) = 0._wp
129      stress12_i(:,:) = 0._wp
130#endif
131
132      !-- lateral boundary conditions
133      CALL lbc_lnk( hicif, 'T', 1. )
134      CALL lbc_lnk( frld , 'T', 1. )
135
136      ! C A U T I O N  frld = 1 over land and lbc_lnk put zero along
137      ! *************  closed boundaries herefore we force to one over land
138      frld(:,:) = tms(:,:) * frld(:,:) + ( 1. - tms(:,:) )   
139
140      CALL lbc_lnk( hsnif, 'T', 1. )
141      CALL lbc_lnk( sist , 'T', 1. , pval = rt0 )      ! set rt0 on closed boundary (required by bulk formulation)
142      DO jk = 1, jplayersp1
143         CALL lbc_lnk(tbif(:,:,jk), 'T', 1. )
144      END DO
145      CALL lbc_lnk( fsbbq  , 'T', 1. )
146      CALL lbc_lnk( qstoif , 'T', 1. )
147
148   END SUBROUTINE lim_istate_2
149
150   
151   SUBROUTINE lim_istate_init_2
152      !!-------------------------------------------------------------------
153      !!                   ***  ROUTINE lim_istate_init_2  ***
154      !!       
155      !! ** Purpose :   Definition of initial state of the ice
156      !!
157      !! ** Method  :   Read the namiceini namelist and check the parameter
158      !!       values called at the first timestep (nit000)
159      !!
160      !! ** input   :   Namelist namiceini
161      !!-------------------------------------------------------------------
162      INTEGER :: inum_ice
163      INTEGER :: ji,jj
164      INTEGER :: ios                 ! Local integer output status for namelist read
165
166      NAMELIST/namiceini/ ln_limini, ttest, hninn, hginn, alinn, &
167         &                hnins, hgins, alins
168      !!-------------------------------------------------------------------
169                   
170      REWIND( numnam_ice_ref )              ! Namelist namiceini in reference namelist : Ice initial state
171      READ  ( numnam_ice_ref, namiceini, IOSTAT = ios, ERR = 901)
172901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceini in reference namelist', lwp )
173
174      REWIND( numnam_ice_cfg )              ! Namelist namiceini in configuration namelist : Ice initial state
175      READ  ( numnam_ice_cfg, namiceini, IOSTAT = ios, ERR = 902 )
176902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceini in configuration namelist', lwp )
177      IF(lwm) WRITE ( numoni, namiceini )
178      !
179      IF(lwp) THEN
180         WRITE(numout,*)
181         WRITE(numout,*) 'lim_istate_init_2 : ice parameters inititialisation '
182         WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
183         WRITE(numout,*) '         threshold water temp. for initial sea-ice    ttest      = ', ttest
184         WRITE(numout,*) '         initial snow thickness in the north          hninn      = ', hninn
185         WRITE(numout,*) '         initial ice thickness in the north           hginn      = ', hginn 
186         WRITE(numout,*) '         initial leads area in the north              alinn      = ', alinn           
187         WRITE(numout,*) '         initial snow thickness in the south          hnins      = ', hnins 
188         WRITE(numout,*) '         initial ice thickness in the south           hgins      = ', hgins
189         WRITE(numout,*) '         initial leads area in the south              alins      = ', alins
190         WRITE(numout,*) '         Ice state initialization using input file    ln_limini  = ', ln_limini
191      ENDIF
192
193      IF( ln_limini ) THEN                      ! Ice initialization using input file
194         !
195         CALL iom_open( 'Ice_initialization.nc', inum_ice )
196         !
197         IF( inum_ice > 0 ) THEN
198            IF(lwp) WRITE(numout,*)
199            IF(lwp) WRITE(numout,*) '                  ice state initialization with : Ice_initialization.nc'
200           
201            CALL iom_get( inum_ice, jpdom_data, 'hicif', hicif )     
202            CALL iom_get( inum_ice, jpdom_data, 'hsnif', hsnif )     
203            CALL iom_get( inum_ice, jpdom_data, 'frld' , frld  )     
204            CALL iom_get( inum_ice, jpdom_data, 'ts'   , sist  )
205            CALL iom_get( inum_ice, jpdom_unknown, 'tbif', tbif(1:nlci,1:nlcj,:),   &
206                 &        kstart = (/ mig(1),mjg(1),1 /), kcount = (/ nlci,nlcj,jplayersp1 /) )
207            ! put some values in the extra-halo...
208            DO jj = nlcj+1, jpj   ;   tbif(1:nlci,jj,:) = tbif(1:nlci,nlej,:)   ;   END DO
209            DO ji = nlci+1, jpi   ;   tbif(ji    ,: ,:) = tbif(nlei  ,:   ,:)   ;   END DO
210
211            CALL iom_close( inum_ice)
212            !
213         ENDIF
214      ENDIF
215      !     
216   END SUBROUTINE lim_istate_init_2
217
218#else
219   !!----------------------------------------------------------------------
220   !!   Default option :         Empty module      NO LIM 2.0 sea-ice model
221   !!----------------------------------------------------------------------
222CONTAINS
223   SUBROUTINE lim_istate_2        ! Empty routine
224   END SUBROUTINE lim_istate_2
225#endif
226
227   !!======================================================================
228END MODULE limistate_2
Note: See TracBrowser for help on using the repository browser.