New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/UKMO/dev_r5518_pcbias_ipc/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5518_pcbias_ipc/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8435

Last change on this file since 8435 was 8435, checked in by isabella, 7 years ago

Added changes after review.

File size: 70.9 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE biaspar         ! bias correction variables
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   z_rhd_st  ! tmp density storage for pressure corr
88      REAL(wp), DIMENSION(jpi,jpj)     ::   z_gru_st  ! tmp ua trends storage for pressure corr
89      REAL(wp), DIMENSION(jpi,jpj)     ::   z_grv_st  ! tmp va trends storage for pressure corr
90      !!----------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
93      !
94      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
95         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
96         ztrdu(:,:,:) = ua(:,:,:)
97         ztrdv(:,:,:) = va(:,:,:)
98      ENDIF
99      !
100      IF ( ln_bias .AND. ln_bias_pc_app ) THEN
101         z_rhd_st(:,:,:) = rhd(:,:,:)     ! store orig density
102         rhd(:,:,:)      = rhd_pc(:,:,:)  ! use pressure corrected density
103         z_gru_st(:,:)   = gru(:,:)
104         gru(:,:)        = gru_pc(:,:)
105         z_grv_st(:,:)   = grv(:,:)
106         grv(:,:)        = grv_pc(:,:)
107      ENDIF
108
109      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
110      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
111      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
112      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
113      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
114      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
115      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
116      END SELECT
117      !
118      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
119         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
120         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
121         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
122         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
123      ENDIF
124      !
125      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
126         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
127      !
128      IF ( ln_bias .AND. ln_bias_pc_app )  THEN
129         IF(lwp) THEN
130         WRITE(numout,*) " ! restore original density"
131         ENDIF
132         rhd(:,:,:) = z_rhd_st(:,:,:)     ! restore original density
133         gru(:,:)   = z_gru_st(:,:)
134         grv(:,:)   = z_grv_st(:,:)
135      ENDIF
136      !
137      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
138      !
139   END SUBROUTINE dyn_hpg
140
141
142   SUBROUTINE dyn_hpg_init
143      !!----------------------------------------------------------------------
144      !!                 ***  ROUTINE dyn_hpg_init  ***
145      !!
146      !! ** Purpose :   initializations for the hydrostatic pressure gradient
147      !!              computation and consistency control
148      !!
149      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
150      !!      with the type of vertical coordinate used (zco, zps, sco)
151      !!----------------------------------------------------------------------
152      INTEGER ::   ioptio = 0      ! temporary integer
153      INTEGER ::   ios             ! Local integer output status for namelist read
154      !!
155      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
156         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
157      !!----------------------------------------------------------------------
158      !
159      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
160      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
161901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
162
163      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
164      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
165902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
166      IF(lwm) WRITE ( numond, namdyn_hpg )
167      !
168      IF(lwp) THEN                   ! Control print
169         WRITE(numout,*)
170         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
171         WRITE(numout,*) '~~~~~~~~~~~~'
172         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
173         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
174         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
175         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
176         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
177         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
178         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
179         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
180      ENDIF
181      !
182      IF( ln_hpg_djc )   &
183         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
184                           & currently disabled (bugs under investigation). Please select &
185                           & either  ln_hpg_sco or  ln_hpg_prj instead')
186      !
187      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
188         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
189                           & the standard jacobian formulation hpg_sco or &
190                           & the pressure jacobian formulation hpg_prj')
191
192      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
193         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
194      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
195         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
196      !
197      !                               ! Set nhpg from ln_hpg_... flags
198      IF( ln_hpg_zco )   nhpg = 0
199      IF( ln_hpg_zps )   nhpg = 1
200      IF( ln_hpg_sco )   nhpg = 2
201      IF( ln_hpg_djc )   nhpg = 3
202      IF( ln_hpg_prj )   nhpg = 4
203      IF( ln_hpg_isf )   nhpg = 5
204      !
205      !                               ! Consistency check
206      ioptio = 0
207      IF( ln_hpg_zco )   ioptio = ioptio + 1
208      IF( ln_hpg_zps )   ioptio = ioptio + 1
209      IF( ln_hpg_sco )   ioptio = ioptio + 1
210      IF( ln_hpg_djc )   ioptio = ioptio + 1
211      IF( ln_hpg_prj )   ioptio = ioptio + 1
212      IF( ln_hpg_isf )   ioptio = ioptio + 1
213      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
214      !
215      ! initialisation of ice load
216      riceload(:,:)=0.0
217      !
218   END SUBROUTINE dyn_hpg_init
219
220
221   SUBROUTINE hpg_zco( kt )
222      !!---------------------------------------------------------------------
223      !!                  ***  ROUTINE hpg_zco  ***
224      !!
225      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
226      !!      The now hydrostatic pressure gradient at a given level, jk,
227      !!      is computed by taking the vertical integral of the in-situ
228      !!      density gradient along the model level from the suface to that
229      !!      level:    zhpi = grav .....
230      !!                zhpj = grav .....
231      !!      add it to the general momentum trend (ua,va).
232      !!            ua = ua - 1/e1u * zhpi
233      !!            va = va - 1/e2v * zhpj
234      !!
235      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
236      !!----------------------------------------------------------------------
237      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
238      !!
239      INTEGER  ::   ji, jj, jk       ! dummy loop indices
240      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
241      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
242      !!----------------------------------------------------------------------
243      !
244      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
245      !
246      IF( kt == nit000 ) THEN
247         IF(lwp) WRITE(numout,*)
248         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
249         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
250      ENDIF
251
252      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
253
254      ! Surface value
255      DO jj = 2, jpjm1
256         DO ji = fs_2, fs_jpim1   ! vector opt.
257            zcoef1 = zcoef0 * fse3w(ji,jj,1)
258            ! hydrostatic pressure gradient
259            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
260            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
261            ! add to the general momentum trend
262            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
263            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
264         END DO
265      END DO
266
267      !
268      ! interior value (2=<jk=<jpkm1)
269      DO jk = 2, jpkm1
270         DO jj = 2, jpjm1
271            DO ji = fs_2, fs_jpim1   ! vector opt.
272               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
273               ! hydrostatic pressure gradient
274               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
275                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
276                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
277
278               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
279                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
280                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
281               ! add to the general momentum trend
282               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
283               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
284            END DO
285         END DO
286      END DO
287      !
288      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
289      !
290   END SUBROUTINE hpg_zco
291
292
293   SUBROUTINE hpg_zps( kt )
294      !!---------------------------------------------------------------------
295      !!                 ***  ROUTINE hpg_zps  ***
296      !!
297      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
298      !!
299      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
300      !!----------------------------------------------------------------------
301      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
302      !!
303      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
304      INTEGER  ::   iku, ikv                         ! temporary integers
305      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
306      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
307      !!----------------------------------------------------------------------
308      !
309      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
310      !
311      IF( kt == nit000 ) THEN
312         IF(lwp) WRITE(numout,*)
313         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
314         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
315      ENDIF
316
317
318      ! Local constant initialization
319      zcoef0 = - grav * 0.5_wp
320
321      !  Surface value (also valid in partial step case)
322      DO jj = 2, jpjm1
323         DO ji = fs_2, fs_jpim1   ! vector opt.
324            zcoef1 = zcoef0 * fse3w(ji,jj,1)
325            ! hydrostatic pressure gradient
326            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
327            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
328            ! add to the general momentum trend
329            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
330            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
331         END DO
332      END DO
333
334
335      ! interior value (2=<jk=<jpkm1)
336      DO jk = 2, jpkm1
337         DO jj = 2, jpjm1
338            DO ji = fs_2, fs_jpim1   ! vector opt.
339               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
340               ! hydrostatic pressure gradient
341               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
342                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
343                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
344
345               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
346                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
347                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
348               ! add to the general momentum trend
349               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
350               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
351            END DO
352         END DO
353      END DO
354
355
356      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
357      DO jj = 2, jpjm1
358         DO ji = 2, jpim1
359            iku = mbku(ji,jj)
360            ikv = mbkv(ji,jj)
361            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
362            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
363            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
364               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
365               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
366                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
367               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
368            ENDIF
369            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
370               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
371               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
372                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
373               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
374            ENDIF
375         END DO
376      END DO
377      !
378      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
379      !
380   END SUBROUTINE hpg_zps
381
382   SUBROUTINE hpg_sco( kt )
383      !!---------------------------------------------------------------------
384      !!                  ***  ROUTINE hpg_sco  ***
385      !!
386      !! ** Method  :   s-coordinate case. Jacobian scheme.
387      !!      The now hydrostatic pressure gradient at a given level, jk,
388      !!      is computed by taking the vertical integral of the in-situ
389      !!      density gradient along the model level from the suface to that
390      !!      level. s-coordinates (ln_sco): a corrective term is added
391      !!      to the horizontal pressure gradient :
392      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
393      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
394      !!      add it to the general momentum trend (ua,va).
395      !!         ua = ua - 1/e1u * zhpi
396      !!         va = va - 1/e2v * zhpj
397      !!
398      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
399      !!----------------------------------------------------------------------
400      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
401      !!
402      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
403      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
404      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
405      !!----------------------------------------------------------------------
406      !
407      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
408      !
409      IF( kt == nit000 ) THEN
410         IF(lwp) WRITE(numout,*)
411         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
412         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
413      ENDIF
414
415      ! Local constant initialization
416      zcoef0 = - grav * 0.5_wp
417      ! To use density and not density anomaly
418      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
419      ELSE                 ;     znad = 0._wp         ! Fixed volume
420      ENDIF
421
422      ! Surface value
423      DO jj = 2, jpjm1
424         DO ji = fs_2, fs_jpim1   ! vector opt.
425            ! hydrostatic pressure gradient along s-surfaces
426            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
427               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
428            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
429               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
430            ! s-coordinate pressure gradient correction
431            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
432               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
433            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
434               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
435            ! add to the general momentum trend
436            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
437            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
438         END DO
439      END DO
440
441      ! interior value (2=<jk=<jpkm1)
442      DO jk = 2, jpkm1
443         DO jj = 2, jpjm1
444            DO ji = fs_2, fs_jpim1   ! vector opt.
445               ! hydrostatic pressure gradient along s-surfaces
446               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
447                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
448                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
449               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
450                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
451                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
452               ! s-coordinate pressure gradient correction
453               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
454                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
455               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
456                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
457               ! add to the general momentum trend
458               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
459               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
460            END DO
461         END DO
462      END DO
463      !
464      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
465      !
466   END SUBROUTINE hpg_sco
467
468   SUBROUTINE hpg_isf( kt )
469      !!---------------------------------------------------------------------
470      !!                  ***  ROUTINE hpg_sco  ***
471      !!
472      !! ** Method  :   s-coordinate case. Jacobian scheme.
473      !!      The now hydrostatic pressure gradient at a given level, jk,
474      !!      is computed by taking the vertical integral of the in-situ
475      !!      density gradient along the model level from the suface to that
476      !!      level. s-coordinates (ln_sco): a corrective term is added
477      !!      to the horizontal pressure gradient :
478      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
479      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
480      !!      add it to the general momentum trend (ua,va).
481      !!         ua = ua - 1/e1u * zhpi
482      !!         va = va - 1/e2v * zhpj
483      !!      iceload is added and partial cell case are added to the top and bottom
484      !!     
485      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
486      !!----------------------------------------------------------------------
487      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
488      !!
489      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
490      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
491      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
492      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
493      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
494      !!----------------------------------------------------------------------
495      !
496      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
497      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
498      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
499      !
500     IF( kt == nit000 ) THEN
501         IF(lwp) WRITE(numout,*)
502         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
503         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
504      ENDIF
505
506      ! Local constant initialization
507      zcoef0 = - grav * 0.5_wp
508      ! To use density and not density anomaly
509!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
510!      ELSE                 ;     znad = 0._wp         ! Fixed volume
511!      ENDIF
512      znad=1._wp
513      ! iniitialised to 0. zhpi zhpi
514      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
515
516!==================================================================================     
517!=====Compute iceload and contribution of the half first wet layer =================
518!===================================================================================
519
520      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
521      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
522
523      ! compute density of the water displaced by the ice shelf
524      zrhd = rhd ! save rhd
525      DO jk = 1, jpk
526           zdept(:,:)=gdept_1d(jk)
527           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
528      END DO
529      WHERE ( tmask(:,:,:) == 1._wp)
530        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
531      END WHERE
532     
533      ! compute rhd at the ice/oce interface (ice shelf side)
534      CALL eos(ztstop,risfdep,zrhdtop_isf)
535
536      ! compute rhd at the ice/oce interface (ocean side)
537      DO ji=1,jpi
538        DO jj=1,jpj
539          ikt=mikt(ji,jj)
540          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
541          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
542        END DO
543      END DO
544      CALL eos(ztstop,risfdep,zrhdtop_oce)
545      !
546      ! Surface value + ice shelf gradient
547      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
548      ziceload = 0._wp
549      DO jj = 1, jpj
550         DO ji = 1, jpi   ! vector opt.
551            ikt=mikt(ji,jj)
552            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
553            DO jk=2,ikt-1
554               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
555                  &                              * (1._wp - tmask(ji,jj,jk))
556            END DO
557            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
558                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
559         END DO
560      END DO
561      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
562      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
563      DO jj = 2, jpjm1
564         DO ji = fs_2, fs_jpim1   ! vector opt.
565            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
566            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
567            ! we assume ISF is in isostatic equilibrium
568            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
569               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
570               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
571               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
572               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
573            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
574               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
575               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
576               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
577               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
578            ! s-coordinate pressure gradient correction (=0 if z coordinate)
579            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
580               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
581            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
582               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
583            ! add to the general momentum trend
584            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
585            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
586         END DO
587      END DO
588!==================================================================================     
589!===== Compute partial cell contribution for the top cell =========================
590!==================================================================================
591      DO jj = 2, jpjm1
592         DO ji = fs_2, fs_jpim1   ! vector opt.
593            iku = miku(ji,jj) ; 
594            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
595            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
596            ! u direction
597            IF ( iku .GT. 1 ) THEN
598               ! case iku
599               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
600                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
601                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
602               ! corrective term ( = 0 if z coordinate )
603               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
604               ! zhpi will be added in interior loop
605               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
606               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
607               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
608
609               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
610               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
611                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
612                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
613                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
614                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
615               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
616            END IF
617               
618            ! v direction
619            ikv = mikv(ji,jj)
620            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
621            IF ( ikv .GT. 1 ) THEN
622               ! case ikv
623               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
624                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
625                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
626               ! corrective term ( = 0 if z coordinate )
627               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
628               ! zhpi will be added in interior loop
629               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
630               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
631               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
632               
633               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
634               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
635                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
636                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
637                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
638                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
639               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
640            END IF
641         END DO
642      END DO
643
644!==================================================================================     
645!===== Compute interior value =====================================================
646!==================================================================================
647
648      DO jj = 2, jpjm1
649         DO ji = fs_2, fs_jpim1   ! vector opt.
650            iku=miku(ji,jj); ikv=mikv(ji,jj)
651            DO jk = 2, jpkm1
652               ! hydrostatic pressure gradient along s-surfaces
653               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
654               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
655                  &                            + zcoef0 / e1u(ji,jj)                                                           &
656                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
657                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
658                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
659                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
660               ! s-coordinate pressure gradient correction
661               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
662               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
663                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
664               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
665
666               ! hydrostatic pressure gradient along s-surfaces
667               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
668               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
669                  &                            + zcoef0 / e2v(ji,jj)                                                           &
670                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
671                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
672                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
673                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
674               ! s-coordinate pressure gradient correction
675               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
676               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
677                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
678               ! add to the general momentum trend
679               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
680            END DO
681         END DO
682      END DO
683
684!==================================================================================     
685!===== Compute bottom cell contribution (partial cell) ============================
686!==================================================================================
687
688      DO jj = 2, jpjm1
689         DO ji = 2, jpim1
690            iku = mbku(ji,jj)
691            ikv = mbkv(ji,jj)
692
693            IF (iku .GT. 1) THEN
694               ! remove old value (interior case)
695               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
696                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
697               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
698               ! put new value
699               ! -zpshpi to avoid double contribution of the partial step in the top layer
700               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
701               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
702               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
703            END IF
704            ! v direction
705            IF (ikv .GT. 1) THEN
706               ! remove old value (interior case)
707               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
708                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
709               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
710               ! put new value
711               ! -zpshpj to avoid double contribution of the partial step in the top layer
712               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
713               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
714               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
715            END IF
716         END DO
717      END DO
718     
719      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
720      rhd = zrhd
721      !
722      CALL wrk_dealloc( jpi,jpj,2, ztstop)
723      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
724      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
725      !
726   END SUBROUTINE hpg_isf
727
728
729   SUBROUTINE hpg_djc( kt )
730      !!---------------------------------------------------------------------
731      !!                  ***  ROUTINE hpg_djc  ***
732      !!
733      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
734      !!
735      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
736      !!----------------------------------------------------------------------
737      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
738      !!
739      INTEGER  ::   ji, jj, jk          ! dummy loop indices
740      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
741      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
742      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
743      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
744      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
745      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
746      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
747      !!----------------------------------------------------------------------
748      !
749      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
750      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
751      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
752      !
753
754      IF( kt == nit000 ) THEN
755         IF(lwp) WRITE(numout,*)
756         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
757         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
758      ENDIF
759
760      ! Local constant initialization
761      zcoef0 = - grav * 0.5_wp
762      z1_10  = 1._wp / 10._wp
763      z1_12  = 1._wp / 12._wp
764
765      !----------------------------------------------------------------------------------------
766      !  compute and store in provisional arrays elementary vertical and horizontal differences
767      !----------------------------------------------------------------------------------------
768
769!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
770
771      DO jk = 2, jpkm1
772         DO jj = 2, jpjm1
773            DO ji = fs_2, fs_jpim1   ! vector opt.
774               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
775               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
776               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
777               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
778               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
779               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
780            END DO
781         END DO
782      END DO
783
784      !-------------------------------------------------------------------------
785      ! compute harmonic averages using eq. 5.18
786      !-------------------------------------------------------------------------
787      zep = 1.e-15
788
789!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
790!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
791
792      DO jk = 2, jpkm1
793         DO jj = 2, jpjm1
794            DO ji = fs_2, fs_jpim1   ! vector opt.
795               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
796
797               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
798               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
799
800               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
801               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
802
803               IF( cffw > zep) THEN
804                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
805                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
806               ELSE
807                  drhow(ji,jj,jk) = 0._wp
808               ENDIF
809
810               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
811                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
812
813               IF( cffu > zep ) THEN
814                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
815                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
816               ELSE
817                  drhou(ji,jj,jk ) = 0._wp
818               ENDIF
819
820               IF( cffx > zep ) THEN
821                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
822                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
823               ELSE
824                  dzu(ji,jj,jk) = 0._wp
825               ENDIF
826
827               IF( cffv > zep ) THEN
828                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
829                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
830               ELSE
831                  drhov(ji,jj,jk) = 0._wp
832               ENDIF
833
834               IF( cffy > zep ) THEN
835                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
836                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
837               ELSE
838                  dzv(ji,jj,jk) = 0._wp
839               ENDIF
840
841            END DO
842         END DO
843      END DO
844
845      !----------------------------------------------------------------------------------
846      ! apply boundary conditions at top and bottom using 5.36-5.37
847      !----------------------------------------------------------------------------------
848      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
849      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
850      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
851
852      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
853      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
854      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
855
856
857      !--------------------------------------------------------------
858      ! Upper half of top-most grid box, compute and store
859      !-------------------------------------------------------------
860
861!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
862!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
863
864      DO jj = 2, jpjm1
865         DO ji = fs_2, fs_jpim1   ! vector opt.
866            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
867               &                   * (  rhd(ji,jj,1)                                    &
868               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
869               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
870               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
871         END DO
872      END DO
873
874!!bug gm    : here also, simplification is possible
875!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
876
877      DO jk = 2, jpkm1
878         DO jj = 2, jpjm1
879            DO ji = fs_2, fs_jpim1   ! vector opt.
880
881               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
882                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
883                  &            - grav * z1_10 * (                                                                     &
884                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
885                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
886                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
887                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
888                  &                             )
889
890               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
891                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
892                  &            - grav* z1_10 * (                                                                      &
893                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
894                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
895                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
896                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
897                  &                            )
898
899               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
900                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
901                  &            - grav* z1_10 * (                                                                      &
902                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
903                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
904                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
905                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
906                  &                            )
907
908            END DO
909         END DO
910      END DO
911      CALL lbc_lnk(rho_k,'W',1.)
912      CALL lbc_lnk(rho_i,'U',1.)
913      CALL lbc_lnk(rho_j,'V',1.)
914
915
916      ! ---------------
917      !  Surface value
918      ! ---------------
919      DO jj = 2, jpjm1
920         DO ji = fs_2, fs_jpim1   ! vector opt.
921            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
922            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
923            ! add to the general momentum trend
924            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
925            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
926         END DO
927      END DO
928
929      ! ----------------
930      !  interior value   (2=<jk=<jpkm1)
931      ! ----------------
932      DO jk = 2, jpkm1
933         DO jj = 2, jpjm1
934            DO ji = fs_2, fs_jpim1   ! vector opt.
935               ! hydrostatic pressure gradient along s-surfaces
936               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
937                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
938                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
939               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
940                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
941                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
942               ! add to the general momentum trend
943               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
944               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
945            END DO
946         END DO
947      END DO
948      !
949      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
950      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
951      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
952      !
953   END SUBROUTINE hpg_djc
954
955
956   SUBROUTINE hpg_prj( kt )
957      !!---------------------------------------------------------------------
958      !!                  ***  ROUTINE hpg_prj  ***
959      !!
960      !! ** Method  :   s-coordinate case.
961      !!      A Pressure-Jacobian horizontal pressure gradient method
962      !!      based on the constrained cubic-spline interpolation for
963      !!      all vertical coordinate systems
964      !!
965      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
966      !!----------------------------------------------------------------------
967      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
968      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
969      !!
970      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
971      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
972      !!
973      !! The local variables for the correction term
974      INTEGER  :: jk1, jis, jid, jjs, jjd
975      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
976      REAL(wp) :: zrhdt1
977      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
978      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
979      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
980      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
981      !!----------------------------------------------------------------------
982      !
983      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
984      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
985      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
986      !
987      IF( kt == nit000 ) THEN
988         IF(lwp) WRITE(numout,*)
989         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
990         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
991      ENDIF
992
993      !!----------------------------------------------------------------------
994      ! Local constant initialization
995      zcoef0 = - grav
996      znad = 0.0_wp
997      IF( lk_vvl ) znad = 1._wp
998
999      ! Clean 3-D work arrays
1000      zhpi(:,:,:) = 0._wp
1001      zrhh(:,:,:) = rhd(:,:,:)
1002
1003      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1004      DO jj = 1, jpj
1005        DO ji = 1, jpi
1006          jk = mbathy(ji,jj)
1007          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1008          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1009          ELSE IF(jk < jpkm1) THEN
1010             DO jkk = jk+1, jpk
1011                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1012                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1013             END DO
1014          ENDIF
1015        END DO
1016      END DO
1017
1018      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1019      DO jj = 1, jpj
1020         DO ji = 1, jpi
1021            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1022         END DO
1023      END DO
1024
1025      DO jk = 2, jpk
1026         DO jj = 1, jpj
1027            DO ji = 1, jpi
1028               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1029            END DO
1030         END DO
1031      END DO
1032
1033      fsp(:,:,:) = zrhh (:,:,:)
1034      xsp(:,:,:) = zdept(:,:,:)
1035
1036      ! Construct the vertical density profile with the
1037      ! constrained cubic spline interpolation
1038      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1039      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1040
1041      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1042      DO jj = 2, jpj
1043        DO ji = 2, jpi
1044          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1045                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1046                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1047
1048          ! assuming linear profile across the top half surface layer
1049          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1050        END DO
1051      END DO
1052
1053      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1054      DO jk = 2, jpkm1
1055        DO jj = 2, jpj
1056          DO ji = 2, jpi
1057            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1058                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1059                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1060                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1061          END DO
1062        END DO
1063      END DO
1064
1065      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1066
1067      ! Prepare zsshu_n and zsshv_n
1068      DO jj = 2, jpjm1
1069        DO ji = 2, jpim1
1070          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1071                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1072          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1073                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1074        END DO
1075      END DO
1076
1077      DO jj = 2, jpjm1
1078        DO ji = 2, jpim1
1079          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1080          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1081        END DO
1082      END DO
1083
1084      DO jk = 2, jpkm1
1085        DO jj = 2, jpjm1
1086          DO ji = 2, jpim1
1087            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1088            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1089          END DO
1090        END DO
1091      END DO
1092
1093      DO jk = 1, jpkm1
1094        DO jj = 2, jpjm1
1095          DO ji = 2, jpim1
1096            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1097            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1098          END DO
1099        END DO
1100      END DO
1101
1102      DO jk = 1, jpkm1
1103        DO jj = 2, jpjm1
1104          DO ji = 2, jpim1
1105            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1106            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1107            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1108            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1109          END DO
1110        END DO
1111      END DO
1112
1113
1114      DO jk = 1, jpkm1
1115        DO jj = 2, jpjm1
1116          DO ji = 2, jpim1
1117            zpwes = 0._wp; zpwed = 0._wp
1118            zpnss = 0._wp; zpnsd = 0._wp
1119            zuijk = zu(ji,jj,jk)
1120            zvijk = zv(ji,jj,jk)
1121
1122            !!!!!     for u equation
1123            IF( jk <= mbku(ji,jj) ) THEN
1124               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1125                 jis = ji + 1; jid = ji
1126               ELSE
1127                 jis = ji;     jid = ji +1
1128               ENDIF
1129
1130               ! integrate the pressure on the shallow side
1131               jk1 = jk
1132               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1133                 IF( jk1 == mbku(ji,jj) ) THEN
1134                   zuijk = -zdept(jis,jj,jk1)
1135                   EXIT
1136                 ENDIF
1137                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1138                 zpwes = zpwes +                                    &
1139                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1140                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1141                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1142                 jk1 = jk1 + 1
1143               END DO
1144
1145               ! integrate the pressure on the deep side
1146               jk1 = jk
1147               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1148                 IF( jk1 == 1 ) THEN
1149                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1150                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1151                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1152                                                     dsp(jid,jj,1)) * zdeps
1153                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1154                   EXIT
1155                 ENDIF
1156                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1157                 zpwed = zpwed +                                        &
1158                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1159                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1160                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1161                 jk1 = jk1 - 1
1162               END DO
1163
1164               ! update the momentum trends in u direction
1165
1166               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1167               IF( lk_vvl ) THEN
1168                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1169                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1170                ELSE
1171                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1172               ENDIF
1173
1174               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1175               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1176            ENDIF
1177
1178            !!!!!     for v equation
1179            IF( jk <= mbkv(ji,jj) ) THEN
1180               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1181                 jjs = jj + 1; jjd = jj
1182               ELSE
1183                 jjs = jj    ; jjd = jj + 1
1184               ENDIF
1185
1186               ! integrate the pressure on the shallow side
1187               jk1 = jk
1188               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1189                 IF( jk1 == mbkv(ji,jj) ) THEN
1190                   zvijk = -zdept(ji,jjs,jk1)
1191                   EXIT
1192                 ENDIF
1193                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1194                 zpnss = zpnss +                                      &
1195                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1196                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1197                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1198                 jk1 = jk1 + 1
1199               END DO
1200
1201               ! integrate the pressure on the deep side
1202               jk1 = jk
1203               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1204                 IF( jk1 == 1 ) THEN
1205                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1206                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1207                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1208                                                     dsp(ji,jjd,1) ) * zdeps
1209                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1210                   EXIT
1211                 ENDIF
1212                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1213                 zpnsd = zpnsd +                                        &
1214                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1215                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1216                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1217                 jk1 = jk1 - 1
1218               END DO
1219
1220
1221               ! update the momentum trends in v direction
1222
1223               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1224               IF( lk_vvl ) THEN
1225                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1226                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1227               ELSE
1228                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1229               ENDIF
1230
1231               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1232               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1233            ENDIF
1234
1235
1236           END DO
1237        END DO
1238      END DO
1239      !
1240      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1241      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1242      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1243      !
1244   END SUBROUTINE hpg_prj
1245
1246
1247   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1248      !!----------------------------------------------------------------------
1249      !!                 ***  ROUTINE cspline  ***
1250      !!
1251      !! ** Purpose :   constrained cubic spline interpolation
1252      !!
1253      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1254      !!
1255      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1256      !!----------------------------------------------------------------------
1257      IMPLICIT NONE
1258      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1259      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1260                                                                    ! the interpoated function
1261      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1262                                                                    ! 2: Linear
1263      !
1264      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1265      INTEGER  ::   jpi, jpj, jpkm1
1266      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1267      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1268      REAL(wp) ::   zdf(size(fsp,3))
1269      !!----------------------------------------------------------------------
1270
1271      jpi   = size(fsp,1)
1272      jpj   = size(fsp,2)
1273      jpkm1 = size(fsp,3) - 1
1274
1275
1276      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1277         DO ji = 1, jpi
1278            DO jj = 1, jpj
1279           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1280           !    DO jk = 2, jpkm1-1
1281           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1282           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1283           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1284           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1285           !
1286           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1287           !
1288           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1289           !           zdf(jk) = 0._wp
1290           !       ELSE
1291           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1292           !       ENDIF
1293           !    END DO
1294
1295           !!Simply geometric average
1296               DO jk = 2, jpkm1-1
1297                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1298                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1299
1300                  IF(zdf1 * zdf2 <= 0._wp) THEN
1301                     zdf(jk) = 0._wp
1302                  ELSE
1303                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1304                  ENDIF
1305               END DO
1306
1307               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1308                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1309               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1310                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1311                          & 0.5_wp * zdf(jpkm1 - 1)
1312
1313               DO jk = 1, jpkm1 - 1
1314                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1315                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1316                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1317                 zddf1  = -2._wp * ztmp1 + ztmp2
1318                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1319                 zddf2  =  2._wp * ztmp1 - ztmp2
1320
1321                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1322                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1323                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1324                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1325                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1326                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1327                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1328                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1329                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1330               END DO
1331            END DO
1332         END DO
1333
1334      ELSE IF (polynomial_type == 2) THEN     ! Linear
1335         DO ji = 1, jpi
1336            DO jj = 1, jpj
1337               DO jk = 1, jpkm1-1
1338                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1339                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1340
1341                  dsp(ji,jj,jk) = 0._wp
1342                  csp(ji,jj,jk) = 0._wp
1343                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1344                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1345               END DO
1346            END DO
1347         END DO
1348
1349      ELSE
1350           CALL ctl_stop( 'invalid polynomial type in cspline' )
1351      ENDIF
1352
1353   END SUBROUTINE cspline
1354
1355
1356   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1357      !!----------------------------------------------------------------------
1358      !!                 ***  ROUTINE interp1  ***
1359      !!
1360      !! ** Purpose :   1-d linear interpolation
1361      !!
1362      !! ** Method  :   interpolation is straight forward
1363      !!                extrapolation is also permitted (no value limit)
1364      !!----------------------------------------------------------------------
1365      IMPLICIT NONE
1366      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1367      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1368      REAL(wp)             ::  zdeltx
1369      !!----------------------------------------------------------------------
1370
1371      zdeltx = xr - xl
1372      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1373        f = 0.5_wp * (fl + fr)
1374      ELSE
1375        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1376      ENDIF
1377
1378   END FUNCTION interp1
1379
1380
1381   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1382      !!----------------------------------------------------------------------
1383      !!                 ***  ROUTINE interp1  ***
1384      !!
1385      !! ** Purpose :   1-d constrained cubic spline interpolation
1386      !!
1387      !! ** Method  :  cubic spline interpolation
1388      !!
1389      !!----------------------------------------------------------------------
1390      IMPLICIT NONE
1391      REAL(wp), INTENT(in) ::  x, a, b, c, d
1392      REAL(wp)             ::  f ! value from the interpolation
1393      !!----------------------------------------------------------------------
1394
1395      f = a + x* ( b + x * ( c + d * x ) )
1396
1397   END FUNCTION interp2
1398
1399
1400   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1401      !!----------------------------------------------------------------------
1402      !!                 ***  ROUTINE interp1  ***
1403      !!
1404      !! ** Purpose :   Calculate the first order of deriavtive of
1405      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1406      !!
1407      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1408      !!
1409      !!----------------------------------------------------------------------
1410      IMPLICIT NONE
1411      REAL(wp), INTENT(in) ::  x, a, b, c, d
1412      REAL(wp)             ::  f ! value from the interpolation
1413      !!----------------------------------------------------------------------
1414
1415      f = b + x * ( 2._wp * c + 3._wp * d * x)
1416
1417   END FUNCTION interp3
1418
1419
1420   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1421      !!----------------------------------------------------------------------
1422      !!                 ***  ROUTINE interp1  ***
1423      !!
1424      !! ** Purpose :   1-d constrained cubic spline integration
1425      !!
1426      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1427      !!
1428      !!----------------------------------------------------------------------
1429      IMPLICIT NONE
1430      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1431      REAL(wp)             ::  za1, za2, za3
1432      REAL(wp)             ::  f                   ! integration result
1433      !!----------------------------------------------------------------------
1434
1435      za1 = 0.5_wp * b
1436      za2 = c / 3.0_wp
1437      za3 = 0.25_wp * d
1438
1439      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1440         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1441
1442   END FUNCTION integ_spline
1443
1444   !!======================================================================
1445END MODULE dynhpg
1446
Note: See TracBrowser for help on using the repository browser.