New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/UKMO/r5518_sst_landsea_cpl/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/r5518_sst_landsea_cpl/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 7147

Last change on this file since 7147 was 7147, checked in by jcastill, 7 years ago

Remove svn keywords

File size: 70.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61
62   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
63
64   !! * Substitutions
65#  include "domzgr_substitute.h90"
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE dyn_hpg( kt )
75      !!---------------------------------------------------------------------
76      !!                  ***  ROUTINE dyn_hpg  ***
77      !!
78      !! ** Method  :   Call the hydrostatic pressure gradient routine
79      !!              using the scheme defined in the namelist
80      !!
81      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
89      !
90      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
91         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
92         ztrdu(:,:,:) = ua(:,:,:)
93         ztrdv(:,:,:) = va(:,:,:)
94      ENDIF
95      !
96      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
97      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
98      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
99      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
100      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
101      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
102      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
103      END SELECT
104      !
105      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
110      ENDIF
111      !
112      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
113         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
114      !
115      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
116      !
117   END SUBROUTINE dyn_hpg
118
119
120   SUBROUTINE dyn_hpg_init
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_hpg_init  ***
123      !!
124      !! ** Purpose :   initializations for the hydrostatic pressure gradient
125      !!              computation and consistency control
126      !!
127      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
128      !!      with the type of vertical coordinate used (zco, zps, sco)
129      !!----------------------------------------------------------------------
130      INTEGER ::   ioptio = 0      ! temporary integer
131      INTEGER ::   ios             ! Local integer output status for namelist read
132      !!
133      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
134         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
135      !!----------------------------------------------------------------------
136      !
137      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
138      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
139901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
140
141      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
142      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
143902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
144      IF(lwm) WRITE ( numond, namdyn_hpg )
145      !
146      IF(lwp) THEN                   ! Control print
147         WRITE(numout,*)
148         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
149         WRITE(numout,*) '~~~~~~~~~~~~'
150         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
151         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
152         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
153         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
154         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
155         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
156         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
157      ENDIF
158      !
159      IF( ln_hpg_djc )   &
160         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
161                           & currently disabled (bugs under investigation). Please select &
162                           & either  ln_hpg_sco or  ln_hpg_prj instead')
163      !
164      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
165         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
166                           & the standard jacobian formulation hpg_sco or &
167                           & the pressure jacobian formulation hpg_prj')
168
169      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
170         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
171      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
172         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
173      !
174      !                               ! Set nhpg from ln_hpg_... flags
175      IF( ln_hpg_zco )   nhpg = 0
176      IF( ln_hpg_zps )   nhpg = 1
177      IF( ln_hpg_sco )   nhpg = 2
178      IF( ln_hpg_djc )   nhpg = 3
179      IF( ln_hpg_prj )   nhpg = 4
180      IF( ln_hpg_isf )   nhpg = 5
181      !
182      !                               ! Consistency check
183      ioptio = 0
184      IF( ln_hpg_zco )   ioptio = ioptio + 1
185      IF( ln_hpg_zps )   ioptio = ioptio + 1
186      IF( ln_hpg_sco )   ioptio = ioptio + 1
187      IF( ln_hpg_djc )   ioptio = ioptio + 1
188      IF( ln_hpg_prj )   ioptio = ioptio + 1
189      IF( ln_hpg_isf )   ioptio = ioptio + 1
190      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
191      !
192      ! initialisation of ice load
193      riceload(:,:)=0.0
194      !
195   END SUBROUTINE dyn_hpg_init
196
197
198   SUBROUTINE hpg_zco( kt )
199      !!---------------------------------------------------------------------
200      !!                  ***  ROUTINE hpg_zco  ***
201      !!
202      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
203      !!      The now hydrostatic pressure gradient at a given level, jk,
204      !!      is computed by taking the vertical integral of the in-situ
205      !!      density gradient along the model level from the suface to that
206      !!      level:    zhpi = grav .....
207      !!                zhpj = grav .....
208      !!      add it to the general momentum trend (ua,va).
209      !!            ua = ua - 1/e1u * zhpi
210      !!            va = va - 1/e2v * zhpj
211      !!
212      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
213      !!----------------------------------------------------------------------
214      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
215      !!
216      INTEGER  ::   ji, jj, jk       ! dummy loop indices
217      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
218      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
219      !!----------------------------------------------------------------------
220      !
221      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
222      !
223      IF( kt == nit000 ) THEN
224         IF(lwp) WRITE(numout,*)
225         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
226         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
227      ENDIF
228
229      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
230
231      ! Surface value
232      DO jj = 2, jpjm1
233         DO ji = fs_2, fs_jpim1   ! vector opt.
234            zcoef1 = zcoef0 * fse3w(ji,jj,1)
235            ! hydrostatic pressure gradient
236            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
237            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
238            ! add to the general momentum trend
239            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
240            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
241         END DO
242      END DO
243
244      !
245      ! interior value (2=<jk=<jpkm1)
246      DO jk = 2, jpkm1
247         DO jj = 2, jpjm1
248            DO ji = fs_2, fs_jpim1   ! vector opt.
249               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
250               ! hydrostatic pressure gradient
251               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
252                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
253                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
254
255               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
256                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
257                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
258               ! add to the general momentum trend
259               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
260               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
261            END DO
262         END DO
263      END DO
264      !
265      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
266      !
267   END SUBROUTINE hpg_zco
268
269
270   SUBROUTINE hpg_zps( kt )
271      !!---------------------------------------------------------------------
272      !!                 ***  ROUTINE hpg_zps  ***
273      !!
274      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
275      !!
276      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
277      !!----------------------------------------------------------------------
278      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
279      !!
280      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
281      INTEGER  ::   iku, ikv                         ! temporary integers
282      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
283      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
284      !!----------------------------------------------------------------------
285      !
286      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
287      !
288      IF( kt == nit000 ) THEN
289         IF(lwp) WRITE(numout,*)
290         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
291         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
292      ENDIF
293
294      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
295!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
296
297      ! Local constant initialization
298      zcoef0 = - grav * 0.5_wp
299
300      !  Surface value (also valid in partial step case)
301      DO jj = 2, jpjm1
302         DO ji = fs_2, fs_jpim1   ! vector opt.
303            zcoef1 = zcoef0 * fse3w(ji,jj,1)
304            ! hydrostatic pressure gradient
305            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
306            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
307            ! add to the general momentum trend
308            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
309            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
310         END DO
311      END DO
312
313
314      ! interior value (2=<jk=<jpkm1)
315      DO jk = 2, jpkm1
316         DO jj = 2, jpjm1
317            DO ji = fs_2, fs_jpim1   ! vector opt.
318               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
319               ! hydrostatic pressure gradient
320               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
321                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
322                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
323
324               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
325                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
326                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
327               ! add to the general momentum trend
328               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
329               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
330            END DO
331         END DO
332      END DO
333
334
335      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
336      DO jj = 2, jpjm1
337         DO ji = 2, jpim1
338            iku = mbku(ji,jj)
339            ikv = mbkv(ji,jj)
340            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
341            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
342            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
343               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
344               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
345                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
347            ENDIF
348            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
349               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
350               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
351                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
353            ENDIF
354         END DO
355      END DO
356      !
357      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
358      !
359   END SUBROUTINE hpg_zps
360
361   SUBROUTINE hpg_sco( kt )
362      !!---------------------------------------------------------------------
363      !!                  ***  ROUTINE hpg_sco  ***
364      !!
365      !! ** Method  :   s-coordinate case. Jacobian scheme.
366      !!      The now hydrostatic pressure gradient at a given level, jk,
367      !!      is computed by taking the vertical integral of the in-situ
368      !!      density gradient along the model level from the suface to that
369      !!      level. s-coordinates (ln_sco): a corrective term is added
370      !!      to the horizontal pressure gradient :
371      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
372      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
373      !!      add it to the general momentum trend (ua,va).
374      !!         ua = ua - 1/e1u * zhpi
375      !!         va = va - 1/e2v * zhpj
376      !!
377      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
378      !!----------------------------------------------------------------------
379      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
380      !!
381      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
382      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
383      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
384      !!----------------------------------------------------------------------
385      !
386      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
387      !
388      IF( kt == nit000 ) THEN
389         IF(lwp) WRITE(numout,*)
390         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
391         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
392      ENDIF
393
394      ! Local constant initialization
395      zcoef0 = - grav * 0.5_wp
396      ! To use density and not density anomaly
397      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
398      ELSE                 ;     znad = 0._wp         ! Fixed volume
399      ENDIF
400
401      ! Surface value
402      DO jj = 2, jpjm1
403         DO ji = fs_2, fs_jpim1   ! vector opt.
404            ! hydrostatic pressure gradient along s-surfaces
405            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
406               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
407            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
408               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
409            ! s-coordinate pressure gradient correction
410            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
411               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
412            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
413               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
414            ! add to the general momentum trend
415            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
416            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
417         END DO
418      END DO
419
420      ! interior value (2=<jk=<jpkm1)
421      DO jk = 2, jpkm1
422         DO jj = 2, jpjm1
423            DO ji = fs_2, fs_jpim1   ! vector opt.
424               ! hydrostatic pressure gradient along s-surfaces
425               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
426                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
427                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
428               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
429                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
430                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
431               ! s-coordinate pressure gradient correction
432               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
433                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
434               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
435                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
436               ! add to the general momentum trend
437               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
438               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
439            END DO
440         END DO
441      END DO
442      !
443      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
444      !
445   END SUBROUTINE hpg_sco
446
447   SUBROUTINE hpg_isf( kt )
448      !!---------------------------------------------------------------------
449      !!                  ***  ROUTINE hpg_sco  ***
450      !!
451      !! ** Method  :   s-coordinate case. Jacobian scheme.
452      !!      The now hydrostatic pressure gradient at a given level, jk,
453      !!      is computed by taking the vertical integral of the in-situ
454      !!      density gradient along the model level from the suface to that
455      !!      level. s-coordinates (ln_sco): a corrective term is added
456      !!      to the horizontal pressure gradient :
457      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
458      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
459      !!      add it to the general momentum trend (ua,va).
460      !!         ua = ua - 1/e1u * zhpi
461      !!         va = va - 1/e2v * zhpj
462      !!      iceload is added and partial cell case are added to the top and bottom
463      !!     
464      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
465      !!----------------------------------------------------------------------
466      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
467      !!
468      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
469      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
470      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
471      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
472      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
473      !!----------------------------------------------------------------------
474      !
475      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
476      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
477      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
478      !
479     IF( kt == nit000 ) THEN
480         IF(lwp) WRITE(numout,*)
481         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
482         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
483      ENDIF
484
485      ! Local constant initialization
486      zcoef0 = - grav * 0.5_wp
487      ! To use density and not density anomaly
488!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
489!      ELSE                 ;     znad = 0._wp         ! Fixed volume
490!      ENDIF
491      znad=1._wp
492      ! iniitialised to 0. zhpi zhpi
493      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
494
495      ! Partial steps: top & bottom before horizontal gradient
496!jc      CALL zps_hde_isf( kt, jpts, tsn, gtsu, gtsv, gtui, gtvi,   &
497!jc               &       rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
498!jc               &      grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi  )
499
500!==================================================================================     
501!=====Compute iceload and contribution of the half first wet layer =================
502!===================================================================================
503
504      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
505      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
506
507      ! compute density of the water displaced by the ice shelf
508      zrhd = rhd ! save rhd
509      DO jk = 1, jpk
510           zdept(:,:)=gdept_1d(jk)
511           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
512      END DO
513      WHERE ( tmask(:,:,:) == 1._wp)
514        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
515      END WHERE
516     
517      ! compute rhd at the ice/oce interface (ice shelf side)
518      CALL eos(ztstop,risfdep,zrhdtop_isf)
519
520      ! compute rhd at the ice/oce interface (ocean side)
521      DO ji=1,jpi
522        DO jj=1,jpj
523          ikt=mikt(ji,jj)
524          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
525          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
526        END DO
527      END DO
528      CALL eos(ztstop,risfdep,zrhdtop_oce)
529      !
530      ! Surface value + ice shelf gradient
531      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
532      ziceload = 0._wp
533      DO jj = 1, jpj
534         DO ji = 1, jpi   ! vector opt.
535            ikt=mikt(ji,jj)
536            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
537            DO jk=2,ikt-1
538               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
539                  &                              * (1._wp - tmask(ji,jj,jk))
540            END DO
541            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
542                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
543         END DO
544      END DO
545      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
546      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
547      DO jj = 2, jpjm1
548         DO ji = fs_2, fs_jpim1   ! vector opt.
549            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
550            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
551            ! we assume ISF is in isostatic equilibrium
552            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
553               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
554               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
555               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
556               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
557            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
558               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
559               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
560               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
561               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
562            ! s-coordinate pressure gradient correction (=0 if z coordinate)
563            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
564               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
565            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
566               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
567            ! add to the general momentum trend
568            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
569            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
570         END DO
571      END DO
572!==================================================================================     
573!===== Compute partial cell contribution for the top cell =========================
574!==================================================================================
575      DO jj = 2, jpjm1
576         DO ji = fs_2, fs_jpim1   ! vector opt.
577            iku = miku(ji,jj) ; 
578            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
579            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
580            ! u direction
581            IF ( iku .GT. 1 ) THEN
582               ! case iku
583               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
584                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
585                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
586               ! corrective term ( = 0 if z coordinate )
587               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
588               ! zhpi will be added in interior loop
589               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
590               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
591               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
592
593               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
594               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
595                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
596                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
597                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
598                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
599               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
600            END IF
601               
602            ! v direction
603            ikv = mikv(ji,jj)
604            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
605            IF ( ikv .GT. 1 ) THEN
606               ! case ikv
607               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
608                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
609                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
610               ! corrective term ( = 0 if z coordinate )
611               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
612               ! zhpi will be added in interior loop
613               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
614               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
615               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
616               
617               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
618               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
619                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
620                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
621                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
622                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
623               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
624            END IF
625         END DO
626      END DO
627
628!==================================================================================     
629!===== Compute interior value =====================================================
630!==================================================================================
631
632      DO jj = 2, jpjm1
633         DO ji = fs_2, fs_jpim1   ! vector opt.
634            iku=miku(ji,jj); ikv=mikv(ji,jj)
635            DO jk = 2, jpkm1
636               ! hydrostatic pressure gradient along s-surfaces
637               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
638               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
639                  &                            + zcoef0 / e1u(ji,jj)                                                           &
640                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
641                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
642                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
643                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
644               ! s-coordinate pressure gradient correction
645               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
646               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
647                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
648               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
649
650               ! hydrostatic pressure gradient along s-surfaces
651               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
652               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
653                  &                            + zcoef0 / e2v(ji,jj)                                                           &
654                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
655                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
656                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
657                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
658               ! s-coordinate pressure gradient correction
659               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
660               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
661                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
662               ! add to the general momentum trend
663               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
664            END DO
665         END DO
666      END DO
667
668!==================================================================================     
669!===== Compute bottom cell contribution (partial cell) ============================
670!==================================================================================
671
672      DO jj = 2, jpjm1
673         DO ji = 2, jpim1
674            iku = mbku(ji,jj)
675            ikv = mbkv(ji,jj)
676
677            IF (iku .GT. 1) THEN
678               ! remove old value (interior case)
679               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
680                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
681               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
682               ! put new value
683               ! -zpshpi to avoid double contribution of the partial step in the top layer
684               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
685               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
686               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
687            END IF
688            ! v direction
689            IF (ikv .GT. 1) THEN
690               ! remove old value (interior case)
691               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
692                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
693               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
694               ! put new value
695               ! -zpshpj to avoid double contribution of the partial step in the top layer
696               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
697               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
698               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
699            END IF
700         END DO
701      END DO
702     
703      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
704      rhd = zrhd
705      !
706      CALL wrk_dealloc( jpi,jpj,2, ztstop)
707      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
708      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
709      !
710   END SUBROUTINE hpg_isf
711
712
713   SUBROUTINE hpg_djc( kt )
714      !!---------------------------------------------------------------------
715      !!                  ***  ROUTINE hpg_djc  ***
716      !!
717      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
718      !!
719      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
720      !!----------------------------------------------------------------------
721      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
722      !!
723      INTEGER  ::   ji, jj, jk          ! dummy loop indices
724      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
725      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
726      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
727      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
728      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
729      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
730      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
731      !!----------------------------------------------------------------------
732      !
733      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
734      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
735      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
736      !
737
738      IF( kt == nit000 ) THEN
739         IF(lwp) WRITE(numout,*)
740         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
741         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
742      ENDIF
743
744      ! Local constant initialization
745      zcoef0 = - grav * 0.5_wp
746      z1_10  = 1._wp / 10._wp
747      z1_12  = 1._wp / 12._wp
748
749      !----------------------------------------------------------------------------------------
750      !  compute and store in provisional arrays elementary vertical and horizontal differences
751      !----------------------------------------------------------------------------------------
752
753!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
754
755      DO jk = 2, jpkm1
756         DO jj = 2, jpjm1
757            DO ji = fs_2, fs_jpim1   ! vector opt.
758               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
759               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
760               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
761               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
762               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
763               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
764            END DO
765         END DO
766      END DO
767
768      !-------------------------------------------------------------------------
769      ! compute harmonic averages using eq. 5.18
770      !-------------------------------------------------------------------------
771      zep = 1.e-15
772
773!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
774!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
775
776      DO jk = 2, jpkm1
777         DO jj = 2, jpjm1
778            DO ji = fs_2, fs_jpim1   ! vector opt.
779               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
780
781               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
782               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
783
784               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
785               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
786
787               IF( cffw > zep) THEN
788                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
789                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
790               ELSE
791                  drhow(ji,jj,jk) = 0._wp
792               ENDIF
793
794               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
795                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
796
797               IF( cffu > zep ) THEN
798                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
799                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
800               ELSE
801                  drhou(ji,jj,jk ) = 0._wp
802               ENDIF
803
804               IF( cffx > zep ) THEN
805                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
806                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
807               ELSE
808                  dzu(ji,jj,jk) = 0._wp
809               ENDIF
810
811               IF( cffv > zep ) THEN
812                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
813                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
814               ELSE
815                  drhov(ji,jj,jk) = 0._wp
816               ENDIF
817
818               IF( cffy > zep ) THEN
819                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
820                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
821               ELSE
822                  dzv(ji,jj,jk) = 0._wp
823               ENDIF
824
825            END DO
826         END DO
827      END DO
828
829      !----------------------------------------------------------------------------------
830      ! apply boundary conditions at top and bottom using 5.36-5.37
831      !----------------------------------------------------------------------------------
832      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
833      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
834      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
835
836      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
837      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
838      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
839
840
841      !--------------------------------------------------------------
842      ! Upper half of top-most grid box, compute and store
843      !-------------------------------------------------------------
844
845!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
846!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
847
848      DO jj = 2, jpjm1
849         DO ji = fs_2, fs_jpim1   ! vector opt.
850            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
851               &                   * (  rhd(ji,jj,1)                                    &
852               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
853               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
854               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
855         END DO
856      END DO
857
858!!bug gm    : here also, simplification is possible
859!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
860
861      DO jk = 2, jpkm1
862         DO jj = 2, jpjm1
863            DO ji = fs_2, fs_jpim1   ! vector opt.
864
865               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
866                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
867                  &            - grav * z1_10 * (                                                                     &
868                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
869                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
870                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
871                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
872                  &                             )
873
874               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
875                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
876                  &            - grav* z1_10 * (                                                                      &
877                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
878                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
879                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
880                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
881                  &                            )
882
883               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
884                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
885                  &            - grav* z1_10 * (                                                                      &
886                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
887                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
888                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
889                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
890                  &                            )
891
892            END DO
893         END DO
894      END DO
895      CALL lbc_lnk(rho_k,'W',1.)
896      CALL lbc_lnk(rho_i,'U',1.)
897      CALL lbc_lnk(rho_j,'V',1.)
898
899
900      ! ---------------
901      !  Surface value
902      ! ---------------
903      DO jj = 2, jpjm1
904         DO ji = fs_2, fs_jpim1   ! vector opt.
905            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
906            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
907            ! add to the general momentum trend
908            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
909            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
910         END DO
911      END DO
912
913      ! ----------------
914      !  interior value   (2=<jk=<jpkm1)
915      ! ----------------
916      DO jk = 2, jpkm1
917         DO jj = 2, jpjm1
918            DO ji = fs_2, fs_jpim1   ! vector opt.
919               ! hydrostatic pressure gradient along s-surfaces
920               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
921                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
922                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
923               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
924                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
925                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
926               ! add to the general momentum trend
927               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
928               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
929            END DO
930         END DO
931      END DO
932      !
933      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
934      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
935      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
936      !
937   END SUBROUTINE hpg_djc
938
939
940   SUBROUTINE hpg_prj( kt )
941      !!---------------------------------------------------------------------
942      !!                  ***  ROUTINE hpg_prj  ***
943      !!
944      !! ** Method  :   s-coordinate case.
945      !!      A Pressure-Jacobian horizontal pressure gradient method
946      !!      based on the constrained cubic-spline interpolation for
947      !!      all vertical coordinate systems
948      !!
949      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
950      !!----------------------------------------------------------------------
951      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
952      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
953      !!
954      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
955      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
956      !!
957      !! The local variables for the correction term
958      INTEGER  :: jk1, jis, jid, jjs, jjd
959      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
960      REAL(wp) :: zrhdt1
961      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
962      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
963      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
964      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
965      !!----------------------------------------------------------------------
966      !
967      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
968      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
969      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
970      !
971      IF( kt == nit000 ) THEN
972         IF(lwp) WRITE(numout,*)
973         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
974         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
975      ENDIF
976
977      !!----------------------------------------------------------------------
978      ! Local constant initialization
979      zcoef0 = - grav
980      znad = 0.0_wp
981      IF( lk_vvl ) znad = 1._wp
982
983      ! Clean 3-D work arrays
984      zhpi(:,:,:) = 0._wp
985      zrhh(:,:,:) = rhd(:,:,:)
986
987      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
988      DO jj = 1, jpj
989        DO ji = 1, jpi
990          jk = mbathy(ji,jj)
991          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
992          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
993          ELSE IF(jk < jpkm1) THEN
994             DO jkk = jk+1, jpk
995                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
996                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
997             END DO
998          ENDIF
999        END DO
1000      END DO
1001
1002      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1003      DO jj = 1, jpj
1004         DO ji = 1, jpi
1005            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1006         END DO
1007      END DO
1008
1009      DO jk = 2, jpk
1010         DO jj = 1, jpj
1011            DO ji = 1, jpi
1012               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1013            END DO
1014         END DO
1015      END DO
1016
1017      fsp(:,:,:) = zrhh (:,:,:)
1018      xsp(:,:,:) = zdept(:,:,:)
1019
1020      ! Construct the vertical density profile with the
1021      ! constrained cubic spline interpolation
1022      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1023      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1024
1025      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1026      DO jj = 2, jpj
1027        DO ji = 2, jpi
1028          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1029                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1030                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1031
1032          ! assuming linear profile across the top half surface layer
1033          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1034        END DO
1035      END DO
1036
1037      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1038      DO jk = 2, jpkm1
1039        DO jj = 2, jpj
1040          DO ji = 2, jpi
1041            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1042                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1043                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1044                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1045          END DO
1046        END DO
1047      END DO
1048
1049      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1050
1051      ! Prepare zsshu_n and zsshv_n
1052      DO jj = 2, jpjm1
1053        DO ji = 2, jpim1
1054          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1055                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1056          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1057                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1058        END DO
1059      END DO
1060
1061      DO jj = 2, jpjm1
1062        DO ji = 2, jpim1
1063          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1064          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1065        END DO
1066      END DO
1067
1068      DO jk = 2, jpkm1
1069        DO jj = 2, jpjm1
1070          DO ji = 2, jpim1
1071            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1072            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1073          END DO
1074        END DO
1075      END DO
1076
1077      DO jk = 1, jpkm1
1078        DO jj = 2, jpjm1
1079          DO ji = 2, jpim1
1080            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1081            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1082          END DO
1083        END DO
1084      END DO
1085
1086      DO jk = 1, jpkm1
1087        DO jj = 2, jpjm1
1088          DO ji = 2, jpim1
1089            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1090            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1091            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1092            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1093          END DO
1094        END DO
1095      END DO
1096
1097
1098      DO jk = 1, jpkm1
1099        DO jj = 2, jpjm1
1100          DO ji = 2, jpim1
1101            zpwes = 0._wp; zpwed = 0._wp
1102            zpnss = 0._wp; zpnsd = 0._wp
1103            zuijk = zu(ji,jj,jk)
1104            zvijk = zv(ji,jj,jk)
1105
1106            !!!!!     for u equation
1107            IF( jk <= mbku(ji,jj) ) THEN
1108               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1109                 jis = ji + 1; jid = ji
1110               ELSE
1111                 jis = ji;     jid = ji +1
1112               ENDIF
1113
1114               ! integrate the pressure on the shallow side
1115               jk1 = jk
1116               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1117                 IF( jk1 == mbku(ji,jj) ) THEN
1118                   zuijk = -zdept(jis,jj,jk1)
1119                   EXIT
1120                 ENDIF
1121                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1122                 zpwes = zpwes +                                    &
1123                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1124                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1125                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1126                 jk1 = jk1 + 1
1127               END DO
1128
1129               ! integrate the pressure on the deep side
1130               jk1 = jk
1131               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1132                 IF( jk1 == 1 ) THEN
1133                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1134                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1135                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1136                                                     dsp(jid,jj,1)) * zdeps
1137                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1138                   EXIT
1139                 ENDIF
1140                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1141                 zpwed = zpwed +                                        &
1142                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1143                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1144                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1145                 jk1 = jk1 - 1
1146               END DO
1147
1148               ! update the momentum trends in u direction
1149
1150               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1151               IF( lk_vvl ) THEN
1152                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1153                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1154                ELSE
1155                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1156               ENDIF
1157
1158               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1159               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1160            ENDIF
1161
1162            !!!!!     for v equation
1163            IF( jk <= mbkv(ji,jj) ) THEN
1164               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1165                 jjs = jj + 1; jjd = jj
1166               ELSE
1167                 jjs = jj    ; jjd = jj + 1
1168               ENDIF
1169
1170               ! integrate the pressure on the shallow side
1171               jk1 = jk
1172               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1173                 IF( jk1 == mbkv(ji,jj) ) THEN
1174                   zvijk = -zdept(ji,jjs,jk1)
1175                   EXIT
1176                 ENDIF
1177                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1178                 zpnss = zpnss +                                      &
1179                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1180                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1181                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1182                 jk1 = jk1 + 1
1183               END DO
1184
1185               ! integrate the pressure on the deep side
1186               jk1 = jk
1187               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1188                 IF( jk1 == 1 ) THEN
1189                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1190                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1191                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1192                                                     dsp(ji,jjd,1) ) * zdeps
1193                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1194                   EXIT
1195                 ENDIF
1196                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1197                 zpnsd = zpnsd +                                        &
1198                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1199                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1200                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1201                 jk1 = jk1 - 1
1202               END DO
1203
1204
1205               ! update the momentum trends in v direction
1206
1207               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1208               IF( lk_vvl ) THEN
1209                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1210                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1211               ELSE
1212                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1213               ENDIF
1214
1215               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1216               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1217            ENDIF
1218
1219
1220           END DO
1221        END DO
1222      END DO
1223      !
1224      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1225      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1226      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1227      !
1228   END SUBROUTINE hpg_prj
1229
1230
1231   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1232      !!----------------------------------------------------------------------
1233      !!                 ***  ROUTINE cspline  ***
1234      !!
1235      !! ** Purpose :   constrained cubic spline interpolation
1236      !!
1237      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1238      !!
1239      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1240      !!----------------------------------------------------------------------
1241      IMPLICIT NONE
1242      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1243      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1244                                                                    ! the interpoated function
1245      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1246                                                                    ! 2: Linear
1247      !
1248      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1249      INTEGER  ::   jpi, jpj, jpkm1
1250      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1251      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1252      REAL(wp) ::   zdf(size(fsp,3))
1253      !!----------------------------------------------------------------------
1254
1255      jpi   = size(fsp,1)
1256      jpj   = size(fsp,2)
1257      jpkm1 = size(fsp,3) - 1
1258
1259
1260      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1261         DO ji = 1, jpi
1262            DO jj = 1, jpj
1263           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1264           !    DO jk = 2, jpkm1-1
1265           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1266           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1267           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1268           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1269           !
1270           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1271           !
1272           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1273           !           zdf(jk) = 0._wp
1274           !       ELSE
1275           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1276           !       ENDIF
1277           !    END DO
1278
1279           !!Simply geometric average
1280               DO jk = 2, jpkm1-1
1281                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1282                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1283
1284                  IF(zdf1 * zdf2 <= 0._wp) THEN
1285                     zdf(jk) = 0._wp
1286                  ELSE
1287                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1288                  ENDIF
1289               END DO
1290
1291               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1292                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1293               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1294                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1295                          & 0.5_wp * zdf(jpkm1 - 1)
1296
1297               DO jk = 1, jpkm1 - 1
1298                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1299                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1300                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1301                 zddf1  = -2._wp * ztmp1 + ztmp2
1302                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1303                 zddf2  =  2._wp * ztmp1 - ztmp2
1304
1305                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1306                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1307                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1308                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1309                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1310                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1311                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1312                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1313                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1314               END DO
1315            END DO
1316         END DO
1317
1318      ELSE IF (polynomial_type == 2) THEN     ! Linear
1319         DO ji = 1, jpi
1320            DO jj = 1, jpj
1321               DO jk = 1, jpkm1-1
1322                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1323                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1324
1325                  dsp(ji,jj,jk) = 0._wp
1326                  csp(ji,jj,jk) = 0._wp
1327                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1328                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1329               END DO
1330            END DO
1331         END DO
1332
1333      ELSE
1334           CALL ctl_stop( 'invalid polynomial type in cspline' )
1335      ENDIF
1336
1337   END SUBROUTINE cspline
1338
1339
1340   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1341      !!----------------------------------------------------------------------
1342      !!                 ***  ROUTINE interp1  ***
1343      !!
1344      !! ** Purpose :   1-d linear interpolation
1345      !!
1346      !! ** Method  :   interpolation is straight forward
1347      !!                extrapolation is also permitted (no value limit)
1348      !!----------------------------------------------------------------------
1349      IMPLICIT NONE
1350      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1351      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1352      REAL(wp)             ::  zdeltx
1353      !!----------------------------------------------------------------------
1354
1355      zdeltx = xr - xl
1356      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1357        f = 0.5_wp * (fl + fr)
1358      ELSE
1359        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1360      ENDIF
1361
1362   END FUNCTION interp1
1363
1364
1365   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1366      !!----------------------------------------------------------------------
1367      !!                 ***  ROUTINE interp1  ***
1368      !!
1369      !! ** Purpose :   1-d constrained cubic spline interpolation
1370      !!
1371      !! ** Method  :  cubic spline interpolation
1372      !!
1373      !!----------------------------------------------------------------------
1374      IMPLICIT NONE
1375      REAL(wp), INTENT(in) ::  x, a, b, c, d
1376      REAL(wp)             ::  f ! value from the interpolation
1377      !!----------------------------------------------------------------------
1378
1379      f = a + x* ( b + x * ( c + d * x ) )
1380
1381   END FUNCTION interp2
1382
1383
1384   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1385      !!----------------------------------------------------------------------
1386      !!                 ***  ROUTINE interp1  ***
1387      !!
1388      !! ** Purpose :   Calculate the first order of deriavtive of
1389      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1390      !!
1391      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1392      !!
1393      !!----------------------------------------------------------------------
1394      IMPLICIT NONE
1395      REAL(wp), INTENT(in) ::  x, a, b, c, d
1396      REAL(wp)             ::  f ! value from the interpolation
1397      !!----------------------------------------------------------------------
1398
1399      f = b + x * ( 2._wp * c + 3._wp * d * x)
1400
1401   END FUNCTION interp3
1402
1403
1404   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1405      !!----------------------------------------------------------------------
1406      !!                 ***  ROUTINE interp1  ***
1407      !!
1408      !! ** Purpose :   1-d constrained cubic spline integration
1409      !!
1410      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1411      !!
1412      !!----------------------------------------------------------------------
1413      IMPLICIT NONE
1414      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1415      REAL(wp)             ::  za1, za2, za3
1416      REAL(wp)             ::  f                   ! integration result
1417      !!----------------------------------------------------------------------
1418
1419      za1 = 0.5_wp * b
1420      za2 = c / 3.0_wp
1421      za3 = 0.25_wp * d
1422
1423      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1424         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1425
1426   END FUNCTION integ_spline
1427
1428   !!======================================================================
1429END MODULE dynhpg
1430
Note: See TracBrowser for help on using the repository browser.