Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

sbcrnf.F90 @ 9987

Last change on this file since 9987 was 9987, checked in by emmafiedler, 6 years ago
Merge with GO6 FOAMv14 package branch r9288
File size: 29.0 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC sbc_rnf ! routine call in sbcmod module
34	PUBLIC sbc_rnf_div ! routine called in divcurl module
35	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
36	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
39	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
41	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
45	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
46	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
47	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
48	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
49	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
50	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
51	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
52	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
53	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
54	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
55
56	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
57
58	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
59	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
62	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
64
65	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
66	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
68
69	!! * Substitutions
70	# include "domzgr_substitute.h90"
71	!!----------------------------------------------------------------------
72	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
73	!! $Id$
74	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
75	!!----------------------------------------------------------------------
76	CONTAINS
77
78	INTEGER FUNCTION sbc_rnf_alloc()
79	!!----------------------------------------------------------------------
80	!! * ROUTINE sbc_rnf_alloc *
81	!!----------------------------------------------------------------------
82	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
83	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
84	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
85	!
86	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
87	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
88	END FUNCTION sbc_rnf_alloc
89
90
91	SUBROUTINE sbc_rnf( kt )
92	!!----------------------------------------------------------------------
93	!! * ROUTINE sbc_rnf *
94	!!
95	!! ** Purpose : Introduce a climatological run off forcing
96	!!
97	!! ** Method : Set each river mouth with a monthly climatology
98	!! provided from different data.
99	!! CAUTION : upward water flux, runoff forced to be < 0
100	!!
101	!! ** Action : runoff updated runoff field at time-step kt
102	!!----------------------------------------------------------------------
103	INTEGER, INTENT(in) :: kt ! ocean time step
104	!
105	INTEGER :: ji, jj ! dummy loop indices
106	INTEGER :: z_err = 0 ! dummy integer for error handling
107	!!----------------------------------------------------------------------
108	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
109	!
110	CALL wrk_alloc( jpi,jpj, ztfrz)
111	!
112	! !-------------------!
113	! ! Update runoff !
114	! !-------------------!
115	!
116	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
117	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
118	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
119	!
120	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
121	!
122	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
123	CALL lbc_lnk(rnf(:,:), 'T', 1._wp)
124	!
125	! ! set temperature & salinity content of runoffs
126	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
127	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
128	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
129	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
130	END WHERE
131	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
132	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
133	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
134	END WHERE
135	ELSE ! use SST as runoffs temperature
136	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
137	ENDIF
138	! ! use runoffs salinity data
139	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
140	! ! else use S=0 for runoffs (done one for all in the init)
141	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
142	ENDIF
143	!
144	! ! ---------------------------------------- !
145	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
146	! ! ---------------------------------------- !
147	IF( ln_rstart .AND. & !* Restart: read in restart file
148	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
149	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
150	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
151	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
152	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
153	ELSE !* no restart: set from nit000 values
154	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
155	rnf_b (:,: ) = rnf (:,: )
156	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
157	ENDIF
158	ENDIF
159	! ! ---------------------------------------- !
160	IF( lrst_oce ) THEN ! Write in the ocean restart file !
161	! ! ---------------------------------------- !
162	IF(lwp) WRITE(numout,*)
163	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
164	& 'at it= ', kt,' date= ', ndastp
165	IF(lwp) WRITE(numout,*) '~~~~'
166	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
167	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
168	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
169	ENDIF
170	!
171	CALL wrk_dealloc( jpi,jpj, ztfrz)
172	!
173	END SUBROUTINE sbc_rnf
174
175
176	SUBROUTINE sbc_rnf_div( phdivn )
177	!!----------------------------------------------------------------------
178	!! * ROUTINE sbc_rnf *
179	!!
180	!! ** Purpose : update the horizontal divergence with the runoff inflow
181	!!
182	!! ** Method :
183	!! CAUTION : rnf is positive (inflow) decreasing the
184	!! divergence and expressed in m/s
185	!!
186	!! ** Action : phdivn decreased by the runoff inflow
187	!!----------------------------------------------------------------------
188	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
189	!!
190	INTEGER :: ji, jj, jk ! dummy loop indices
191	REAL(wp) :: zfact ! local scalar
192	!!----------------------------------------------------------------------
193	!
194	zfact = 0.5_wp
195	!
196	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
197	IF( lk_vvl ) THEN ! variable volume case
198	DO jj = 1, jpj ! update the depth over which runoffs are distributed
199	DO ji = 1, jpi
200	h_rnf(ji,jj) = 0._wp
201	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
202	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
203	END DO
204	! ! apply the runoff input flow
205	DO jk = 1, nk_rnf(ji,jj)
206	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
207	END DO
208	END DO
209	END DO
210	ELSE ! constant volume case : just apply the runoff input flow
211	DO jj = 1, jpj
212	DO ji = 1, jpi
213	DO jk = 1, nk_rnf(ji,jj)
214	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
215	END DO
216	END DO
217	END DO
218	ENDIF
219	ELSE !== runoff put only at the surface ==!
220	IF( lk_vvl ) THEN ! variable volume case
221	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
222	ENDIF
223	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
224	ENDIF
225	!
226	END SUBROUTINE sbc_rnf_div
227
228
229	SUBROUTINE sbc_rnf_init
230	!!----------------------------------------------------------------------
231	!! * ROUTINE sbc_rnf_init *
232	!!
233	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
234	!!
235	!! ** Method : - read the runoff namsbc_rnf namelist
236	!!
237	!! ** Action : - read parameters
238	!!----------------------------------------------------------------------
239	CHARACTER(len=32) :: rn_dep_file ! runoff file name
240	INTEGER :: ji, jj, jk, jm ! dummy loop indices
241	INTEGER :: ierror, inum ! temporary integer
242	INTEGER :: ios ! Local integer output status for namelist read
243	INTEGER :: nbrec ! temporary integer
244	REAL(wp) :: zacoef
245	REAL(wp), DIMENSION(12) :: zrec ! times records
246	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
247	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
248	!
249	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
250	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
251	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
252	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
253	!!----------------------------------------------------------------------
254	!
255	! !== allocate runoff arrays
256	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
257	!
258	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
259	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
260	nkrnf = 0
261	rnf (:,:) = 0.0_wp
262	rnf_b (:,:) = 0.0_wp
263	rnfmsk (:,:) = 0.0_wp
264	rnfmsk_z(:) = 0.0_wp
265	RETURN
266	ENDIF
267	!
268	! ! ============
269	! ! Namelist
270	! ! ============
271	!
272	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
273	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
274	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
275
276	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
277	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
278	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
279	IF(lwm) WRITE ( numond, namsbc_rnf )
280	!
281	! ! Control print
282	IF(lwp) THEN
283	WRITE(numout,*)
284	WRITE(numout,*) 'sbc_rnf : runoff '
285	WRITE(numout,*) '~~~~~~~ '
286	WRITE(numout,*) ' Namelist namsbc_rnf'
287	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
288	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
289	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
290	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
291	ENDIF
292	! ! ==================
293	! ! Type of runoff
294	! ! ==================
295	!
296	IF( .NOT. l_rnfcpl ) THEN
297	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
298	IF(lwp) WRITE(numout,*)
299	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
300	IF( ierror > 0 ) THEN
301	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
302	ENDIF
303	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
304	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
305	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
306	ENDIF
307	!
308	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
309	IF(lwp) WRITE(numout,*)
310	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
311	ALLOCATE( sf_t_rnf(1), STAT=ierror )
312	IF( ierror > 0 ) THEN
313	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
314	ENDIF
315	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
316	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
317	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
318	ENDIF
319	!
320	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
321	IF(lwp) WRITE(numout,*)
322	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
323	ALLOCATE( sf_s_rnf(1), STAT=ierror )
324	IF( ierror > 0 ) THEN
325	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
326	ENDIF
327	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
328	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
329	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
330	ENDIF
331	!
332	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
333	IF(lwp) WRITE(numout,*)
334	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
335	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
336	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
337	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
338	ENDIF
339	CALL iom_open ( rn_dep_file, inum ) ! open file
340	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
341	CALL iom_close( inum ) ! close file
342	!
343	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
344	DO jj = 1, jpj
345	DO ji = 1, jpi
346	IF( h_rnf(ji,jj) > 0._wp ) THEN
347	jk = 2
348	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
349	END DO
350	nk_rnf(ji,jj) = jk
351	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
352	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
353	ELSE
354	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
355	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
356	ENDIF
357	END DO
358	END DO
359	DO jj = 1, jpj ! set the associated depth
360	DO ji = 1, jpi
361	h_rnf(ji,jj) = 0._wp
362	DO jk = 1, nk_rnf(ji,jj)
363	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
364	END DO
365	END DO
366	END DO
367	!
368	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
369	!
370	IF(lwp) WRITE(numout,*)
371	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
372	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
373	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
374	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
375
376	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
377	CALL iom_gettime( inum, zrec, kntime=nbrec)
378	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
379	DO jm = 1, nbrec
380	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
381	END DO
382	CALL iom_close( inum )
383	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
384	DEALLOCATE( zrnfcl )
385	!
386	h_rnf(:,:) = 1.
387	!
388	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
389	!
390	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
391	!
392	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
393	DO ji = 1, jpi
394	IF( zrnf(ji,jj) > 0._wp ) THEN
395	jk = mbkt(ji,jj)
396	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
397	ENDIF
398	END DO
399	END DO
400	!
401	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
402	DO jj = 1, jpj
403	DO ji = 1, jpi
404	IF( zrnf(ji,jj) > 0._wp ) THEN
405	jk = 2
406	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
407	END DO
408	nk_rnf(ji,jj) = jk
409	ELSE
410	nk_rnf(ji,jj) = 1
411	ENDIF
412	END DO
413	END DO
414	!
415	DEALLOCATE( zrnf )
416	!
417	DO jj = 1, jpj ! set the associated depth
418	DO ji = 1, jpi
419	h_rnf(ji,jj) = 0._wp
420	DO jk = 1, nk_rnf(ji,jj)
421	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
422	END DO
423	END DO
424	END DO
425	!
426	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
427	IF(lwp) WRITE(numout,*) ' create runoff depht file'
428	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
429	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
430	CALL iom_close ( inum )
431	ENDIF
432	ELSE ! runoffs applied at the surface
433	nk_rnf(:,:) = 1
434	h_rnf (:,:) = fse3t(:,:,1)
435	ENDIF
436	!
437	rnf(:,:) = 0._wp ! runoff initialisation
438	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
439	!
440	! ! ========================
441	! ! River mouth vicinity
442	! ! ========================
443	!
444	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
445	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
446	! ! - set to zero SSS damping (ln_ssr=T)
447	! ! - mixed upstream-centered (ln_traadv_cen2=T)
448	!
449	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
450	& 'be spread through depth by ln_rnf_depth' )
451	!
452	nkrnf = 0 ! Number of level over which Kz increase
453	IF( rn_hrnf > 0._wp ) THEN
454	nkrnf = 2
455	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
456	END DO
457	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
458	ENDIF
459	IF(lwp) WRITE(numout,*)
460	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
461	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
462	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
463	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
464	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
465	!
466	CALL rnf_mouth ! set river mouth mask
467	!
468	ELSE ! No treatment at river mouths
469	IF(lwp) WRITE(numout,*)
470	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
471	rnfmsk (:,:) = 0._wp
472	rnfmsk_z(:) = 0._wp
473	nkrnf = 0
474	ENDIF
475	!
476	END SUBROUTINE sbc_rnf_init
477
478
479	SUBROUTINE rnf_mouth
480	!!----------------------------------------------------------------------
481	!! * ROUTINE rnf_mouth *
482	!!
483	!! ** Purpose : define the river mouths mask
484	!!
485	!! ** Method : read the river mouth mask (=0/1) in the river runoff
486	!! climatological file. Defined a given vertical structure.
487	!! CAUTION, the vertical structure is hard coded on the
488	!! first 5 levels.
489	!! This fields can be used to:
490	!! - set an upstream advection scheme
491	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
492	!! - increase vertical on the top nn_krnf vertical levels
493	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
494	!! - set to zero SSS restoring flux at river mouth grid points
495	!!
496	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
497	!! rnfmsk_z vertical structure
498	!!----------------------------------------------------------------------
499	INTEGER :: inum ! temporary integers
500	CHARACTER(len=140) :: cl_rnfile ! runoff file name
501	!!----------------------------------------------------------------------
502	!
503	IF(lwp) WRITE(numout,*)
504	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
505	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
506	!
507	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
508	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
509	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
510	ENDIF
511	!
512	! horizontal mask (read in NetCDF file)
513	CALL iom_open ( cl_rnfile, inum ) ! open file
514	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
515	CALL iom_close( inum ) ! close file
516	!
517	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
518	!
519	rnfmsk_z(:) = 0._wp ! vertical structure
520	rnfmsk_z(1) = 1.0
521	rnfmsk_z(2) = 1.0 ! **********
522	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
523	rnfmsk_z(4) = 0.25 ! **********
524	rnfmsk_z(5) = 0.125
525	!
526	END SUBROUTINE rnf_mouth
527
528	!!======================================================================
529	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_obs_oper_update_icethick/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 9987

Download in other formats: