Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

obs_read_surf.F90 @ 13384

Last change on this file since 13384 was 13384, checked in by mattmartin, 4 years ago
First working version of surface velocity observation operator code.
File size: 23.5 KB

Line
1	MODULE obs_read_surf
2	!!======================================================================
3	!! * MODULE obs_read_surf *
4	!! Observation diagnostics: Read the surface data from feedback files
5	!!======================================================================
6
7	!!----------------------------------------------------------------------
8	!! obs_rea_surf : Driver for reading surface data from feedback files
9	!!----------------------------------------------------------------------
10
11	!! * Modules used
12	USE par_kind ! Precision variables
13	USE in_out_manager ! I/O manager
14	USE dom_oce ! Ocean space and time domain variables
15	USE obs_mpp ! MPP support routines for observation diagnostics
16	USE julian ! Julian date routines
17	USE obs_utils ! Observation operator utility functions
18	USE obs_grid ! Grid search
19	USE obs_sort ! Sorting observation arrays
20	USE obs_surf_def ! Surface observation definitions
21	USE obs_types ! Observation type definitions
22	USE obs_fbm ! Feedback routines
23	USE netcdf ! NetCDF library
24
25	IMPLICIT NONE
26
27	!! * Routine accessibility
28	PRIVATE
29
30	PUBLIC obs_rea_surf ! Read the surface observations from the point data
31
32	!!----------------------------------------------------------------------
33	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
34	!! $Id$
35	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36	!!----------------------------------------------------------------------
37
38	CONTAINS
39
40	SUBROUTINE obs_rea_surf( surfdata, knumfiles, cdfilenames, &
41	& kvars, kextr, kstp, ddobsini, ddobsend, MeanPeriodHours, &
42	& ldignmis, ldmod, ldnightav, ldclim, ln_time_mean_sla_bkg, cdvars )
43	!!---------------------------------------------------------------------
44	!!
45	!! * ROUTINE obs_rea_surf *
46	!!
47	!! ** Purpose : Read from file the surface data
48	!!
49	!! ** Method : Read in the data from feedback format files and
50	!! put into the NEMO internal surface data structure
51	!!
52	!! ** Action :
53	!!
54	!!
55	!! History :
56	!! ! : 2009-01 (K. Mogensen) Initial version based on old versions
57	!! ! : 2015-02 (M. Martin) Unify the different surface data type reading.
58	!!----------------------------------------------------------------------
59	!! * Modules used
60
61	!! * Arguments
62	TYPE(obs_surf), INTENT(INOUT) :: &
63	& surfdata ! Surface data to be read
64	INTEGER, INTENT(IN) :: knumfiles ! Number of corio format files to read
65	CHARACTER(LEN=128), INTENT(IN) :: &
66	& cdfilenames(knumfiles) ! File names to read in
67	INTEGER, INTENT(IN) :: kvars ! Number of variables in surfdata
68	INTEGER, INTENT(IN) :: kextr ! Number of extra fields for each var
69	INTEGER, INTENT(IN) :: kstp ! Ocean time-step index
70	LOGICAL, INTENT(IN) :: ldignmis ! Ignore missing files
71	LOGICAL, INTENT(IN) :: ldmod ! Initialize model from input data
72	LOGICAL, INTENT(IN) :: ldnightav ! Observations represent a night-time average
73	LOGICAL, INTENT(IN) :: ldclim ! Will include climatology at obs points.
74	LOGICAL, INTENT(IN) :: ln_time_mean_sla_bkg ! Will reset times to end of averaging period.
75	REAL(dp), INTENT(IN) :: ddobsini ! Obs. ini time in YYYYMMDD.HHMMSS
76	REAL(dp), INTENT(IN) :: ddobsend ! Obs. end time in YYYYMMDD.HHMMSS
77	REAL(wp), INTENT(IN) :: MeanPeriodHours ! Averaging period in hours
78	CHARACTER(len=8), DIMENSION(kvars), INTENT(IN) :: cdvars
79
80	!! * Local declarations
81	CHARACTER(LEN=11), PARAMETER :: cpname='obs_rea_surf'
82	CHARACTER(len=8) :: clrefdate
83	CHARACTER(len=8), DIMENSION(:), ALLOCATABLE :: clvarsin
84	INTEGER :: ji
85	INTEGER :: jj
86	INTEGER :: jk
87	INTEGER :: jvar
88	INTEGER :: iflag
89	INTEGER :: inobf
90	INTEGER :: i_file_id
91	INTEGER :: inowin
92	INTEGER :: iyea
93	INTEGER :: imon
94	INTEGER :: iday
95	INTEGER :: ihou
96	INTEGER :: imin
97	INTEGER :: isec
98	INTEGER :: itype
99	INTEGER :: iobsmpp
100	INTEGER :: iobs
101	INTEGER :: iobstot
102	INTEGER :: ios
103	INTEGER :: ioserrcount
104	INTEGER :: iextr
105	INTEGER, PARAMETER :: jpsurfmaxtype = 1024
106	INTEGER, DIMENSION(knumfiles) :: irefdate
107	INTEGER, DIMENSION(jpsurfmaxtype+1) :: &
108	& ityp, &
109	& itypmpp
110	INTEGER, DIMENSION(:,:), ALLOCATABLE :: &
111	& iobsi, &
112	& iobsj, &
113	& iproc
114	INTEGER, DIMENSION(:), ALLOCATABLE :: &
115	& iindx, &
116	& ifileidx, &
117	& isurfidx, &
118	& iadd_std
119	REAL(wp), DIMENSION(:), ALLOCATABLE :: &
120	& zphi, &
121	& zlam
122	REAL(wp), DIMENSION(:), ALLOCATABLE :: &
123	& zdat
124	REAL(wp), DIMENSION(knumfiles) :: &
125	& djulini, &
126	& djulend
127	LOGICAL :: llvalprof
128	TYPE(obfbdata), POINTER, DIMENSION(:) :: &
129	& inpfiles
130	CHARACTER(LEN=256) :: cout1 ! Diagnostic output line
131
132	! Local initialization
133	iobs = 0
134	iextr = kextr
135	!-----------------------------------------------------------------------
136	! Count the number of files needed and allocate the obfbdata type
137	!-----------------------------------------------------------------------
138
139	inobf = knumfiles
140
141	ALLOCATE( inpfiles(inobf) )
142	ALLOCATE( iadd_std(inobf) )
143
144	surf_files : DO jj = 1, inobf
145
146	!---------------------------------------------------------------------
147	! Prints
148	!---------------------------------------------------------------------
149	IF(lwp) THEN
150	WRITE(numout,*)
151	WRITE(numout,*) ' obs_rea_surf : Reading from file = ', &
152	& TRIM( TRIM( cdfilenames(jj) ) )
153	WRITE(numout,*) ' ~~~~~~~~~~~'
154	WRITE(numout,*)
155	ENDIF
156
157	!---------------------------------------------------------------------
158	! Initialization: Open file and get dimensions only
159	!---------------------------------------------------------------------
160
161	iflag = nf90_open( TRIM( TRIM( cdfilenames(jj) ) ), nf90_nowrite, &
162	& i_file_id )
163
164	IF ( iflag /= nf90_noerr ) THEN
165
166	IF ( ldignmis ) THEN
167	inpfiles(jj)%nobs = 0
168	CALL ctl_warn( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
169	& ' not found' )
170	ELSE
171	CALL ctl_stop( 'File ' // TRIM( TRIM( cdfilenames(jj) ) ) // &
172	& ' not found' )
173	ENDIF
174
175	ELSE
176
177	!------------------------------------------------------------------
178	! Close the file since it is opened in read_obfbdata
179	!------------------------------------------------------------------
180
181	iflag = nf90_close( i_file_id )
182
183	!------------------------------------------------------------------
184	! Read the surface file into inpfiles
185	!------------------------------------------------------------------
186	CALL init_obfbdata( inpfiles(jj) )
187	CALL read_obfbdata( TRIM( cdfilenames(jj) ), inpfiles(jj), &
188	& ldgrid = .TRUE. )
189
190	IF ( inpfiles(jj)%nvar /= kvars ) THEN
191	CALL ctl_stop( 'Feedback format error: ', &
192	& ' unexpected number of vars in feedback file' )
193	ENDIF
194
195	IF ( ldmod .AND. ( inpfiles(jj)%nadd == 0 ) ) THEN
196	CALL ctl_stop( 'Model not in input data' )
197	RETURN
198	ENDIF
199
200	IF ( jj == 1 ) THEN
201	ALLOCATE( clvarsin( inpfiles(jj)%nvar ) )
202	DO ji = 1, inpfiles(jj)%nvar
203	clvarsin(ji) = inpfiles(jj)%cname(ji)
204	IF ( clvarsin(ji) /= cdvars(ji) ) THEN
205	CALL ctl_stop( 'Feedback file variables do not match', &
206	& ' expected variable names for this type' )
207	ENDIF
208	END DO
209	ELSE
210	DO ji = 1, inpfiles(jj)%nvar
211	IF ( inpfiles(jj)%cname(ji) /= clvarsin(ji) ) THEN
212	CALL ctl_stop( 'Feedback file variables not consistent', &
213	& ' with previous files for this type' )
214	ENDIF
215	END DO
216	ENDIF
217
218	iadd_std(jj) = -1
219	IF ( inpfiles(jj)%nadd > 0 ) THEN
220	DO ji = 1, inpfiles(jj)%nadd
221	IF ( TRIM( inpfiles(jj)%caddname(ji) ) == 'STD' ) THEN
222	iextr = kextr + 1
223	iadd_std(jj) = ji
224	ENDIF
225	END DO
226	ENDIF
227
228	IF(lwp) THEN
229	IF ( iadd_std(jj) /= -1 ) THEN
230	WRITE(numout,*) ' STD variable available in input file so passing it through the obs oper'
231	WRITE(numout,*)
232	ENDIF
233	ENDIF
234
235	!------------------------------------------------------------------
236	! Change longitude (-180,180)
237	!------------------------------------------------------------------
238
239	DO ji = 1, inpfiles(jj)%nobs
240
241	IF ( inpfiles(jj)%plam(ji) < -180. ) &
242	& inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) + 360.
243
244	IF ( inpfiles(jj)%plam(ji) > 180. ) &
245	& inpfiles(jj)%plam(ji) = inpfiles(jj)%plam(ji) - 360.
246
247	END DO
248
249	!------------------------------------------------------------------
250	! Calculate the date (change eventually)
251	!------------------------------------------------------------------
252	clrefdate=inpfiles(jj)%cdjuldref(1:8)
253	READ(clrefdate,'(I8)') irefdate(jj)
254
255	CALL ddatetoymdhms( ddobsini, iyea, imon, iday, ihou, imin, isec )
256	CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulini(jj), &
257	& krefdate = irefdate(jj) )
258	CALL ddatetoymdhms( ddobsend, iyea, imon, iday, ihou, imin, isec )
259	CALL greg2jul( isec, imin, ihou, iday, imon, iyea, djulend(jj), &
260	& krefdate = irefdate(jj) )
261
262	IF ( ldnightav ) THEN
263
264	IF ( lwp ) THEN
265	WRITE(numout,*)'Resetting time of night-time averaged observations', &
266	& ' to the end of the day'
267	ENDIF
268
269	DO ji = 1, inpfiles(jj)%nobs
270	! for night-time averaged data force the time
271	! to be the last time-step of the day, but still within the day.
272	IF ( inpfiles(jj)%ptim(ji) >= 0. ) THEN
273	inpfiles(jj)%ptim(ji) = &
274	& INT(inpfiles(jj)%ptim(ji)) + 0.9999
275	ELSE
276	inpfiles(jj)%ptim(ji) = &
277	& INT(inpfiles(jj)%ptim(ji)) - 0.0001
278	ENDIF
279	END DO
280	ENDIF
281
282	IF ( inpfiles(jj)%nobs > 0 ) THEN
283	inpfiles(jj)%iproc(:,:) = -1
284	inpfiles(jj)%iobsi(:,:) = -1
285	inpfiles(jj)%iobsj(:,:) = -1
286	ENDIF
287
288	!If SLA observations are representing a time mean then set the time
289	!of the obs to the end of that meaning period relative to the start of the run
290	IF ( ln_time_mean_sla_bkg .AND. ( TRIM( clvarsin(1) ) == 'SLA' ) ) THEN
291	DO ji = 1, inpfiles(jj)%nobs
292	! Only do this for obs within time window
293	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
294	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
295	inpfiles(jj)%ptim(ji) = &
296	& djulini(jj) + (MeanPeriodHours/24.)
297	ENDIF
298	END DO
299	ENDIF
300
301	inowin = 0
302	DO ji = 1, inpfiles(jj)%nobs
303	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
304	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
305	inowin = inowin + 1
306	ENDIF
307	END DO
308	ALLOCATE( zlam(inowin) )
309	ALLOCATE( zphi(inowin) )
310	ALLOCATE( iobsi(inowin,kvars) )
311	ALLOCATE( iobsj(inowin,kvars) )
312	ALLOCATE( iproc(inowin,kvars) )
313	inowin = 0
314	DO ji = 1, inpfiles(jj)%nobs
315	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
316	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
317	inowin = inowin + 1
318	zlam(inowin) = inpfiles(jj)%plam(ji)
319	zphi(inowin) = inpfiles(jj)%pphi(ji)
320	ENDIF
321	END DO
322
323	! Assume anything other than velocity is on T grid
324	IF ( TRIM( inpfiles(jj)%cname(1) ) == 'UVEL' ) THEN
325	CALL obs_grid_search( inowin, zlam, zphi, iobsi(:,1), iobsj(:,1), &
326	& iproc(:,1), 'U' )
327	CALL obs_grid_search( inowin, zlam, zphi, iobsi(:,2), iobsj(:,2), &
328	& iproc(:,2), 'V' )
329	ELSE
330	CALL obs_grid_search( inowin, zlam, zphi, iobsi(:,1), iobsj(:,1), &
331	& iproc(:,1), 'T' )
332	IF ( kvars > 1 ) THEN
333	DO jvar = 2, kvars
334	iobsi(:,jvar) = iobsi(:,1)
335	iobsj(:,jvar) = iobsj(:,1)
336	iproc(:,jvar) = iproc(:,1)
337	END DO
338	ENDIF
339	ENDIF
340
341	inowin = 0
342	DO ji = 1, inpfiles(jj)%nobs
343	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
344	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
345	inowin = inowin + 1
346	DO jvar = 1, kvars
347	inpfiles(jj)%iproc(ji,jvar) = iproc(inowin,jvar)
348	inpfiles(jj)%iobsi(ji,jvar) = iobsi(inowin,jvar)
349	inpfiles(jj)%iobsj(ji,jvar) = iobsj(inowin,jvar)
350	END DO
351	ENDIF
352	END DO
353	DEALLOCATE( zlam, zphi, iobsi, iobsj, iproc )
354
355	DO ji = 1, inpfiles(jj)%nobs
356	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
357	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
358	IF ( nproc == 0 ) THEN
359	IF ( inpfiles(jj)%iproc(ji,1) > nproc ) CYCLE
360	ELSE
361	IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
362	ENDIF
363	llvalprof = .FALSE.
364	IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
365	iobs = iobs + 1
366	ENDIF
367	ENDIF
368	END DO
369
370	ENDIF
371
372	END DO surf_files
373
374	!-----------------------------------------------------------------------
375	! Get the time ordered indices of the input data
376	!-----------------------------------------------------------------------
377
378	!---------------------------------------------------------------------
379	! Loop over input data files to count total number of profiles
380	!---------------------------------------------------------------------
381	iobstot = 0
382	DO jj = 1, inobf
383	DO ji = 1, inpfiles(jj)%nobs
384	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
385	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
386	iobstot = iobstot + 1
387	ENDIF
388	END DO
389	END DO
390
391	ALLOCATE( iindx(iobstot), ifileidx(iobstot), &
392	& isurfidx(iobstot), zdat(iobstot) )
393	jk = 0
394	DO jj = 1, inobf
395	DO ji = 1, inpfiles(jj)%nobs
396	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
397	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
398	jk = jk + 1
399	ifileidx(jk) = jj
400	isurfidx(jk) = ji
401	zdat(jk) = inpfiles(jj)%ptim(ji)
402	ENDIF
403	END DO
404	END DO
405	CALL sort_dp_indx( iobstot, &
406	& zdat, &
407	& iindx )
408
409	CALL obs_surf_alloc( surfdata, iobs, kvars, iextr, kstp, jpi, jpj, ldclim )
410
411	! Read obs/positions, QC, all variable and assign to surfdata
412
413	iobs = 0
414	surfdata%cvars(:) = clvarsin(:)
415	IF ( ldmod .AND. ( TRIM( surfdata%cvars(1) ) == 'SLA' ) ) THEN
416	surfdata%cext(1) = 'SSH'
417	surfdata%cext(2) = 'MDT'
418	ENDIF
419	IF ( ldmod .AND. ( TRIM( surfdata%cvars(1) ) == 'FBD' ) ) THEN
420	surfdata%cext(1) = 'freeboard'
421	surfdata%cext(2) = 'thick_s'
422	ENDIF
423	IF ( iextr > kextr ) surfdata%cext(iextr) = 'STD'
424
425	ityp (:) = 0
426	itypmpp(:) = 0
427
428	ioserrcount = 0
429
430	DO jk = 1, iobstot
431
432	jj = ifileidx(iindx(jk))
433	ji = isurfidx(iindx(jk))
434	IF ( ( inpfiles(jj)%ptim(ji) > djulini(jj) ) .AND. &
435	& ( inpfiles(jj)%ptim(ji) <= djulend(jj) ) ) THEN
436
437	IF ( nproc == 0 ) THEN
438	IF ( inpfiles(jj)%iproc(ji,1) > nproc ) CYCLE
439	ELSE
440	IF ( inpfiles(jj)%iproc(ji,1) /= nproc ) CYCLE
441	ENDIF
442
443	! Set observation information
444
445	IF ( .NOT. BTEST(inpfiles(jj)%ivlqc(1,ji,1),2) ) THEN
446
447	iobs = iobs + 1
448
449	CALL jul2greg( isec, &
450	& imin, &
451	& ihou, &
452	& iday, &
453	& imon, &
454	& iyea, &
455	& inpfiles(jj)%ptim(ji), &
456	& irefdate(jj) )
457
458
459	! Surface time coordinates
460	surfdata%nyea(iobs) = iyea
461	surfdata%nmon(iobs) = imon
462	surfdata%nday(iobs) = iday
463	surfdata%nhou(iobs) = ihou
464	surfdata%nmin(iobs) = imin
465
466	! Surface space coordinates
467	surfdata%rlam(iobs) = inpfiles(jj)%plam(ji)
468	surfdata%rphi(iobs) = inpfiles(jj)%pphi(ji)
469
470	! Coordinate search parameters
471	DO jvar = 1, kvars
472	surfdata%mi(iobs,jvar) = inpfiles(jj)%iobsi(ji,jvar)
473	surfdata%mj(iobs,jvar) = inpfiles(jj)%iobsj(ji,jvar)
474	END DO
475
476	! WMO number
477	surfdata%cwmo(iobs) = inpfiles(jj)%cdwmo(ji)
478
479	! Instrument type
480	READ( inpfiles(jj)%cdtyp(ji), '(I4)', IOSTAT = ios, ERR = 901 ) itype
481	901 IF ( ios /= 0 ) THEN
482	IF (ioserrcount == 0) THEN
483	CALL ctl_warn ( 'Problem converting an instrument type ', &
484	& 'to integer. Setting type to zero' )
485	ENDIF
486	ioserrcount = ioserrcount + 1
487	itype = 0
488	ENDIF
489	surfdata%ntyp(iobs) = itype
490	IF ( itype < jpsurfmaxtype + 1 ) THEN
491	ityp(itype+1) = ityp(itype+1) + 1
492	ELSE
493	IF(lwp)WRITE(numout,*)'WARNING:Increase jpsurfmaxtype in ',&
494	& cpname
495	ENDIF
496
497	! Bookkeeping data to match observations
498	surfdata%nsidx(iobs) = iobs
499	surfdata%nsfil(iobs) = iindx(jk)
500
501	! QC flags
502	surfdata%nqc(iobs) = inpfiles(jj)%ivqc(ji,1)
503
504	! Observed value
505	DO jvar = 1, kvars
506	surfdata%robs(iobs,jvar) = inpfiles(jj)%pob(1,ji,jvar)
507	END DO
508	IF ( TRIM(surfdata%cvars(1)) == 'FBD' ) THEN
509	surfdata%rext(iobs,1) = inpfiles(jj)%pob(1,ji,1)
510	surfdata%rext(iobs,2) = fbrmdi
511	ENDIF
512
513	! Model and MDT is set to fbrmdi unless read from file
514	IF ( ldmod ) THEN
515	DO jvar = 1, kvars
516	surfdata%rmod(iobs,jvar) = inpfiles(jj)%padd(1,ji,1,jvar)
517	END DO
518	IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) THEN
519	surfdata%rext(iobs,1) = inpfiles(jj)%padd(1,ji,2,1)
520	surfdata%rext(iobs,2) = inpfiles(jj)%pext(1,ji,1)
521	ENDIF
522	ELSE
523	DO jvar = 1, kvars
524	surfdata%rmod(iobs,jvar) = fbrmdi
525	END DO
526	IF ( TRIM(surfdata%cvars(1)) == 'SLA' ) surfdata%rext(iobs,:) = fbrmdi
527	ENDIF
528
529	! Initialise climatology if set
530	IF ( surfdata%lclim ) THEN
531	DO jvar = 1, kvars
532	surfdata%rclm(iobs,jvar) = fbrmdi
533	END DO
534	ENDIF
535
536	! STD (obs error standard deviation) read from file and passed through obs operator
537	IF ( iadd_std(jj) /= -1 ) THEN
538	surfdata%rext(iobs,iextr) = inpfiles(jj)%padd(1,ji,iadd_std(jj),1)
539	ENDIF
540	ENDIF
541	ENDIF
542
543	END DO
544
545	!-----------------------------------------------------------------------
546	! Sum up over processors
547	!-----------------------------------------------------------------------
548
549	CALL obs_mpp_sum_integer( iobs, iobsmpp )
550	CALL obs_mpp_sum_integers( ityp, itypmpp, jpsurfmaxtype + 1 )
551
552	!-----------------------------------------------------------------------
553	! Output number of observations.
554	!-----------------------------------------------------------------------
555	IF (lwp) THEN
556	DO jvar = 1, surfdata%nvar
557	IF ( jvar == 1 ) THEN
558	cout1=TRIM(surfdata%cvars(1))
559	ELSE
560	WRITE(cout1,'(A,A1,A)') TRIM(cout1), '/', TRIM(surfdata%cvars(jvar))
561	ENDIF
562	END DO
563
564	WRITE(numout,*)
565	WRITE(numout,'(1X,A)')TRIM( cout1 )//' data'
566	WRITE(numout,'(1X,A)')'--------------'
567	DO jj = 1,8
568	IF ( itypmpp(jj) > 0 ) THEN
569	WRITE(numout,'(1X,A4,I4,A3,I10)')'Type ', jj,' = ',itypmpp(jj)
570	ENDIF
571	END DO
572	WRITE(numout,'(1X,A)') &
573	& '---------------------------------------------------------------'
574	WRITE(numout,'(1X,A,I8)') &
575	& 'Total data for variable '//TRIM( cout1 )// &
576	& ' = ', iobsmpp
577	WRITE(numout,'(1X,A)') &
578	& '---------------------------------------------------------------'
579	WRITE(numout,*)
580
581	ENDIF
582
583	!-----------------------------------------------------------------------
584	! Deallocate temporary data
585	!-----------------------------------------------------------------------
586	DEALLOCATE( ifileidx, isurfidx, zdat, clvarsin )
587
588	!-----------------------------------------------------------------------
589	! Deallocate input data
590	!-----------------------------------------------------------------------
591	DO jj = 1, inobf
592	IF ( inpfiles(jj)%lalloc ) THEN
593	CALL dealloc_obfbdata( inpfiles(jj) )
594	ENDIF
595	END DO
596	DEALLOCATE( inpfiles )
597	DEALLOCATE( iadd_std )
598
599	END SUBROUTINE obs_rea_surf
600
601	END MODULE obs_read_surf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_obs_oper_update_vel_obsoper/NEMOGCM/NEMO/OPA_SRC/OBS/obs_read_surf.F90 @ 13384

Download in other formats: