New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/UKMO/dev_r6393_CO6_package_trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r6393_CO6_package_trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 7019

Last change on this file since 7019 was 7019, checked in by deazer, 8 years ago

Cleared svn keywords
File size: 13.2 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61      DO jj = 1, jpj
62         DO ji = 1, jpi
63            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
64            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
65         END DO
66      END DO
67      !
68      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
69         !                                                ! ---------------------------------------- !
70         ssu_m(:,:) = ub(:,:,1)
71         ssv_m(:,:) = vb(:,:,1)
72         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
73         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
74         ENDIF
75         sss_m(:,:) = zts(:,:,jp_sal)
76         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
77         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
78         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
79         ENDIF
80         !
81         e3t_m(:,:) = e3t_n(:,:,1)
82         !
83         frq_m(:,:) = fraqsr_1lev(:,:)
84         !
85      ELSE
86         !                                                ! ----------------------------------------------- !
87         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
88            !                                             ! ----------------------------------------------- !
89            IF(lwp) WRITE(numout,*)
90            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
91            zcoef = REAL( nn_fsbc - 1, wp )
92            ssu_m(:,:) = zcoef * ub(:,:,1)
93            ssv_m(:,:) = zcoef * vb(:,:,1)
94            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
95            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
96            ENDIF
97            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
98            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
99            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
100            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
101            ENDIF
102            !
103            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
104            !
105            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
106            !                                             ! ---------------------------------------- !
107         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
108            !                                             ! ---------------------------------------- !
109            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
110            ssv_m(:,:) = 0._wp
111            sst_m(:,:) = 0._wp
112            sss_m(:,:) = 0._wp
113            ssh_m(:,:) = 0._wp
114            e3t_m(:,:) = 0._wp
115            frq_m(:,:) = 0._wp
116         ENDIF
117         !                                                ! ---------------------------------------- !
118         !                                                !        Cumulate at each time step        !
119         !                                                ! ---------------------------------------- !
120         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
121         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
122         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
123         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
124         ENDIF
125         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
126         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
127         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
128         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
129         ENDIF
130         !
131         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
132         !
133         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
134
135         !                                                ! ---------------------------------------- !
136         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
137            !                                             ! ---------------------------------------- !
138            zcoef = 1. / REAL( nn_fsbc, wp )
139            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celcius]
140            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
141            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
142            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
143            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
144            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
145            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
146            !
147         ENDIF
148         !                                                ! ---------------------------------------- !
149         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
150            !                                             ! ---------------------------------------- !
151            IF(lwp) WRITE(numout,*)
152            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
153               &                    'at it= ', kt,' date= ', ndastp
154            IF(lwp) WRITE(numout,*) '~~~~~~~'
155            zf_sbc = REAL( nn_fsbc, wp )
156            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
157            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
158            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
161            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
162            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
163            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
164            !
165         ENDIF
166         !
167      ENDIF
168      !
169      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
170         CALL iom_put( 'ssu_m', ssu_m )
171         CALL iom_put( 'ssv_m', ssv_m )
172         CALL iom_put( 'sst_m', sst_m )
173         CALL iom_put( 'sss_m', sss_m )
174         CALL iom_put( 'ssh_m', ssh_m )
175         CALL iom_put( 'e3t_m', e3t_m )
176         CALL iom_put( 'frq_m', frq_m )
177      ENDIF
178      !
179   END SUBROUTINE sbc_ssm
180
181
182   SUBROUTINE sbc_ssm_init
183      !!----------------------------------------------------------------------
184      !!                  ***  ROUTINE sbc_ssm_init  ***
185      !!
186      !! ** Purpose :   Initialisation of the sbc data
187      !!
188      !! ** Action  : - read parameters
189      !!----------------------------------------------------------------------
190      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
191      !!----------------------------------------------------------------------
192      !
193      IF( nn_fsbc == 1 ) THEN
194         !
195         IF(lwp) WRITE(numout,*)
196         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
197         IF(lwp) WRITE(numout,*) '~~~~~~~ '
198         !
199      ELSE
200         !               
201         IF(lwp) WRITE(numout,*)
202         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
203         IF(lwp) WRITE(numout,*) '~~~~~~~ '
204         !
205         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
206            l_ssm_mean = .TRUE.
207            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
208            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
209            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
210            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
211            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
212            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
213            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
214            ! fraction of solar net radiation absorbed in 1st T level
215            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
216               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
217            ELSE
218               frq_m(:,:) = 1._wp   ! default definition
219            ENDIF
220            !
221            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
222               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
223                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
224               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
225               ssu_m(:,:) = zcoef * ssu_m(:,:) 
226               ssv_m(:,:) = zcoef * ssv_m(:,:)
227               sst_m(:,:) = zcoef * sst_m(:,:)
228               sss_m(:,:) = zcoef * sss_m(:,:)
229               ssh_m(:,:) = zcoef * ssh_m(:,:)
230               e3t_m(:,:) = zcoef * e3t_m(:,:)
231               frq_m(:,:) = zcoef * frq_m(:,:)
232            ELSE
233               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
234            ENDIF
235         ENDIF
236      ENDIF
237      !
238      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
239         !
240         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
241         ssu_m(:,:) = ub(:,:,1)
242         ssv_m(:,:) = vb(:,:,1)
243         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
244         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
245         ENDIF
246         sss_m(:,:) = tsn  (:,:,1,jp_sal)
247         ssh_m(:,:) = sshn (:,:)
248         e3t_m(:,:) = e3t_n(:,:,1)
249         frq_m(:,:) = 1._wp
250         !
251      ENDIF
252      !
253   END SUBROUTINE sbc_ssm_init
254
255   !!======================================================================
256END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.