New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfbfr.F90 in branches/UKMO/dev_r8183_ICEMODEL_svn_removed/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/dev_r8183_ICEMODEL_svn_removed/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfbfr.F90 @ 8733

Last change on this file since 8733 was 8733, checked in by dancopsey, 6 years ago

Remove svn keywords.

File size: 24.8 KB
Line 
1MODULE zdfbfr
2   !!======================================================================
3   !!                       ***  MODULE  zdfbfr  ***
4   !! Ocean physics: Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   zdf_bfr      : update bottom friction coefficient (non-linear bottom friction only)
16   !!   zdf_bfr_init : read in namelist and control the bottom friction parameters.
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE zdf_oce         ! ocean vertical physics variables
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! distributed memory computing
24   USE prtctl          ! Print control
25   USE timing          ! Timing
26   USE wrk_nemo        ! Memory Allocation
27   USE phycst, ONLY: vkarmn
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   zdf_bfr         ! called by step.F90
33   PUBLIC   zdf_bfr_init    ! called by nemogcm.F90
34
35   !                                 !!* Namelist nambfr: bottom friction namelist *
36   INTEGER , PUBLIC ::   nn_bfr       ! = 0/1/2/3 type of bottom friction  (PUBLIC for TAM)
37   REAL(wp), PUBLIC ::   rn_bfri1     ! bottom drag coefficient (linear case)  (PUBLIC for TAM)
38   REAL(wp), PUBLIC ::   rn_bfri2     ! bottom drag coefficient (non linear case) (PUBLIC for TAM)
39   REAL(wp), PUBLIC ::   rn_bfri2_max ! Maximum bottom drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
40   REAL(wp), PUBLIC ::   rn_bfeb2     ! background bottom turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
41   REAL(wp), PUBLIC ::   rn_bfrien    ! local factor to enhance coefficient bfri (PUBLIC for TAM)
42   LOGICAL , PUBLIC ::   ln_bfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
43   REAL(wp), PUBLIC ::   rn_tfri1     ! top drag coefficient (linear case)  (PUBLIC for TAM)
44   REAL(wp), PUBLIC ::   rn_tfri2     ! top drag coefficient (non linear case) (PUBLIC for TAM)
45   REAL(wp), PUBLIC ::   rn_tfri2_max ! Maximum top drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
46   REAL(wp), PUBLIC ::   rn_tfeb2     ! background top turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
47   REAL(wp), PUBLIC ::   rn_tfrien    ! local factor to enhance coefficient tfri (PUBLIC for TAM)
48   LOGICAL , PUBLIC ::   ln_tfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
49
50   LOGICAL , PUBLIC ::   ln_loglayer  ! switch for log layer bfr coeff. (PUBLIC for TAM)
51   REAL(wp), PUBLIC ::   rn_bfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
52   REAL(wp), PUBLIC ::   rn_tfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
53   LOGICAL , PUBLIC ::   ln_bfrimp    ! logical switch for implicit bottom friction
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::  bfrcoef2d, tfrcoef2d   ! 2D bottom/top drag coefficient (PUBLIC for TAM)
55
56   !! * Substitutions
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   INTEGER FUNCTION zdf_bfr_alloc()
66      !!----------------------------------------------------------------------
67      !!                ***  FUNCTION zdf_bfr_alloc  ***
68      !!----------------------------------------------------------------------
69      ALLOCATE( bfrcoef2d(jpi,jpj), tfrcoef2d(jpi,jpj), STAT=zdf_bfr_alloc )
70      !
71      IF( lk_mpp             )   CALL mpp_sum ( zdf_bfr_alloc )
72      IF( zdf_bfr_alloc /= 0 )   CALL ctl_warn('zdf_bfr_alloc: failed to allocate arrays.')
73   END FUNCTION zdf_bfr_alloc
74
75
76   SUBROUTINE zdf_bfr( kt )
77      !!----------------------------------------------------------------------
78      !!                   ***  ROUTINE zdf_bfr  ***
79      !!
80      !! ** Purpose :   compute the bottom friction coefficient.
81      !!
82      !! ** Method  :   Calculate and store part of the momentum trend due
83      !!              to bottom friction following the chosen friction type
84      !!              (free-slip, linear, or quadratic). The component
85      !!              calculated here is multiplied by the bottom velocity in
86      !!              dyn_bfr to provide the trend term.
87      !!                The coefficients are updated at each time step only
88      !!              in the quadratic case.
89      !!
90      !! ** Action  :   bfrua , bfrva   bottom friction coefficients
91      !!----------------------------------------------------------------------
92      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
93      !!
94      INTEGER  ::   ji, jj                       ! dummy loop indices
95      INTEGER  ::   ikbt, ikbu, ikbv             ! local integers
96      REAL(wp) ::   zvu, zuv, zecu, zecv, ztmp   ! temporary scalars
97      REAL(wp), POINTER, DIMENSION(:,:) ::  zbfrt, ztfrt
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr')
101      !
102      IF( nn_bfr == 2 ) THEN                 ! quadratic bottom friction only
103         !
104         CALL wrk_alloc( jpi, jpj, zbfrt, ztfrt )
105
106         IF ( ln_loglayer.AND. .NOT.ln_linssh ) THEN ! "log layer" bottom friction coefficient
107
108            DO jj = 1, jpj
109               DO ji = 1, jpi
110                  ikbt = mbkt(ji,jj)
111!! JC: possible WAD implementation should modify line below if layers vanish
112                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
113                  zbfrt(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
114                  zbfrt(ji,jj) = MIN(zbfrt(ji,jj), rn_bfri2_max)
115               END DO
116            END DO
117! (ISF)
118            IF ( ln_isfcav ) THEN
119               DO jj = 1, jpj
120                  DO ji = 1, jpi
121                     ikbt = mikt(ji,jj)
122! JC: possible WAD implementation should modify line below if layers vanish
123                     ztmp = (1.-tmask(ji,jj,1)) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
124                     ztfrt(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
125                     ztfrt(ji,jj) = MIN(ztfrt(ji,jj), rn_tfri2_max)
126                  END DO
127               END DO
128            END IF
129            !   
130         ELSE
131            zbfrt(:,:) = bfrcoef2d(:,:)
132            ztfrt(:,:) = tfrcoef2d(:,:)
133         ENDIF
134
135         DO jj = 2, jpjm1
136            DO ji = 2, jpim1
137               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
138               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
139               !
140               zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
141                  &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
142               zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
143                  &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
144               !
145               zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_bfeb2  )
146               zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_bfeb2  )
147               !
148               bfrua(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) * zecu
149               bfrva(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) * zecv
150               !
151               ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
152               IF ( ln_isfcav ) THEN
153                  IF ( miku(ji,jj) + 1  >=  mbku(ji,jj) ) THEN
154                     bfrua(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) )   &
155                                  &            + ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) ) &
156                                  &          * zecu * (1._wp - umask(ji,jj,1))
157                  ENDIF
158                  IF( mikv(ji,jj) + 1  >=  mbkv(ji,jj) ) THEN
159                     bfrva(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) )   &
160                                  &            + ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) ) &
161                                  &          * zecv * (1._wp - vmask(ji,jj,1))
162                  ENDIF
163               ENDIF
164            END DO
165         END DO
166         CALL lbc_lnk( bfrua, 'U', 1. )   ;   CALL lbc_lnk( bfrva, 'V', 1. )      ! Lateral boundary condition
167
168         IF( ln_isfcav ) THEN
169            DO jj = 2, jpjm1
170               DO ji = 2, jpim1
171                  ! (ISF) ========================================================================
172                  ikbu = miku(ji,jj)         ! ocean top level at u- and v-points
173                  ikbv = mikv(ji,jj)         ! (1st wet ocean u- and v-points)
174                  !
175                  zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
176                     &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
177                  zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
178                     &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
179              !
180                  zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_tfeb2 )
181                  zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_tfeb2 )
182              !
183                  tfrua(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) * zecu * (1._wp - umask(ji,jj,1))
184                  tfrva(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) * zecv * (1._wp - vmask(ji,jj,1))
185              ! (ISF) END ====================================================================
186              ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
187                  IF ( miku(ji,jj) + 1 .GE. mbku(ji,jj) ) THEN
188                     tfrua(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) )   &
189                                  &            + ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) ) &
190                                  &          * zecu * (1._wp - umask(ji,jj,1))
191                  END IF
192                  IF ( mikv(ji,jj) + 1 .GE. mbkv(ji,jj) ) THEN
193                     tfrva(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) )   &
194                                  &            + ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) ) &
195                                  &          * zecv * (1._wp - vmask(ji,jj,1))
196                  END IF
197               END DO
198            END DO
199            CALL lbc_lnk( tfrua, 'U', 1. )   ;   CALL lbc_lnk( tfrva, 'V', 1. )      ! Lateral boundary condition
200         END IF
201         !
202         !
203         IF(ln_ctl)   CALL prt_ctl( tab2d_1=bfrua, clinfo1=' bfr  - u: ', mask1=umask,        &
204            &                       tab2d_2=bfrva, clinfo2=       ' v: ', mask2=vmask,ovlap=1 )
205         CALL wrk_dealloc( jpi,jpj,zbfrt, ztfrt )
206      ENDIF
207      !
208      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr')
209      !
210   END SUBROUTINE zdf_bfr
211
212
213   SUBROUTINE zdf_bfr_init
214      !!----------------------------------------------------------------------
215      !!                  ***  ROUTINE zdf_bfr_init  ***
216      !!
217      !! ** Purpose :   Initialization of the bottom friction
218      !!
219      !! ** Method  :   Read the nambfr namelist and check their consistency
220      !!                called at the first timestep (nit000)
221      !!----------------------------------------------------------------------
222      USE iom   ! I/O module for ehanced bottom friction file
223      !!
224      INTEGER   ::   inum         ! logical unit for enhanced bottom friction file
225      INTEGER   ::   ji, jj       ! dummy loop indexes
226      INTEGER   ::   ikbt, ikbu, ikbv   ! temporary integers
227      INTEGER   ::   ictu, ictv         !    -          -
228      INTEGER   ::   ios
229      REAL(wp)  ::   zminbfr, zmaxbfr   ! temporary scalars
230      REAL(wp)  ::   zmintfr, zmaxtfr   ! temporary scalars
231      REAL(wp)  ::   ztmp, zfru, zfrv   !    -         -
232      !!
233      NAMELIST/nambfr/ nn_bfr, rn_bfri1, rn_bfri2, rn_bfri2_max, rn_bfeb2, rn_bfrz0, ln_bfr2d, &
234                    &          rn_tfri1, rn_tfri2, rn_tfri2_max, rn_tfeb2, rn_tfrz0, ln_tfr2d, &
235                    &  rn_bfrien, rn_tfrien, ln_bfrimp, ln_loglayer
236      !!----------------------------------------------------------------------
237      !
238      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr_init')
239      !
240      !                              !* Allocate zdfbfr arrays
241      IF( zdf_bfr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_bfr_init : unable to allocate arrays' )
242      !
243      !                              !* Parameter control and print
244      !
245      REWIND( numnam_ref )              ! Namelist nambfr in reference namelist : Bottom momentum boundary condition
246      READ  ( numnam_ref, nambfr, IOSTAT = ios, ERR = 901)
247901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in reference namelist', lwp )
248
249      REWIND( numnam_cfg )              ! Namelist nambfr in configuration namelist : Bottom momentum boundary condition
250      READ  ( numnam_cfg, nambfr, IOSTAT = ios, ERR = 902 )
251902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in configuration namelist', lwp )
252      IF(lwm) WRITE ( numond, nambfr )
253      IF(lwp) WRITE(numout,*)
254      IF(lwp) WRITE(numout,*) 'zdf_bfr_init : momentum bottom friction'
255      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
256      IF(lwp) WRITE(numout,*) '   Namelist nam_bfr : set bottom friction parameters'
257      !
258      SELECT CASE (nn_bfr)
259      !
260      CASE( 0 )
261         IF(lwp) WRITE(numout,*) '      free-slip '
262         bfrua(:,:) = 0._wp
263         bfrva(:,:) = 0._wp
264         tfrua(:,:) = 0._wp
265         tfrva(:,:) = 0._wp
266         !
267      CASE( 1 )
268         IF(lwp) WRITE(numout,*) '      linear botton friction'
269         IF(lwp) WRITE(numout,*) '      bottom friction coef.   rn_bfri1  = ', rn_bfri1
270         IF( ln_bfr2d ) THEN
271            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
272            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
273         ENDIF
274         IF ( ln_isfcav ) THEN
275            IF(lwp) WRITE(numout,*) '      top    friction coef.   rn_bfri1  = ', rn_tfri1
276            IF( ln_tfr2d ) THEN
277               IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
278               IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
279            ENDIF
280         END IF
281         !
282         IF(ln_bfr2d) THEN
283            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
284            CALL iom_open('bfr_coef.nc',inum)
285            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
286            CALL iom_close(inum)
287            bfrcoef2d(:,:) = rn_bfri1 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
288         ELSE
289            bfrcoef2d(:,:) = rn_bfri1  ! initialize bfrcoef2d to the namelist variable
290         ENDIF
291         !
292         bfrua(:,:) = - bfrcoef2d(:,:)
293         bfrva(:,:) = - bfrcoef2d(:,:)
294         !
295         IF ( ln_isfcav ) THEN
296            IF(ln_tfr2d) THEN
297               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
298               CALL iom_open('tfr_coef.nc',inum)
299               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! tfrcoef2d is used as tmp array
300               CALL iom_close(inum)
301               tfrcoef2d(:,:) = rn_tfri1 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
302            ELSE
303               tfrcoef2d(:,:) = rn_tfri1  ! initialize tfrcoef2d to the namelist variable
304            ENDIF
305            !
306            tfrua(:,:) = - tfrcoef2d(:,:)
307            tfrva(:,:) = - tfrcoef2d(:,:)
308         END IF
309         !
310      CASE( 2 )
311         IF(lwp) WRITE(numout,*) '      quadratic bottom friction'
312         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri2  = ', rn_bfri2
313         IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_bfri2_max  = ', rn_bfri2_max
314         IF(lwp) WRITE(numout,*) '      background tke   rn_bfeb2  = ', rn_bfeb2
315         IF(lwp) WRITE(numout,*) '      log formulation   ln_bfr2d = ', ln_loglayer
316         IF(lwp) WRITE(numout,*) '      bottom roughness  rn_bfrz0 [m] = ', rn_bfrz0
317         IF( rn_bfrz0 <= 0._wp ) THEN
318            WRITE(ctmp1,*) '      bottom roughness must be strictly positive'
319            CALL ctl_stop( ctmp1 )
320         ENDIF
321         IF( ln_bfr2d ) THEN
322            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
323            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
324         ENDIF
325         IF ( ln_isfcav ) THEN
326            IF(lwp) WRITE(numout,*) '      quadratic top    friction'
327            IF(lwp) WRITE(numout,*) '      friction coef.    rn_tfri2     = ', rn_tfri2
328            IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_tfri2_max  = ', rn_tfri2_max
329            IF(lwp) WRITE(numout,*) '      background tke    rn_tfeb2     = ', rn_tfeb2
330            IF(lwp) WRITE(numout,*) '      log formulation   ln_tfr2d     = ', ln_loglayer
331            IF(lwp) WRITE(numout,*) '      top roughness     rn_tfrz0 [m] = ', rn_tfrz0
332            IF( rn_tfrz0 <= 0._wp ) THEN
333               WRITE(ctmp1,*) '      top roughness must be strictly positive'
334               CALL ctl_stop( ctmp1 )
335            ENDIF
336            IF( ln_tfr2d ) THEN
337               IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
338               IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
339            ENDIF
340         END IF
341         !
342         IF(ln_bfr2d) THEN
343            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
344            CALL iom_open('bfr_coef.nc',inum)
345            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
346            CALL iom_close(inum)
347            !
348            bfrcoef2d(:,:) = rn_bfri2 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
349         ELSE
350            bfrcoef2d(:,:) = rn_bfri2  ! initialize bfrcoef2d to the namelist variable
351         ENDIF
352         
353         IF ( ln_isfcav ) THEN
354            IF(ln_tfr2d) THEN
355               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
356               CALL iom_open('tfr_coef.nc',inum)
357               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! tfrcoef2d is used as tmp array
358               CALL iom_close(inum)
359               !
360               tfrcoef2d(:,:) = rn_tfri2 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
361            ELSE
362               tfrcoef2d(:,:) = rn_tfri2  ! initialize tfrcoef2d to the namelist variable
363            ENDIF
364         END IF
365         !
366         IF( ln_loglayer.AND. ln_linssh ) THEN ! set "log layer" bottom friction once for all
367            DO jj = 1, jpj
368               DO ji = 1, jpi
369                  ikbt = mbkt(ji,jj)
370                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
371                  bfrcoef2d(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
372                  bfrcoef2d(ji,jj) = MIN(bfrcoef2d(ji,jj), rn_bfri2_max)
373               END DO
374            END DO
375            IF ( ln_isfcav ) THEN
376               DO jj = 1, jpj
377                  DO ji = 1, jpi
378                     ikbt = mikt(ji,jj)
379                     ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_tfrz0 ))**2._wp
380                     tfrcoef2d(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
381                     tfrcoef2d(ji,jj) = MIN(tfrcoef2d(ji,jj), rn_tfri2_max)
382                  END DO
383               END DO
384            END IF
385         ENDIF
386         !
387      CASE DEFAULT
388         IF(lwp) WRITE(ctmp1,*) '         bad flag value for nn_bfr = ', nn_bfr
389         CALL ctl_stop( ctmp1 )
390         !
391      END SELECT
392      !
393      IF(lwp) WRITE(numout,*) '      implicit bottom friction switch                ln_bfrimp  = ', ln_bfrimp
394      !
395      !                              ! Make sure ln_zdfexp=.false. when use implicit bfr
396      IF( ln_bfrimp .AND. ln_zdfexp ) THEN
397         IF(lwp) THEN
398            WRITE(numout,*)
399            WRITE(numout,*) 'Implicit bottom friction can only be used when ln_zdfexp=.false.'
400            WRITE(numout,*) '         but you set: ln_bfrimp=.true. and ln_zdfexp=.true.!!!!'
401            WRITE(ctmp1,*)  '         set either ln_zdfexp = .false or ln_bfrimp = .false.'
402            CALL ctl_stop( ctmp1 )
403         END IF
404      END IF
405      !
406      ! Basic stability check on bottom friction coefficient
407      !
408      ictu = 0               ! counter for stability criterion breaches at U-pts
409      ictv = 0               ! counter for stability criterion breaches at V-pts
410      zminbfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
411      zmaxbfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
412      zmintfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
413      zmaxtfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
414      !
415      DO jj = 2, jpjm1
416         DO ji = 2, jpim1
417             ikbu = mbku(ji,jj)       ! deepest ocean level at u- and v-points
418             ikbv = mbkv(ji,jj)
419             zfru = 0.5 * e3u_n(ji,jj,ikbu) / rdt
420             zfrv = 0.5 * e3v_n(ji,jj,ikbv) / rdt
421             IF( ABS( bfrcoef2d(ji,jj) ) > zfru ) THEN
422                IF( ln_ctl ) THEN
423                   WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbu
424                   WRITE(numout,*) 'BFR ', ABS( bfrcoef2d(ji,jj) ), zfru
425                ENDIF
426                ictu = ictu + 1
427             ENDIF
428             IF( ABS( bfrcoef2d(ji,jj) ) > zfrv ) THEN
429                 IF( ln_ctl ) THEN
430                     WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbv
431                     WRITE(numout,*) 'BFR ', bfrcoef2d(ji,jj), zfrv
432                 ENDIF
433                 ictv = ictv + 1
434             ENDIF
435             zminbfr = MIN(  zminbfr, MIN( zfru, ABS( bfrcoef2d(ji,jj) ) )  )
436             zmaxbfr = MAX(  zmaxbfr, MIN( zfrv, ABS( bfrcoef2d(ji,jj) ) )  )
437! (ISF)
438             IF ( ln_isfcav ) THEN
439                ikbu = miku(ji,jj)       ! 1st wet ocean level at u- and v-points
440                ikbv = mikv(ji,jj)
441                zfru = 0.5 * e3u_n(ji,jj,ikbu) / rdt
442                zfrv = 0.5 * e3v_n(ji,jj,ikbv) / rdt
443                IF( ABS( tfrcoef2d(ji,jj) ) > zfru ) THEN
444                   IF( ln_ctl ) THEN
445                      WRITE(numout,*) 'TFR ', narea, nimpp+ji, njmpp+jj, ikbu
446                      WRITE(numout,*) 'TFR ', ABS( tfrcoef2d(ji,jj) ), zfru
447                   ENDIF
448                   ictu = ictu + 1
449                ENDIF
450                IF( ABS( tfrcoef2d(ji,jj) ) > zfrv ) THEN
451                   IF( ln_ctl ) THEN
452                      WRITE(numout,*) 'TFR ', narea, nimpp+ji, njmpp+jj, ikbv
453                      WRITE(numout,*) 'TFR ', tfrcoef2d(ji,jj), zfrv
454                   ENDIF
455                   ictv = ictv + 1
456                ENDIF
457                zmintfr = MIN(  zmintfr, MIN( zfru, ABS( tfrcoef2d(ji,jj) ) )  )
458                zmaxtfr = MAX(  zmaxtfr, MIN( zfrv, ABS( tfrcoef2d(ji,jj) ) )  )
459             END IF
460! END ISF
461         END DO
462      END DO
463      IF( lk_mpp ) THEN
464         CALL mpp_sum( ictu )
465         CALL mpp_sum( ictv )
466         CALL mpp_min( zminbfr )
467         CALL mpp_max( zmaxbfr )
468         IF ( ln_isfcav) CALL mpp_min( zmintfr )
469         IF ( ln_isfcav) CALL mpp_max( zmaxtfr )
470      ENDIF
471      IF( .NOT.ln_bfrimp) THEN
472      IF( lwp .AND. ictu + ictv > 0 ) THEN
473         WRITE(numout,*) ' Bottom/Top friction stability check failed at ', ictu, ' U-points '
474         WRITE(numout,*) ' Bottom/Top friction stability check failed at ', ictv, ' V-points '
475         WRITE(numout,*) ' Bottom friction coefficient now ranges from: ', zminbfr, ' to ', zmaxbfr
476         IF ( ln_isfcav ) WRITE(numout,*) ' Top friction coefficient now ranges from: ', zmintfr, ' to ', zmaxtfr
477         WRITE(numout,*) ' Bottom/Top friction coefficient will be reduced where necessary'
478      ENDIF
479      ENDIF
480      !
481      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr_init')
482      !
483   END SUBROUTINE zdf_bfr_init
484
485   !!======================================================================
486END MODULE zdfbfr
Note: See TracBrowser for help on using the repository browser.