New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmicro.F90 in branches/UKMO/dev_r8600_nn_etau_options/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_r8600_nn_etau_options/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zmicro.F90 @ 8875

Last change on this file since 8875 was 8875, checked in by davestorkey, 6 years ago

UKMO/dev_r8600_nn_etau_options branch: remove SVN keywords.

  • Property svn:executable set to *
File size: 21.7 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p5zlim          !  Phytoplankton limitation terms
18   USE iom             !  I/O manager
19   USE prtctl_trc      !  print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p5z_micro         ! called in p5zbio.F90
25   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
26
27   !! * Shared module variables
28   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
30   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
32   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
33   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
34   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
35   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
40   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
41   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
42   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
43   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
44   REAL(wp), PUBLIC ::  unassc      !: Efficicency of microzoo growth
45   REAL(wp), PUBLIC ::  unassn      !: Efficicency of microzoo growth
46   REAL(wp), PUBLIC ::  unassp      !: Efficicency of microzoo growth
47   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
48   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
49   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
50   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id$
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p5z_micro( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p5z_micro  ***
63      !!
64      !! ** Purpose :   Compute the sources/sinks for microzooplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::  kt  ! ocean time step
69      INTEGER, INTENT(in) ::  knt 
70      !
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
73      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
74      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
75      REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
76      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
77      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
78      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
79      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
80      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
81      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
82      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
83      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
85      CHARACTER (len=25) :: charout
86      !!---------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('p5z_micro')
89      !
90      CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
91      !
92      zmetexcess = 0.0
93      IF ( bmetexc ) zmetexcess = 1.0
94      !
95      DO jk = 1, jpkm1
96         DO jj = 1, jpj
97            DO ji = 1, jpi
98               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
99               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
100
101               !   Michaelis-Menten mortality rates of microzooplankton
102               !   -----------------------------------------------------
103               zrespz = resrat * zfact * ( trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
104               &        + 3. * nitrfac(ji,jj,jk) )
105
106               !   Zooplankton mortality. A square function has been selected with
107               !   no real reason except that it seems to be more stable and may mimic predation.
108               !   ------------------------------------------------------------------------------
109               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
110
111               !   Computation of the abundance of the preys
112               !   A threshold can be specified in the namelist
113               !   --------------------------------------------
114               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
115               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
116               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthreshzoo ), 0.e0 )
117               zcompapi  = MAX( ( trb(ji,jj,jk,jppic) - xthreshpic ), 0.e0 )
118               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
119               
120               !   Microzooplankton grazing
121               !   ------------------------
122               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
123               &           + xprefz * zcompaz + xprefp * zcompapi
124               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
125               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
126               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
127
128               !   An active switching parameterization is used here.
129               !   We don't use the KTW parameterization proposed by
130               !   Vallina et al. because it tends to produce to steady biomass
131               !   composition and the variance of Chl is too low as it grazes
132               !   too strongly on winning organisms. Thus, instead of a square
133               !   a 1.5 power value is used which decreases the pressure on the
134               !   most abundant species
135               !   ------------------------------------------------------------ 
136               ztmp1 = xprefn * zcompaph**1.5
137               ztmp2 = xprefp * zcompapi**1.5
138               ztmp3 = xprefc * zcompapoc**1.5
139               ztmp4 = xprefd * zcompadi**1.5
140               ztmp5 = xprefz * zcompaz**1.5
141               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
142               ztmp1 = ztmp1 / ztmptot
143               ztmp2 = ztmp2 / ztmptot
144               ztmp3 = ztmp3 / ztmptot
145               ztmp4 = ztmp4 / ztmptot
146               ztmp5 = ztmp5 / ztmptot
147
148               !   Microzooplankton regular grazing on the different preys
149               !   -------------------------------------------------------
150               zgraznc   = zgraze  * ztmp1  * zdenom
151               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / (trb(ji,jj,jk,jpphy) + rtrn)
152               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / (trb(ji,jj,jk,jpphy) + rtrn)
153               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
154               zgrazpc   = zgraze  * ztmp2  * zdenom
155               zgrazpn   = zgrazpc * trb(ji,jj,jk,jpnpi) / (trb(ji,jj,jk,jppic) + rtrn)
156               zgrazpp   = zgrazpc * trb(ji,jj,jk,jpppi) / (trb(ji,jj,jk,jppic) + rtrn)
157               zgrazpf   = zgrazpc * trb(ji,jj,jk,jppfe) / (trb(ji,jj,jk,jppic) + rtrn)
158               zgrazz    = zgraze  * ztmp5   * zdenom
159               zgrazpoc  = zgraze  * ztmp3   * zdenom
160               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn )
161               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn )
162               zgrazpof  = zgrazpoc* trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
163               zgrazdc   = zgraze  * ztmp4  * zdenom
164               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / (trb(ji,jj,jk,jpdia) + rtrn)
165               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / (trb(ji,jj,jk,jpdia) + rtrn)
166               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
167               !
168               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
169               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
170               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
171               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
172               !
173               ! Grazing by microzooplankton
174               zgrazing(ji,jj,jk) = zgraztotc
175
176               !   Stoichiometruc ratios of the food ingested by zooplanton
177               !   --------------------------------------------------------
178               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
179               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
180               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
181
182               !   Growth efficiency is made a function of the quality
183               !   and the quantity of the preys
184               !   ---------------------------------------------------
185               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
186               zbeta = 1./ (epsher - 0.2)
187               zepsherf = 0.2 + 1./ (zbeta + 0.04 * 12. * zfood * 1E6 )
188               zepsherv  = zepsherf * zepshert
189
190               !   Respiration of microzooplankton
191               !   Excess carbon in the food is used preferentially
192               !   ------------------------------------------------
193               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
194               zbasresb = MAX(0., zrespz - zexcess)
195               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
196               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
197               
198               !   When excess carbon is used, the other elements in excess
199               !   are also used proportionally to their abundance
200               !   --------------------------------------------------------
201               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
202               zbasresn = zbasresi * zexcess * zgrasratn 
203               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
204               zbasresp = zbasresi * zexcess * zgrasratp
205               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
206               zbasresf = zbasresi * zexcess * zgrasratf
207
208               !   Voiding of the excessive elements as DOM
209               !   ----------------------------------------
210               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
211               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
212               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
213               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
214
215               !  Since only semilabile DOM is represented in PISCES
216               !  part of DOM is in fact labile and is then released
217               !  as dissolved inorganic compounds (ssigma)
218               !  --------------------------------------------------
219               zgradoc =  zgradoct * ssigma
220               zgradon =  zgradont * ssigma
221               zgradop =  zgradopt * ssigma
222               zgrarem = (1.0 - ssigma) * zgradoct
223               zgraren = (1.0 - ssigma) * zgradont
224               zgrarep = (1.0 - ssigma) * zgradopt
225               zgraref = zgrareft
226
227               !   Defecation as a result of non assimilated products
228               !   --------------------------------------------------
229               zgrapoc   = zgraztotc * unassc
230               zgrapon   = zgraztotn * unassn
231               zgrapop   = zgraztotp * unassp
232               zgrapof   = zgraztotf * unassc
233
234               !  Addition of respiration to the release of inorganic nutrients
235               !  -------------------------------------------------------------
236               zgrarem = zgrarem + zbasresi + zrespirc
237               zgraren = zgraren + zbasresn + zrespirc * no3rat3
238               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
239               zgraref = zgraref + zbasresf + zrespirc * ferat3
240
241               !   Update of the TRA arrays
242               !   ------------------------
243               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep
244               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
245               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
246               !
247               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
248               !
249               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
250               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
251               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem 
252               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
253               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
254               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
255               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
256               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
257               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zgrazpc
258               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zgrazpn
259               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zgrazpp
260               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
261               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
262               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
263               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
264               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zgrazpc * trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
265               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
266               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
267               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
268               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
269               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zgrazpf
270               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
271               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortz + zgrapoc - zgrazpoc 
272               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
273               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
274               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + no3rat3 * ztortz + zgrapon - zgrazpon
275               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + po4rat3 * ztortz + zgrapop - zgrazpop
276               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * ztortz  + zgrapof - zgrazpof
277               !
278               ! calcite production
279               zprcaca = xfracal(ji,jj,jk) * zgraznc
280               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
281               !
282               zprcaca = part * zprcaca
283               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem - zprcaca
284               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca     &
285               &                     + rno3 * zgraren
286               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
287            END DO
288         END DO
289      END DO
290      !
291      IF( lk_iomput .AND. knt == nrdttrc ) THEN
292         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
293         IF( iom_use( "GRAZ1" ) ) THEN
294            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
295            CALL iom_put( "GRAZ1", zw3d )
296         ENDIF
297         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
298      ENDIF
299      !
300      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
301         WRITE(charout, FMT="('micro')")
302         CALL prt_ctl_trc_info(charout)
303         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
304      ENDIF
305      !
306      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
307      !
308      IF( nn_timing == 1 )  CALL timing_stop('p5z_micro')
309      !
310   END SUBROUTINE p5z_micro
311
312
313   SUBROUTINE p5z_micro_init
314
315      !!----------------------------------------------------------------------
316      !!                  ***  ROUTINE p5z_micro_init  ***
317      !!
318      !! ** Purpose :   Initialization of microzooplankton parameters
319      !!
320      !! ** Method  :   Read the nampiszoo namelist and check the parameters
321      !!                called at the first timestep (nittrc000)
322      !!
323      !! ** input   :   Namelist nampiszoo
324      !!
325      !!----------------------------------------------------------------------
326
327      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
328         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
329         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
330         &                epsher, ssigma, srespir, unassc, unassn, unassp
331
332      INTEGER :: ios                 ! Local integer output status for namelist read
333
334      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
335      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
336901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist', lwp )
337
338      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
339      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
340902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist', lwp )
341      IF(lwm) WRITE ( numonp, namp5zzoo )
342
343      IF(lwp) THEN                         ! control print
344         WRITE(numout,*) ' '
345         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
346         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
347         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
348         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
349         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
350         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
351         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
352         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
353         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
354         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
355         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
356         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
357         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
358         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
359         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
360         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
361         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
362         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
363         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
364         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
365         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
366         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
367         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
368         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
369         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
370      ENDIF
371
372   END SUBROUTINE p5z_micro_init
373
374   !!======================================================================
375END MODULE  p5zmicro
Note: See TracBrowser for help on using the repository browser.