New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/UKMO/dev_r8126_LIM3_couple/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_r8126_LIM3_couple/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 8877

Last change on this file since 8877 was 8877, checked in by frrh, 6 years ago

Clear out SVN keywords and properties.

File size: 8.5 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
33   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
34
35   !! * Module variables
36   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
37 
38   INTEGER  :: rmtss                      !: number of seconds per month
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt, knt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      !
59      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
60      INTEGER  ::   ji, jj, jk, jn
61      REAL(wp) ::   zdispot, zfact, zcalcon
62      REAL(wp) ::   zomegaca, zexcess, zexcess0
63      CHARACTER (len=25) :: charout
64      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zcaldiss, zhinit, zhi, zco3sat
65      !!---------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
68      !
69      CALL wrk_alloc( jpi, jpj, jpk, zco3, zcaldiss, zhinit, zhi, zco3sat )
70      !
71      zco3    (:,:,:) = 0.
72      zcaldiss(:,:,:) = 0.
73      zhinit(:,:,:)   = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
74      !     -------------------------------------------
75      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
76      !     -------------------------------------------
77
78      CALL solve_at_general(zhinit, zhi)
79
80      DO jk = 1, jpkm1
81         DO jj = 1, jpj
82            DO ji = 1, jpi
83               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
84               &                + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
85               hi(ji,jj,jk)   = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
86            END DO
87         END DO
88      END DO
89
90      !     ---------------------------------------------------------
91      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
92      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
93      !        MGCO3)
94      !     ---------------------------------------------------------
95
96      DO jk = 1, jpkm1
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99
100               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
101               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
102               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
103               zfact    = rhop(ji,jj,jk) / 1000._wp
104               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
105               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
106
107               ! SET DEGREE OF UNDER-/SUPERSATURATION
108               excess(ji,jj,jk) = 1._wp - zomegaca
109               zexcess0 = MAX( 0., excess(ji,jj,jk) )
110               zexcess  = zexcess0**nca
111
112               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
113               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
114               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
115               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
116              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
117              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
118              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
119              !
120              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
121              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
122              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
123            END DO
124         END DO
125      END DO
126      !
127
128      IF( lk_iomput .AND. knt == nrdttrc ) THEN
129         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
130         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)    * 1.e+3            * tmask(:,:,:) )
131         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:) * 1.e+3            * tmask(:,:,:) )
132         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
133      ENDIF
134      !
135      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
136        WRITE(charout, FMT="('lys ')")
137        CALL prt_ctl_trc_info(charout)
138        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
139      ENDIF
140      !
141      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zcaldiss, zhinit, zhi, zco3sat )
142      !
143      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
144      !
145   END SUBROUTINE p4z_lys
146
147   SUBROUTINE p4z_lys_init
148
149      !!----------------------------------------------------------------------
150      !!                  ***  ROUTINE p4z_lys_init  ***
151      !!
152      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
153      !!
154      !! ** Method  :   Read the nampiscal namelist and check the parameters
155      !!      called at the first timestep (nittrc000)
156      !!
157      !! ** input   :   Namelist nampiscal
158      !!
159      !!----------------------------------------------------------------------
160      INTEGER  ::  ios                 ! Local integer output status for namelist read
161
162      NAMELIST/nampiscal/ kdca, nca
163      !!----------------------------------------------------------------------
164
165      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
166      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
167901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
168
169      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
170      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
171902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
172      IF(lwm) WRITE ( numonp, nampiscal )
173
174      IF(lwp) THEN                         ! control print
175         WRITE(numout,*) ' '
176         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
177         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
178         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
179         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
180      ENDIF
181
182      ! Number of seconds per month
183      rmtss =  nyear_len(1) * rday / raamo
184      !
185   END SUBROUTINE p4z_lys_init
186   !!======================================================================
187END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.