source: branches/UKMO/dev_r7750_GO6_package_oasis_timers/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 9252

Last change on this file since 9252 was 9252, checked in by andmirek, 3 years ago

#1978 timers for nn_timing 3

File size: 16.7 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE ioipsl, ONLY : ju2ymds    ! for calendar
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   USE divcur          ! hor. divergence and curl      (div & cur routines)
27   USE sbc_oce         ! for icesheet freshwater input variables
28   USE timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn         ! routine called by step module
34   PUBLIC   rst_write       ! routine called by step module
35   PUBLIC   rst_read        ! routine called by istate module
36   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      INTEGER             ::   iyear, imonth, iday
60      REAL (wp)           ::   zsec
61      REAL (wp)           ::   zfjulday
62      !!
63      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
64      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
65      CHARACTER(LEN=150)  ::   clpath   ! full path to ocean output restart file
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         IF( ln_rst_list ) THEN
71            nrst_lst = 1
72            nitrst = nstocklist( nrst_lst )
73         ELSE
74            nitrst = nitend
75         ENDIF
76      ENDIF
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
89            IF ( ln_rstdate ) THEN
90               zfjulday = fjulday + rdttra(1) / rday
91               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
92               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
93               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
94            ELSE
95               ! beware of the format used to write kt (default is i8.8, that should be large enough...)
96               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
97               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
98               ENDIF
99            ENDIF
100            ! create the file
101            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
102            clpath = TRIM(cn_ocerst_outdir)
103            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
104            IF(lwp) THEN
105               WRITE(numout,*)
106               SELECT CASE ( jprstlib )
107               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
108                   '             open ocean restart binary file: ',TRIM(clpath)//clname
109               CASE DEFAULT         ;   WRITE(numout,*)                            &
110                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
111               END SELECT
112               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
113               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
114               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
115               ENDIF
116            ENDIF
117            !
118            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
119            lrst_oce = .TRUE.
120         ENDIF
121      ENDIF
122      !
123   END SUBROUTINE rst_opn
124
125
126   SUBROUTINE rst_write( kt )
127      !!---------------------------------------------------------------------
128      !!                   ***  ROUTINE rstwrite  ***
129      !!                     
130      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
131      !!
132      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
133      !!              file, save fields which are necessary for restart
134      !!----------------------------------------------------------------------
135      INTEGER, INTENT(in) ::   kt   ! ocean time-step
136      !!----------------------------------------------------------------------
137                     IF(nn_timing == 3)  CALL timing_start('rst_put')
138                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
139                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
140
141                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
142                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
143                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
144                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
145                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
146                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
147                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
148                     !
149                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
150                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
151                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
152                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
153                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
154                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
156                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
157#if defined key_zdfkpp
158                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
159#endif
160                     IF( lk_oasis) THEN
161                     ! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
162                     IF( ln_coupled_iceshelf_fluxes ) THEN
163                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass )
164                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
165                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
166                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
167                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
168                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
169                     ENDIF
170                     ENDIF
171                     IF(nn_timing == 3)  CALL timing_stop('rst_put')
172
173      IF( kt == nitrst ) THEN
174         CALL iom_close( numrow )     ! close the restart file (only at last time step)
175!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
176!!gm  not sure what to do here   ===>>>  ask to Sebastian
177         lrst_oce = .FALSE.
178            IF( ln_rst_list ) THEN
179               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
180               nitrst = nstocklist( nrst_lst )
181            ENDIF
182            lrst_oce = .FALSE.
183      ENDIF
184      !
185   END SUBROUTINE rst_write
186
187
188   SUBROUTINE rst_read_open
189      !!----------------------------------------------------------------------
190      !!                   ***  ROUTINE rst_read_open  ***
191      !!
192      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
193      !!
194      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
195      !!                the file has already been opened
196      !!----------------------------------------------------------------------
197      INTEGER        ::   jlibalt = jprstlib
198      LOGICAL        ::   llok
199      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
200      !!----------------------------------------------------------------------
201      !
202      IF( numror <= 0 ) THEN
203         IF(lwp) THEN                                             ! Contol prints
204            WRITE(numout,*)
205            SELECT CASE ( jprstlib )
206            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
207            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
208            END SELECT
209            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
210            WRITE(numout,*) '~~~~~~~~'
211         ENDIF
212
213         clpath = TRIM(cn_ocerst_indir)
214         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
215         IF ( jprstlib == jprstdimg ) THEN
216           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
217           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
218           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
219           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
220         ENDIF
221         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
222      ENDIF
223   END SUBROUTINE rst_read_open
224
225   SUBROUTINE rst_read
226      !!----------------------------------------------------------------------
227      !!                   ***  ROUTINE rst_read  ***
228      !!
229      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
230      !!
231      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
232      !!----------------------------------------------------------------------
233      REAL(wp) ::   zrdt, zrdttra1
234      INTEGER  ::   jk
235      LOGICAL  ::   llok
236      !!----------------------------------------------------------------------
237
238      CALL rst_read_open           ! open restart for reading (if not already opened)
239
240      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
241      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
242         CALL iom_get( numror, 'rdt', zrdt )
243         IF( zrdt /= rdt )   neuler = 0
244      ENDIF
245      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
246         CALL iom_get( numror, 'rdttra1', zrdttra1 )
247         IF( zrdttra1 /= rdttra(1) )   neuler = 0
248      ENDIF
249      !
250      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
251         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
252         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
253         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
254         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
255         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
256         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
257         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
258      ELSE
259         neuler = 0
260      ENDIF
261      !
262      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
263      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
264      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
265      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
266      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
267      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
268         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
269         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
270      ELSE
271         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
272      ENDIF
273      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
274         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
275      ELSE
276         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
277      ENDIF
278#if defined key_zdfkpp
279      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
280         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
281      ELSE
282         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
283      ENDIF
284#endif
285      !
286      IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
287         CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
288         CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
289         CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
290      ELSE
291         greenland_icesheet_mass = 0.0 
292         greenland_icesheet_mass_rate_of_change = 0.0 
293         greenland_icesheet_timelapsed = 0.0
294      ENDIF
295      IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
296         CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
297         CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
298         CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
299      ELSE
300         antarctica_icesheet_mass = 0.0 
301         antarctica_icesheet_mass_rate_of_change = 0.0 
302         antarctica_icesheet_timelapsed = 0.0
303      ENDIF
304
305      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
306         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
307         ub   (:,:,:)   = un   (:,:,:)
308         vb   (:,:,:)   = vn   (:,:,:)
309         rotb (:,:,:)   = rotn (:,:,:)
310         hdivb(:,:,:)   = hdivn(:,:,:)
311         sshb (:,:)     = sshn (:,:)
312
313         IF( lk_vvl ) THEN
314            DO jk = 1, jpk
315               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
316            END DO
317         ENDIF
318
319      ENDIF
320      !
321   END SUBROUTINE rst_read
322
323   !!=====================================================================
324END MODULE restart
Note: See TracBrowser for help on using the repository browser.