Context Navigation

sbcwave.F90 @ 8738

Last change on this file since 8738 was 8738, checked in by dancopsey, 6 years ago
Merged in main ICEMODEL branch (branches/2017/dev_r8183_ICEMODEL) up to revision 8588
File size: 18.0 KB

Line
1	MODULE sbcwave
2	!!======================================================================
3	!! * MODULE sbcwave *
4	!! Wave module
5	!!======================================================================
6	!! History : 3.3 ! 2011-09 (M. Adani) Original code: Drag Coefficient
7	!! : 3.4 ! 2012-10 (M. Adani) Stokes Drift
8	!! 3.6 ! 2014-09 (E. Clementi,P. Oddo) New Stokes Drift Computation
9	!! - ! 2016-12 (G. Madec, E. Clementi) update Stoke drift computation
10	!! + add sbc_wave_ini routine
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_stokes : calculate 3D Stokes-drift velocities
15	!! sbc_wave : wave data from wave model in netcdf files
16	!! sbc_wave_init : initialisation fo surface waves
17	!!----------------------------------------------------------------------
18	USE phycst ! physical constants
19	USE oce ! ocean variables
20	USE sbc_oce ! Surface boundary condition: ocean fields
21	USE zdf_oce, ONLY : ln_zdfqiao
22	USE bdy_oce ! open boundary condition variables
23	USE domvvl ! domain: variable volume layers
24	!
25	USE iom ! I/O manager library
26	USE in_out_manager ! I/O manager
27	USE lib_mpp ! distribued memory computing library
28	USE fldread ! read input fields
29	USE wrk_nemo !
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC sbc_stokes ! routine called in sbccpl
35	PUBLIC sbc_wave ! routine called in sbcmod
36	PUBLIC sbc_wave_init ! routine called in sbcmod
37
38	! Variables checking if the wave parameters are coupled (if not, they are read from file)
39	LOGICAL, PUBLIC :: cpl_hsig = .FALSE.
40	LOGICAL, PUBLIC :: cpl_phioc = .FALSE.
41	LOGICAL, PUBLIC :: cpl_sdrftx = .FALSE.
42	LOGICAL, PUBLIC :: cpl_sdrfty = .FALSE.
43	LOGICAL, PUBLIC :: cpl_wper = .FALSE.
44	LOGICAL, PUBLIC :: cpl_wnum = .FALSE.
45	LOGICAL, PUBLIC :: cpl_wstrf = .FALSE.
46	LOGICAL, PUBLIC :: cpl_wdrag = .FALSE.
47
48	INTEGER :: jpfld ! number of files to read for stokes drift
49	INTEGER :: jp_usd ! index of stokes drift (i-component) (m/s) at T-point
50	INTEGER :: jp_vsd ! index of stokes drift (j-component) (m/s) at T-point
51	INTEGER :: jp_hsw ! index of significant wave hight (m) at T-point
52	INTEGER :: jp_wmp ! index of mean wave period (s) at T-point
53
54	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_cd ! structure of input fields (file informations, fields read) Drag Coefficient
55	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sd ! structure of input fields (file informations, fields read) Stokes Drift
56	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_wn ! structure of input fields (file informations, fields read) wave number for Qiao
57	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: cdn_wave !:
59	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: hsw, wmp, wnum !:
60	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: tauoc_wave !:
61	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: tsd2d !:
62	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: div_sd !: barotropic stokes drift divergence
63	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) :: ut0sd, vt0sd !: surface Stokes drift velocities at t-point
64	REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) :: usd , vsd , wsd !: Stokes drift velocities at u-, v- & w-points, resp.
65
66	!! * Substitutions
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE sbc_stokes( )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE sbc_stokes *
78	!!
79	!! ** Purpose : compute the 3d Stokes Drift according to Breivik et al.,
80	!! 2014 (DOI: 10.1175/JPO-D-14-0020.1)
81	!!
82	!! ** Method : - Calculate Stokes transport speed
83	!! - Calculate horizontal divergence
84	!! - Integrate the horizontal divergenze from the bottom
85	!! ** action
86	!!---------------------------------------------------------------------
87	INTEGER :: jj, ji, jk ! dummy loop argument
88	INTEGER :: ik ! local integer
89	REAL(wp) :: ztransp, zfac, ztemp, zsp0
90	REAL(wp) :: zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
91	REAL(wp), DIMENSION(:,:) , POINTER :: zk_t, zk_u, zk_v, zu0_sd, zv0_sd ! 2D workspace
92	REAL(wp), DIMENSION(:,:,:), POINTER :: ze3divh ! 3D workspace
93	!!---------------------------------------------------------------------
94	!
95	CALL wrk_alloc( jpi,jpj,jpk, ze3divh )
96	CALL wrk_alloc( jpi,jpj, zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
97	!
98	!
99	zfac = 2.0_wp * rpi / 16.0_wp
100	DO jj = 1, jpj ! exp. wave number at t-point (Eq. (19) in Breivick et al. (2014) )
101	DO ji = 1, jpi
102	! Stokes drift velocity estimated from Hs and Tmean
103	ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj) , 0.0000001_wp )
104	! Stokes surface speed
105	zsp0 = SQRT( ut0sd(ji,jj)ut0sd(ji,jj) + vt0sd(ji,jj)vt0sd(ji,jj) )
106	tsd2d(ji,jj) = zsp0
107	! Wavenumber scale
108	zk_t(ji,jj) = ABS( zsp0 ) / MAX( ABS( 5.97_wp*ztransp ) , 0.0000001_wp )
109	END DO
110	END DO
111	DO jj = 1, jpjm1 ! exp. wave number & Stokes drift velocity at u- & v-points
112	DO ji = 1, jpim1
113	zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
114	zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
115	!
116	zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
117	zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
118	END DO
119	END DO
120	!
121	! !== horizontal Stokes Drift 3D velocity ==!
122	DO jk = 1, jpkm1
123	DO jj = 2, jpjm1
124	DO ji = 2, jpim1
125	zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
126	zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
127	!
128	zkh_u = zk_u(ji,jj) * zdep_u ! k * depth
129	zkh_v = zk_v(ji,jj) * zdep_v
130	! ! Depth attenuation
131	zda_u = EXP( -2.0_wpzkh_u ) / ( 1.0_wp + 8.0_wpzkh_u )
132	zda_v = EXP( -2.0_wpzkh_v ) / ( 1.0_wp + 8.0_wpzkh_v )
133	!
134	usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
135	vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
136	END DO
137	END DO
138	END DO
139	!!gm CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
140	CALL lbc_lnk( usd(:,:,:), 'U', -1. )
141	CALL lbc_lnk( vsd(:,:,:), 'V', -1. )
142
143
144	!
145	! !== vertical Stokes Drift 3D velocity ==!
146	!
147	DO jk = 1, jpkm1 ! Horizontal e3*divergence
148	DO jj = 2, jpj
149	DO ji = fs_2, jpi
150	ze3divh(ji,jj,jk) = ( e2u(ji ,jj) * e3u_n(ji ,jj,jk) * usd(ji ,jj,jk) &
151	& - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk) &
152	& + e1v(ji,jj ) * e3v_n(ji,jj ,jk) * vsd(ji,jj ,jk) &
153	& - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk) ) * r1_e1e2t(ji,jj)
154	END DO
155	END DO
156	END DO
157	!
158	#if defined key_agrif
159	IF( .NOT. Agrif_Root() ) THEN
160	IF( nbondi == -1 .OR. nbondi == 2 ) ze3divh( 2:nbghostcells+1,: ,:) = 0._wp ! west
161	IF( nbondi == 1 .OR. nbondi == 2 ) ze3divh( nlci-nbghostcells:nlci-1,:,:) = 0._wp ! east
162	IF( nbondj == -1 .OR. nbondj == 2 ) ze3divh( :,2:nbghostcells+1 ,:) = 0._wp ! south
163	IF( nbondj == 1 .OR. nbondj == 2 ) ze3divh( :,nlcj-nbghostcells:nlcj-1,:) = 0._wp ! north
164	ENDIF
165	#endif
166	!
167	CALL lbc_lnk( ze3divh, 'T', 1. )
168	!
169	IF( ln_linssh ) THEN ; ik = 1 ! none zero velocity through the sea surface
170	ELSE ; ik = 2 ! w=0 at the surface (set one for all in sbc_wave_init)
171	ENDIF
172	DO jk = jpkm1, ik, -1 ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
173	wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
174	END DO
175	!
176	IF( ln_bdy ) THEN
177	DO jk = 1, jpkm1
178	wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
179	END DO
180	ENDIF
181	! !== Horizontal divergence of barotropic Stokes transport ==!
182	div_sd(:,:) = 0._wp
183	DO jk = 1, jpkm1 !
184	div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
185	END DO
186	!
187	CALL iom_put( "ustokes", usd )
188	CALL iom_put( "vstokes", vsd )
189	CALL iom_put( "wstokes", wsd )
190	!
191	CALL wrk_dealloc( jpi,jpj,jpk, ze3divh )
192	CALL wrk_dealloc( jpi,jpj, zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
193	!
194	END SUBROUTINE sbc_stokes
195
196
197	SUBROUTINE sbc_wave( kt )
198	!!---------------------------------------------------------------------
199	!! * ROUTINE sbc_wave *
200	!!
201	!! ** Purpose : read wave parameters from wave model in netcdf files.
202	!!
203	!! ** Method : - Read namelist namsbc_wave
204	!! - Read Cd_n10 fields in netcdf files
205	!! - Read stokes drift 2d in netcdf files
206	!! - Read wave number in netcdf files
207	!! - Compute 3d stokes drift using Breivik et al.,2014
208	!! formulation
209	!! ** action
210	!!---------------------------------------------------------------------
211	INTEGER, INTENT(in ) :: kt ! ocean time step
212	!!---------------------------------------------------------------------
213	!
214	IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN !== Neutral drag coefficient ==!
215	CALL fld_read( kt, nn_fsbc, sf_cd ) ! read from external forcing
216	cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
217	ENDIF
218
219	IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN !== Wave induced stress ==!
220	CALL fld_read( kt, nn_fsbc, sf_tauoc ) ! read wave norm stress from external forcing
221	tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
222	ENDIF
223
224	IF( ln_sdw ) THEN !== Computation of the 3d Stokes Drift ==!
225	!
226	IF( jpfld > 0 ) THEN ! Read from file only if the field is not coupled
227	CALL fld_read( kt, nn_fsbc, sf_sd ) ! read wave parameters from external forcing
228	IF( jp_hsw > 0 ) hsw (:,:) = sf_sd(jp_hsw)%fnow(:,:,1) ! significant wave height
229	IF( jp_wmp > 0 ) wmp (:,:) = sf_sd(jp_wmp)%fnow(:,:,1) ! wave mean period
230	IF( jp_usd > 0 ) ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1) ! 2D zonal Stokes Drift at T point
231	IF( jp_vsd > 0 ) vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1) ! 2D meridional Stokes Drift at T point
232	ENDIF
233	!
234	! Read also wave number if needed, so that it is available in coupling routines
235	IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
236	CALL fld_read( kt, nn_fsbc, sf_wn ) ! read wave parameters from external forcing
237	wnum(:,:) = sf_wn(1)%fnow(:,:,1)
238	ENDIF
239
240	! !== Computation of the 3d Stokes Drift ==!
241	!
242	IF( jpfld == 4 ) CALL sbc_stokes() ! Calculate only if required fields are read
243	! ! In coupled wave model-NEMO case the call is done after coupling
244	!
245	ENDIF
246	!
247	END SUBROUTINE sbc_wave
248
249
250	SUBROUTINE sbc_wave_init
251	!!---------------------------------------------------------------------
252	!! * ROUTINE sbc_wave_init *
253	!!
254	!! ** Purpose : read wave parameters from wave model in netcdf files.
255	!!
256	!! ** Method : - Read namelist namsbc_wave
257	!! - Read Cd_n10 fields in netcdf files
258	!! - Read stokes drift 2d in netcdf files
259	!! - Read wave number in netcdf files
260	!! - Compute 3d stokes drift using Breivik et al.,2014
261	!! formulation
262	!! ** action
263	!!---------------------------------------------------------------------
264	INTEGER :: ierror, ios ! local integer
265	INTEGER :: ifpr
266	!!
267	CHARACTER(len=100) :: cn_dir ! Root directory for location of drag coefficient files
268	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i ! array of namelist informations on the fields to read
269	TYPE(FLD_N) :: sn_cdg, sn_usd, sn_vsd, &
270	& sn_hsw, sn_wmp, sn_wnum, sn_tauoc ! informations about the fields to be read
271	!
272	NAMELIST/namsbc_wave/ sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc
273	!!---------------------------------------------------------------------
274	!
275	REWIND( numnam_ref ) ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
276	READ ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
277	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
278
279	REWIND( numnam_cfg ) ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
280	READ ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
281	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
282	IF(lwm) WRITE ( numond, namsbc_wave )
283	!
284	IF( ln_cdgw ) THEN
285	IF( .NOT. cpl_wdrag ) THEN
286	ALLOCATE( sf_cd(1), STAT=ierror ) !* allocate and fill sf_wave with sn_cdg
287	IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
288	!
289	ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1) )
290	IF( sn_cdg%ln_tint ) ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
291	CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
292	ENDIF
293	ALLOCATE( cdn_wave(jpi,jpj) )
294	ENDIF
295
296	IF( ln_tauoc ) THEN
297	IF( .NOT. cpl_wstrf ) THEN
298	ALLOCATE( sf_tauoc(1), STAT=ierror ) !* allocate and fill sf_wave with sn_tauoc
299	IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
300	!
301	ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1) )
302	IF( sn_tauoc%ln_tint ) ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
303	CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
304	ENDIF
305	ALLOCATE( tauoc_wave(jpi,jpj) )
306	ENDIF
307
308	IF( ln_sdw ) THEN ! Find out how many fields have to be read from file if not coupled
309	jpfld=0
310	jp_usd=0 ; jp_vsd=0 ; jp_hsw=0 ; jp_wmp=0
311	IF( .NOT. cpl_sdrftx ) THEN
312	jpfld = jpfld + 1
313	jp_usd = jpfld
314	ENDIF
315	IF( .NOT. cpl_sdrfty ) THEN
316	jpfld = jpfld + 1
317	jp_vsd = jpfld
318	ENDIF
319	IF( .NOT. cpl_hsig ) THEN
320	jpfld = jpfld + 1
321	jp_hsw = jpfld
322	ENDIF
323	IF( .NOT. cpl_wper ) THEN
324	jpfld = jpfld + 1
325	jp_wmp = jpfld
326	ENDIF
327
328	! Read from file only the non-coupled fields
329	IF( jpfld > 0 ) THEN
330	ALLOCATE( slf_i(jpfld) )
331	IF( jp_usd > 0 ) slf_i(jp_usd) = sn_usd
332	IF( jp_vsd > 0 ) slf_i(jp_vsd) = sn_vsd
333	IF( jp_hsw > 0 ) slf_i(jp_hsw) = sn_hsw
334	IF( jp_wmp > 0 ) slf_i(jp_wmp) = sn_wmp
335	ALLOCATE( sf_sd(jpfld), STAT=ierror ) !* allocate and fill sf_sd with stokes drift
336	IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
337	!
338	DO ifpr= 1, jpfld
339	ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
340	IF( slf_i(ifpr)%ln_tint ) ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
341	END DO
342	!
343	CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
344	ENDIF
345	ALLOCATE( usd (jpi,jpj,jpk), vsd (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
346	ALLOCATE( hsw (jpi,jpj) , wmp (jpi,jpj) )
347	ALLOCATE( ut0sd(jpi,jpj) , vt0sd(jpi,jpj) )
348	ALLOCATE( div_sd(jpi,jpj) )
349	ALLOCATE( tsd2d (jpi,jpj) )
350	usd(:,:,:) = 0._wp
351	vsd(:,:,:) = 0._wp
352	wsd(:,:,:) = 0._wp
353	! Wave number needed only if ln_zdfqiao=T
354	IF( .NOT. cpl_wnum ) THEN
355	ALLOCATE( sf_wn(1), STAT=ierror ) !* allocate and fill sf_wave with sn_wnum
356	IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
357	ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1) )
358	IF( sn_wnum%ln_tint ) ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
359	CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
360	ENDIF
361	ALLOCATE( wnum(jpi,jpj) )
362	ENDIF
363	!
364	END SUBROUTINE sbc_wave_init
365
366	!!======================================================================
367	END MODULE sbcwave

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r8183_ICEMODEL_svn_removed/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 8738

Download in other formats: