New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
geo2ocean.F90 in branches/UKMO/dev_r8183_GC_couple_pkg/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r8183_GC_couple_pkg/NEMOGCM/NEMO/OPA_SRC/SBC/geo2ocean.F90 @ 8731

Last change on this file since 8731 was 8731, checked in by dancopsey, 6 years ago

Merged in NEMO3.6 version of this branch (dev_r5518_GC3_couple_pkg)

File size: 23.9 KB
Line 
1MODULE geo2ocean
2   !!======================================================================
3   !!                     ***  MODULE  geo2ocean  ***
4   !! Ocean mesh    :  ???
5   !!======================================================================
6   !! History :  OPA  !  07-1996  (O. Marti)  Original code
7   !!   NEMO     1.0  !  06-2006  (G. Madec )  Free form, F90 + opt.
8   !!                 !  04-2007  (S. Masson)  angle: Add T, F points and bugfix in cos lateral boundary
9   !!            3.0  !  07-2008  (G. Madec)  geo2oce suppress lon/lat agruments
10   !!            3.7  !  11-2015  (G. Madec)  remove the unused repere and repcmo routines
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rot_rep       : Rotate the Repere: geographic grid <==> stretched coordinates grid
15   !!   angle         :
16   !!   geo2oce       :
17   !!   oce2geo       :
18   !!----------------------------------------------------------------------
19   USE dom_oce        ! mesh and scale factors
20   USE phycst         ! physical constants
21   !
22   USE in_out_manager ! I/O manager
23   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
24   USE lib_mpp        ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   rot_rep   ! called in sbccpl, fldread, and cyclone
30   PUBLIC   geo2oce   ! called in sbccpl
31   PUBLIC   oce2geo   ! called in sbccpl
32   PUBLIC   obs_rot   ! called in obs_rot_vel and obs_write
33
34   !                                         ! cos/sin between model grid lines and NP direction
35   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   gsint, gcost   ! at T point
36   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   gsinu, gcosu   ! at U point
37   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   gsinv, gcosv   ! at V point
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   gsinf, gcosf   ! at F point
39
40   LOGICAL ,              SAVE, DIMENSION(4)     ::   linit = .FALSE.
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   gsinlon, gcoslon, gsinlat, gcoslat
42
43   LOGICAL ::   lmust_init = .TRUE.        !: used to initialize the cos/sin variables (see above)
44
45   !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE repcmo ( pxu1, pyu1, pxv1, pyv1,   &
55                       px2 , py2 , kchoix  )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE repcmo  ***
58      !!
59      !! ** Purpose :   Change vector componantes from a geographic grid to a
60      !!      stretched coordinates grid.
61      !!
62      !! ** Method  :   Initialization of arrays at the first call.
63      !!
64      !! ** Action  : - px2 : first  componante (defined at u point)
65      !!              - py2 : second componante (defined at v point)
66      !!----------------------------------------------------------------------
67      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   pxu1, pyu1   ! geographic vector componantes at u-point
68      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   pxv1, pyv1   ! geographic vector componantes at v-point
69      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   px2          ! i-componante (defined at u-point)
70      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   py2          ! j-componante (defined at v-point)
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT( IN ) ::   &
73         kchoix   ! type of transformation
74                  ! = 1 change from geographic to model grid.
75                  ! =-1 change from model to geographic grid
76      !!----------------------------------------------------------------------
77 
78      SELECT CASE (kchoix)
79      CASE ( 1)
80        ! Change from geographic to stretched coordinate
81        ! ----------------------------------------------
82     
83        CALL rot_rep( pxu1, pyu1, 'U', 'en->i',px2 )
84        CALL rot_rep( pxv1, pyv1, 'V', 'en->j',py2 )
85      CASE (-1)
86       ! Change from stretched to geographic coordinate
87       ! ----------------------------------------------
88     
89       CALL rot_rep( pxu1, pyu1, 'U', 'ij->e',px2 )
90       CALL rot_rep( pxv1, pyv1, 'V', 'ij->n',py2 )
91     END SELECT
92     
93   END SUBROUTINE repcmo
94
95   SUBROUTINE rot_rep ( pxin, pyin, cd_type, cdtodo, prot )
96      !!----------------------------------------------------------------------
97      !!                  ***  ROUTINE rot_rep  ***
98      !!
99      !! ** Purpose :   Rotate the Repere: Change vector componantes between
100      !!                geographic grid <--> stretched coordinates grid.
101      !!----------------------------------------------------------------------
102      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   pxin, pyin   ! vector componantes
103      CHARACTER(len=1),             INTENT(in   ) ::   cd_type      ! define the nature of pt2d array grid-points
104      CHARACTER(len=5),             INTENT(in   ) ::   cdtodo       ! type of transpormation:
105      !                                                             ! 'en->i' = east-north to i-component
106      !                                                             ! 'en->j' = east-north to j-component
107      !                                                             ! 'ij->e' = (i,j) components to east
108      !                                                             ! 'ij->n' = (i,j) components to north
109      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   prot     
110      !!----------------------------------------------------------------------
111      !
112      IF( lmust_init ) THEN      ! at 1st call only: set  gsin. & gcos.
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) ' rot_rep: coordinate transformation : geographic <==> model (i,j)-components'
115         IF(lwp) WRITE(numout,*) ' ~~~~~~~~    '
116         !
117         CALL angle       ! initialization of the transformation
118         lmust_init = .FALSE.
119      ENDIF
120      !
121      SELECT CASE( cdtodo )      ! type of rotation
122      !
123      CASE( 'en->i' )                  ! east-north to i-component
124         SELECT CASE (cd_type)
125         CASE ('T')   ;   prot(:,:) = pxin(:,:) * gcost(:,:) + pyin(:,:) * gsint(:,:)
126         CASE ('U')   ;   prot(:,:) = pxin(:,:) * gcosu(:,:) + pyin(:,:) * gsinu(:,:)
127         CASE ('V')   ;   prot(:,:) = pxin(:,:) * gcosv(:,:) + pyin(:,:) * gsinv(:,:)
128         CASE ('F')   ;   prot(:,:) = pxin(:,:) * gcosf(:,:) + pyin(:,:) * gsinf(:,:)
129         CASE DEFAULT   ;   CALL ctl_stop( 'Only T, U, V and F grid points are coded' )
130         END SELECT
131      CASE ('en->j')                   ! east-north to j-component
132         SELECT CASE (cd_type)
133         CASE ('T')   ;   prot(:,:) = pyin(:,:) * gcost(:,:) - pxin(:,:) * gsint(:,:)
134         CASE ('U')   ;   prot(:,:) = pyin(:,:) * gcosu(:,:) - pxin(:,:) * gsinu(:,:)
135         CASE ('V')   ;   prot(:,:) = pyin(:,:) * gcosv(:,:) - pxin(:,:) * gsinv(:,:)   
136         CASE ('F')   ;   prot(:,:) = pyin(:,:) * gcosf(:,:) - pxin(:,:) * gsinf(:,:)   
137         CASE DEFAULT   ;   CALL ctl_stop( 'Only T, U, V and F grid points are coded' )
138         END SELECT
139      CASE ('ij->e')                   ! (i,j)-components to east
140         SELECT CASE (cd_type)
141         CASE ('T')   ;   prot(:,:) = pxin(:,:) * gcost(:,:) - pyin(:,:) * gsint(:,:)
142         CASE ('U')   ;   prot(:,:) = pxin(:,:) * gcosu(:,:) - pyin(:,:) * gsinu(:,:)
143         CASE ('V')   ;   prot(:,:) = pxin(:,:) * gcosv(:,:) - pyin(:,:) * gsinv(:,:)
144         CASE ('F')   ;   prot(:,:) = pxin(:,:) * gcosf(:,:) - pyin(:,:) * gsinf(:,:)
145         CASE DEFAULT   ;   CALL ctl_stop( 'Only T, U, V and F grid points are coded' )
146         END SELECT
147      CASE ('ij->n')                   ! (i,j)-components to north
148         SELECT CASE (cd_type)
149         CASE ('T')   ;   prot(:,:) = pyin(:,:) * gcost(:,:) + pxin(:,:) * gsint(:,:)
150         CASE ('U')   ;   prot(:,:) = pyin(:,:) * gcosu(:,:) + pxin(:,:) * gsinu(:,:)
151         CASE ('V')   ;   prot(:,:) = pyin(:,:) * gcosv(:,:) + pxin(:,:) * gsinv(:,:)
152         CASE ('F')   ;   prot(:,:) = pyin(:,:) * gcosf(:,:) + pxin(:,:) * gsinf(:,:)
153         CASE DEFAULT   ;   CALL ctl_stop( 'Only T, U, V and F grid points are coded' )
154         END SELECT
155      CASE DEFAULT   ;   CALL ctl_stop( 'rot_rep: Syntax Error in the definition of cdtodo' )
156      !
157      END SELECT
158      !
159   END SUBROUTINE rot_rep
160
161
162   SUBROUTINE angle
163      !!----------------------------------------------------------------------
164      !!                  ***  ROUTINE angle  ***
165      !!
166      !! ** Purpose :   Compute angles between model grid lines and the North direction
167      !!
168      !! ** Method  :   sinus and cosinus of the angle between the north-south axe
169      !!              and the j-direction at t, u, v and f-points
170      !!                dot and cross products are used to obtain cos and sin, resp.
171      !!
172      !! ** Action  : - gsint, gcost, gsinu, gcosu, gsinv, gcosv, gsinf, gcosf
173      !!----------------------------------------------------------------------
174      INTEGER  ::   ji, jj   ! dummy loop indices
175      INTEGER  ::   ierr     ! local integer
176      REAL(wp) ::   zlam, zphi            ! local scalars
177      REAL(wp) ::   zlan, zphh            !   -      -
178      REAL(wp) ::   zxnpt, zynpt, znnpt   ! x,y components and norm of the vector: T point to North Pole
179      REAL(wp) ::   zxnpu, zynpu, znnpu   ! x,y components and norm of the vector: U point to North Pole
180      REAL(wp) ::   zxnpv, zynpv, znnpv   ! x,y components and norm of the vector: V point to North Pole
181      REAL(wp) ::   zxnpf, zynpf, znnpf   ! x,y components and norm of the vector: F point to North Pole
182      REAL(wp) ::   zxvvt, zyvvt, znvvt   ! x,y components and norm of the vector: between V points below and above a T point
183      REAL(wp) ::   zxffu, zyffu, znffu   ! x,y components and norm of the vector: between F points below and above a U point
184      REAL(wp) ::   zxffv, zyffv, znffv   ! x,y components and norm of the vector: between F points left  and right a V point
185      REAL(wp) ::   zxuuf, zyuuf, znuuf   ! x,y components and norm of the vector: between U points below and above a F point
186      !!----------------------------------------------------------------------
187      !
188      ALLOCATE( gsint(jpi,jpj), gcost(jpi,jpj),   & 
189         &      gsinu(jpi,jpj), gcosu(jpi,jpj),   & 
190         &      gsinv(jpi,jpj), gcosv(jpi,jpj),   & 
191         &      gsinf(jpi,jpj), gcosf(jpi,jpj), STAT=ierr )
192      IF(lk_mpp)   CALL mpp_sum( ierr )
193      IF( ierr /= 0 )   CALL ctl_stop( 'angle: unable to allocate arrays' )
194      !
195      ! ============================= !
196      ! Compute the cosinus and sinus !
197      ! ============================= !
198      ! (computation done on the north stereographic polar plane)
199      !
200      DO jj = 2, jpjm1
201         DO ji = fs_2, jpi   ! vector opt.
202            !                 
203            zlam = glamt(ji,jj)     ! north pole direction & modulous (at t-point)
204            zphi = gphit(ji,jj)
205            zxnpt = 0. - 2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
206            zynpt = 0. - 2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
207            znnpt = zxnpt*zxnpt + zynpt*zynpt
208            !
209            zlam = glamu(ji,jj)     ! north pole direction & modulous (at u-point)
210            zphi = gphiu(ji,jj)
211            zxnpu = 0. - 2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
212            zynpu = 0. - 2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
213            znnpu = zxnpu*zxnpu + zynpu*zynpu
214            !
215            zlam = glamv(ji,jj)     ! north pole direction & modulous (at v-point)
216            zphi = gphiv(ji,jj)
217            zxnpv = 0. - 2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
218            zynpv = 0. - 2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
219            znnpv = zxnpv*zxnpv + zynpv*zynpv
220            !
221            zlam = glamf(ji,jj)     ! north pole direction & modulous (at f-point)
222            zphi = gphif(ji,jj)
223            zxnpf = 0. - 2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
224            zynpf = 0. - 2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )
225            znnpf = zxnpf*zxnpf + zynpf*zynpf
226            !
227            zlam = glamv(ji,jj  )   ! j-direction: v-point segment direction (around t-point)
228            zphi = gphiv(ji,jj  )
229            zlan = glamv(ji,jj-1)
230            zphh = gphiv(ji,jj-1)
231            zxvvt =  2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
232               &  -  2. * COS( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
233            zyvvt =  2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
234               &  -  2. * SIN( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
235            znvvt = SQRT( znnpt * ( zxvvt*zxvvt + zyvvt*zyvvt )  )
236            znvvt = MAX( znvvt, 1.e-14 )
237            !
238            zlam = glamf(ji,jj  )   ! j-direction: f-point segment direction (around u-point)
239            zphi = gphif(ji,jj  )
240            zlan = glamf(ji,jj-1)
241            zphh = gphif(ji,jj-1)
242            zxffu =  2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
243               &  -  2. * COS( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
244            zyffu =  2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
245               &  -  2. * SIN( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
246            znffu = SQRT( znnpu * ( zxffu*zxffu + zyffu*zyffu )  )
247            znffu = MAX( znffu, 1.e-14 )
248            !
249            zlam = glamf(ji  ,jj)   ! i-direction: f-point segment direction (around v-point)
250            zphi = gphif(ji  ,jj)
251            zlan = glamf(ji-1,jj)
252            zphh = gphif(ji-1,jj)
253            zxffv =  2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
254               &  -  2. * COS( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
255            zyffv =  2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
256               &  -  2. * SIN( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
257            znffv = SQRT( znnpv * ( zxffv*zxffv + zyffv*zyffv )  )
258            znffv = MAX( znffv, 1.e-14 )
259            !
260            zlam = glamu(ji,jj+1)   ! j-direction: u-point segment direction (around f-point)
261            zphi = gphiu(ji,jj+1)
262            zlan = glamu(ji,jj  )
263            zphh = gphiu(ji,jj  )
264            zxuuf =  2. * COS( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
265               &  -  2. * COS( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
266            zyuuf =  2. * SIN( rad*zlam ) * TAN( rpi/4. - rad*zphi/2. )   &
267               &  -  2. * SIN( rad*zlan ) * TAN( rpi/4. - rad*zphh/2. )
268            znuuf = SQRT( znnpf * ( zxuuf*zxuuf + zyuuf*zyuuf )  )
269            znuuf = MAX( znuuf, 1.e-14 )
270            !
271            !                       ! cosinus and sinus using dot and cross products
272            gsint(ji,jj) = ( zxnpt*zyvvt - zynpt*zxvvt ) / znvvt
273            gcost(ji,jj) = ( zxnpt*zxvvt + zynpt*zyvvt ) / znvvt
274            !
275            gsinu(ji,jj) = ( zxnpu*zyffu - zynpu*zxffu ) / znffu
276            gcosu(ji,jj) = ( zxnpu*zxffu + zynpu*zyffu ) / znffu
277            !
278            gsinf(ji,jj) = ( zxnpf*zyuuf - zynpf*zxuuf ) / znuuf
279            gcosf(ji,jj) = ( zxnpf*zxuuf + zynpf*zyuuf ) / znuuf
280            !
281            gsinv(ji,jj) = ( zxnpv*zxffv + zynpv*zyffv ) / znffv
282            gcosv(ji,jj) =-( zxnpv*zyffv - zynpv*zxffv ) / znffv     ! (caution, rotation of 90 degres)
283            !
284         END DO
285      END DO
286
287      ! =============== !
288      ! Geographic mesh !
289      ! =============== !
290
291      DO jj = 2, jpjm1
292         DO ji = fs_2, jpi   ! vector opt.
293            IF( MOD( ABS( glamv(ji,jj) - glamv(ji,jj-1) ), 360. ) < 1.e-8 ) THEN
294               gsint(ji,jj) = 0.
295               gcost(ji,jj) = 1.
296            ENDIF
297            IF( MOD( ABS( glamf(ji,jj) - glamf(ji,jj-1) ), 360. ) < 1.e-8 ) THEN
298               gsinu(ji,jj) = 0.
299               gcosu(ji,jj) = 1.
300            ENDIF
301            IF(      ABS( gphif(ji,jj) - gphif(ji-1,jj) )         < 1.e-8 ) THEN
302               gsinv(ji,jj) = 0.
303               gcosv(ji,jj) = 1.
304            ENDIF
305            IF( MOD( ABS( glamu(ji,jj) - glamu(ji,jj+1) ), 360. ) < 1.e-8 ) THEN
306               gsinf(ji,jj) = 0.
307               gcosf(ji,jj) = 1.
308            ENDIF
309         END DO
310      END DO
311
312      ! =========================== !
313      ! Lateral boundary conditions !
314      ! =========================== !
315      !           ! lateral boundary cond.: T-, U-, V-, F-pts, sgn
316      CALL lbc_lnk( gcost, 'T', -1. )   ;   CALL lbc_lnk( gsint, 'T', -1. )
317      CALL lbc_lnk( gcosu, 'U', -1. )   ;   CALL lbc_lnk( gsinu, 'U', -1. )
318      CALL lbc_lnk( gcosv, 'V', -1. )   ;   CALL lbc_lnk( gsinv, 'V', -1. )
319      CALL lbc_lnk( gcosf, 'F', -1. )   ;   CALL lbc_lnk( gsinf, 'F', -1. )
320      !
321   END SUBROUTINE angle
322
323
324   SUBROUTINE geo2oce ( pxx, pyy, pzz, cgrid, pte, ptn )
325      !!----------------------------------------------------------------------
326      !!                    ***  ROUTINE geo2oce  ***
327      !!     
328      !! ** Purpose :
329      !!
330      !! ** Method  :   Change a vector from geocentric to east/north
331      !!
332      !!----------------------------------------------------------------------
333      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::  pxx, pyy, pzz
334      CHARACTER(len=1)            , INTENT(in   ) ::  cgrid
335      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::  pte, ptn
336      !
337      REAL(wp), PARAMETER :: rpi = 3.141592653e0
338      REAL(wp), PARAMETER :: rad = rpi / 180.e0
339      INTEGER ::   ig     !
340      INTEGER ::   ierr   ! local integer
341      !!----------------------------------------------------------------------
342      !
343      IF( .NOT. ALLOCATED( gsinlon ) ) THEN
344         ALLOCATE( gsinlon(jpi,jpj,4) , gcoslon(jpi,jpj,4) ,   &
345            &      gsinlat(jpi,jpj,4) , gcoslat(jpi,jpj,4) , STAT=ierr )
346         IF( lk_mpp    )   CALL mpp_sum( ierr )
347         IF( ierr /= 0 )   CALL ctl_stop('geo2oce: unable to allocate arrays' )
348      ENDIF
349      !
350      SELECT CASE( cgrid)
351      CASE ( 'T' )   
352         ig = 1
353         IF( .NOT. linit(ig) ) THEN
354            gsinlon(:,:,ig) = SIN( rad * glamt(:,:) )
355            gcoslon(:,:,ig) = COS( rad * glamt(:,:) )
356            gsinlat(:,:,ig) = SIN( rad * gphit(:,:) )
357            gcoslat(:,:,ig) = COS( rad * gphit(:,:) )
358            linit(ig) = .TRUE.
359         ENDIF
360      CASE ( 'U' )   
361         ig = 2
362         IF( .NOT. linit(ig) ) THEN
363            gsinlon(:,:,ig) = SIN( rad * glamu(:,:) )
364            gcoslon(:,:,ig) = COS( rad * glamu(:,:) )
365            gsinlat(:,:,ig) = SIN( rad * gphiu(:,:) )
366            gcoslat(:,:,ig) = COS( rad * gphiu(:,:) )
367            linit(ig) = .TRUE.
368         ENDIF
369      CASE ( 'V' )   
370         ig = 3
371         IF( .NOT. linit(ig) ) THEN
372            gsinlon(:,:,ig) = SIN( rad * glamv(:,:) )
373            gcoslon(:,:,ig) = COS( rad * glamv(:,:) )
374            gsinlat(:,:,ig) = SIN( rad * gphiv(:,:) )
375            gcoslat(:,:,ig) = COS( rad * gphiv(:,:) )
376            linit(ig) = .TRUE.
377         ENDIF
378      CASE ( 'F' )   
379         ig = 4
380         IF( .NOT. linit(ig) ) THEN
381            gsinlon(:,:,ig) = SIN( rad * glamf(:,:) )
382            gcoslon(:,:,ig) = COS( rad * glamf(:,:) )
383            gsinlat(:,:,ig) = SIN( rad * gphif(:,:) )
384            gcoslat(:,:,ig) = COS( rad * gphif(:,:) )
385            linit(ig) = .TRUE.
386         ENDIF
387      CASE default   
388         WRITE(ctmp1,*) 'geo2oce : bad grid argument : ', cgrid
389         CALL ctl_stop( ctmp1 )
390      END SELECT
391      !
392      pte = - gsinlon(:,:,ig) * pxx + gcoslon(:,:,ig) * pyy
393      ptn = - gcoslon(:,:,ig) * gsinlat(:,:,ig) * pxx    &
394         &  - gsinlon(:,:,ig) * gsinlat(:,:,ig) * pyy    &
395         &  + gcoslat(:,:,ig) * pzz
396      !
397   END SUBROUTINE geo2oce
398
399
400   SUBROUTINE oce2geo ( pte, ptn, cgrid, pxx , pyy , pzz )
401      !!----------------------------------------------------------------------
402      !!                    ***  ROUTINE oce2geo  ***
403      !!     
404      !! ** Purpose :
405      !!
406      !! ** Method  :   Change vector from east/north to geocentric
407      !!
408      !! History :     ! (A. Caubel)  oce2geo - Original code
409      !!----------------------------------------------------------------------
410      REAL(wp), DIMENSION(jpi,jpj), INTENT( IN    ) ::  pte, ptn
411      CHARACTER(len=1)            , INTENT( IN    ) ::  cgrid
412      REAL(wp), DIMENSION(jpi,jpj), INTENT(   OUT ) ::  pxx , pyy , pzz
413      !!
414      REAL(wp), PARAMETER :: rpi = 3.141592653E0
415      REAL(wp), PARAMETER :: rad = rpi / 180.e0
416      INTEGER ::   ig     !
417      INTEGER ::   ierr   ! local integer
418      !!----------------------------------------------------------------------
419
420      IF( .NOT. ALLOCATED( gsinlon ) ) THEN
421         ALLOCATE( gsinlon(jpi,jpj,4) , gcoslon(jpi,jpj,4) ,   &
422            &      gsinlat(jpi,jpj,4) , gcoslat(jpi,jpj,4) , STAT=ierr )
423         IF( lk_mpp    )   CALL mpp_sum( ierr )
424         IF( ierr /= 0 )   CALL ctl_stop('oce2geo: unable to allocate arrays' )
425      ENDIF
426
427      SELECT CASE( cgrid)
428         CASE ( 'T' )   
429            ig = 1
430            IF( .NOT. linit(ig) ) THEN
431               gsinlon(:,:,ig) = SIN( rad * glamt(:,:) )
432               gcoslon(:,:,ig) = COS( rad * glamt(:,:) )
433               gsinlat(:,:,ig) = SIN( rad * gphit(:,:) )
434               gcoslat(:,:,ig) = COS( rad * gphit(:,:) )
435               linit(ig) = .TRUE.
436            ENDIF
437         CASE ( 'U' )   
438            ig = 2
439            IF( .NOT. linit(ig) ) THEN
440               gsinlon(:,:,ig) = SIN( rad * glamu(:,:) )
441               gcoslon(:,:,ig) = COS( rad * glamu(:,:) )
442               gsinlat(:,:,ig) = SIN( rad * gphiu(:,:) )
443               gcoslat(:,:,ig) = COS( rad * gphiu(:,:) )
444               linit(ig) = .TRUE.
445            ENDIF
446         CASE ( 'V' )   
447            ig = 3
448            IF( .NOT. linit(ig) ) THEN
449               gsinlon(:,:,ig) = SIN( rad * glamv(:,:) )
450               gcoslon(:,:,ig) = COS( rad * glamv(:,:) )
451               gsinlat(:,:,ig) = SIN( rad * gphiv(:,:) )
452               gcoslat(:,:,ig) = COS( rad * gphiv(:,:) )
453               linit(ig) = .TRUE.
454            ENDIF
455         CASE ( 'F' )   
456            ig = 4
457            IF( .NOT. linit(ig) ) THEN
458               gsinlon(:,:,ig) = SIN( rad * glamf(:,:) )
459               gcoslon(:,:,ig) = COS( rad * glamf(:,:) )
460               gsinlat(:,:,ig) = SIN( rad * gphif(:,:) )
461               gcoslat(:,:,ig) = COS( rad * gphif(:,:) )
462               linit(ig) = .TRUE.
463            ENDIF
464         CASE default   
465            WRITE(ctmp1,*) 'geo2oce : bad grid argument : ', cgrid
466            CALL ctl_stop( ctmp1 )
467      END SELECT
468      !
469      pxx = - gsinlon(:,:,ig) * pte - gcoslon(:,:,ig) * gsinlat(:,:,ig) * ptn 
470      pyy =   gcoslon(:,:,ig) * pte - gsinlon(:,:,ig) * gsinlat(:,:,ig) * ptn
471      pzz =   gcoslat(:,:,ig) * ptn
472      !
473   END SUBROUTINE oce2geo
474
475
476   SUBROUTINE obs_rot( psinu, pcosu, psinv, pcosv )
477      !!----------------------------------------------------------------------
478      !!                  ***  ROUTINE obs_rot  ***
479      !!
480      !! ** Purpose :   Copy gsinu, gcosu, gsinv and gsinv
481      !!                to input data for rotations of
482      !!                current at observation points
483      !!
484      !! History :  9.2  !  09-02  (K. Mogensen)
485      !!----------------------------------------------------------------------
486      REAL(wp), DIMENSION(jpi,jpj), INTENT( OUT )::   psinu, pcosu, psinv, pcosv   ! copy of data
487      !!----------------------------------------------------------------------
488      !
489      ! Initialization of gsin* and gcos* at first call
490      ! -----------------------------------------------
491      IF( lmust_init ) THEN
492         IF(lwp) WRITE(numout,*)
493         IF(lwp) WRITE(numout,*) ' obs_rot : geographic <--> stretched'
494         IF(lwp) WRITE(numout,*) ' ~~~~~~~   coordinate transformation'
495         CALL angle       ! initialization of the transformation
496         lmust_init = .FALSE.
497      ENDIF
498      !
499      psinu(:,:) = gsinu(:,:)
500      pcosu(:,:) = gcosu(:,:)
501      psinv(:,:) = gsinv(:,:)
502      pcosv(:,:) = gcosv(:,:)
503      !
504   END SUBROUTINE obs_rot
505
506  !!======================================================================
507END MODULE geo2ocean
Note: See TracBrowser for help on using the repository browser.