New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

restart.F90 in branches/UKMO/dev_r7573_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

Context Navigation

source: branches/UKMO/dev_r7573_xios_write/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8208

Last change on this file since 8208 was 8208, checked in by andmirek, 7 years ago
open write context at time write-1 as for default write
File size: 18.0 KB

Line
1	MODULE restart
2	!!======================================================================
3	!! * MODULE restart *
4	!! Ocean restart : write the ocean restart file
5	!!======================================================================
6	!! History : OPA ! 1999-11 (M. Imbard) Original code
7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! rst_opn : open the ocean restart file
15	!! rst_write : write the ocean restart file
16	!! rst_read : read the ocean restart file
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and tracers
19	USE dom_oce ! ocean space and time domain
20	USE phycst ! physical constants
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23	USE ioipsl, ONLY : ju2ymds ! for calendar
24	USE eosbn2 ! equation of state (eos bn2 routine)
25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
26	USE divcur ! hor. divergence and curl (div & cur routines)
27	USE sbc_oce ! for icesheet freshwater input variables
28	USE iom_def, ONLY : lwxios
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC rst_opn ! routine called by step module
34	PUBLIC rst_write ! routine called by step module
35	PUBLIC rst_read ! routine called by istate module
36	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
37
38	!! * Substitutions
39	# include "domzgr_substitute.h90"
40	# include "vectopt_loop_substitute.h90"
41	!!----------------------------------------------------------------------
42	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
43	!! $Id$
44	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45	!!----------------------------------------------------------------------
46	CONTAINS
47
48	SUBROUTINE rst_opn( kt )
49	!!---------------------------------------------------------------------
50	!! * ROUTINE rst_opn *
51	!!
52	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
53	!! + open the restart when we are one time step before nitrst
54	!! - restart header is defined when kt = nitrst-1
55	!! - restart data are written when kt = nitrst
56	!! + define lrst_oce to .TRUE. when we need to define or write the restart
57	!!----------------------------------------------------------------------
58	INTEGER, INTENT(in) :: kt ! ocean time-step
59	INTEGER :: iyear, imonth, iday
60	REAL (wp) :: zsec
61	REAL (wp) :: zfjulday
62	!!
63	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
64	CHARACTER(LEN=50) :: clname ! ocean output restart file name
65	CHARACTER(LEN=150) :: clpath ! full path to ocean output restart file
66	!!----------------------------------------------------------------------
67	!
68
69	IF( kt == nit000 ) THEN ! default definitions
70	lrst_oce = .FALSE.
71	IF( ln_rst_list ) THEN
72	nrst_lst = 1
73	nitrst = nstocklist( nrst_lst )
74	ELSE
75	nitrst = nitend
76	ENDIF
77	ENDIF
78
79	! frequency-based restart dumping (nn_stock)
80	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN
81	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
82	nitrst = kt + nstock - 1 ! define the next value of nitrst for restart writing
83	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
84	ENDIF
85	! to get better performances with NetCDF format:
86	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
87	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
88	! NO, because the data is written 2 times on nitrst - 1 and nitrst
89	IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
90	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
91	IF ( ln_rstdate ) THEN
92	zfjulday = fjulday + rdttra(1) / rday
93	IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday ) zfjulday = REAL(NINT(zfjulday),wp) ! avoid truncation error
94	CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )
95	WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
96	ELSE
97	! beware of the format used to write kt (default is i8.8, that should be large enough...)
98	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
99	ELSE ; WRITE(clkt, '(i8.8)') nitrst
100	ENDIF
101	ENDIF
102	! create the file
103	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
104	clpath = TRIM(cn_ocerst_outdir)
105	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
106	IF(lwp) THEN
107	WRITE(numout,*)
108	IF(lwxios) THEN
109	WRITE(numout,*) &
110	' XIOS open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
111	ELSE
112	SELECT CASE ( jprstlib )
113	CASE ( jprstdimg ) ; WRITE(numout,*) &
114	' open ocean restart binary file: ',TRIM(clpath)//TRIM(clname)
115	CASE DEFAULT ; WRITE(numout,*) &
116	' open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
117	END SELECT
118	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
119	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
120	ELSE ; WRITE(numout,*) ' kt = ' , kt
121	ENDIF
122	ENDIF
123	ENDIF
124	!
125	IF(.NOT.lwxios) THEN
126	CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
127	ELSE
128	CALL iom_init( wxios_context, TRIM(clpath)//TRIM(clname) )
129	CALL xios_update_calendar(nitrst)
130	CALL iom_swap( cxios_context )
131	ENDIF
132	lrst_oce = .TRUE.
133	ENDIF
134	ENDIF
135
136	!
137	END SUBROUTINE rst_opn
138
139
140	SUBROUTINE rst_write( kt )
141	!!---------------------------------------------------------------------
142	!! * ROUTINE rstwrite *
143	!!
144	!! ** Purpose : Write restart fields in the format corresponding to jprstlib
145	!!
146	!! ** Method : Write in numrow when kt == nitrst in NetCDF
147	!! file, save fields which are necessary for restart
148	!!----------------------------------------------------------------------
149	INTEGER, INTENT(in) :: kt ! ocean time-step
150	!!----------------------------------------------------------------------
151	IF(lwxios) CALL iom_swap( wxios_context )
152	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt , lxios = lwxios) ! dynamics time step
153	CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) , lxios = lwxios) ! surface tracer time step
154
155	CALL iom_rstput( kt, nitrst, numrow, 'ub' , ub , lxios = lwxios) ! before fields
156	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vb , lxios = lwxios)
157	CALL iom_rstput( kt, nitrst, numrow, 'tb' , tsb(:,:,:,jp_tem) , lxios = lwxios)
158	CALL iom_rstput( kt, nitrst, numrow, 'sb' , tsb(:,:,:,jp_sal) , lxios = lwxios)
159	CALL iom_rstput( kt, nitrst, numrow, 'rotb' , rotb , lxios = lwxios)
160	CALL iom_rstput( kt, nitrst, numrow, 'hdivb' , hdivb , lxios = lwxios)
161	CALL iom_rstput( kt, nitrst, numrow, 'sshb' , sshb , lxios = lwxios)
162	!
163	CALL iom_rstput( kt, nitrst, numrow, 'un' , un , lxios = lwxios) ! now fields
164	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vn , lxios = lwxios)
165	CALL iom_rstput( kt, nitrst, numrow, 'tn' , tsn(:,:,:,jp_tem) , lxios = lwxios)
166	CALL iom_rstput( kt, nitrst, numrow, 'sn' , tsn(:,:,:,jp_sal) , lxios = lwxios)
167	CALL iom_rstput( kt, nitrst, numrow, 'rotn' , rotn , lxios = lwxios)
168	CALL iom_rstput( kt, nitrst, numrow, 'hdivn' , hdivn , lxios = lwxios)
169	CALL iom_rstput( kt, nitrst, numrow, 'sshn' , sshn , lxios = lwxios)
170	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop , lxios = lwxios)
171	#if defined key_zdfkpp
172	CALL iom_rstput( kt, nitrst, numrow, 'rhd' , rhd , lxios = lwxios)
173	#endif
174	IF( lk_oasis) THEN
175	! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
176	IF( ln_coupled_iceshelf_fluxes ) THEN
177	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass ,&
178	& lxios = lwxios)
179	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed ,&
180	& lxios = lwxios)
181	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change ,&
182	& lxios = lwxios)
183	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass , &
184	& lxios = lwxios)
185	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed ,&
186	& lxios = lwxios)
187	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', &
188	& antarctica_icesheet_mass_rate_of_change , lxios = lwxios)
189	ENDIF
190	ENDIF
191
192	IF( kt == nitrst ) THEN
193	IF(.NOT.lwxios) THEN
194	CALL iom_close( numrow ) ! close the restart file (only at last time step)
195	ELSE
196	CALL iom_context_finalize( wxios_context )
197	CALL iom_swap( cxios_context )
198	ENDIF
199	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
200	!!gm not sure what to do here ===>>> ask to Sebastian
201	lrst_oce = .FALSE.
202	IF( ln_rst_list ) THEN
203	nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
204	nitrst = nstocklist( nrst_lst )
205	ENDIF
206	ENDIF
207	!
208	END SUBROUTINE rst_write
209
210
211	SUBROUTINE rst_read_open
212	!!----------------------------------------------------------------------
213	!! * ROUTINE rst_read_open *
214	!!
215	!! ** Purpose : Open read files for restart (format fixed by jprstlib )
216	!!
217	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
218	!! the file has already been opened
219	!!----------------------------------------------------------------------
220	INTEGER :: jlibalt = jprstlib
221	LOGICAL :: llok
222	CHARACTER(lc) :: clpath ! full path to ocean output restart file
223	!!----------------------------------------------------------------------
224	!
225	IF( numror <= 0 ) THEN
226	IF(lwp) THEN ! Contol prints
227	WRITE(numout,*)
228	SELECT CASE ( jprstlib )
229	CASE ( jpnf90 ) ; WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
230	CASE ( jprstdimg ) ; WRITE(numout,*) 'rst_read : read oce binary restart file'
231	END SELECT
232	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
233	WRITE(numout,*) '~~~~~~~~'
234	ENDIF
235
236	clpath = TRIM(cn_ocerst_indir)
237	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
238	IF ( jprstlib == jprstdimg ) THEN
239	! eventually read netcdf file (monobloc) for restarting on different number of processors
240	! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
241	INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
242	IF ( llok ) THEN ; jlibalt = jpnf90 ; ELSE ; jlibalt = jprstlib ; ENDIF
243	ENDIF
244	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
245	ENDIF
246	END SUBROUTINE rst_read_open
247
248	SUBROUTINE rst_read
249	!!----------------------------------------------------------------------
250	!! * ROUTINE rst_read *
251	!!
252	!! ** Purpose : Read files for restart (format fixed by jprstlib )
253	!!
254	!! ** Method : Read in restart.nc file fields which are necessary for restart
255	!!----------------------------------------------------------------------
256	REAL(wp) :: zrdt, zrdttra1
257	INTEGER :: jk
258	LOGICAL :: llok
259	!!----------------------------------------------------------------------
260
261	CALL rst_read_open ! open restart for reading (if not already opened)
262
263	! Check dynamics and tracer time-step consistency and force Euler restart if changed
264	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
265	CALL iom_get( numror, 'rdt', zrdt )
266	IF( zrdt /= rdt ) neuler = 0
267	ENDIF
268	IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 ) THEN
269	CALL iom_get( numror, 'rdttra1', zrdttra1 )
270	IF( zrdttra1 /= rdttra(1) ) neuler = 0
271	ENDIF
272	!
273	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
274	CALL iom_get( numror, jpdom_autoglo, 'ub' , ub ) ! before fields
275	CALL iom_get( numror, jpdom_autoglo, 'vb' , vb )
276	CALL iom_get( numror, jpdom_autoglo, 'tb' , tsb(:,:,:,jp_tem) )
277	CALL iom_get( numror, jpdom_autoglo, 'sb' , tsb(:,:,:,jp_sal) )
278	CALL iom_get( numror, jpdom_autoglo, 'rotb' , rotb )
279	CALL iom_get( numror, jpdom_autoglo, 'hdivb' , hdivb )
280	CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb )
281	ELSE
282	neuler = 0
283	ENDIF
284	!
285	CALL iom_get( numror, jpdom_autoglo, 'un' , un ) ! now fields
286	CALL iom_get( numror, jpdom_autoglo, 'vn' , vn )
287	CALL iom_get( numror, jpdom_autoglo, 'tn' , tsn(:,:,:,jp_tem) )
288	CALL iom_get( numror, jpdom_autoglo, 'sn' , tsn(:,:,:,jp_sal) )
289	CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn )
290	IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
291	CALL iom_get( numror, jpdom_autoglo, 'rotn' , rotn )
292	CALL iom_get( numror, jpdom_autoglo, 'hdivn' , hdivn )
293	ELSE
294	CALL div_cur( 0 ) ! Horizontal divergence & Relative vorticity
295	ENDIF
296	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
297	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop ) ! now potential density
298	ELSE
299	CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) )
300	ENDIF
301	#if defined key_zdfkpp
302	IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
303	CALL iom_get( numror, jpdom_autoglo, 'rhd' , rhd ) ! now in situ density anomaly
304	ELSE
305	CALL eos( tsn, rhd, fsdept_n(:,:,:) ) ! compute rhd
306	ENDIF
307	#endif
308	!
309	IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
310	CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
311	CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
312	CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
313	ELSE
314	greenland_icesheet_mass = 0.0
315	greenland_icesheet_mass_rate_of_change = 0.0
316	greenland_icesheet_timelapsed = 0.0
317	ENDIF
318	IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
319	CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
320	CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
321	CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
322	ELSE
323	antarctica_icesheet_mass = 0.0
324	antarctica_icesheet_mass_rate_of_change = 0.0
325	antarctica_icesheet_timelapsed = 0.0
326	ENDIF
327
328	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
329	tsb (:,:,:,:) = tsn (:,:,:,:) ! all before fields set to now values
330	ub (:,:,:) = un (:,:,:)
331	vb (:,:,:) = vn (:,:,:)
332	rotb (:,:,:) = rotn (:,:,:)
333	hdivb(:,:,:) = hdivn(:,:,:)
334	sshb (:,:) = sshn (:,:)
335
336	IF( lk_vvl ) THEN
337	DO jk = 1, jpk
338	fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
339	END DO
340	ENDIF
341
342	ENDIF
343	!
344	END SUBROUTINE rst_read
345	!!=====================================================================
346	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

Download in other formats: