New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
flowri.F90 in branches/UKMO/dev_r8600_nn_etau_options/NEMOGCM/NEMO/OPA_SRC/FLO – NEMO

source: branches/UKMO/dev_r8600_nn_etau_options/NEMOGCM/NEMO/OPA_SRC/FLO/flowri.F90 @ 8875

Last change on this file since 8875 was 8875, checked in by davestorkey, 6 years ago

UKMO/dev_r8600_nn_etau_options branch: remove SVN keywords.

File size: 12.7 KB
Line 
1MODULE flowri
2   !!======================================================================
3   !!                       ***  MODULE  flowri  ***
4   !!
5   !! Ocean floats: write floats trajectory in ascii                    ln_flo_ascii = T
6   !!                                    or in netcdf ( IOM or IOSPSL ) ln_flo_ascii = F           
7   !!======================================================================
8   !!  History :  OPA  !  1999-09  (Y. Drillet)    : Original code
9   !!              -   !  2000-06  (J.-M. Molines) : Profiling floats for CLS
10   !!   NEMO      1.0  !  2002-10  (A. Bozec)  F90 : Free form and module
11   !!             3.2  !  2010-08  (slaw, cbricaud): netcdf outputs and others
12   !!----------------------------------------------------------------------
13#if   defined key_floats
14   !!----------------------------------------------------------------------
15   !!   'key_floats'                                     float trajectories
16   !!----------------------------------------------------------------------
17   USE flo_oce         ! ocean drifting floats
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE lib_mpp         ! distribued memory computing library
21   USE in_out_manager  ! I/O manager
22   USE phycst          ! physic constants
23   USE dianam          ! build name of file (routine)
24   USE ioipsl
25   USE iom             ! I/O library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC flo_wri         ! routine called by floats.F90
31   PUBLIC flo_wri_alloc   ! routine called by floats.F90
32
33   INTEGER :: jfl                            ! number of floats
34   CHARACTER (len=80)  :: clname             ! netcdf output filename
35
36   ! Following are only workspace arrays but shape is not (jpi,jpj) and
37   ! therefore make them module arrays rather than replacing with wrk_nemo
38   ! member arrays.
39   REAL(wp), ALLOCATABLE, DIMENSION(:) ::   zlon , zlat, zdep   ! 2D workspace
40   REAL(wp), ALLOCATABLE, DIMENSION(:) ::   ztem , zsal, zrho   ! 2D workspace
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.2 , LODYC-IPSL  (2009)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   INTEGER FUNCTION flo_wri_alloc()
50      !!-------------------------------------------------------------------
51      !!                ***  FUNCTION flo_wri_alloc  ***
52      !!-------------------------------------------------------------------
53      ALLOCATE( ztem(jpnfl) , zsal(jpnfl) , zrho(jpnfl) , &
54                zlon(jpnfl) , zlat(jpnfl) , zdep(jpnfl) , STAT=flo_wri_alloc)
55     
56      IF( lk_mpp             )   CALL mpp_sum ( flo_wri_alloc )
57      IF( flo_wri_alloc /= 0 )   CALL ctl_warn('flo_wri_alloc: failed to allocate arrays.')
58   END FUNCTION flo_wri_alloc
59
60   SUBROUTINE flo_wri( kt )
61      !!---------------------------------------------------------------------
62      !!                  ***  ROUTINE flo_wri ***
63      !!             
64      !! ** Purpose :   Write position of floats in "trajec_float.nc",according
65      !!                to ARIANE TOOLS (http://stockage.univ-brest.fr/~grima/Ariane/ )  n
66      !!                nomenclature
67      !!   
68      !!     
69      !! ** Method  :   The frequency of  ??? is nwritefl
70      !!     
71      !!----------------------------------------------------------------------
72      !! * Arguments
73      INTEGER  :: kt                               ! time step
74
75      !! * Local declarations
76      INTEGER  :: iafl , ibfl , icfl             ! temporary integer
77      INTEGER  :: ia1fl, ib1fl, ic1fl            !   "
78      INTEGER  :: iafloc,ibfloc,ia1floc,ib1floc  !   "
79      INTEGER  :: irec, irecflo
80
81      REAL(wp) :: zafl,zbfl,zcfl                 ! temporary real
82      REAL(wp) :: ztime                          !   "
83
84      INTEGER, DIMENSION(2)          :: icount
85      INTEGER, DIMENSION(2)          :: istart
86      INTEGER, DIMENSION(1)          :: ish
87      INTEGER, DIMENSION(2)          :: ish2
88      !!----------------------------------------------------------------------
89     
90      !-----------------------------------------------------
91      ! I- Save positions, temperature, salinty and density
92      !-----------------------------------------------------
93      zlon(:)=0.0 ; zlat(:)=0.0 ; zdep(:)=0.0 
94      ztem(:)=0.0 ; zsal(:)=0.0 ; zrho(:)=0.0 
95
96      DO jfl = 1, jpnfl
97
98         iafl  = INT (tpifl(jfl))            ! I-index of the nearest point before
99         ibfl  = INT (tpjfl(jfl))            ! J-index of the nearest point before
100         icfl  = INT (tpkfl(jfl))            ! K-index of the nearest point before
101         ia1fl = iafl + 1                    ! I-index of the nearest point after
102         ib1fl = ibfl + 1                    ! J-index of the nearest point after
103         ic1fl = icfl + 1                    ! K-index of the nearest point after
104         zafl  = tpifl(jfl) - REAL(iafl,wp)  ! distance  ?????
105         zbfl  = tpjfl(jfl) - REAL(ibfl,wp)  ! distance  ?????
106         zcfl  = tpkfl(jfl) - REAL(icfl,wp)  ! distance  ?????
107
108         IF( lk_mpp ) THEN
109               
110            iafloc = mi1( iafl )
111            ibfloc = mj1( ibfl )
112 
113            IF( nldi <= iafloc .AND. iafloc <= nlei .AND. &
114              & nldj <= ibfloc .AND. ibfloc <= nlej       ) THEN 
115
116               !the float is inside of current proc's area
117               ia1floc = iafloc + 1
118               ib1floc = ibfloc + 1
119     
120               !save position of the float
121               zlat(jfl) = (1.-zafl)*(1.-zbfl)*gphit(iafloc ,ibfloc ) + (1.-zafl) * zbfl * gphit(iafloc ,ib1floc)   &
122                     +     zafl *(1.-zbfl)*gphit(ia1floc,ibfloc ) +     zafl  * zbfl * gphit(ia1floc,ib1floc)   
123               zlon(jfl) = (1.-zafl)*(1.-zbfl)*glamt(iafloc ,ibfloc ) + (1.-zafl) * zbfl * glamt(iafloc ,ib1floc)   &
124                     +     zafl *(1.-zbfl)*glamt(ia1floc,ibfloc ) +     zafl  * zbfl * glamt(ia1floc,ib1floc)
125               zdep(jfl) = (1.-zcfl)*gdepw_n(iafloc,ibfloc,icfl ) + zcfl * gdepw_n(iafloc,ibfloc,ic1fl)     
126
127               !save temperature, salinity and density at this position
128               ztem(jfl) = tsn(iafloc,ibfloc,icfl,jp_tem)
129               zsal (jfl) = tsn(iafloc,ibfloc,icfl,jp_sal)
130               zrho (jfl) = (rhd(iafloc,ibfloc,icfl)+1)*rau0
131
132            ENDIF
133
134         ELSE  ! mono proc case 
135
136            iafloc  = iafl
137            ibfloc  = ibfl
138            ia1floc = iafloc + 1
139            ib1floc = ibfloc + 1
140
141            !save position of the float               
142            zlat(jfl) = (1.-zafl)*(1.-zbfl)*gphit(iafloc ,ibfloc ) + (1.-zafl) * zbfl * gphit(iafloc ,ib1floc)   &
143                      +     zafl *(1.-zbfl)*gphit(ia1floc,ibfloc ) +     zafl  * zbfl * gphit(ia1floc,ib1floc)
144            zlon(jfl) = (1.-zafl)*(1.-zbfl)*glamt(iafloc ,ibfloc ) + (1.-zafl) * zbfl * glamt(iafloc ,ib1floc)   &
145                      +     zafl *(1.-zbfl)*glamt(ia1floc,ibfloc ) +     zafl  * zbfl * glamt(ia1floc,ib1floc)
146            zdep(jfl) = (1.-zcfl)*gdepw_n(iafloc,ibfloc,icfl ) + zcfl * gdepw_n(iafloc,ibfloc,ic1fl)
147
148            ztem(jfl) = tsn(iafloc,ibfloc,icfl,jp_tem)
149            zsal(jfl) = tsn(iafloc,ibfloc,icfl,jp_sal)
150            zrho(jfl) = (rhd(iafloc,ibfloc,icfl)+1)*rau0
151         
152         ENDIF
153
154      END DO ! loop on float
155
156      !Only proc 0 writes all positions : SUM of positions on all procs
157      IF( lk_mpp ) THEN
158         CALL mpp_sum( zlon, jpnfl )   ! sums over the global domain
159         CALL mpp_sum( zlat, jpnfl )   ! sums over the global domain
160         CALL mpp_sum( zdep, jpnfl )   ! sums over the global domain
161         CALL mpp_sum( ztem, jpnfl )   ! sums over the global domain
162         CALL mpp_sum( zsal, jpnfl )   ! sums over the global domain
163         CALL mpp_sum( zrho, jpnfl )   ! sums over the global domain
164      ENDIF
165
166
167      !-------------------------------------!
168      ! II- WRITE WRITE WRITE WRITE WRITE   !
169      !-------------------------------------!
170
171      !--------------------------!
172      ! II-1 Write in ascii file !
173      !--------------------------!
174
175      IF( ln_flo_ascii )THEN
176
177         IF( ( kt == nn_it000 .OR. MOD( kt,nn_writefl)== 0 ) .AND. lwp )THEN
178
179            !II-1-a Open ascii file
180            !----------------------
181            IF( kt == nn_it000 ) THEN
182               CALL ctl_opn( numflo, 'trajec_float', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
183               irecflo = NINT( (nitend-nn_it000) / FLOAT(nn_writefl) )
184               WRITE(numflo,*)cexper,no,irecflo,jpnfl,nn_writefl
185            ENDIF
186
187            !II-1-b Write in ascii file
188            !-----------------------------
189            WRITE(numflo,*) zlon,zlat,zdep,nisobfl,ngrpfl,ztem,zsal, FLOAT(ndastp)
190
191
192            !II-1-c Close netcdf file
193            !-------------------------
194            IF( kt == nitend )   CLOSE( numflo )
195
196         ENDIF
197
198      !-----------------------------------------------------
199      ! II-2 Write in netcdf file
200      !-----------------------------------------------------
201
202      ELSE
203
204      !II-2-a Write with IOM
205      !----------------------
206
207#if defined key_iomput
208         CALL iom_put( "traj_lon"     , zlon )
209         CALL iom_put( "traj_lat"     , zlat )
210         CALL iom_put( "traj_dep"     , zdep )
211         CALL iom_put( "traj_temp"    , ztem )
212         CALL iom_put( "traj_salt"    , zsal  )
213         CALL iom_put( "traj_dens"    , zrho )
214         CALL iom_put( "traj_group"   , REAL(ngrpfl,wp) )
215#else
216
217      !II-2-b Write with IOIPSL
218      !------------------------
219
220         IF( ( kt == nn_it000 .OR. MOD( kt,nn_writefl)== 0 ) .AND. lwp )THEN
221
222
223            !II-2-b-1 Open netcdf file
224            !-------------------------
225            IF( kt==nn_it000 )THEN   ! Create and open
226
227               CALL dia_nam( clname, nn_writefl, 'trajec_float' )
228               clname=TRIM(clname)//".nc"
229
230               CALL fliocrfd( clname , (/ 'ntraj' , 't' /), (/ jpnfl , -1  /) , numflo )
231   
232               CALL fliodefv( numflo, 'traj_lon'    , (/1,2/), v_t=flio_r8, long_name="Longitude"           , units="degrees_east"  )
233               CALL fliodefv( numflo, 'traj_lat'    , (/1,2/), v_t=flio_r8, long_name="Latitude"            , units="degrees_north" )
234               CALL fliodefv( numflo, 'traj_depth'  , (/1,2/), v_t=flio_r8, long_name="Depth"               , units="meters" )
235               CALL fliodefv( numflo, 'time_counter', (/2/)  , v_t=flio_r8, long_name="Time axis"           & 
236                         & , units="seconds since start of the run " )
237               CALL fliodefv( numflo, 'traj_temp'   , (/1,2/), v_t=flio_r8, long_name="Temperature"         , units="C" )
238               CALL fliodefv( numflo, 'traj_salt'   , (/1,2/), v_t=flio_r8, long_name="Salinity"            , units="PSU" )
239               CALL fliodefv( numflo, 'traj_dens'   , (/1,2/), v_t=flio_r8, long_name="Density"             , units="kg/m3" )
240               CALL fliodefv( numflo, 'traj_group'  , (/1/)  , v_t=flio_r8, long_name="number of the group" , units="no unit" )
241
242               CALL flioputv( numflo , 'traj_group' , REAL(ngrpfl,wp) )
243 
244            ELSE  ! Re-open
245       
246               CALL flioopfd( TRIM(clname), numflo , "WRITE" )
247
248            ENDIF
249
250            !II-2-b-2 Write in  netcdf file
251            !-------------------------------
252            irec =  INT( (kt-nn_it000+1)/nn_writefl ) +1
253            ztime = ( kt-nn_it000 + 1 ) * rdt
254
255            CALL flioputv( numflo , 'time_counter', ztime , start=(/irec/) )
256
257            DO jfl = 1, jpnfl
258
259               istart = (/jfl,irec/)
260               icfl   = INT( tpkfl(jfl) )            ! K-index of the nearest point before
261
262               CALL flioputv( numflo , 'traj_lon'    , zlon(jfl)        , start=istart )
263               CALL flioputv( numflo , 'traj_lat'    , zlat(jfl)        , start=istart ) 
264               CALL flioputv( numflo , 'traj_depth'  , zdep(jfl)        , start=istart ) 
265               CALL flioputv( numflo , 'traj_temp'   , ztemp(icfl,jfl)  , start=istart ) 
266               CALL flioputv( numflo , 'traj_salt'   , zsal(icfl,jfl)   , start=istart ) 
267               CALL flioputv( numflo , 'traj_dens'   , zrho(icfl,jfl)   , start=istart ) 
268
269            ENDDO
270
271            !II-2-b-3 Close netcdf file
272            !---------------------------
273            CALL flioclo( numflo )
274
275         ENDIF
276
277#endif
278      ENDIF ! netcdf writing
279   
280   END SUBROUTINE flo_wri
281
282
283#  else
284   !!----------------------------------------------------------------------
285   !!   Default option                                         Empty module
286   !!----------------------------------------------------------------------
287CONTAINS
288   SUBROUTINE flo_wri                 ! Empty routine
289   END SUBROUTINE flo_wri
290#endif
291
292   !!=======================================================================
293END MODULE flowri
Note: See TracBrowser for help on using the repository browser.