New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/UKMO/r5518_amm15_test/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/r5518_amm15_test/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 7144

Last change on this file since 7144 was 7144, checked in by jcastill, 7 years ago

Remove svn keywords
File size: 41.0 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
51      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_adv_fct  ***
54      !!
55      !! **  Purpose :   Compute the now trend due to total advection of
56      !!       tracers and add it to the general trend of tracer equations
57      !!
58      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
59      !!               (choice through the value of kn_fct)
60      !!               - 4th order compact scheme on the vertical
61      !!               - corrected flux (monotonic correction)
62      !!
63      !! ** Action : - update (pta) with the now advective tracer trends
64      !!             - send the trends for further diagnostics
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
71      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
72      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
78      REAL(wp) ::   z2dtt, ztra                              ! local scalar
79      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
80      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      !
98      IF( l_trd )  THEN
99         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
100         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
101      ENDIF
102      !
103      !                                         ! surface & bottom value : flux set to zero one for all
104      IF( lk_vvl )   zwz(:,:, 1 ) = 0._wp                ! except at the surface in linear free surface case
105      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
106      !
107      zwi(:,:,:) = 0._wp       
108      !                                                          ! ===========
109      DO jn = 1, kjpt                                            ! tracer loop
110         !                                                       ! ===========
111         !
112         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
113         !                    !* upstream tracer flux in the i and j direction
114         DO jk = 1, jpkm1
115            DO jj = 1, jpjm1
116               DO ji = 1, fs_jpim1   ! vector opt.
117                  ! upstream scheme
118                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
119                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
120                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
121                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
122                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
123                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
124               END DO
125            END DO
126         END DO
127         !                    !* upstream tracer flux in the k direction *!
128         DO jk = 2, jpkm1         ! Interior value ( multiplied by wmask)
129            DO jj = 1, jpj
130               DO ji = 1, jpi
131                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
132                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
133                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
134               END DO
135            END DO
136         END DO
137         !                   
138         IF(.NOT.lk_vvl ) THEN   ! top ocean value (only in linear free surface as zwz has been w-masked)
139            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
140               DO jj = 1, jpj
141                  DO ji = 1, jpi
142                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
143                  END DO
144               END DO   
145            ELSE                             ! no cavities: only at the ocean surface
146               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
147            ENDIF
148         ENDIF
149         !               
150         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
151            z2dtt = p2dt(jk)
152            DO jj = 2, jpjm1
153               DO ji = fs_2, fs_jpim1   ! vector opt.
154                  ! total intermediate advective trends
155                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
156                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
157                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / ( e1e2t(ji,jj) * fse3t_n(ji,jj,jk) )
158                  ! update and guess with monotonic sheme
159!!gm why tmask added in the two following lines ???    the mask is done in tranxt !
160                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
161                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
166         !               
167         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
168            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
169         END IF
170         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
171         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
172           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
173           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
174         ENDIF
175         !
176         !
177         !        !==  anti-diffusive flux : high order minus low order  ==!
178         !
179         SELECT CASE( kn_fct_h )         !* horizontal anti-diffusive fluxes
180         !
181         CASE(  2  )                         ! 2nd order centered
182            DO jk = 1, jpkm1
183               DO jj = 1, jpjm1
184                  DO ji = 1, fs_jpim1   ! vector opt.
185                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
186                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
187                  END DO
188               END DO
189            END DO
190            !
191         CASE(  4  )                         ! 4th order centered
192            zltu(:,:,jpk) = 0._wp                            ! Bottom value : flux set to zero
193            zltv(:,:,jpk) = 0._wp
194            DO jk = 1, jpkm1                                 ! Laplacian
195               DO jj = 1, jpjm1                                   ! First derivative (gradient)
196                  DO ji = 1, fs_jpim1   ! vector opt.
197                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
198                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
199                  END DO
200               END DO
201               DO jj = 2, jpjm1                                   !
202                  DO ji = fs_2, fs_jpim1   ! vector opt.
203                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
204                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
205                  END DO
206               END DO
207            END DO
208            !
209            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
210            !
211            DO jk = 1, jpkm1                                 ! Horizontal advective fluxes
212               DO jj = 1, jpjm1
213                  DO ji = 1, fs_jpim1   ! vector opt.
214                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
215                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
216                     !                                                  ! C4 minus upstream advective fluxes
217                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
218                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
219                  END DO
220               END DO
221            END DO         
222            !
223         CASE(  41 )                         ! 4th order centered       ==>>   !!gm coding attempt   need to be tested
224            ztu(:,:,jpk) = 0._wp                             ! Bottom value : flux set to zero
225            ztv(:,:,jpk) = 0._wp
226            DO jk = 1, jpkm1                                 ! gradient
227               DO jj = 1, jpjm1                                   ! First derivative (gradient)
228                  DO ji = 1, fs_jpim1   ! vector opt.
229                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
230                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
231                  END DO
232               END DO
233            END DO
234            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
235            !
236            DO jk = 1, jpkm1                                 ! Horizontal advective fluxes
237               DO jj = 2, jpjm1
238                  DO ji = 2, fs_jpim1   ! vector opt.
239                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
240                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
241                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
242                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
243                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
244                     !                                                  ! C4 minus upstream advective fluxes
245                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
246                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
247                  END DO
248               END DO
249            END DO
250            !
251         END SELECT
252         !                                !* vertical anti-diffusive fluxes
253         SELECT CASE( kn_fct_v )                ! Interior values (w-masked)
254         !
255         CASE(  2  )                                  ! 2nd order centered
256            DO jk = 2, jpkm1   
257               DO jj = 2, jpjm1
258                  DO ji = fs_2, fs_jpim1
259                     zwz(ji,jj,jk) =  ( 0.5_wp * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
260                                       - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
261                  END DO
262               END DO
263            END DO
264            !
265         CASE(  4  )                                  ! 4th order COMPACT
266            !   
267            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )         ! COMPACT interpolation of T at w-point
268            !
269            DO jk = 2, jpkm1
270               DO jj = 2, jpjm1
271                  DO ji = fs_2, fs_jpim1
272                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
273                  END DO
274               END DO
275            END DO
276            !
277         END SELECT
278         !                                      ! top ocean value: high order = upstream  ==>>  zwz=0
279         zwz(:,:, 1 ) = 0._wp                   ! only ocean surface as interior zwz values have been w-masked
280         !
281         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
282         CALL lbc_lnk( zwz, 'W',  1. )
283
284         !        !==  monotonicity algorithm  ==!
285         !
286         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
287
288
289         !        !==  final trend with corrected fluxes  ==!
290         !
291         DO jk = 1, jpkm1
292            DO jj = 2, jpjm1
293               DO ji = fs_2, fs_jpim1   ! vector opt. 
294                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
295                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
296                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
297                     &                                / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
298               END DO
299            END DO
300         END DO
301         !
302         IF( l_trd ) THEN                 ! trend diagnostics (contribution of upstream fluxes)
303            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
304            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
305            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
306            !
307            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
308            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
309            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
310            !
311            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
312         END IF
313         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
314         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
315           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
316           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
317         ENDIF
318         !
319      END DO
320      !
321      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
322      !
323      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
324      !
325   END SUBROUTINE tra_adv_fct
326
327
328   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
329      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
330      !!----------------------------------------------------------------------
331      !!                  ***  ROUTINE tra_adv_fct_zts  ***
332      !!
333      !! **  Purpose :   Compute the now trend due to total advection of
334      !!       tracers and add it to the general trend of tracer equations
335      !!
336      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
337      !!       corrected flux (monotonic correction). This version use sub-
338      !!       timestepping for the vertical advection which increases stability
339      !!       when vertical metrics are small.
340      !!       note: - this advection scheme needs a leap-frog time scheme
341      !!
342      !! ** Action : - update (pta) with the now advective tracer trends
343      !!             - save the trends
344      !!----------------------------------------------------------------------
345      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
346      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
347      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
348      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
349      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
350      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
351      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
352      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
353      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
354      !
355      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
356      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
357      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
358      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
359      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
360      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
361      REAL(wp) ::   z2dtt, ztra              ! local scalar
362      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
363      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
364      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
365      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
366      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
367      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
368      !!----------------------------------------------------------------------
369      !
370      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
371      !
372      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
373      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
374      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
375      !
376      IF( kt == kit000 )  THEN
377         IF(lwp) WRITE(numout,*)
378         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
379         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
380      ENDIF
381      !
382      l_trd = .FALSE.
383      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
384      !
385      IF( l_trd )  THEN
386         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
387         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
388      ENDIF
389      !
390      zwi(:,:,:) = 0._wp
391      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
392      zr_p2dt(:) = 1._wp / p2dt(:)
393      !
394      !                                                          ! ===========
395      DO jn = 1, kjpt                                            ! tracer loop
396         !                                                       ! ===========
397         ! 1. Bottom value : flux set to zero
398         ! ----------------------------------
399         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
400         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
401
402         ! 2. upstream advection with initial mass fluxes & intermediate update
403         ! --------------------------------------------------------------------
404         ! upstream tracer flux in the i and j direction
405         DO jk = 1, jpkm1
406            DO jj = 1, jpjm1
407               DO ji = 1, fs_jpim1   ! vector opt.
408                  ! upstream scheme
409                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
410                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
411                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
412                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
413                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
414                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
415               END DO
416            END DO
417         END DO
418
419         ! upstream tracer flux in the k direction
420         DO jk = 2, jpkm1         ! Interior value
421            DO jj = 1, jpj
422               DO ji = 1, jpi
423                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
424                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
425                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
426               END DO
427            END DO
428         END DO
429         !                       ! top value
430         IF( lk_vvl ) THEN             ! variable volume: only k=1 as zwz is multiplied by wmask
431            zwz(:,:, 1 ) = 0._wp
432         ELSE                          ! linear free surface
433            IF( ln_isfcav ) THEN             ! ice-shelf cavities
434               DO jj = 1, jpj
435                  DO ji = 1, jpi
436                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
437                  END DO
438               END DO   
439            ELSE                             ! standard case
440               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
441            ENDIF
442         ENDIF
443         !
444         DO jk = 1, jpkm1         ! total advective trend
445            z2dtt = p2dt(jk)
446            DO jj = 2, jpjm1
447               DO ji = fs_2, fs_jpim1   ! vector opt.
448                  ! total intermediate advective trends
449                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
450                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
451                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / ( e1e2t(ji,jj) * fse3t_n(ji,jj,jk) )
452                  ! update and guess with monotonic sheme
453                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
454                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
455               END DO
456            END DO
457         END DO
458         !                           
459         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
460         !               
461         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
462            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
463         END IF
464         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
465         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
466           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
467           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
468         ENDIF
469
470         ! 3. anti-diffusive flux : high order minus low order
471         ! ---------------------------------------------------
472
473         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
474            !
475            DO jj = 1, jpjm1
476               DO ji = 1, fs_jpim1   ! vector opt.
477                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
478                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
479                  !
480                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
481                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
482               END DO
483            END DO
484            !
485            DO jj = 2, jpjm1                    ! partial horizontal divergence
486               DO ji = fs_2, fs_jpim1
487                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
488                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
489               END DO
490            END DO
491            !
492            DO jj = 1, jpjm1
493               DO ji = 1, fs_jpim1   ! vector opt.
494                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
495                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
496               END DO
497            END DO
498         END DO
499     
500         !                                !* vertical anti-diffusive flux
501         zwz_sav(:,:,:)   = zwz(:,:,:)
502         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
503         zwzts  (:,:,:)   = 0._wp
504         IF( lk_vvl )   zwz(:,:, 1 ) = 0._wp    ! surface value set to zero in vvl case
505         !
506         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
507            !
508            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
509               jtb = 1   ;   jtn = 1   ;   jta = 2
510               zts(:) = p2dt(:) * z_rzts
511               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
512               !                                            ! starting at jl =1 if kn_fct_zts is odd;
513               !                                            ! starting at jl =2 otherwise
514            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
515               jtb = 1   ;   jtn = 2   ;   jta = 3
516               zts(:) = 2._wp * p2dt(:) * z_rzts
517            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
518               jtb = MOD(jtb,3) + 1
519               jtn = MOD(jtn,3) + 1
520               jta = MOD(jta,3) + 1
521            ENDIF
522            DO jk = 2, jpkm1                          ! interior value
523               DO jj = 2, jpjm1
524                  DO ji = fs_2, fs_jpim1
525                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
526                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
527                  END DO
528               END DO
529            END DO
530            IF(.NOT.lk_vvl ) THEN                    ! top value (only in linear free surface case)
531               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
532                  DO jj = 1, jpj
533                     DO ji = 1, jpi
534                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
535                     END DO
536                  END DO   
537               ELSE                                      ! standard case
538                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
539               ENDIF
540            ENDIF
541            !
542            jtaken = MOD( jtaken + 1 , 2 )
543            !
544            DO jk = 2, jpkm1                             ! total advective trends
545               DO jj = 2, jpjm1
546                  DO ji = fs_2, fs_jpim1
547                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
548                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
549                        &                         / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
550                  END DO
551               END DO
552            END DO
553            !
554         END DO
555
556         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
557            DO jj = 2, jpjm1
558               DO ji = fs_2, fs_jpim1
559                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
560               END DO
561            END DO
562         END DO
563         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
564         CALL lbc_lnk( zwz, 'W',  1. )
565
566         ! 4. monotonicity algorithm
567         ! -------------------------
568         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
569
570
571         ! 5. final trend with corrected fluxes
572         ! ------------------------------------
573         DO jk = 1, jpkm1
574            DO jj = 2, jpjm1
575               DO ji = fs_2, fs_jpim1   ! vector opt. 
576                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
577                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
578                     &                                / ( e1e2t(ji,jj) * fse3t_n(ji,jj,jk) )
579               END DO
580            END DO
581         END DO
582
583         !                                 ! trend diagnostics (contribution of upstream fluxes)
584         IF( l_trd )  THEN
585            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
586            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
587            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
588            !
589            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
590            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
591            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
592            !
593            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
594         END IF
595         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
596         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
597           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
598           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
599         ENDIF
600         !
601      END DO
602      !
603      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
604      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
605      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
606      !
607      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
608      !
609   END SUBROUTINE tra_adv_fct_zts
610
611
612   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
613      !!---------------------------------------------------------------------
614      !!                    ***  ROUTINE nonosc  ***
615      !!     
616      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
617      !!       scheme and the before field by a nonoscillatory algorithm
618      !!
619      !! **  Method  :   ... ???
620      !!       warning : pbef and paft must be masked, but the boundaries
621      !!       conditions on the fluxes are not necessary zalezak (1979)
622      !!       drange (1995) multi-dimensional forward-in-time and upstream-
623      !!       in-space based differencing for fluid
624      !!----------------------------------------------------------------------
625      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
626      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
627      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
628      !
629      INTEGER  ::   ji, jj, jk   ! dummy loop indices
630      INTEGER  ::   ikm1         ! local integer
631      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
632      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
633      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
634      !!----------------------------------------------------------------------
635      !
636      IF( nn_timing == 1 )  CALL timing_start('nonosc')
637      !
638      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
639      !
640      zbig  = 1.e+40_wp
641      zrtrn = 1.e-15_wp
642      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
643
644      ! Search local extrema
645      ! --------------------
646      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
647      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
648         &        paft * tmask - zbig * ( 1._wp - tmask )  )
649      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
650         &        paft * tmask + zbig * ( 1._wp - tmask )  )
651
652      DO jk = 1, jpkm1
653         ikm1 = MAX(jk-1,1)
654         z2dtt = p2dt(jk)
655         DO jj = 2, jpjm1
656            DO ji = fs_2, fs_jpim1   ! vector opt.
657
658               ! search maximum in neighbourhood
659               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
660                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
661                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
662                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
663
664               ! search minimum in neighbourhood
665               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
666                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
667                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
668                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
669
670               ! positive part of the flux
671               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
672                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
673                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
674
675               ! negative part of the flux
676               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
677                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
678                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
679
680               ! up & down beta terms
681               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
682               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
683               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
684            END DO
685         END DO
686      END DO
687      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
688
689      ! 3. monotonic flux in the i & j direction (paa & pbb)
690      ! ----------------------------------------
691      DO jk = 1, jpkm1
692         DO jj = 2, jpjm1
693            DO ji = fs_2, fs_jpim1   ! vector opt.
694               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
695               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
696               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
697               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
698
699               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
700               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
701               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
702               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
703
704      ! monotonic flux in the k direction, i.e. pcc
705      ! -------------------------------------------
706               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
707               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
708               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
709               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
710            END DO
711         END DO
712      END DO
713      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
714      !
715      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
716      !
717      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
718      !
719   END SUBROUTINE nonosc
720
721
722   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
723      !!----------------------------------------------------------------------
724      !!                  ***  ROUTINE interp_4th_cpt  ***
725      !!
726      !! **  Purpose :   Compute the interpolation of tracer at w-point
727      !!
728      !! **  Method  :   4th order compact interpolation
729      !!----------------------------------------------------------------------
730      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
731      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
732      !
733      INTEGER :: ji, jj, jk   ! dummy loop integers
734      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
735      !!----------------------------------------------------------------------
736     
737      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
738         DO jj = 1, jpj
739            DO ji = 1, jpi
740               zwd (ji,jj,jk) = 4._wp
741               zwi (ji,jj,jk) = 1._wp
742               zws (ji,jj,jk) = 1._wp
743               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
744               !
745               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
746                  zwd (ji,jj,jk) = 1._wp
747                  zwi (ji,jj,jk) = 0._wp
748                  zws (ji,jj,jk) = 0._wp
749                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
750               ENDIF
751            END DO
752         END DO
753      END DO
754      !
755      jk=2                                            ! Switch to second order centered at top
756      DO jj=1,jpj
757         DO ji=1,jpi
758            zwd (ji,jj,jk) = 1._wp
759            zwi (ji,jj,jk) = 0._wp
760            zws (ji,jj,jk) = 0._wp
761            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
762         END DO
763      END DO   
764      !
765      !                       !==  tridiagonal solve  ==!
766      DO jj = 1, jpj                ! first recurrence
767         DO ji = 1, jpi
768            zwt(ji,jj,2) = zwd(ji,jj,2)
769         END DO
770      END DO
771      DO jk = 3, jpkm1
772         DO jj = 1, jpj
773            DO ji = 1, jpi
774               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
775            END DO
776         END DO
777      END DO
778      !
779      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
780         DO ji = 1, jpi
781            pt_out(ji,jj,2) = zwrm(ji,jj,2)
782         END DO
783      END DO
784      DO jk = 3, jpkm1
785         DO jj = 1, jpj
786            DO ji = 1, jpi
787               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
788            END DO
789         END DO
790      END DO
791
792      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
793         DO ji = 1, jpi
794            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
795         END DO
796      END DO
797      DO jk = jpk-2, 2, -1
798         DO jj = 1, jpj
799            DO ji = 1, jpi
800               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
801            END DO
802         END DO
803      END DO
804      !   
805   END SUBROUTINE interp_4th_cpt
806   
807   !!======================================================================
808END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.