New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf_exp.F90 in branches/UKMO/r5518_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/r5518_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf_exp.F90 @ 7152

Last change on this file since 7152 was 7152, checked in by jcastill, 7 years ago

Initial implementation of wave coupling branch - INGV wave branch + UKMO wave coupling branch
File size: 6.6 KB
Line 
1MODULE dynzdf_exp
2   !!==============================================================================
3   !!                     ***  MODULE  dynzdf_exp  ***
4   !! Ocean dynamics:  vertical component(s) of the momentum mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            8.0  !  1997-05  (G. Madec)  vertical component of isopycnal
8   !!   NEMO     0.5  !  2002-08  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!            3.7  !  2015-11  (J. Chanut) output velocities instead of trends
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   dyn_zdf_exp  : update the momentum trend with the vertical diffu-
15   !!                  sion using an explicit time-stepping scheme.
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE zdf_oce         ! ocean vertical physics
21   USE dynadv, ONLY: ln_dynadv_vec ! Momentum advection form
22   USE sbc_oce         ! surface boundary condition: ocean
23   USE lib_mpp         ! MPP library
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! MPP library
26   USE wrk_nemo        ! Memory Allocation
27   USE timing          ! Timing
28
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   dyn_zdf_exp   ! called by step.F90
34   
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE dyn_zdf_exp( kt, p2dt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE dyn_zdf_exp  ***
48      !!                   
49      !! ** Purpose :   Compute the trend due to the vert. momentum diffusion
50      !!
51      !! ** Method  :   Explicit forward time stepping with a time splitting
52      !!      technique. The vertical diffusion of momentum is given by:
53      !!         diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) )
54      !!      Surface boundary conditions: wind stress input (averaged over kt-1/2 & kt+1/2)
55      !!      Bottom boundary conditions : bottom stress (cf zdfbfr.F90)
56      !!      Add this trend to the general trend ua :
57      !!         ua = ua + dz( avmu dz(u) )
58      !!
59      !! ** Action : - Update (ua,va) with the vertical diffusive trend
60      !!---------------------------------------------------------------------
61      INTEGER , INTENT(in) ::   kt     ! ocean time-step index
62      REAL(wp), INTENT(in) ::   p2dt   ! time-step
63      !
64      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
65      REAL(wp) ::   zlavmr, zua, zva   ! local scalars
66      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwx, zwy, zwz, zww
67      !!----------------------------------------------------------------------
68      !
69      IF( nn_timing == 1 )  CALL timing_start('dyn_zdf_exp')
70      !
71      CALL wrk_alloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) 
72      !
73      IF( kt == nit000 .AND. lwp ) THEN
74         WRITE(numout,*)
75         WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion - explicit operator'
76         WRITE(numout,*) '~~~~~~~~~~~ '
77      ENDIF
78
79      zlavmr = 1. / REAL( nn_zdfexp )
80
81
82      DO jj = 2, jpjm1                 ! Surface boundary condition
83         DO ji = 2, jpim1
84            zwy(ji,jj,1) = ( utau_b(ji,jj) + utau(ji,jj) ) * r1_rau0
85            zww(ji,jj,1) = ( vtau_b(ji,jj) + vtau(ji,jj) ) * r1_rau0
86         END DO 
87      END DO 
88      DO jk = 1, jpk                   ! Initialization of x, z and contingently trends array
89         DO jj = 2, jpjm1 
90            DO ji = 2, jpim1
91               zwx(ji,jj,jk) = ub(ji,jj,jk)
92               zwz(ji,jj,jk) = vb(ji,jj,jk)
93            END DO 
94         END DO 
95      END DO 
96      !
97      DO jl = 1, nn_zdfexp             ! Time splitting loop
98         !
99         DO jk = 2, jpk                      ! First vertical derivative
100            DO jj = 2, jpjm1 
101               DO ji = 2, jpim1
102                  zwy(ji,jj,jk) = avmu(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) / fse3uw(ji,jj,jk) 
103                  zww(ji,jj,jk) = avmv(ji,jj,jk) * ( zwz(ji,jj,jk-1) - zwz(ji,jj,jk) ) / fse3vw(ji,jj,jk)
104               END DO 
105            END DO 
106         END DO 
107         DO jk = 1, jpkm1                    ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp
108            DO jj = 2, jpjm1 
109               DO ji = 2, jpim1
110                  zua = zlavmr * ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) / fse3u(ji,jj,jk)
111                  zva = zlavmr * ( zww(ji,jj,jk) - zww(ji,jj,jk+1) ) / fse3v(ji,jj,jk)
112                  ua(ji,jj,jk) = ua(ji,jj,jk) + zua
113                  va(ji,jj,jk) = va(ji,jj,jk) + zva
114                  !
115                  zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt * zua * umask(ji,jj,jk)
116                  zwz(ji,jj,jk) = zwz(ji,jj,jk) + p2dt * zva * vmask(ji,jj,jk)
117               END DO 
118            END DO 
119         END DO 
120         !
121      END DO                           ! End of time splitting
122
123      ! Time step momentum here to be compliant with what is done in the implicit case
124      !
125      IF( ln_dynadv_vec .OR. .NOT. lk_vvl ) THEN      ! applied on velocity
126         DO jk = 1, jpkm1
127            ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk)
128            va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk)
129         END DO
130      ELSE                                            ! applied on thickness weighted velocity
131         DO jk = 1, jpkm1
132            ua(:,:,jk) = (          ub(:,:,jk) * fse3u_b(:,:,jk)      &
133               &           + p2dt * ua(:,:,jk) * fse3u_n(:,:,jk)  )   &
134               &         / fse3u_a(:,:,jk) * umask(:,:,jk)
135            va(:,:,jk) = (          vb(:,:,jk) * fse3v_b(:,:,jk)      &
136               &           + p2dt * va(:,:,jk) * fse3v_n(:,:,jk)  )   &
137               &         / fse3v_a(:,:,jk) * vmask(:,:,jk)
138         END DO
139      ENDIF
140      !
141      CALL wrk_dealloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) 
142      !
143      IF( nn_timing == 1 )  CALL timing_stop('dyn_zdf_exp')
144      !
145   END SUBROUTINE dyn_zdf_exp
146
147   !!==============================================================================
148END MODULE dynzdf_exp
Note: See TracBrowser for help on using the repository browser.