New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynbfr.F90 in branches/UKMO/dev_r5785_SSS_obsoper/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/dev_r5785_SSS_obsoper/NEMOGCM/NEMO/OPA_SRC/DYN/dynbfr.F90 @ 7773

Last change on this file since 7773 was 7773, checked in by mattmartin, 7 years ago

Committing updates after doing the following:

  • merging the branch dev_r4650_general_vert_coord_obsoper@7763 into this branch
  • updating it so that the following OBS changes were implemented correctly on top of the simplification changes:
    • generalised vertical coordinate for profile obs. This was done so that is now the default option.
    • sst bias correction implemented with the new simplified obs code.
    • included the biogeochemical obs types int he new simplified obs code.
    • included the changes to exclude obs in the boundary for limited area models
    • included other changes for the efficiency of the obs operator to remove global arrays.
File size: 5.5 KB
Line 
1MODULE dynbfr
2   !!==============================================================================
3   !!                 ***  MODULE  dynbfr  ***
4   !! Ocean dynamics :  bottom friction component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  3.2  ! 2008-11  (A. C. Coward)  Original code
7   !!            3.4  ! 2011-09  (H. Liu) Make it consistent with semi-implicit
8   !!                            Bottom friction (ln_bfrimp = .true.)
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_bfr       : Update the momentum trend with the bottom friction contribution
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE zdf_oce        ! ocean vertical physics variables
17   USE zdfbfr         ! ocean bottom friction variables
18   USE trd_oce        ! trends: ocean variables
19   USE trddyn         ! trend manager: dynamics
20   USE in_out_manager ! I/O manager
21   USE prtctl         ! Print control
22   USE timing         ! Timing
23   USE wrk_nemo       ! Memory Allocation
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dyn_bfr   !  routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "zdfddm_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40   
41   SUBROUTINE dyn_bfr( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE dyn_bfr  ***
44      !!
45      !! ** Purpose :   compute the bottom friction ocean dynamics physics.
46      !!
47      !! ** Action  :   (ua,va)   momentum trend increased by bottom friction trend
48      !!---------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
50      !!
51      INTEGER  ::   ji, jj       ! dummy loop indexes
52      INTEGER  ::   ikbu, ikbv   ! local integers
53      REAL(wp) ::   zm1_2dt      ! local scalar
54      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
55      !!---------------------------------------------------------------------
56      !
57      IF( nn_timing == 1 )  CALL timing_start('dyn_bfr')
58      !
59!!gm issue: better to put the logical in step to control the call of zdf_bfr
60!!          ==> change the logical from ln_bfrimp to ln_bfr_exp !!
61      IF( .NOT.ln_bfrimp) THEN     ! only for explicit bottom friction form
62                                    ! implicit bfr is implemented in dynzdf_imp
63
64!!gm bug : time step is only rdt (not 2 rdt if euler start !)
65        zm1_2dt = - 1._wp / ( 2._wp * rdt )
66
67        IF( l_trddyn )   THEN                      ! temporary save of ua and va trends
68           CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
69           ztrdu(:,:,:) = ua(:,:,:)
70           ztrdv(:,:,:) = va(:,:,:)
71        ENDIF
72
73
74        DO jj = 2, jpjm1
75           DO ji = 2, jpim1
76              ikbu = mbku(ji,jj)          ! deepest ocean u- & v-levels
77              ikbv = mbkv(ji,jj)
78              !
79              ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
80              ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX(  bfrua(ji,jj) / fse3u(ji,jj,ikbu) , zm1_2dt  ) * ub(ji,jj,ikbu)
81              va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX(  bfrva(ji,jj) / fse3v(ji,jj,ikbv) , zm1_2dt  ) * vb(ji,jj,ikbv)
82           END DO
83        END DO
84       
85        IF ( ln_isfcav ) THEN
86           DO jj = 2, jpjm1
87              DO ji = 2, jpim1
88                 ! (ISF) stability criteria for top friction
89                 ikbu = miku(ji,jj)          ! first wet ocean u- & v-levels
90                 ikbv = mikv(ji,jj)
91                 !
92                 ! Apply stability criteria on absolute value  : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt)
93                 ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX(  tfrua(ji,jj) / fse3u(ji,jj,ikbu) , zm1_2dt  ) * ub(ji,jj,ikbu) &
94                    &             * (1.-umask(ji,jj,1))
95                 va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX(  tfrva(ji,jj) / fse3v(ji,jj,ikbv) , zm1_2dt  ) * vb(ji,jj,ikbv) &
96                    &             * (1.-vmask(ji,jj,1))
97                 ! (ISF)
98              END DO
99           END DO
100        END IF
101
102        !
103        IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
104           ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
105           ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
106           CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt )
107           CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
108        ENDIF
109        !                                          ! print mean trends (used for debugging)
110        IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' bfr  - Ua: ', mask1=umask,               &
111           &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
112        !
113      ENDIF     ! end explicit bottom friction
114      !
115      IF( nn_timing == 1 )  CALL timing_stop('dyn_bfr')
116      !
117   END SUBROUTINE dyn_bfr
118
119   !!==============================================================================
120END MODULE dynbfr
Note: See TracBrowser for help on using the repository browser.