source: branches/UKMO/dev_r7750_GO6_package_oasis_timers/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 9261

Last change on this file since 9261 was 9261, checked in by andmirek, 3 years ago

#1978 only 1 and 2 for nn_timing

File size: 29.7 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE sbcisf          ! PM we could remove it I think
22   USE closea          ! closed seas
23   USE fldread         ! read input field at current time step
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O module
26   USE lib_mpp         ! MPP library
27   USE eosbn2
28   USE wrk_nemo        ! Memory allocation
29   USE timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_rnf       ! routine call in sbcmod module
35   PUBLIC   sbc_rnf_div   ! routine called in divcurl module
36   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
37   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
38   !                                                     !!* namsbc_rnf namelist *
39   CHARACTER(len=100)         ::   cn_dir          !: Root directory for location of rnf files
40   LOGICAL                    ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
41   LOGICAL                    ::   ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
42   REAL(wp)                   ::   rn_rnf_max        !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
43   REAL(wp)                   ::   rn_dep_max        !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
44   INTEGER                    ::   nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45   LOGICAL                    ::   ln_rnf_tem      !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal      !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf          !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf          !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_s_rnf        !: information about the salinities of runoff file to be read
50   TYPE(FLD_N)                ::   sn_t_rnf        !: information about the temperatures of runoff file to be read
51   TYPE(FLD_N)                ::   sn_dep_rnf      !: information about the depth which river inflow affects
52   LOGICAL           , PUBLIC ::   ln_rnf_mouth    !: specific treatment in mouths vicinity
53   REAL(wp)                   ::   rn_hrnf         !: runoffs, depth over which enhanced vertical mixing is used
54   REAL(wp)          , PUBLIC ::   rn_avt_rnf      !: runoffs, value of the additional vertical mixing coef. [m2/s]
55   REAL(wp)          , PUBLIC ::   rn_rfact        !: multiplicative factor for runoff
56
57   LOGICAL           , PUBLIC ::   l_rnfcpl = .false.       ! runoffs recieved from oasis
58
59   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
63   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
65
66   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
69 
70   !! * Substitutions 
71#  include "domzgr_substitute.h90" 
72   !!----------------------------------------------------------------------
73   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
74   !! $Id$
75   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   INTEGER FUNCTION sbc_rnf_alloc()
80      !!----------------------------------------------------------------------
81      !!                ***  ROUTINE sbc_rnf_alloc  ***
82      !!----------------------------------------------------------------------
83      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
84         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
85         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
86         !
87      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
88      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
89   END FUNCTION sbc_rnf_alloc
90
91
92   SUBROUTINE sbc_rnf( kt )
93      !!----------------------------------------------------------------------
94      !!                  ***  ROUTINE sbc_rnf  ***
95      !!
96      !! ** Purpose :   Introduce a climatological run off forcing
97      !!
98      !! ** Method  :   Set each river mouth with a monthly climatology
99      !!                provided from different data.
100      !!                CAUTION : upward water flux, runoff forced to be < 0
101      !!
102      !! ** Action  :   runoff updated runoff field at time-step kt
103      !!----------------------------------------------------------------------
104      INTEGER, INTENT(in) ::   kt          ! ocean time step
105      !
106      INTEGER  ::   ji, jj    ! dummy loop indices
107      INTEGER  ::   z_err = 0 ! dummy integer for error handling
108      !!----------------------------------------------------------------------
109      REAL(wp), DIMENSION(:,:), POINTER       ::   ztfrz   ! freezing point used for temperature correction
110      !
111      CALL wrk_alloc( jpi,jpj, ztfrz)
112
113      !                                            ! ---------------------------------------- !
114      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
115         !                                         ! ---------------------------------------- !
116         rnf_b    (:,:  ) = rnf    (:,:  )               ! Swap the ocean forcing fields except at nit000
117         rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)               ! where before fields are set at the end of the routine
118         !
119      ENDIF
120
121      !                                            !-------------------!
122      !                                            !   Update runoff   !
123      !                                            !-------------------!
124      !
125      IF( .NOT. l_rnfcpl )   CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
126      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
127      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
128      !
129      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
130         !
131         IF( .NOT. l_rnfcpl )   rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )       ! updated runoff value at time step kt
132         !
133         !                                                     ! set temperature & salinity content of runoffs
134         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
135            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
136            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
137               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
138            END WHERE
139            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
140               ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
141               rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
142            END WHERE
143         ELSE                                                        ! use SST as runoffs temperature
144            rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
145         ENDIF
146         !                                                           ! use runoffs salinity data
147         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
148         !                                                           ! else use S=0 for runoffs (done one for all in the init)
149         CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
150      ENDIF
151      !
152      !                                                ! ---------------------------------------- !
153      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
154         !                                             ! ---------------------------------------- !
155         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
156            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
157            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
158            IF(nn_timing == 2)  CALL timing_start('iom_rstget')
159            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
160            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
161            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
162            IF(nn_timing == 2)  CALL timing_stop('iom_rstget')
163         ELSE                                                   !* no restart: set from nit000 values
164            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
165            rnf_b    (:,:  ) = rnf    (:,:  )
166            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
167         ENDIF
168      ENDIF
169      !                                                ! ---------------------------------------- !
170      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
171         !                                             ! ---------------------------------------- !
172         IF(lwp) WRITE(numout,*)
173         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
174            &                    'at it= ', kt,' date= ', ndastp
175         IF(lwp) WRITE(numout,*) '~~~~'
176         IF(nn_timing == 2)  CALL timing_start('iom_rstput')
177         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
178         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
179         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
180         IF(nn_timing == 2)  CALL timing_stop('iom_rstput')
181      ENDIF
182      !
183      CALL wrk_dealloc( jpi,jpj, ztfrz)
184      !
185   END SUBROUTINE sbc_rnf
186
187
188   SUBROUTINE sbc_rnf_div( phdivn )
189      !!----------------------------------------------------------------------
190      !!                  ***  ROUTINE sbc_rnf  ***
191      !!
192      !! ** Purpose :   update the horizontal divergence with the runoff inflow
193      !!
194      !! ** Method  :
195      !!                CAUTION : rnf is positive (inflow) decreasing the
196      !!                          divergence and expressed in m/s
197      !!
198      !! ** Action  :   phdivn   decreased by the runoff inflow
199      !!----------------------------------------------------------------------
200      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
201      !!
202      INTEGER  ::   ji, jj, jk   ! dummy loop indices
203      REAL(wp) ::   zfact     ! local scalar
204      !!----------------------------------------------------------------------
205      !
206      zfact = 0.5_wp
207      !
208      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
209         IF( lk_vvl ) THEN             ! variable volume case
210            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
211               DO ji = 1, jpi
212                  h_rnf(ji,jj) = 0._wp
213                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
214                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
215                  END DO
216                  !                          ! apply the runoff input flow
217                  DO jk = 1, nk_rnf(ji,jj)
218                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
219                  END DO
220               END DO
221            END DO
222         ELSE                          ! constant volume case : just apply the runoff input flow
223            DO jj = 1, jpj
224               DO ji = 1, jpi
225                  DO jk = 1, nk_rnf(ji,jj)
226                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
227                  END DO
228               END DO
229            END DO
230         ENDIF
231      ELSE                       !==   runoff put only at the surface   ==!
232         IF( lk_vvl ) THEN              ! variable volume case
233            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
234         ENDIF
235         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
236      ENDIF
237      !
238   END SUBROUTINE sbc_rnf_div
239
240
241   SUBROUTINE sbc_rnf_init
242      !!----------------------------------------------------------------------
243      !!                  ***  ROUTINE sbc_rnf_init  ***
244      !!
245      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
246      !!
247      !! ** Method  : - read the runoff namsbc_rnf namelist
248      !!
249      !! ** Action  : - read parameters
250      !!----------------------------------------------------------------------
251      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
252      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
253      INTEGER           ::   ierror, inum  ! temporary integer
254      INTEGER           ::   ios           ! Local integer output status for namelist read
255      INTEGER           ::   nbrec         ! temporary integer
256      REAL(wp)          ::   zacoef 
257      REAL(wp), DIMENSION(12)                 :: zrec             ! times records
258      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl   
259      REAL(wp), DIMENSION(:,:  ), ALLOCATABLE :: zrnf
260      !
261      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
262         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
263         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
264         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
265      !!----------------------------------------------------------------------
266      !
267      !                                         !==  allocate runoff arrays
268      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
269      !
270      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
271         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
272         nkrnf         = 0
273         rnf     (:,:) = 0.0_wp
274         rnf_b   (:,:) = 0.0_wp
275         rnfmsk  (:,:) = 0.0_wp
276         rnfmsk_z(:)   = 0.0_wp
277         RETURN
278      ENDIF
279      !
280      !                                   ! ============
281      !                                   !   Namelist
282      !                                   ! ============
283      !
284      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
285      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
286901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
287
288      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
289      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
290902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
291      IF(lwm) WRITE ( numond, namsbc_rnf )
292      !
293      !                                         ! Control print
294      IF(lwp) THEN
295         WRITE(numout,*)
296         WRITE(numout,*) 'sbc_rnf : runoff '
297         WRITE(numout,*) '~~~~~~~ '
298         WRITE(numout,*) '   Namelist namsbc_rnf'
299         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
300         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
301         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
302         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
303      ENDIF
304      !                                   ! ==================
305      !                                   !   Type of runoff
306      !                                   ! ==================
307      !
308      IF( .NOT. l_rnfcpl ) THEN                   
309         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
310         IF(lwp) WRITE(numout,*)
311         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
312         IF( ierror > 0 ) THEN
313            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
314         ENDIF
315         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
316         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
317         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
318      ENDIF
319      !
320      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
321         IF(lwp) WRITE(numout,*)
322         IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
323         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
324         IF( ierror > 0 ) THEN
325            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
326         ENDIF
327         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
328         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
329         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
330      ENDIF
331      !
332      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
333         IF(lwp) WRITE(numout,*)
334         IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
335         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
336         IF( ierror > 0 ) THEN
337            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
338         ENDIF
339         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
340         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
341         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
342      ENDIF
343      !
344      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
345         IF(lwp) WRITE(numout,*)
346         IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
347         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
348         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
349            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
350         ENDIF
351         CALL iom_open ( rn_dep_file, inum )                           ! open file
352         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
353         CALL iom_close( inum )                                        ! close file
354         !
355         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
356         DO jj = 1, jpj
357            DO ji = 1, jpi
358               IF( h_rnf(ji,jj) > 0._wp ) THEN
359                  jk = 2
360                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
361                  END DO
362                  nk_rnf(ji,jj) = jk
363               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
364               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
365               ELSE
366                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
367                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
368               ENDIF
369            END DO
370         END DO
371         DO jj = 1, jpj                                ! set the associated depth
372            DO ji = 1, jpi
373               h_rnf(ji,jj) = 0._wp
374               DO jk = 1, nk_rnf(ji,jj)
375                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
376               END DO
377            END DO
378         END DO
379         !
380      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
381         !
382         IF(lwp) WRITE(numout,*)
383         IF(lwp) WRITE(numout,*) '    depth of runoff computed once from max value of runoff'
384         IF(lwp) WRITE(numout,*) '    max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
385         IF(lwp) WRITE(numout,*) '    depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
386         IF(lwp) WRITE(numout,*) '     create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
387
388         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
389         CALL iom_gettime( inum, zrec, kntime=nbrec)
390         ALLOCATE( zrnfcl(jpi,jpj,nbrec) )     ;      ALLOCATE( zrnf(jpi,jpj) )
391         DO jm = 1, nbrec
392            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
393         END DO
394         CALL iom_close( inum )
395         zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 )   !  maximum value in time
396         DEALLOCATE( zrnfcl )
397         !
398         h_rnf(:,:) = 1.
399         !
400         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
401         !
402         WHERE( zrnf(:,:) > 0._wp )  h_rnf(:,:) = zacoef * zrnf(:,:)   ! compute depth for all runoffs
403         !
404         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
405            DO ji = 1, jpi
406               IF( zrnf(ji,jj) > 0._wp ) THEN
407                  jk = mbkt(ji,jj)
408                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
409               ENDIF
410            END DO
411         END DO
412         !
413         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
414         DO jj = 1, jpj
415            DO ji = 1, jpi
416               IF( zrnf(ji,jj) > 0._wp ) THEN
417                  jk = 2
418                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
419                  END DO
420                  nk_rnf(ji,jj) = jk
421               ELSE
422                  nk_rnf(ji,jj) = 1
423               ENDIF
424            END DO
425         END DO
426         !
427         DEALLOCATE( zrnf )
428         !
429         DO jj = 1, jpj                                ! set the associated depth
430            DO ji = 1, jpi
431               h_rnf(ji,jj) = 0._wp
432               DO jk = 1, nk_rnf(ji,jj)
433                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
434               END DO
435            END DO
436         END DO
437         !
438         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
439            IF(lwp) WRITE(numout,*) '              create runoff depht file'
440            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
441            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
442            CALL iom_close ( inum )
443         ENDIF
444      ELSE                                       ! runoffs applied at the surface
445         nk_rnf(:,:) = 1
446         h_rnf (:,:) = fse3t(:,:,1)
447      ENDIF
448      !
449      rnf(:,:) =  0._wp                         ! runoff initialisation
450      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
451      !
452      !                                   ! ========================
453      !                                   !   River mouth vicinity
454      !                                   ! ========================
455      !
456      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
457         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
458         !                                      !    - set to zero SSS damping (ln_ssr=T)
459         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
460         !
461         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
462            &                                              'be spread through depth by ln_rnf_depth'               )
463         !
464         nkrnf = 0                                  ! Number of level over which Kz increase
465         IF( rn_hrnf > 0._wp ) THEN
466            nkrnf = 2
467            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
468            END DO
469            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
470         ENDIF
471         IF(lwp) WRITE(numout,*)
472         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
473         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
474         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
475         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
476         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
477         !
478         CALL rnf_mouth                             ! set river mouth mask
479         !
480      ELSE                                      ! No treatment at river mouths
481         IF(lwp) WRITE(numout,*)
482         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
483         rnfmsk  (:,:) = 0._wp
484         rnfmsk_z(:)   = 0._wp
485         nkrnf = 0
486      ENDIF
487      !
488   END SUBROUTINE sbc_rnf_init
489
490
491   SUBROUTINE rnf_mouth
492      !!----------------------------------------------------------------------
493      !!                  ***  ROUTINE rnf_mouth  ***
494      !!
495      !! ** Purpose :   define the river mouths mask
496      !!
497      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
498      !!                climatological file. Defined a given vertical structure.
499      !!                CAUTION, the vertical structure is hard coded on the
500      !!                first 5 levels.
501      !!                This fields can be used to:
502      !!                 - set an upstream advection scheme
503      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
504      !!                 - increase vertical on the top nn_krnf vertical levels
505      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
506      !!                 - set to zero SSS restoring flux at river mouth grid points
507      !!
508      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
509      !!                rnfmsk_z vertical structure
510      !!----------------------------------------------------------------------
511      INTEGER            ::   inum        ! temporary integers
512      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
513      !!----------------------------------------------------------------------
514      !
515      IF(lwp) WRITE(numout,*)
516      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
517      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
518      !
519      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
520      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
521         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
522      ENDIF
523      !
524      ! horizontal mask (read in NetCDF file)
525      CALL iom_open ( cl_rnfile, inum )                           ! open file
526      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
527      CALL iom_close( inum )                                      ! close file
528      !
529      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
530      !
531      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
532      rnfmsk_z(1)   = 1.0
533      rnfmsk_z(2)   = 1.0                                         ! **********
534      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
535      rnfmsk_z(4)   = 0.25                                        ! **********
536      rnfmsk_z(5)   = 0.125
537      !
538   END SUBROUTINE rnf_mouth
539
540   !!======================================================================
541END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.