New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/UKMO/icebergs_restart_single_file/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/icebergs_restart_single_file/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6020

Last change on this file since 6020 was 6020, checked in by timgraham, 8 years ago

Merged with head of trunk

  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn         ! routine called by step module
34   PUBLIC   rst_write       ! routine called by step module
35   PUBLIC   rst_read        ! routine called by istate module
36   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      !!----------------------------------------------------------------------
64      !
65      IF( kt == nit000 ) THEN   ! default definitions
66         lrst_oce = .FALSE.   
67         IF( ln_rst_list ) THEN
68            nrst_lst = 1
69            nitrst = nstocklist( nrst_lst )
70         ELSE
71            nitrst = nitend
72         ENDIF
73      ENDIF
74
75      ! frequency-based restart dumping (nn_stock)
76      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
77         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
78         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
79         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
80      ENDIF
81      ! to get better performances with NetCDF format:
82      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
83      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
84      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
85         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
86            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
87            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
88            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
89            ENDIF
90            ! create the file
91            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
92            clpath = TRIM(cn_ocerst_outdir)
93            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
94            IF(lwp) THEN
95               WRITE(numout,*)
96               SELECT CASE ( jprstlib )
97               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
98                   '             open ocean restart binary file: ',TRIM(clpath)//clname
99               CASE DEFAULT         ;   WRITE(numout,*)                            &
100                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
101               END SELECT
102               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
103               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
104               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
105               ENDIF
106            ENDIF
107            !
108            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
109            lrst_oce = .TRUE.
110         ENDIF
111      ENDIF
112      !
113   END SUBROUTINE rst_opn
114
115
116   SUBROUTINE rst_write( kt )
117      !!---------------------------------------------------------------------
118      !!                   ***  ROUTINE rstwrite  ***
119      !!                     
120      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
121      !!
122      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
123      !!              file, save fields which are necessary for restart
124      !!----------------------------------------------------------------------
125      INTEGER, INTENT(in) ::   kt   ! ocean time-step
126      !!----------------------------------------------------------------------
127
128                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
129                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
130
131                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
132                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
133                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
134                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
135                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
136                     !
137                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
138                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
139                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
140                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
141                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
142                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
143      IF( kt == nitrst ) THEN
144         CALL iom_close( numrow )     ! close the restart file (only at last time step)
145!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
146!!gm  not sure what to do here   ===>>>  ask to Sebastian
147         lrst_oce = .FALSE.
148            IF( ln_rst_list ) THEN
149               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
150               nitrst = nstocklist( nrst_lst )
151            ENDIF
152            lrst_oce = .FALSE.
153      ENDIF
154      !
155   END SUBROUTINE rst_write
156
157
158   SUBROUTINE rst_read_open
159      !!----------------------------------------------------------------------
160      !!                   ***  ROUTINE rst_read_open  ***
161      !!
162      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
163      !!
164      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
165      !!                the file has already been opened
166      !!----------------------------------------------------------------------
167      INTEGER        ::   jlibalt = jprstlib
168      LOGICAL        ::   llok
169      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
170      !!----------------------------------------------------------------------
171      !
172      IF( numror <= 0 ) THEN
173         IF(lwp) THEN                                             ! Contol prints
174            WRITE(numout,*)
175            SELECT CASE ( jprstlib )
176            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
177            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
178            END SELECT
179            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
180            WRITE(numout,*) '~~~~~~~~'
181         ENDIF
182
183         clpath = TRIM(cn_ocerst_indir)
184         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
185         IF ( jprstlib == jprstdimg ) THEN
186           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
187           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
188           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
189           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
190         ENDIF
191         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
192      ENDIF
193   END SUBROUTINE rst_read_open
194
195
196   SUBROUTINE rst_read
197      !!----------------------------------------------------------------------
198      !!                   ***  ROUTINE rst_read  ***
199      !!
200      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
201      !!
202      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
203      !!----------------------------------------------------------------------
204      REAL(wp) ::   zrdt, zrdttra1
205      INTEGER  ::   jk
206      LOGICAL  ::   llok
207      !!----------------------------------------------------------------------
208
209      CALL rst_read_open           ! open restart for reading (if not already opened)
210
211      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
212      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
213         CALL iom_get( numror, 'rdt', zrdt )
214         IF( zrdt /= rdt )   neuler = 0
215      ENDIF
216      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
217         CALL iom_get( numror, 'rdttra1', zrdttra1 )
218         IF( zrdttra1 /= rdttra(1) )   neuler = 0
219      ENDIF
220      !
221      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
222         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
223         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
224         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
225         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
226         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
227      ELSE
228         neuler = 0
229      ENDIF
230      !
231      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
232      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
233      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
234      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
235      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
236      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
237         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
238      ELSE
239         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
240      ENDIF
241      !
242      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
243         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
244         ub   (:,:,:)   = un   (:,:,:)
245         vb   (:,:,:)   = vn   (:,:,:)
246         sshb (:,:)     = sshn (:,:)
247         !
248         IF( lk_vvl ) THEN
249            DO jk = 1, jpk
250               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
251            END DO
252         ENDIF
253         !
254      ENDIF
255      !
256   END SUBROUTINE rst_read
257
258   !!=====================================================================
259END MODULE restart
Note: See TracBrowser for help on using the repository browser.